Named Groups

The Wolfram Language provides permutation representations for many important finite groups. Some of these groups are members of infinite families, parametrized by one or more integers; other groups are uniquely distinguished by their special properties and are frequently named after their discoverers.

This is the alternating group of degree 10:

group=AlternatingGroup[10]

Compute its order:

GroupOrder[group]

Give generators of an explicit permutation representation:

GroupGenerators[group]

From these generators it is possible to reconstruct the group explicitly:

PermutationGroup[%]

GroupOrder[%]

The Wolfram Language provides information on the following infinite families of groups, and on some groups not belonging to parametrized families.

Named infinite families of groups.

Mathieu Groups

The following five Mathieu groups were the first five sporadic simple groups to be discovered, in the second half of the nineteenth century, and are multiply transitive groups, all being subgroups of the largest one. The Wolfram Language provides default permutation representations for them.

Mathieu groups.

These are the orders of the five sporadic simple Mathieu groups:

GroupOrder/@{
MathieuGroupM11[],
MathieuGroupM12[],
MathieuGroupM22[],
MathieuGroupM23[],
MathieuGroupM24[]}

Explicit generators of a permutation representation of (RefLink[MathieuGroupM24, paclet:ref/MathieuGroupM24]) acting on 24 points:

group=MathieuGroupM24[];

GroupGenerators[group]

To show that (RefLink[MathieuGroupM24, paclet:ref/MathieuGroupM24]) is 5-transitive, check transitivity of the group itself and of its first four stabilizers:

GroupOrbits[group]

GroupOrbits[GroupStabilizer[group,{1}]]

GroupOrbits[GroupStabilizer[group,{1,2}]]

GroupOrbits[GroupStabilizer[group,{1,2,3}]]

GroupOrbits[GroupStabilizer[group,{1,2,3,4}]]

However, the stabilizer of five points is not transitive, because its action splits into two nontrivial orbits:

GroupOrbits[GroupStabilizer[group,{1,2,3,4,5}]]

These are the orders of the stabilizers of the points of a base in the group. They correspond to the groups (RefLink[MathieuGroupM24, paclet:ref/MathieuGroupM24]), (RefLink[MathieuGroupM23, paclet:ref/MathieuGroupM23]), (RefLink[MathieuGroupM22, paclet:ref/MathieuGroupM22]), and then three more groups sometimes called Mathieu group (Subscript[M, 21]), Mathieu group (Subscript[M, 20]), and Mathieu group (Subscript[M, 19]), which are not simple. Finally there is the cyclic group of order 3 and the trivial group:

GroupStabilizerChain[group]/.group_PermutationGroup:>GroupOrder[group]//Column

A similar chain is obtained starting from (RefLink[MathieuGroupM12, paclet:ref/MathieuGroupM12]). It contains (RefLink[MathieuGroupM11, paclet:ref/MathieuGroupM11]) and non-simple groups that can be called Mathieu group (Subscript[M, 10]), Mathieu group (Subscript[M, 9]), and Mathieu group (Subscript[M, 8]), with the trivial group at the end:

GroupStabilizerChain[MathieuGroupM12[]]/.group_PermutationGroup:>GroupOrder[group]//Column

It is known that the largest permutation order in (RefLink[MathieuGroupM24, paclet:ref/MathieuGroupM24]) is 23. This is an example:

Cycles[{{1,2,16,5,21,10,13,18,11,15,3,7,17,8,9,24,22,14,19,6,20,12,4}}]

PermutationOrder[%]

GroupElementQ[group,%%]

Other Sporadic Simple Groups

There are 26 sporadic simple groups (27 if the Tits group is included). Apart from the five Mathieu groups, the Wolfram Language provides permutation representations for those of intermediate support length. The largest ones are too big to be handled as permutation groups in practice, and it is more efficient to represent them as matrix groups. These are the 13 groups (including the Tits group) for which representations on domains of less than 50000 points are known.

Intermediate sporadic simple groups.

Some sporadic groups are related to symmetries of the Leech lattice, a particular lattice in a Euclidean 24-dimensional space. These are sometimes known as the "second generation" of the sporadic simple groups.

The six groups of the second generation:

secondgeneration={
JankoGroupJ2[],
HigmanSimsGroupHS[],
McLaughlinGroupMcL[],
SuzukiGroupSuz[],
ConwayGroupCo3[],
ConwayGroupCo2[]};

Their group orders are as follows:

GroupOrder/@secondgeneration

And these are the permutation degrees of the provided representations:

Map[PermutationMax,GroupGenerators/@secondgeneration,{2}]

For example, these are generators for (RefLink[JankoGroupJ2, paclet:ref/JankoGroupJ2]) acting on 100 points:

GroupGenerators[JankoGroupJ2[]]

This is the last permutation in the group:

GroupElements[JankoGroupJ2[],{-1}]

And this is its corresponding list of images:

PermutationReplace[Range[100],First[%]]

This is a chain of stabilizers of (RefLink[ConwayGroupCo2, paclet:ref/ConwayGroupCo2]), acting on 2300 points. The base has six points only, and hence knowing the images of these six points suffices to uniquely identify each permutation in the group:

GroupStabilizerChain[ConwayGroupCo2[]]/.gr_PermutationGroup:>GroupOrder[gr]//Column

These are other sporadic simple groups representable as permutation groups on less than 50000 points:

othersporadic={
JankoGroupJ1[],
TitsGroupT[],
JankoGroupJ3[],
HeldGroupHe[],
RudvalisGroupRu[],
FischerGroupFi22[],
FischerGroupFi23[]};

Their orders and degrees are as follows:

Rule[#,GroupOrder[#]]&/@othersporadic//Column

Map[PermutationMax,GroupGenerators/@othersporadic,{2}]

Large sporadic simple groups.

Finally, the remaining sporadic groups and their orders are as follows:

largesporadic={
ONanGroupON[],
HaradaNortonGroupHN[],
ConwayGroupCo1[],
FischerGroupFi24Prime[],
ThompsonGroupTh[],
JankoGroupJ4[],
LyonsGroupLy[],
BabyMonsterGroupB[],
MonsterGroupM[]
};

Rule[#,GroupOrder[#]]&/@largesporadic//Column