Insetting Objects in Graphics

"Redrawing and Combining Plots" describes how you can make regular arrays of plots using (RefLink[GraphicsGrid, paclet:ref/GraphicsGrid]). Using the (RefLink[Inset, paclet:ref/Inset]) graphics primitive, however, you can combine and superimpose plots in any way.

Creating an inset.

Here is a plot:

p1=Plot[{Sin[x],Sin[2x]},{x,0,2π},ImageSize->200,Frame->True,Background->LightYellow]

This creates a plot within a parametric plot:

ParametricPlot[{Sin[x],Sin[2x]},{x,0,4π},Epilog->Inset[p1,{.3,-.5}]]

Here is a three-dimensional plot:

p3=Plot3D[Sin[x] Exp[y],{x,-5,5},{y,-2,2}]

This creates a two-dimensional graphics object that contains two differently sized copies of the three-dimensional plot:

Graphics[{Inset[p3,-{1,1},Center,{2,2}],Inset[p3,{.5,.5},Center,{3,3}]},PlotRange->2]

Here are rotated and skewed plots inset in a graphic:

Graphics[{
Inset[p1,{1,0},Center,{1,1},{1,1}],
Inset[p1,{2,0},Center,{1,1},{{1,0},{1,1}}]
}]

The Wolfram Language can render plots, arbitrary 2D or 3D graphics, cells, and text within an (RefLink[Inset, paclet:ref/Inset]). Notice that in general the display area for graphics objects will be sized so as to touch at least one pair of edges of the (RefLink[Inset, paclet:ref/Inset]).