sol = DSolve[y'[x]+5y[x]==1, y[x],x]

m =sol[[1]]

y[x]/.m

y'[x]/.m

y[1]/.m

sol = DSolve[y'[x]+5y[x]==1, y,x]

m= sol[[1]]

y[x]/.m

y'[x]/.m

y[1]/.m

sol=DSolve[y'[x]^2 == x+11, y,x]

y[x]/.sol[[1]]

y[x]/.sol[[2]]

y[x]/.sol

sol=DSolve[{x'[t]==y[t]+z[t], y'[t]+z[t]-x[t]==0, z'[t] +y[t]==x[t]}, {x,y,z},t]

{x[t], y[t],z[t]}/.sol[[1]]//Simplify

DSolve[{y''[x] +y[x]==5, y[0]==1, y'[0]==7}, y[x],x]

DSolve[{y''[x] +y[x]==5, y[0]==1}, y[x],x]

DSolve[D[u[x,y], x] + Sin[x]*D[u[x,y],y]==8, u, {x,y}]

DSolve[{x'[t] +y[t]==Sin[t], x[t]+y[t]==1, x[0]==4}, {x,y},t]

sol=DSolve[y'[x]+y[x]^3+y[x]^2==1,y[x],x]

sol[[1]]

sol=DSolve[Derivative[2][y][x] + y[x]*Derivative[1][y][x]^4 == 0, y, x]

soly= y[x]/.sol[[1]]

implicitequation =( Head[soly][[1]][y[x]]==soly[[1]] )

eqn = y'[x]== x;

sol = DSolve[eqn, y,x]

eqn/.sol

eqn = {y'[x]== x, y[0]==1};

sol = DSolve[eqn, y,x]

eqn/.sol

eqn =y''[x] +5*y'[x] +6y[x]==1;

sol=DSolve[eqn, y,x]

eqn/.sol

Simplify[eqn/.sol]

PDE =D[u[x,y], x] + Sin[x]*D[u[x,y],y]==x^2;

sol=DSolve[PDE, u, {x,y}]

Simplify[PDE/.sol]

eqn = x*y''[x] + y'[x]-y[x]==1;

sol=DSolve[eqn, y,x]

FullSimplify[eqn/.sol]

Clear[a,y,x, r]

eqn = y''[x] - (a*x^6+x^2)*y[x];

sol=DSolve[eqn==0,y,x]

Union[Flatten[Table[Chop[eqn/.sol/. {x-> RandomReal[], a-> RandomReal[], (C[1])-> RandomReal[], (C[2])-> RandomReal[]}], {i,1,10}]]]

Chop[eqn/.sol/. {x-> RandomReal[ {1,2},WorkingPrecision ->20], a-> RandomReal[ {1,2}, WorkingPrecision ->20], (C[1])->RandomReal[ {1,2}, WorkingPrecision ->20] , (C[2])-> RandomReal[ {1,2}, WorkingPrecision ->20]}]

r:=RandomComplex[]

Chop[N[eqn/.sol/. {x-> r, a->r , (C[1])->r , (C[2])-> r}]]

eqn= y'[x]+2*x ((y[x])^2)+ ((y[x])^3);

sol=DSolve[eqn==0,y,x]

sol[[1]]

Simplify[Solve[D[sol[[1]],x], y'[x]]]

sol = DSolve[y'[x] +x*y[x]==Cos[x^2],y, x]

Plot[Evaluate[y[x]/.sol/. {(C[1]) -> 1}], {x,-7, 7}, PlotRange -> All]

sol=DSolve[{y''[x]/y[x]==-4* Exp[-x/4], y[0]==1, y'[0]==1/2},y,x]

Plot[Evaluate[y[x]/.sol], {x,0,30}]

sol = DSolve[{y'[x]^2==x-x^3, y[0]==1}, y,x]

Plot[Evaluate[y[x]/.sol], {x,1/100,9/10}]

sol=DSolve[y'[x]==-5 ((y[x])^2)-(((y[x])^3)/x),y[x],x]

expr=(C[1])/.Solve[sol[[1]], (C[1])][[1]]/.{y[x] -> y}

ContourPlot[expr, {x,-0.4,-0.1}, {y,1.,1.8}]

sol = DSolve[{x'[t]+t*y[t]==0, 2y'[t] -3x[t]==0, x[0]==1, y[0]==3}, {x,y},t]

Plot[Evaluate[{x[t], y[t]}/.sol], {t,-1,10}, WorkingPrecision -> 20]

ParametricPlot[Evaluate[{x[t],y[t]}/.sol], {t,-1,7}, WorkingPrecision -> 20]

sol = DSolve[{x''[t]+3*y[t] == UnitStep[t], x[t]-5*y[t]==t^2, x[0]==1, x'[0]==1}, {x,y},t]

Plot[Evaluate[{x[t],y[t], x[t]-5*y[t]}/.sol], {t,-2,2}]

sol=DSolve[D[u[x,y],x]+x^2*D[u[x,y],y]==Exp[x], u, {x,y}]

Plot3D[Evaluate[u[x,y]/.sol/.{(C[1])[t_]-> Sin[3*t]}[[1]]], {x,-2,2},{y,-2,2}, Mesh -> False]

DSolve[y'[x] +y[x]== 1, y[x],x]

DSolve[y'[x] +y[x]== 1, y[x],x, GeneratedParameters -> P]

parameter =C[#]&;

indexset = {1,2,3,4};

parameter[indexset[[1]]]

parameter[indexset[[3]]]

DSolve[y''[x] +y[x]== 1, y[x],x, GeneratedParameters -> (const[#]&)]

DSolve[y''[x] +y[x]== 1, y[x],x, GeneratedParameters -> (const[1+#]&)]

DSolve[y''[x] +y[x]== 1, y[x],x, GeneratedParameters ->((Subscript[c, #1])&)]

DSolve[y''[x] +y[x]== 1, y[x],x, GeneratedParameters -> Module[{C}, C[#]&]]

DSolve[y''[x] +y[x]== 1, y[x],x, GeneratedParameters -> Module[{C}, C[#]&]]

DSolve[y''[x] -8*x*y[x] ==0, y,x]

sol=DSolve[{y''[x] +k^2*y[x] == x^2, y[0]==3k+1, y'[0]==k}, y,x]

Plot[Evaluate[Table[y[x]/.sol/.{k-> i}, {i,1,5, 2}]], {x,-7,7}]

eqn=y''[x] - c*x^a*y[x] ;

sol=DSolve[eqn==0, y, x]

sol1=y[x]/.sol[[1]]/. {a -> 0, c-> 4}

sol=DSolve[{y'[x] ==x, y[0]==1/a}, y,x]

sol=DSolve[{y'[x] ==x, y[0]==k}, y,x]

exactpi = Pi;

Precision[exactpi]

(machinepi = N[Pi])//InputForm

Precision[machinepi]

highprecisionpi = N[Pi, 30]

Precision[highprecisionpi]

DSolve[x'[t]==3. x[t], x, t]

DSolve[x'[t]==3.`40* x[t], x, t]

n=8;
(Subscript[x, 0])[t_]:=0;
(Subscript[x, n])[t_]:=1;
eqns = Table[{(Subscript[x, i])'[t] - ( (Subscript[x, i+1])[t] - 2 (Subscript[x, i])[t] + (Subscript[x, i-1])[t]), (Subscript[x, i])[0] - (1/n)},{i,n-1}];
vars = Table[(Subscript[x, i]),{i,n-1}];
sol=DSolve[Map[#==0&,Flatten[eqns]],vars,t];//Timing

LeafCount[sol]

eqns/.sol/. {t-> RandomReal[ {0,1}, WorkingPrecision -> 200]}//N//Chop//Flatten//Union

n=8;
(Subscript[x, 0])[t_]:=0.;
(Subscript[x, n])[t_]:=1;
eqns = Table[{(Subscript[x, i])'[t] - ( (Subscript[x, i+1])[t] - 2 (Subscript[x, i])[t] + (Subscript[x, i-1])[t]), (Subscript[x, i])[0] - (1/n)},{i,n-1}];
vars = Table[(Subscript[x, i]),{i,n-1}];
sol=DSolve[Map[#==0&,Flatten[eqns]],vars,t];//Timing

LeafCount[sol]

eqns/.sol/. {t-> RandomReal[ {0,1}] }//N[#]&//Chop//Flatten//Union

DSolve[{x'[t]==0.0001*x[t], x[0]==3.07}, x[t], t]

DSolve[Rationalize[{x'[t]==0.0001*x[t], x[0]==3.07}, 0], x[t], t]

DSolve[y'[x] ==1-y[x], y,x]

eqns ={y'[x] ==1 -y[x], y[3]==5};

sol = DSolve[eqns, y,x]

eqns/.sol

generalsol = DSolve[{y'[x] == 1/y[x]}, y,x]

Plot[Evaluate[y[x]/.generalsol/.{(C[1]) -> 1}], {x,-1,3}]

DSolve[{y'[x] == 1/y[x], y[0]==1}, y,x]

DSolve[{y''[x]+y[x]==0, y[0]==1, y[Pi]==3}, y[x],x]

eqn=y'[x]==y[x]^(1/2);

sol=DSolve[{eqn, y[0]==1}, y,x]

Table[eqn/.sol/.{x-> i}, {i, 0,5}]

DSolve[y'[x] ==1/(x-y[x])&&y[0]==1, y,x]

DSolve[x'[y] ==(x[y]-y)&&x[1]==0, x,y]