sol=DSolve[y'[x] ==x^2*Sin[x]+Sqrt[1+x^2], y,x]

tab=Table[y[x] /.sol[[1]] /.{(C[1]) -> k}, {k, -80, 80, 40}];

Plot[Evaluate[tab], {x, 3, 18}]

DSolve[y'[x]==(((x^2) y[x]^2)/(Sqrt[3-(x^2)])),y,x]

DSolve[y'[x]==(((x^2) Exp[y[x]])/(Sqrt[3-(x^2)])),y,x]

sol=DSolve[y'[x]==(((x^2) )/((Sqrt[9-(x^2)])Log[y[x]]*Sin[y[x]])),y[x],x]

eqn=y'[x]==-(x^2-3y[x]^2)/(x*y[x]);
sol=DSolve[eqn,y,x]

tab1=Table[y[x]/.sol[[1]]/.(C[1])-> k, {k,0,3, 0.5}];

tab2=Table[y[x]/.sol[[2]]/.(C[1])-> k, {k,0,3, 0.5}];

Plot[Evaluate[Join[tab1,tab2]], {x,0,1.7}]

DSolve[{eqn, y[1]==3}, y[x],x]

DSolve[y'[x] + x*y[x] == Exp[3x], y[x],x]

sol=DSolve[y'[x] + y[x] == Q[x], y[x],x]

sol/.{K[1]->t}

DSolve[y'[x]== 1/(-x*y[x] +Exp[3*y[x]]), y[x],x]

eqn=y'[x]+11x*y[x]==x^3*y[x]^3

sol=DSolve[eqn, y,x]

eqn/.sol//Simplify

DSolve[3x*y'[x] -7x*Log[x]*y[x]^5-y[x]==0, y[x],x]

DSolve[y'[x] +(2/x^2)-3y[x]^2==0, y[x], x]//Simplify

DSolve[u'[x]==((2x)/(1-x^2))*u[x]-((15/4)/(1-x^2))-u[x]^2, u[x],x]//Simplify

DSolve[(1-x^2)*y''[x] -2x*y'[x] +(15/4)*y[x]==0, y[x],x]

eqn=y'[x]== 3x+5*y[x]-(3x+5)*y[x]^2;

RightHandSideCoeffs = {3x, 5,-(3x+5)};

Total[RightHandSideCoeffs ]

sol=DSolve[eqn, y,x]

eqn/.sol//Simplify

P[x_,y_]:=-(5x^2-2y^2+11)

Q[x_,y_]:=(Sin[y]+4x*y+3)

Simplify[D[P[x,y],y] -D[Q[x,y],x]]

eqn=y'[x]==-P[x,y[x]]/Q[x,y[x]]

sol=DSolve[eqn, y[x],x]

Solve[D[sol[[1]],x], y'[x]]//Simplify

ContourPlot[Evaluate[sol[[1,1]]/.{y[x]-> y}], {x,-5,5}, {y,-5,5}]

sol=DSolve[y[x]==x*y'[x] +y'[x]^2 + Exp[y'[x]] ,y[x],x]

Plot[Evaluate[Table[y[x]/.sol/.{(C[1])-> 1/k}, {k,-5,5,2}]], {x,1,5}]

f0=0;f1=(1/x);f2=-3;f3=x;

Invariant=f0 (f3^2)+(1/3) (((2 (f2^3))/9)-f1 f3 f2-(∂_x)f3 f2+f3 (∂_x)f2)

AbelODE=y'[x]==f0+f1 y[x]+f2 ((y[x])^2)+f3 ((y[x])^3)

sol=DSolve[AbelODE, y,x]

AbelODE/.sol//Simplify

Clear[f0,f1,f2,f3]

DSolve[y'[x]==((y[x])^3)-((x ((y[x])^2))/(x-1)),y[x],x]

AbelODE=y'[x]==(((y[x])^3)/(8 (x^2)))-((y[x])^2)

sol=DSolve[AbelODE,y[x],x]

Solve[D[sol[[1]],x],y'[x]]//FullSimplify

sol=DSolve[y'[x]==((-((2x)/9)+ x^3+y[x])/(y[x])),y[x],x]

Solve[D[sol[[1]],x],y'[x]]//FullSimplify

DSolve[y'[x]==5*y[x]^4+ 3*x^(-4/3), y[x],x]

sol=DSolve[y''[x] +5*y'[x]-6y[x] ==0, y,x]

sol1= y[x]/.sol[[1]]/.{(C[1])-> 2, (C[2])->3}

Solve[m^2+5m-6==0, m]

sol=DSolve[y''[x] - 6 y'[x] +9y[x]==0, y, x]

sol2= y[x]/.sol[[1]]/.{(C[1])-> 2, (C[2])-> 3}

sol=DSolve[y''[x] - y'[x] +y[x]==0, y, x]

sol3= y[x]/.sol[[1]]/.{(C[1])-> 2, (C[2])-> 3}

Plot[{sol1, sol2, sol3}, {x,-0.5, 0.5}]

DSolve[x^2*y''[x] +5*x*y'[x]+6*y[x]==0, y[x],x]

DSolve[(3x+1)^2*y''[x] +5*(3x+1)*y'[x]+6*y[x]==0, y[x],x]

a0=1;

a1=Log[x];

a2=1/x;

eqn=a0*y''[x]+a1*y'[x]+ a2*y[x]==0;

conditionforexactness = (D[a0, {x,2}]-D[a1,x]+a2==0)

sol=DSolve[eqn, y,x]

eqn/.sol//FullSimplify

Clear[a0,a1,a2]

DSolve[y''[x]-x*y[x]==0, y[x],x]

Plot[{AiryAi[x],AiryBi[x]},{x,-15,-12}]

DSolve[ ((a*x+b ))*y''[x]-a*y'[x] -(a*(a*x+b))^2* y[x] == 0, y, x]

DSolve[x^2*y''[x] + x*y'[x] +(x^2-16)*y[x]==0, y[x],x]

Plot[{BesselJ[1,x], BesselJ[3,x], BesselJ[4,x]}, {x,0,10}]

DSolve[16(1-x^2)*y''[x]-32x*y'[x]+21*y[x]==0, y[x],x]

{BesselJ[1/2,x], LegendreP[4,x], HermiteH[5,x]}

DSolve[y''[x]-2x*y'[x]+2n*y[x]==0, y[x],x]

Collect[Simplify[PowerExpand[y[x]/.DSolve[y''[x]-2*x*y'[x]+10*y[x]==0,y[x],x][[1]]]],{(C[1]),(C[2])}]

DSolve[(x^2-x)*y''[x]+ ((a+b+1)*x-c)*y'[x]+b*a*y[x]==0, y[x], x]

sol=DSolve[64 (x^2) (((x-1))^2) y''[x]+32 x (x-1) (3 x-1) y'[x]+(5x-21) y[x]==0,y,x]

64 (x^2) (((x-1))^2) y''[x]+32 x (x-1) (3 x-1) y'[x]+(5x-21) y[x]/. sol[[1]]/.{x-> RandomComplex[]}//Simplify//Chop

sol=Simplify[PowerExpand[y[x]/.DSolve[Derivative[2][y][x]+(a*x^(2*c)+b*x^(c-1))*y[x]==0,y,x][[1]]]]

DSolve[x*y''[x] +(10x^3-1)*y'[x] +5x^2(5x^3+1)*y[x]==0, y[x],x]

DSolve[4x*y''[x] +(7x+12)*y'[x] +21y[x]==0, y[x],x]

sol =DSolve[y''[x]- (x^(2 ))y'[x]-y[x]-1==0&& y[0]==0 && y'[0]==-1, y, x]

Table[y[x]/.sol[[1]],{x,-1,1,0.4}]

Plot[y[x]/.sol[[1]],{x,-1,1}]

DSolve[y''[x]-Exp[5x]*y[x]==0,y,x]

DSolve[y''[x]*Sin[x]*Cos[x]^2 - y'[x]*(3*Sin[x]^2 + 1)*Cos[x] - y[x]*Sin[x]^3 == 0, y, x]

DSolve[y''[x] + (k^2 + 2*Sech[x]^2)y[x] == 0, y[x], x]

expr=y''[x]+ (-d+d(1-Exp[-b x])^2) y[x] -l y[x];

sol=DSolve[expr==0,y, x]

expr/.sol[[1]]/.{x-> RandomComplex[], b-> RandomComplex[], d-> RandomComplex[], l-> RandomComplex[]}//Simplify//Chop

sol=DSolve[x^2y''[x]+y[x]==x^2, y[x],x]

DSolve[x^2y''[x]+y[x]==0, y[x],x]

particularsolutions= Flatten[Table[y[x]/.sol/.{(C[1])-> i, (C[2])-> j}, {i,0,5,3}, {j,1,3}]]

Plot[Evaluate[particularsolutions], {x,0.1,2} ]

eqn=y''[x]==5 x y'[x]+((y'[x])^2);sol=DSolve[eqn,y,x]

Plot[Evaluate[y[x]/.sol/. {(C[1])-> -1/2, (C[2])-> -1/8}], {x,-0.4,1}]

eqn/.sol//Simplify

DSolve[y''[x] == Exp[3*y[x]], y[x],x]

sol = y[x]/.DSolve[y''[x] ==3*y[x]*y'[x] +(3y[x]^2+4*y[x] +1), y[x],x][[1]]//Simplify

DSolve[7*y[x]*y''[x] -11*y'[x]^2==0, y[x], x]

eqn=y''[x] +y[x]* y'[x]^2-x^2*y'[x]==0;

sol=DSolve[eqn, y[x], x]

DSolve[y'''[x] -4*y''[x]-25*y'[x]+28*y[x]==0, y[x], x]

DSolve[y''''[x] -16*y'''[x]+94*y''[x]-240*y'[x] +225*y[x]==0, y[x],x]

DSolve[y''''[x] -10*y'''[x]+54*y''[x]-130*y'[x]+125*y[x]==0, y[x],x]

DSolve[y'''''[x] -17*y''''[x]+108*y'''[x]-330*y''[x]+488*y'[x]-280*y[x]==0, y[x],x]

DSolve[x^4*y''''[x] -2*x^3*y'''[x] -x^2*y''[x] +5*x*y'[x]+y[x]==0, y[x],x]

DSolve[(3x+5)^4*y''''[x] -2*(3x+5)^3*y'''[x] -(3x+5)^2*y''[x] +5*(3x+5)*y'[x]+y[x]==0, y[x],x]

a0 = 1;

a1=-1 ;

a2=5x;

a3=5;

ExactODE=a0*y'''[x] +a1*y''[x]+a2*y'[x]+a3*y[x]

conditionforexactness= -D[a0, {x,3}]+D[a1,{x,2}]-D[a2,x]+a3

sol=DSolve[ExactODE==0, y,x]

ExactODE/.sol[[1]]/. {x-> RandomReal[],(C[1])-> RandomReal[], (C[2])-> RandomReal[]}//N//Simplify//Chop

Clear[a0,a1,a2,a3]

sol1=DSolve[y'''[x] -4*(x + 2)*y'[x] - 2*y[x] == 0, y, x]

sol2=DSolve[x^3*y'''[x]+ 3*x^2*y''[x]+(4x^3-11x)*y'[x]+4x^2*y[x] == 0, y, x]

Show[{Plot[y[x]/.sol1/.{(C[1])->2,(C[2])->3,(C[3])->1},{x,-10,-4},PlotStyle->{Red}],Plot[y[x]/.sol2/.{(C[1])->2,(C[2])->3,(C[3])->1},{x,2,10},PlotStyle->{Dashing[{0.02}],Blue}]}, PlotRange->{{-10,10},Automatic}]

HypergeometricPFQTypeEquation=30*x^3*y''''[x]+193*x^2*y'''[x]+(219*x-30x^2)*y''[x]+(21-90x)*y'[x]-30y[x];

sol3=DSolve[HypergeometricPFQTypeEquation==0, y,x]

HypergeometricPFQTypeEquation/.sol3[[1]]/.{x-> RandomComplex[]}//Simplify//Chop

DSolve[((6 - 24*x + 4*x^2 - 10*x^3 + 9*x^4 - 4*x^5 + x^6)*y[x])/ ((-1 + x)^4*x^2) + ((-8 + 30*x - 10*x^2 + 10*x^3 - 3*x^4 - 2*x^5 + x^6)*Derivative[1][y][x])/((-1 + x)^3*x^2) + ((4 - 16*x + 5*x^2 - 2*x^3)*Derivative[2][y][x])/ ((-1 + x)^2*x^2) + ((4 - x^2)*Derivative[3][y][x])/ ((-1 + x)*x) == 0, y, x]

sol=DSolve[y'''[x] -13*y''[x]+19*y'[x]+33*y[x]== Cos[2x], y[x], x]

generalsolution = y[x]/.DSolve[y'''[x] -13*y''[x]+19*y'[x]+33*y[x]== 0, y[x], x][[1]]

particularsolution = (y[x]/.sol[[1]]) -generalsolution

DSolve[7*y'[x]*y'''[x]-11*y''[x]^2==0, y[x],x]

A={{4,-6},{1,-1}};

Eigenvalues[A]

X[t_] = {x[t], y[t]};

system=X'[t]==A.X[t];

sol=DSolve[system, {x,y},t]

particularsols=Partition[Flatten[Table[{x[t], y[t]}/.sol/.{(C[1]) -> 1/i, (C[2])-> 1/j}, {i,-20,20, 6}, {j,-20,20, 6}]], 2];

ParametricPlot[Evaluate[particularsols], {t,-3,3}, PlotRange -> {-2,2}]

A={{7,-8},{5,-5}};

Eigenvalues[A]

X[t_] = {x[t], y[t]};

system=X'[t]==A.X[t];

sol=DSolve[system, {x,y},t]

particularsols=Partition[Flatten[Table[{x[t], y[t]}/.sol/.{(C[1])-> 1/i, (C[2])-> 1/j}, {i,-10,10, 8}, {j,-10,10, 8}]], 2];

ParametricPlot[Evaluate[particularsols], {t,-35,35}, PlotRange -> All, PlotPoints -> 70, Method->{Compiled -> False}]

system={x'''[t]+ y[t], y'''[t]-64 x[t]};

sol=DSolve[{system[[1]]==0, system[[2]]==0}, {x,y},t]

system/.sol[[1]]/.{t-> RandomComplex[], (C[1])-> RandomComplex[], (C[2])-> RandomComplex[], (C[3])-> RandomComplex[], (C[4])-> RandomComplex[], (C[5])-> RandomComplex[], (C[6])-> RandomComplex[]}//Chop//Quiet

DSolve[{x'[t]==Sin[t]*x[t], y'[t]==t^2*y[t]}, {x,y},t]

A={{E^t, Tan[t]}, {-Tan[t], E^t}};

A.Transpose[A]/Det[A]

X[t_] = {x[t], y[t]};

system=X'[t]==A.X[t];

sol=DSolve[system,{x,y},t]

system/.sol[[1]]//Simplify

A={{E^t, 2, 3}, {0, 2,-1}, {0,0,1}};

MatrixForm[A]

X[t_] = {x[t], y[t], z[t]};

system=X'[t]==A.X[t];

sol=DSolve[system, {x,y,z},t]

DSolve[{y'[x]==(((5+x) w[x])/((-3-2 x+(x^2)) (-1+(x^3))))+(((6+2 x-3 (x^3)-(x^5)) y[x])/(x (-3-2 x+(x^2)) (-1+(x^3)))),w'[x]==(((1+20 (x^2)+3 (x^3)) w[x])/((5+x) (-1+(x^3))))-((4 x (-3-2 x+(x^2)) y[x])/((5+x) (-1+(x^3))))},{y,w},x]

system={x'[t]==(2*((-9+t+t^2)*x[t]+(-6+t^2)*y[t]))/((-2+t)*t),y'[t]==(-3*(-12+2*t+t^2)*x[t]+(24-2*t-3*t^2)*y[t])/((-2+t)*t), z'[t]==t*z[t]};

sol=DSolve[system,{x,y,z},t]

system/.sol//Simplify

A={{7,-8}, {5,-5}};

B={E^(t/10),t};

X[t_] = {x[t], y[t]};

system=X'[t]==A.X[t]+B;

sol=DSolve[system, {x,y},t]

particularsol = {x[t], y[t]}/.sol[[1]]/.{(C[1])-> -1, (C[2])-> 2};

Plot[Evaluate[particularsol], {t,0,Pi}]

system={p'[x] == 1,q'[x] == x, r'[x] == 0, s'[x] == r[x]/(p[x] + 4*q[x]*r[x])};

sol=DSolve[system, {p,q,r,s}, x]

system/.sol//Simplify

system={u'[x]==1/Sqrt[v[x]], v'[x] ==u[x]};

sol=DSolve[system, {u,v},x][[1]]

system/.sol//Simplify//PowerExpand//Simplify

m = x*Cos[t] +y*Sin[t];

n = -x*Sin[t] + y*Cos[t];

Show[{Graphics[{{Red, PointSize[0.04],Point[{3*Cos[1/4], 3*Sin[1/4]}]},{Blue, PointSize[0.04],Point[{3*Cos[(1/4)+(Pi/3)], 3*Sin[(1/4)+(Pi/3)]}]},{Green,Line[{{0,0}, {3*Cos[1/4], 3*Sin[1/4]}}]},{Green,Line[{{0,0}, {3*Cos[(1/4)+(Pi/3)], 3*Sin[(1/4)+(Pi/3)]}}]}}],ParametricPlot[{3*Cos[t], 3*Sin[t]}, {t, 0,2Pi}, DisplayFunction -> Identity ]},AspectRatio ->1, ImageSize -> 200, Axes -> True]

M[t_]:={{Cos[t],Sin[t]},{-Sin[t],Cos[t]}}

Simplify[M[a+b]==M[a].M[b]]

M[a].M[0]==M[0].M[a]==M[a]

M[0]==IdentityMatrix[2]

M[a].M[-a]==M[-a].M[a]==IdentityMatrix[2]//Simplify

Series[m , {t, 0, 1}]//Normal

Series[n , {t, 0, 1}]//Normal

v = (y*D[#, x] - x*D[#, y])&;

DSolve[{x'[t] == y[t], y'[t] ==-x[t]}, {x[t],y[t]},t]

invariant = x^2 +y^2;

v[invariant]

Riccatiequation = y'[x] +y[x]^2- 1/x^2==0;

m = x*E^t;

n =y*E^(-t);

Series[m, {t, 0,1}]//Normal

Series[n, {t, 0,1}]//Normal

v= (x*D[#, x] -y*D[#, y])&;

prolongedv = (x*D[#, x] -y*D[#, y] -2p*D[#, p] )&;

Riccatiexpression =p+y^2-(1/x^2);

prolongedv[Riccatiexpression]/.{p-> (1/x^2)-y^2}//Together

FirstOrderODE=x*y'[x]==y[x]*(x*Log[x^2/y[x]]+2);

v= (-2*Exp[-x]*y)*D[#, y]&;

sol=DSolve[FirstOrderODE, y,x]

FirstOrderODE/.sol[[1]]/. {x-> RandomReal[], (C[1])-> RandomReal[]}//Simplify//Chop

SecondOrderODE = x^3*y''[x] == 6*(x*y'[x]- y[x])^2;

m= x*E^t;

n=y*E^t;

sol=DSolve[SecondOrderODE, y,x]

SecondOrderODE /.sol//Simplify

Clear[u,v]

NonlinearSystem = {u'[x]==Exp[v[x]]+1, v'[x] == u[x]-x};

sol=DSolve[NonlinearSystem, {u,v},x]

NonlinearSystem/.sol//Simplify

Clear[m,n,u,v]