Finding symbolic solutions to ordinary differential equations.

DSolve[{y'[x]==y[x]}, y[x], x]

y[x]/.DSolve[{y'[x]==y[x]}, y[x], x]

sol=DSolve[{y'[x]==y[x], y[0]==1}, y[x], x]

Plot[y[x]/.sol,{x,-3,2}]

Finding symbolic solutions to ordinary differential equations as pure functions.

eqn = {y'[x]==y[x]^2, y[0]==1};
sol= DSolve[eqn, y, x]

eqn/.sol

eqns={(t^2+1)*x'[t]==-t*x[t]+y[t]-Sign[t], (t^2+1)*y'[t]==-x[t]-t*y[t]+t*UnitStep[t], x[0]==-1/2, y[0]==2};
sol=DSolve[eqns, {x,y},t]

eqns/.sol/.{t-> RandomReal[]}

Plot[{x[t]/.sol, y[t]/.sol}, {t,-10,10}]

Finding symbolic solutions to partial differential equations.

eqn=x^2*D[u[x,y],x]+y^2*D[u[x,y],y]-(x+y)*u[x,y];
sol=DSolve[eqn==0, u, {x,y}]

fn=u[x,y]/.sol[[1]]/.{(C[1])[t_]-> Sin[t^2] +(t/10)}

Plot3D[fn, {x,-5,5}, {y,-5,5}]

eqns = {f''[x] == g[x], f[x] + g[x] == 3 Sin[x], f[Pi] == 1, f'[Pi] == 0}; 
sol = DSolve[eqns, {f, g}, x]

Simplify[eqns/.sol]

Plot[{f[x]/.sol, g[x]/.sol, f[x]+g[x]/.sol}, {x,-5,5}]