Contexts

It is always a good idea to give variables and functions names that are as explicit as possible. Sometimes, however, such names may get inconveniently long.

In the Wolfram Language, you can use the notion of "contexts" to organize the names of symbols. Contexts are particularly important in Wolfram Language packages that introduce symbols whose names must not conflict with those of any other symbols. If you write Wolfram Language packages, or make sophisticated use of packages that others have written, then you will need to know about contexts.

The basic idea is that the full name of any symbol is broken into two parts: a context and a short name. The full name is written as context`short, where the ` is the backquote or grave accent character (ASCII decimal code 96), called a "context mark" in the Wolfram Language.

Here is a symbol with short name x, and context aaaa:

aaaa`x

You can use this symbol just like any other symbol:

%^2-%

You can for example define a value for the symbol:

aaaa`x=78

The Wolfram Language treats a`x and b`x as completely different symbols:

a`x==b`x

It is typical to have all the symbols that relate to a particular topic in a particular context. Thus, for example, symbols that represent physical units might have a context PhysicalUnits`. Such symbols might have full names like PhysicalUnits`Joule or PhysicalUnits`Mole.

Although you can always refer to a symbol by its full name, it is often convenient to use a shorter name.

At any given point in a Wolfram Language session, there is always a current context (RefLink[$Context, paclet:ref/$Context]). You can refer to symbols that are in this context simply by giving their short names, unless the symbol is shadowed by the symbol with the same short name on the (RefLink[$ContextPath, paclet:ref/$ContextPath]). If a symbol with the given short name exists on the context path, it will be used instead of the symbol in the current context.

The default context for Wolfram Language sessions is Global`:

$Context

No symbols with the name x exist on (RefLink[$ContextPath, paclet:ref/$ContextPath]), so the short name is sufficient to refer to the symbol in the current context:

{x,Global`x}

Contexts in the Wolfram Language work somewhat like file directories in many operating systems. You can always specify a particular file by giving its complete name, including its directory. But at any given point, there is usually a current working directory, analogous to the current Wolfram Language context. Files that are in this directory can then be specified just by giving their short names.

Like directories in many operating systems, contexts in the Wolfram Language can be hierarchical. Thus, for example, the full name of a symbol can involve a sequence of context names, as in (Subscript[c, 1]) (Subscript[`c, 2]) (Subscript[`c, 3]) `name.

Specifying symbols in various contexts.

Here is a symbol in the context a`b`:

a`b`x

When you start a Wolfram Language session, the default current context is Global`. Symbols that you introduce will usually be in this context. However, built-in symbols such as (RefLink[Pi, paclet:ref/Pi]) are in the context System`.

In order to let you easily access not only symbols in the context Global`, but also in contexts such as System`, the Wolfram Language supports the notion of a context search path. At any point in a Wolfram Language session, there is both a current context (RefLink[$Context, paclet:ref/$Context]), and also a current context search path (RefLink[$ContextPath, paclet:ref/$ContextPath]). The idea of the search path is to allow you to type in the short name of a symbol, then have the Wolfram Language search in a sequence of contexts to find a symbol with that short name.

The context search path for symbols in the Wolfram Language is analogous to the "search path" for program files provided in operating systems. Since (RefLink[$Context, paclet:ref/$Context]) is searched after (RefLink[$ContextPath, paclet:ref/$ContextPath]), you can think of it as having "." appended to the file search path.

The default context path includes the contexts for system-defined symbols:

$ContextPath

When you type in (RefLink[Pi, paclet:ref/Pi]), the Wolfram Language interprets it as the symbol with full name System`Pi:

Context[Pi]

Finding contexts and context search paths.

When you use contexts in the Wolfram Language, there is no reason that two symbols that are in different contexts cannot have the same short name. Thus, for example, you can have symbols with the short name Mole both in the context PhysicalUnits` and in the context BiologicalOrganisms`.

There is, however, then the question of which symbol you actually get when you type in only the short name Mole. The answer to this question is determined by which of the contexts comes first in the sequence of contexts listed in the context search path.

This introduces two symbols, both with short name Mole:

{PhysicalUnits`Mole,BiologicalOrganisms`Mole}

This adds two additional contexts to (RefLink[$ContextPath, paclet:ref/$ContextPath]). Typically, the Wolfram Language adds new contexts to the beginning of (RefLink[$ContextPath, paclet:ref/$ContextPath]):

$ContextPath=Join[{"PhysicalUnits`","BiologicalOrganisms`"},$ContextPath]

Now if you type in Mole, you get the symbol in the context PhysicalUnits`:

Context[Mole]

In general, when you type in a short name for a symbol, the Wolfram Language assumes that you want the symbol with that name whose context appears earliest in the context search path. As a result, symbols with the same short name whose contexts appear later in the context search path or symbols with the same short name in the current context are effectively "shadowed". To refer to these symbols, you need to use their full names.

The Wolfram Language issues a message when you introduce new symbols that "shadow" existing symbols with your current choice for (RefLink[$ContextPath, paclet:ref/$ContextPath]). In addition, in the notebook front end the Wolfram Language warns you of shadowed symbols by coloring them red.

This introduces a symbol with short name Mole in the context Global`:The Wolfram Language warns you that the new symbol shadows existing symbols with short name Mole:

Global`Mole

Now when you type in Mole, you get the symbol that appears first in the context path, PhysicalUnits`:

Context[Mole]

If you once introduce a symbol that shadows existing symbols, it will continue to do so until you either rearrange (RefLink[$ContextPath, paclet:ref/$ContextPath]), or explicitly remove the symbol. You should realize that it is not sufficient to clear the value of the symbol; you need to actually remove the symbol completely from the Wolfram Language. You can do this using the function (RefLink[Remove, paclet:ref/Remove])[s].

Clearing and removing symbols in the Wolfram Language.

This removes the symbol PhysicalUnits`Mole:

Remove[Mole]

Now if you type in Mole, you get the symbol BiologicalOrganisms`Mole:

Context[Mole]

When the Wolfram Language prints out the name of a symbol, it has to choose whether to give the full name, or just the short name. What it does is to give whatever version of the name you would have to type in to get the particular symbol, given your current settings for (RefLink[$Context, paclet:ref/$Context]) and (RefLink[$ContextPath, paclet:ref/$ContextPath]).

The short name is printed for the first symbol, so this would give that symbol if you typed it in:

{BiologicalOrganisms`Mole,Global`Mole}

If you type in a short name for which there is no symbol either in the current context, or in any context on the context search path, then the Wolfram Language has to create a new symbol with this name. It always puts new symbols of this kind in the current context, as specified by (RefLink[$Context, paclet:ref/$Context]).

This introduces the new symbol with short name tree:

tree

The Wolfram Language puts tree in the current context Global`:

Context[tree]