Blocks and Local Values

Modules in the Wolfram Language allow you to treat the names of variables as local. Sometimes, however, you want the names to be global, but values to be local. You can do this in the Wolfram Language using (RefLink[Block, paclet:ref/Block]).

Setting up local values.

Here is an expression involving x:

x^2+3

This evaluates the previous expression, using a local value for x:

Block[{x=a+1},%]

There is no global value for x:

x

As described in "Modules and Local Variables", the variable x in a module such as (RefLink[Module, paclet:ref/Module])[{x},body] is always set up to refer to a unique symbol, different each time the module is used, and distinct from the global symbol x. The x in a block such as (RefLink[Block, paclet:ref/Block])[{x},body] is, however, taken to be the global symbol x. What the block does is to make the value of x local. The value x had when you entered the block is always restored when you exit the block. And during the execution of the block, x can take on any value.

This sets the symbol t to have value 17:

t=17

Variables in modules have unique local names:

Module[{t},Print[t]]

In blocks, variables retain their global names, but can have local values:

Block[{t},Print[t]]

t is given a local value inside the block:

Block[{t},t=6;t^4+1]

When the execution of the block is over, the previous value of t is restored:

t

Blocks in the Wolfram Language effectively allow you to set up "environments" in which you can temporarily change the values of variables. Expressions you evaluate at any point during the execution of a block will use the values currently defined for variables in the block. This is true whether the expressions appear directly as part of the body of the block, or are produced at any point in its evaluation.

This defines a delayed value for the symbol u:

u:=x^2+t^2

If you evaluate u outside a block, the global value for t is used:

u

You can specify a temporary value for t to use inside the block:

Block[{t=5},u+7]

An important implicit use of (RefLink[Block, paclet:ref/Block]) in the Wolfram Language is for iteration constructs such as (RefLink[Do, paclet:ref/Do]), (RefLink[Sum, paclet:ref/Sum]), and (RefLink[Table, paclet:ref/Table]). The Wolfram Language effectively uses (RefLink[Block, paclet:ref/Block]) to set up local values for the iteration variables in all of these constructs.

(RefLink[Sum, paclet:ref/Sum]) automatically makes the value of the iterator t local:

Sum[t^2,{t,10}]

The local values in iteration constructs are slightly more general than in (RefLink[Block, paclet:ref/Block]). They handle variables such as a[1], as well as pure symbols:

Sum[a[1]^2,{a[1],10}]

When you set up functions in the Wolfram Language, it is sometimes convenient to have "global variables" that can affect the functions without being given explicitly as arguments. Thus, for example, the Wolfram Language itself has a global variable (RefLink[$RecursionLimit, paclet:ref/$RecursionLimit]) that affects the evaluation of all functions, but is never explicitly given as an argument.

The Wolfram Language will usually keep any value you define for a global variable until you explicitly change it. Often, however, you want to set up values that last only for the duration of a particular computation, or part of a computation. You can do this by making the values local to a Wolfram Language block.

This defines a function that depends on the "global variable" t:

f[x_]:=x^2+t

In this case, the global value of t is used:

f[a]

Inside a block, you can set up a local value for t:

Block[{t=2},f[b]]

You can use global variables not only to set parameters in functions, but also to accumulate results from functions. By setting up such variables to be local to a block, you can arrange to accumulate results only from functions called during the execution of the block.

This function increments the global variable t, and returns its current value:

h[x_]:=(t+=x^2)

If you do not use a block, evaluating h[a] changes the global value of t:

h[a]

With a block, only the local value of t is affected:

Block[{t=0},h[c]]

The global value of t remains unchanged:

t

When you enter a block such as (RefLink[Block, paclet:ref/Block])[{x},body], any value for x is removed. This means that you can in principle treat x as a "symbolic variable" inside the block. However, if you explicitly return x from the block, it will be replaced by its value outside the block as soon as it is evaluated.

The value of t is removed when you enter the block:

Block[{t},Print[Expand[(t+1)^2]]]

If you return an expression involving t, however, it is evaluated using the global value for t:

Block[{t},t^2-3]