({{, (RefLink[ProbabilityPlot, paclet:ref/ProbabilityPlot])[list]
generates a plot of the CDF of list against the CDF of a normal distribution.}, {, (RefLink[ProbabilityPlot, paclet:ref/ProbabilityPlot])[dist]
generates a plot of the CDF of the distribution dist against the CDF of a normal distribution.}, {, (RefLink[ProbabilityPlot, paclet:ref/ProbabilityPlot])[data,rdata] 
generates a plot of the CDF of data against the CDF of rdata.}, {, (RefLink[ProbabilityPlot, paclet:ref/ProbabilityPlot])[data,rdist]
generates a plot of the CDF of data against the CDF of symbolic distribution rdist.}, {, (RefLink[ProbabilityPlot, paclet:ref/ProbabilityPlot])[{(Subscript[data, 1]),(Subscript[data, 2]),…},ref]
generates a plot of the CDF of (Subscript[data, i]) against the CDF of a reference distribution ref.}})

OpenersNotesSection(Spacer1)Details and Options

(RefLink[ProbabilityPlot, paclet:ref/ProbabilityPlot])[(Subscript[data, 1]),(Subscript[data, 2])] works with (Subscript[data, i]) being either a dataset of real values or a symbolic univariate distribution.

For datasets list, empirical CDFs are used, and for symbolic distributions dist, exact CDFs are used.

(RefLink[ProbabilityPlot, paclet:ref/ProbabilityPlot])[data,dist[(Subscript[θ, 1]),…]] with symbolic parameters (Subscript[θ, i]) is equivalent to (RefLink[ProbabilityPlot, paclet:ref/ProbabilityPlot])[data,(RefLink[EstimatedDistribution, paclet:ref/EstimatedDistribution])[data,dist[(Subscript[θ, 1]),…]]].

Datasets can be given in the following forms:

The form w[data] or w[dist] provides a wrapper w to be applied to the resulting graphics primitives.

The following wrappers can be used:

(RefLink[ProbabilityPlot, paclet:ref/ProbabilityPlot]) has the same options as (RefLink[Graphics, paclet:ref/Graphics]), with the following additions and changes:

With (RefLink[Filling, paclet:ref/Filling])->(RefLink[Automatic, paclet:ref/Automatic]), the region between a dataset and reference line will be filled. By default, "stems" are used for datasets, and "solid" filling is used for symbolic distributions. The setting (RefLink[Joined, paclet:ref/Joined])->(RefLink[True, paclet:ref/True]) will force "solid" filling for datasets.

The arguments supplied to functions in (RefLink[MeshFunctions, paclet:ref/MeshFunctions]) and (RefLink[RegionFunction, paclet:ref/RegionFunction]) are x, y. Functions in (RefLink[ColorFunction, paclet:ref/ColorFunction]) are by default supplied with scaled versions of these arguments.

The setting (RefLink[Joined, paclet:ref/Joined])->(RefLink[Automatic, paclet:ref/Automatic]) is equivalent to (RefLink[Joined, paclet:ref/Joined])->(RefLink[True, paclet:ref/True]) when comparing two distributions and (RefLink[Joined, paclet:ref/Joined])->(RefLink[False, paclet:ref/False]) otherwise.

The setting (RefLink[PlotStyle, paclet:ref/PlotStyle])->(RefLink[Automatic, paclet:ref/Automatic]) uses a sequence of different plot styles for different lines.

With the (RefLink[ReferenceLineStyle, paclet:ref/ReferenceLineStyle])->(RefLink[None, paclet:ref/None]), no reference line will be drawn.

Typical settings for (RefLink[PlotLegends, paclet:ref/PlotLegends]) include:

With (RefLink[ScalingFunctions, paclet:ref/ScalingFunctions])->{(Subscript[s, x]),(Subscript[s, y])}, the x coordinate is scaled using (Subscript[s, x]) and the y coordinate is scaled using (Subscript[s, y]).

OpenersPrimaryExamplesSection(Spacer1)Examples  (99)

OpenersExampleSection0(Spacer1)Basic Examples  (4)

A normal probability plot compared to an estimated normal distribution:

data=RandomVariate[NormalDistribution[1,2],100];

ProbabilityPlot[data]

Compare to the standard normal distribution:

data=RandomVariate[NormalDistribution[1,2],100];

ProbabilityPlot[data,NormalDistribution[0,1]]

A probability-probability plot of two datasets:

data1=RandomVariate[NormalDistribution[2,3],100];
data2=RandomVariate[StudentTDistribution[4,2,3],200];

ProbabilityPlot[data1,data2]

Plot several datasets with a legend:

data1=RandomVariate[NormalDistribution[2,3],100];
data2=RandomVariate[StudentTDistribution[4,2,1],200];

ProbabilityPlot[{data1,data2},PlotLegends->{"normal", "Student t"}]

OpenersExampleSection1(Spacer1)Scope  (23)

OpenersExampleSubsection0(Spacer1)Data and Distributions  (12)

(RefLink[ProbabilityPlot, paclet:ref/ProbabilityPlot]) works with numeric data:

ProbabilityPlot[RandomVariate[UniformDistribution[{0,1}],100]]

(RefLink[ProbabilityPlot, paclet:ref/ProbabilityPlot]) works with symbolic distributions:

ProbabilityPlot[UniformDistribution[{0,1}]]

Use multiple datasets and distributions:

ProbabilityPlot[{RandomReal[NormalDistribution[],100],RandomInteger[PoissonDistribution[1],100],WeibullDistribution[2,2]}]

The default reference distribution is the closest estimated (RefLink[NormalDistribution, paclet:ref/NormalDistribution]):

data = RandomVariate[UniformDistribution[{0,1}],100];
ref = EstimatedDistribution[data,NormalDistribution[a,b]];

{ProbabilityPlot[data],ProbabilityPlot[data,ref]}

Specify data or distributions as the reference:

data= RandomVariate[UniformDistribution[{0,1}],100];

{ProbabilityPlot[data,RandomVariate[NormalDistribution[0,1],100]], ProbabilityPlot[data, NormalDistribution[0,1]]}

Reference distributions are estimated for each dataset:

data = RandomVariate[UniformDistribution[{0,1}],100];

ProbabilityPlot[{data,2+data^2},PlotRange->All]

Estimate specific reference distributions for numeric datasets:

ProbabilityPlot[RandomVariate[UniformDistribution[{0,1}],100], WeibullDistribution[a,b,c]]

Use all forms of built-in distributions:

data=RandomVariate[NormalDistribution[2,1],100];

Parametric:

ProbabilityPlot[data,WeibullDistribution[2,5]]

Nonparametric:

ProbabilityPlot[data,SmoothKernelDistribution[data]]

Derived:

ProbabilityPlot[data,TruncatedDistribution[{1,4},ExponentialDistribution[1]]]

Plot values with units:

Short[data=EntityValue[EntityList[EntityClass["Country","Countries"]],"LifeExpectancy"]]

ProbabilityPlot[data]

Plot the values from an association:

ProbabilityPlot[<|"a"->2,"b"->3,"c"->5,"d"->7,"e"->11|>]

Plot data with weights:

data=WeightedData[RandomVariate[NormalDistribution[],100],Abs[RandomVariate[NormalDistribution[],100]]]

ProbabilityPlot[data]

Plot data from time series:

data=TimeSeries[RandomReal[1,50],{Automatic,Today}]

ProbabilityPlot[data]

OpenersExampleSubsection1(Spacer1)Presentation  (11)

Multiple datasets are automatically colored to be distinct:

data={RandomVariate[NormalDistribution[],100],RandomVariate[WeibullDistribution[1,2],100]};

ProbabilityPlot[data]

Provide explicit styling to different sets:

data={RandomVariate[NormalDistribution[],100],RandomVariate[WeibullDistribution[1,2],100]};

ProbabilityPlot[data,PlotStyle->{Blue,Red}]

Include legends for each dataset:

data={RandomVariate[NormalDistribution[],100],RandomVariate[WeibullDistribution[1,2],100]};

ProbabilityPlot[data,PlotLegends->{"one","two"}]

Add labels:

ProbabilityPlot[RandomVariate[UniformDistribution[{0,1}],100],FrameLabel->{"Empirical Probabilities", "Theoretical Probabilities"},PlotLabel->"P-P Plot",PlotStyle->Purple]

Use specific styles for the reference line:

ProbabilityPlot[Range[100],ReferenceLineStyle->Directive[Dashing[{}],Red]]

Turn off the reference line:

ProbabilityPlot[Range[100],ReferenceLineStyle->None]

Provide an interactive (RefLink[Tooltip, paclet:ref/Tooltip]) for the data:

ProbabilityPlot[Tooltip[RandomVariate[UniformDistribution[{0,1}],100]],PlotStyle->Directive[PointSize[Medium],Orange]]

Provide a specific tooltip for the data:

data = RandomVariate[UniformDistribution[{0,1}],100];

ProbabilityPlot[Tooltip[data,BoxWhiskerChart[data]],PlotStyle->Purple]

Create filled plots:

data1=RandomReal[NormalDistribution[100,400],200];
data2 =RandomReal[UniformDistribution[{5,400}],500];

ProbabilityPlot[{data1,data2},Filling->{1->{2}},Joined->True]

Use shapes to distinguish different datasets:

ProbabilityPlot[{{1,2,3,5,8},{2,3,6,9,10},{4,5,7,10,12}},PlotMarkers->Automatic]

Use (RefLink[Joined, paclet:ref/Joined]) to connect datasets with lines:

ProbabilityPlot[{1,2,4,7,3,5,8,10,9},Joined->True,PlotStyle->Orange]

Use a theme with grid lines:

ProbabilityPlot[{1,2,4,7,3,5,8,10,9},PlotTheme->"Detailed"]

OpenersExampleSection2(Spacer1)Options  (61)

OpenersExampleSubsection2(Spacer1)AspectRatio  (1)

Choose the ratio of height to width from the actual plot values:

ProbabilityPlot[Range[0,1,0.025],AspectRatio->Automatic]

OpenersExampleSubsection3(Spacer1)Axes  (1)

Draw axes instead of a frame:

ProbabilityPlot[Range[0,1,0.025],Frame->False,Axes->True]

OpenersExampleSubsection4(Spacer1)AxesLabel  (1)

Use labels based on variables specified:

ProbabilityPlot[Range[0,1,0.025],AxesLabel->{"Empirical Probabilities", "Theoretical Probabilities"},Axes->True, Frame->False]

OpenersExampleSubsection5(Spacer1)ColorFunction  (6)

(RefLink[ColorFunction, paclet:ref/ColorFunction]) requires at least one dataset to be (RefLink[Joined, paclet:ref/Joined]):

{ProbabilityPlot[RandomVariate[NormalDistribution[],100],ColorFunction->"Rainbow"],ProbabilityPlot[RandomVariate[NormalDistribution[],100],ColorFunction->"Rainbow",Joined->True]}

Color by scaled x and y coordinates:

Table[ProbabilityPlot[Range[0,1,0.025]^2,Joined->True,ColorFunction->Function[{x,y},f],PlotLabel->f,PlotStyle->Thick],{f,{Hue[x],Hue[y]}}]

Color with a named color scheme:

ProbabilityPlot[RandomVariate[NormalDistribution[],100],Joined->True,ColorFunction->"DarkRainbow"]

Fill to the reference line with the color used for the curve:

ProbabilityPlot[RandomVariate[NormalDistribution[1,2],100],Joined->True,ColorFunction->Function[{x,y},Hue[x]],Filling->Automatic]

(RefLink[ColorFunction, paclet:ref/ColorFunction]) has higher priority than (RefLink[PlotStyle, paclet:ref/PlotStyle]) for coloring the curve:

ProbabilityPlot[RandomVariate[NormalDistribution[1,2],100],Joined->True,ColorFunction->"DarkRainbow",PlotStyle->Directive[Red,Thick]]

Use (RefLink[Automatic, paclet:ref/Automatic]) in (RefLink[MeshShading, paclet:ref/MeshShading]) to use (RefLink[ColorFunction, paclet:ref/ColorFunction]):

ProbabilityPlot[RandomVariate[NormalDistribution[1,2],100],Joined->True,ColorFunction->"Rainbow",PlotStyle->Directive[Red,Thick],Mesh->9,MeshShading->{Automatic,Black},MeshStyle->None]

OpenersExampleSubsection6(Spacer1)ColorFunctionScaling  (2)

Color the line based on scaled y value:

ProbabilityPlot[RandomVariate[NormalDistribution[],100],Joined->True,ColorFunction->Function[{x,y},Hue[y]],PlotStyle->Thick, ColorFunctionScaling->True]

Color the line based on unscaled y value:

ProbabilityPlot[RandomVariate[NormalDistribution[],100],Joined->True,ColorFunction->Function[{x,y},Hue[y]],PlotStyle->Thick, ColorFunctionScaling->False]

OpenersExampleSubsection7(Spacer1)Filling  (6)

Fill from the data to the reference line:

ProbabilityPlot[Range[0,1,0.025],Filling->Automatic]

Use symbolic or explicit values for filling:

Table[ProbabilityPlot[Range[0,1,0.025],Filling->c],{c,{Top,Bottom,Axis,0.5}}]

Points fill with stems:

ProbabilityPlot[Range[0,1,0.025],Filling->Automatic]

Curves fill with solid regions:

ProbabilityPlot[Range[0,1,0.025],Filling->Automatic,Joined->True]

Fill from the third dataset to the axis:

ProbabilityPlot[{RandomVariate[NormalDistribution[],14],RandomVariate[PoissonDistribution[1],10],WeibullDistribution[2,2]},Filling->{3->Axis}]

Fill between datasets using a particular style:

ProbabilityPlot[{RandomVariate[WeibullDistribution[1,2],100],RandomVariate[WeibullDistribution[2,4],100]},Joined->True,Filling->{1->{{2},Directive[Orange,Dashed]}}]

Use different styles above and below the filling level:

ProbabilityPlot[{RandomVariate[WeibullDistribution[1,2],100],RandomVariate[WeibullDistribution[2,4],100]},Joined->True,Filling->{1->{{2},{Yellow,Red}}}]

OpenersExampleSubsection8(Spacer1)FillingStyle  (2)

Use different fill colors:

Table[ProbabilityPlot[Range[0,1,0.025],Filling->Automatic,Joined->True,FillingStyle->c],{c,{Red,Green,Blue,Yellow}}]

Use a transparent orange filling:

ProbabilityPlot[Table[Range[0,1,0.025]^i,{i,3}],Filling->Bottom,Joined->True,FillingStyle->Directive[Opacity[0.3],Orange]]

OpenersExampleSubsection9(Spacer1)Joined  (2)

Datasets are not joined by default:

ProbabilityPlot[RandomVariate[NormalDistribution[],100]]

Join the points:

ProbabilityPlot[RandomVariate[NormalDistribution[],100],Joined->True]

Symbolic distributions are joined by default:

ProbabilityPlot[LogNormalDistribution[0,1]]

OpenersExampleSubsection10(Spacer1)Mesh  (3)

Use 20 mesh levels evenly spaced in the x direction:

ProbabilityPlot[NormalDistribution[],NormalDistribution[],Mesh->20]

Use the mesh to divide the curve into deciles:

data=RandomVariate[UniformDistribution[{1,10}],100];ProbabilityPlot[data,Joined->True,Mesh->{Range[0.1,0.9,0.1]}]

Specify (RefLink[Style, paclet:ref/Style]) and mesh levels in the x direction:

data=RandomVariate[UniformDistribution[{1,10}],100];ProbabilityPlot[data,Joined->True,Mesh->{Table[{x,Hue[x]},{x,0.,1,.1}]}]

OpenersExampleSubsection11(Spacer1)MeshFunctions  (2)

Use a mesh evenly spaced in the x and y directions:

Table[ProbabilityPlot[Range[0,1,0.025],Joined->True,MeshFunctions->{Function[{x,y},Evaluate[f]]},Mesh->9,PlotLabel->f],{f,{x,y}}]

Show 5 mesh levels in the x direction (red) and 10 in the y direction (blue):

ProbabilityPlot[Range[0,1,0.025],Joined->True,Mesh->{5,10},MeshFunctions->{#1&,#2&},MeshStyle->{Directive[PointSize[Medium],Red],Blue}]

OpenersExampleSubsection12(Spacer1)MeshShading  (6)

Alternate red and blue segments of equal width in the x direction:

ProbabilityPlot[RandomVariate[NormalDistribution[],100],Joined->True,Mesh->10,MeshShading->{Red,Blue}]

Use (RefLink[None, paclet:ref/None]) to remove segments:

ProbabilityPlot[RandomVariate[NormalDistribution[],100],Joined->True,Mesh->10,MeshShading->{Red,None}]

(RefLink[MeshShading, paclet:ref/MeshShading]) can be used with (RefLink[PlotStyle, paclet:ref/PlotStyle]):

ProbabilityPlot[RandomVariate[NormalDistribution[],100],Joined->True,Mesh->10,PlotStyle->Thick,MeshFunctions->{#1&},MeshShading->{Red,Blue}]

(RefLink[MeshShading, paclet:ref/MeshShading]) has higher priority than (RefLink[PlotStyle, paclet:ref/PlotStyle]) for styling the curve:

ProbabilityPlot[RandomVariate[NormalDistribution[],100],Joined->True,Mesh->10,PlotStyle->Black,MeshFunctions->{#1&},MeshShading->{Red,Blue}]

Use (RefLink[PlotStyle, paclet:ref/PlotStyle]) for some segments by setting (RefLink[MeshShading, paclet:ref/MeshShading]) to (RefLink[Automatic, paclet:ref/Automatic]):

ProbabilityPlot[RandomVariate[NormalDistribution[],100],Joined->True,Mesh->10,PlotStyle->Directive[Thick,Yellow],MeshFunctions->{#1&},MeshShading->{Red,Automatic}]

(RefLink[MeshShading, paclet:ref/MeshShading]) can be used with (RefLink[ColorFunction, paclet:ref/ColorFunction]):

ProbabilityPlot[RandomVariate[NormalDistribution[],100],Joined->True,Mesh->10,PlotStyle->Thick,MeshFunctions->{#1&},MeshShading->{Black,Automatic},
ColorFunction->Function[{x,y},Hue[x]]]

OpenersExampleSubsection13(Spacer1)MeshStyle  (4)

Color the mesh the same color as the plot:

ProbabilityPlot[RandomVariate[NormalDistribution[],100],RandomVariate[NormalDistribution[],200],Joined->True,Mesh->9,MeshStyle->Automatic]

Use a red mesh in the x direction:

ProbabilityPlot[RandomVariate[NormalDistribution[],100],RandomVariate[NormalDistribution[],200],Joined->True,Mesh->9,MeshStyle->Red]

Use a red mesh in the x direction and a blue mesh in the y direction:

ProbabilityPlot[RandomVariate[NormalDistribution[],100],Joined->True,Mesh->9,MeshStyle->{Red,Blue},MeshFunctions->{#1&,#2&}]

Use big red mesh points in the x direction:

ProbabilityPlot[RandomVariate[NormalDistribution[],100],Joined->True,Mesh->10,MeshStyle->Directive[PointSize[Large],Red]]

OpenersExampleSubsection14(Spacer1)PlotLegends  (7)

By default, no legends are used:

ProbabilityPlot[{Sqrt[Range[40]],Log[Range[40]]}]

Generate a legend using labels:

ProbabilityPlot[{Sqrt[Range[40]],Log[Range[40]]},PlotLegends->{"sqrt","log"}]

Generate a legend using placeholders:

ProbabilityPlot[{Sqrt[Range[40]],Log[Range[40]]},PlotLegends->Automatic]

Legends use the same styles as the plot:

ProbabilityPlot[{Sqrt[Range[40]],Log[Range[40]]},PlotStyle->{Red,Blue},PlotLegends->{"sqrt","log"}]

Use (RefLink[Placed, paclet:ref/Placed]) to specify the legend placement:

ProbabilityPlot[{Sqrt[Range[40]],Log[Range[40]]},PlotLegends->Placed[{"sqrt","log"},Below]]

Place the legend inside the plot:

ProbabilityPlot[{Sqrt[Range[40]],Log[Range[40]]},PlotLegends->Placed[{"sqrt","log"},{0.25,0.75}]]

Use (RefLink[LineLegend, paclet:ref/LineLegend]) to change the legend appearance:

ProbabilityPlot[{Sqrt[Range[40]],Log[Range[40]]},PlotLegends->LineLegend[{"sqrt","log"},LegendFunction->Frame,LegendMarkers->None]]

OpenersExampleSubsection15(Spacer1)PlotMarkers  (7)

(RefLink[ProbabilityPlot, paclet:ref/ProbabilityPlot]) normally uses distinct colors to distinguish different sets of data:

ProbabilityPlot[Table[Range[0,1,0.025]^i,{i,0.5,2,0.5}],PlotMarkers->None]

Automatically use colors and shapes to distinguish sets of data:

ProbabilityPlot[Table[Range[0,1,0.025]^i,{i,0.5,2,0.5}],PlotMarkers->Automatic]

Use shapes only:

ProbabilityPlot[Table[Range[0,1,0.025]^i,{i,0.5,2,0.5}],PlotMarkers->Automatic,PlotStyle->Black]

Change the size of the default plot markers:

Table[ProbabilityPlot[Table[Range[0,1,0.025]^i,{i,0.5,2,0.5}],PlotMarkers->{Automatic,s}],{s,{Tiny,Small,Medium,Large}}]

Use arbitrary text for plot markers:

ProbabilityPlot[Table[Range[0,1,0.025]^i,{i,0.5,2,0.5}],PlotMarkers->{"1","2","3","4"}]

Use explicit graphics for plot markers:

ProbabilityPlot[Table[Range[0,1,0.025]^i,{i,0.5,2,0.5}],PlotMarkers->{,,,}]

Use the same symbol for all the sets of data:

ProbabilityPlot[Table[Range[0,1,0.025]^i,{i,0.5,2,0.5}],PlotMarkers->{"○"}]

OpenersExampleSubsection16(Spacer1)PlotStyle  (3)

Use different style directives:

Table[ProbabilityPlot[Range[0,1,0.025],PlotStyle->ps,Joined->True],{ps,{Red,Thick,Dashed,Directive[Red,Thick]}}]

By default, different styles are chosen for multiple curves:

ProbabilityPlot[Table[Range[0,1,0.025]^i,{i,1/2,2,1/2}]]

Explicitly specify the style for different curves:

ProbabilityPlot[Table[Range[0,1,0.025]^i,{i,1/2,2,1/2}],PlotStyle->{Red,Green, Blue,Brown}]

OpenersExampleSubsection17(Spacer1)PlotTheme  (2)

Use a theme with grid lines:

ProbabilityPlot[{1,2,4,7,3,5,8,10,9},PlotTheme->"Detailed"]

Use a theme with high-contrast colors:

ProbabilityPlot[{1,2,4,7,3,5,8,10,9},PlotTheme->"Marketing"]

Turn off the grid lines:

ProbabilityPlot[{1,2,4,7,3,5,8,10,9},PlotTheme->"Marketing",GridLines->None]

OpenersExampleSubsection18(Spacer1)ReferenceLineStyle  (4)

(RefLink[ReferenceLineStyle, paclet:ref/ReferenceLineStyle]) by default uses a (RefLink[Dotted, paclet:ref/Dotted]) form of (RefLink[PlotStyle, paclet:ref/PlotStyle]):

ProbabilityPlot[Range[0,1,0.025]]

Draw a dotted red reference line:

ProbabilityPlot[Range[0,1,0.025],ReferenceLineStyle->Red]

Draw a solid red reference line:

ProbabilityPlot[Range[0,1,0.025],ReferenceLineStyle->Directive[Red,Dashing[0]]]

Use (RefLink[None, paclet:ref/None]) to turn off the reference line:

ProbabilityPlot[Range[0,1,0.025],ReferenceLineStyle->None]

(RefLink[ReferenceLineStyle, paclet:ref/ReferenceLineStyle]) can be combined with (RefLink[PlotStyle, paclet:ref/PlotStyle]):

ProbabilityPlot[Range[0,1,0.025],ReferenceLineStyle->Thick]

OpenersExampleSubsection19(Spacer1)ScalingFunctions  (2)

Data is normally shown on linear scales:

ProbabilityPlot[RandomVariate[ExponentialDistribution[4],100]]

Plot the data on a log-scaled y axis:

ProbabilityPlot[RandomVariate[ExponentialDistribution[4],100],ScalingFunctions->{None,"Log"}]

OpenersExampleSection3(Spacer1)Applications  (3)

(RefLink[KolmogorovSmirnovTest, paclet:ref/KolmogorovSmirnovTest]) can be used to create a measure that quantifies the behavior in (RefLink[ProbabilityPlot, paclet:ref/ProbabilityPlot]). The Kolmogorov–Smirnov test statistic is equivalent to the maximum vertical distance between a point in the plot and the reference line:

data=RandomVariate[𝒟=ExponentialDistribution[1],100];

{ProbabilityPlot[data,𝒟],ProbabilityPlot[data,NormalDistribution[μ,σ]]}

The p-value is larger when the points are closer to the reference line:

{KolmogorovSmirnovTest[data,𝒟],KolmogorovSmirnovTest[data,NormalDistribution[μ,σ]]}

A t-test for location assumes that the data was drawn from a (RefLink[NormalDistribution, paclet:ref/NormalDistribution]). If this assumption does not hold, a nonparametric test such as a signed-rank test is more appropriate. Suppose one wants to test for a location parameter of zero using the following data:

data={-6.205,-0.733,1.304,-4.837,-0.205,-0.382,-0.133,35.092,-1.128,6.194,0.538,-1.197,-4.054,-1.525,-0.318};

ProbabilityPlot[data]

The plot suggests that the tails of the distribution are quite heavy. A (RefLink[SignedRankTest, paclet:ref/SignedRankTest]) for location is more appropriate than the (RefLink[TTest, paclet:ref/TTest]):

SignedRankTest[data,0,"TestDataTable"]

Compare two time slices for a random process:

data1=RandomVariate[WienerProcess[0,2][5],10^3];
data2=RandomVariate[WienerProcess[0,2][2],10^3];

ProbabilityPlot[data1,data2]

OpenersExampleSection4(Spacer1)Properties & Relations  (8)

With no second argument, data is compared against an estimated normal distribution:

data=RandomVariate[NormalDistribution[1,2],10^3];

{ProbabilityPlot[data],ProbabilityPlot[data,NormalDistribution[μ,σ]]}

(RefLink[QuantilePlot, paclet:ref/QuantilePlot]) compares quantiles for the data:

data=RandomVariate[NormalDistribution[1,2],10^3];

QuantilePlot[data]

(RefLink[ProbabilityScalePlot, paclet:ref/ProbabilityScalePlot]) scales the axes so that points from distributions are on a straight line:

data=RandomVariate[NormalDistribution[1,2],10^3];

ProbabilityScalePlot[data,"Normal"]

(RefLink[BoxWhiskerChart, paclet:ref/BoxWhiskerChart]) and (RefLink[DistributionChart, paclet:ref/DistributionChart]) can be used to visualize the distribution of data:

data=RandomVariate[ExponentialDistribution[2],10^3];

{BoxWhiskerChart[data], DistributionChart[data]}

(RefLink[SmoothHistogram, paclet:ref/SmoothHistogram]) and (RefLink[Histogram, paclet:ref/Histogram]) can be used to visualize the distribution of data:

data=RandomVariate[ExponentialDistribution[2],10^3];

{SmoothHistogram[data,Automatic,"CDF"], Histogram[data,Automatic,"CDF"]}

(RefLink[DiscretePlot, paclet:ref/DiscretePlot]) can be used to visualize the discrete distributions:

{ProbabilityPlot[PoissonDistribution[3]],DiscretePlot[CDF[PoissonDistribution[3],x],{x,0,6},PlotStyle->PointSize[Medium]]}

Use (RefLink[ListPlot, paclet:ref/ListPlot]) to see the data:

data = FindClusters[RandomVariate[ExponentialDistribution[2],100]];

ListPlot[data]

(RefLink[ProbabilityPlot, paclet:ref/ProbabilityPlot]) ignores time stamps when input is a (RefLink[TimeSeries, paclet:ref/TimeSeries]):

data=TimeSeries[];

{ProbabilityPlot[data],ProbabilityPlot[data["Values"]]}

({{DocumentationFooterIconsRelatedFunction.png, ({{See Also}, {(RefLink[QuantilePlot, paclet:ref/QuantilePlot])  ▪  (RefLink[ProbabilityScalePlot, paclet:ref/ProbabilityScalePlot])  ▪  (RefLink[Quantile, paclet:ref/Quantile])  ▪  (RefLink[Histogram, paclet:ref/Histogram])  ▪  (RefLink[BoxWhiskerChart, paclet:ref/BoxWhiskerChart])  ▪  (RefLink[DistributionChart, paclet:ref/DistributionChart])  ▪  (RefLink[ListPlot, paclet:ref/ListPlot])  ▪  (RefLink[DiscretePlot, paclet:ref/DiscretePlot])  ▪  (RefLink[Plot, paclet:ref/Plot])}})}})

({{DocumentationFooterIconsRelatedGuide.png, ({{Related Guides}, {▪(RefLinkPlain[Statistical Visualization, paclet:guide/StatisticalVisualization])}, {▪(RefLinkPlain[Random Variables, paclet:guide/RandomVariables])}, {▪(RefLinkPlain[Reliability, paclet:guide/Reliability])}})}})