({{, (RefLink[LogLogPlot, paclet:ref/LogLogPlot])[f,{x,(Subscript[x, min]),(Subscript[x, max])}]
generates a log-log plot of f as a function of x from (Subscript[x, min]) to (Subscript[x, max]). }, {, (RefLink[LogLogPlot, paclet:ref/LogLogPlot])[{(Subscript[f, 1]),(Subscript[f, 2]),…},{x,(Subscript[x, min]),(Subscript[x, max])}]
plots several functions (Subscript[f, i]). }, {, (RefLink[LogLogPlot, paclet:ref/LogLogPlot])[{…,w[(Subscript[f, i])],…},…]
plots (Subscript[f, i]) with features defined by the symbolic wrapper w.}, {, (RefLink[LogLogPlot, paclet:ref/LogLogPlot])[…,{x}∈reg]
takes the variable x to be in the geometric region reg.}})

OpenersNotesSection(Spacer1)Details and Options

(RefLink[LogLogPlot, paclet:ref/LogLogPlot]) effectively generates a curve in which (RefLink[Log, paclet:ref/Log])[f] is plotted against (RefLink[Log, paclet:ref/Log])[x], but with tick marks indicating the original values of f and x.

(RefLink[LogLogPlot, paclet:ref/LogLogPlot]) makes power-law functions appear as straight lines.

(RefLink[LogLogPlot, paclet:ref/LogLogPlot]) evaluates f at different values of x to create a smooth curve of the form {x,f[x]}.

Gaps are left at any x where the (Subscript[f, i]) evaluate to anything other than positive real numbers or 
(RefLink[Quantity, paclet:ref/Quantity]).

The limits (Subscript[x, min]) and (Subscript[x, max]) can be real numbers or (RefLink[Quantity, paclet:ref/Quantity]) expressions.

The region reg can be any (RefLink[RegionQ, paclet:ref/RegionQ]) object in 1D.

(RefLink[LogLogPlot, paclet:ref/LogLogPlot]) treats the variable x as local, effectively using (RefLink[Block, paclet:ref/Block]).

(RefLink[LogLogPlot, paclet:ref/LogLogPlot]) has attribute (RefLink[HoldAll, paclet:ref/HoldAll]) and evaluates f only after assigning specific numerical values to x.

In some cases, it may be more efficient to use (RefLink[Evaluate, paclet:ref/Evaluate]) to evaluate f symbolically before specific numerical values are assigned to x.

The following wrappers w can be used for the (Subscript[f, i]):

Wrappers w can be applied at multiple levels:

(RefLink[Callout, paclet:ref/Callout]), (RefLink[Labeled, paclet:ref/Labeled]), and (RefLink[Placed, paclet:ref/Placed]) can use the following positions pos:

(RefLink[LogLogPlot, paclet:ref/LogLogPlot]) has the same options as (RefLink[Graphics, paclet:ref/Graphics]), with the following additions and changes:

Possible settings for (RefLink[ClippingStyle, paclet:ref/ClippingStyle]) are:

With the default settings (RefLink[Exclusions, paclet:ref/Exclusions])->(RefLink[Automatic, paclet:ref/Automatic]) and (RefLink[ExclusionsStyle, paclet:ref/ExclusionsStyle])->(RefLink[None, paclet:ref/None]), (RefLink[LogLogPlot, paclet:ref/LogLogPlot]) breaks curves at discontinuities and singularities it detects. (RefLink[Exclusions, paclet:ref/Exclusions])->(RefLink[None, paclet:ref/None]) joins across discontinuities and singularities.

(RefLink[Exclusions, paclet:ref/Exclusions])->{(Subscript[x, 1]),(Subscript[x, 2]),…} is equivalent to (RefLink[Exclusions, paclet:ref/Exclusions])->{x==(Subscript[x, 1]),x==(Subscript[x, 2]),…}.

(RefLink[PlotLegends, paclet:ref/PlotLegends])->"Expressions" uses the (Subscript[f, i]) as the legend text.

(RefLink[LogLogPlot, paclet:ref/LogLogPlot]) initially evaluates f at a number of equally spaced sample points specified by (RefLink[PlotPoints, paclet:ref/PlotPoints]). Then it uses an adaptive algorithm to choose additional sample points, subdividing a given interval at most (RefLink[MaxRecursion, paclet:ref/MaxRecursion]) times.

Since only a finite number of sample points are used, it is possible for (RefLink[LogLogPlot, paclet:ref/LogLogPlot]) to miss features of f. Increasing the settings for (RefLink[PlotPoints, paclet:ref/PlotPoints]) and (RefLink[MaxRecursion, paclet:ref/MaxRecursion]) will often catch such features.

Themes that affect curves include:

The arguments supplied to functions in (RefLink[MeshFunctions, paclet:ref/MeshFunctions]) and (RefLink[RegionFunction, paclet:ref/RegionFunction]) are x, y. Functions in (RefLink[ColorFunction, paclet:ref/ColorFunction]) are by default supplied with scaled versions of these arguments.

OpenersPrimaryExamplesSection(Spacer1)Examples  (112)

OpenersExampleSection0(Spacer1)Basic Examples  (4)

Powers show up as straight lines on a log-log plot:

LogLogPlot[x^2+x^3,{x,1,100}]

Plot several functions with legends:

LogLogPlot[{x^2,x^3,x^4,x^5},{x,1,10^4},PlotLegends->"Expressions"]

Label each curve:

LogLogPlot[{Log[x]^x,x^x},{x,0.1,10},PlotLabels->"Expressions"]

Fill between curves:

LogLogPlot[{10/(x^2-6x+10),100/(x^2+100)},{x,0.1,1000},Filling->{1->{2}}]

OpenersExampleSection1(Spacer1)Scope  (24)

OpenersExampleSubsection0(Spacer1)Sampling  (7)

More points are sampled when the function changes quickly:

LogLogPlot[Sum[i/(x^2-2 i 0.99 x+i^2),{i,{1,10,100}}],{x,0.1,1000}]

The plot range is selected automatically:

LogLogPlot[Abs[1/(x-5)],{x,1,10}]

Ranges where the function becomes negative are excluded:

LogLogPlot[1/((x-3)(x-5)),{x,1,10}]

The curve is split when there are discontinuities in the function:

LogLogPlot[Floor[Sqrt[x]],{x,1,100}]

Use (RefLink[PlotPoints, paclet:ref/PlotPoints]) and (RefLink[MaxRecursion, paclet:ref/MaxRecursion]) to control adaptive sampling:

Grid@Table[LogLogPlot[Sum[i/(x^2-2 i 0.99 x+i^2),{i,{1,10,100}}],{x,0.1,1000},PlotPoints->pp,MaxRecursion->mr],{mr,{0,1,2}},{pp,{5,10}}]

Use (RefLink[PlotRange, paclet:ref/PlotRange]) to focus in on areas of interest:

{LogLogPlot[10/(x^2-5x+10),{x,1,100}],LogLogPlot[10/(x^2-5x+10),{x,1,100},PlotRange->{1,3}]}

Use (RefLink[Exclusions, paclet:ref/Exclusions]) to remove points or split the resulting curve:

LogLogPlot[Exp[Tan[x]],{x,1,10},Exclusions->{Cos[x]==0}]

OpenersExampleSubsection1(Spacer1)Labeling and Legending  (8)

Label curves with (RefLink[Labeled, paclet:ref/Labeled]):

LogLogPlot[Evaluate@Table[Labeled[Log[n x]^x,Log[n x]^x],{n,1,3}],{x,0.5,3}]

Place the labels relative to the curves:

Table[LogLogPlot[Labeled[x^Sin[x],"label",p],{x,1,6},PlotLabel->p],{p,{Above,Below,Before,After}}]

Label curves with (RefLink[PlotLabels, paclet:ref/PlotLabels]):

LogLogPlot[{Log[x]^x,x^x},{x,1,10},PlotLabels->{Log[x]^x,x^x}]

Place the label near the curve at an x value:

LogLogPlot[Labeled[x^Sin[x],"label",Log[6]],{x,2,10}]

Use a scaled position:

LogLogPlot[Labeled[x^Sin[x],"label",Scaled[0.1]],{x,2,10}]

Specify the text position relative to the point:

LogLogPlot[Labeled[x^Sin[x],"label",{Scaled[0.1],Below}],{x,2,10}]

Label curves automatically with (RefLink[Callout, paclet:ref/Callout]):

LogLogPlot[{Callout[x^Sin[x],x^Sin[x]],Callout[x,x]},{x,1,20}]

Place labels at specific locations:

LogLogPlot[Callout[x^(Sin[x]),"max",Above],{x,1,5}]

LogLogPlot[{Callout[x,x,{5,Above}],Callout[x^(Sin[x]),x^x,{4,Below}]},{x,1,18}]

Include legends for each curve:

LogLogPlot[{x^Sin[x],x^Cos[x]},{x,1,2π},PlotLegends->{x^Sin[x],x^Cos[x]}]

Use (RefLink[Legended, paclet:ref/Legended]) to provide a legend for a specific curve:

LogLogPlot[{x^Sin[x],Legended[Mean[{x^Sin[x],x^Cos[x]}],"average"],x^Cos[x]},{x,1,2π}]

Use (RefLink[Placed, paclet:ref/Placed]) to change the legend location:

LogLogPlot[{x^Sin[x],Legended[Mean[{x^Sin[x],x^Cos[x]}],Placed["average",Below]],x^Cos[x]},{x,1,2π}]

OpenersExampleSubsection2(Spacer1)Presentation  (9)

Multiple curves are automatically colored to be distinct:

LogLogPlot[{Log[x],x,x^2,E^x},{x,1,100}]

Provide explicit styling to different curves:

LogLogPlot[{Log[x],x,x^2,E^x},{x,1,100},PlotStyle->{AbsoluteThickness[3],Automatic,Red,Dashed}]

Add labels:

LogLogPlot[1/Abs[x-10],{x,1,1000},AxesLabel->Automatic,PlotLabel->1/Abs[x-10]]

Create legends from the functions:

LogLogPlot[{10/(x^2-6x+10),100/(x^2+100)},{x,0.1,1000},PlotLegends->"Expressions"]

Specify labels for legends:

LogLogPlot[{10/(x^2-6x+10),100/(x^2+100)},{x,0.1,1000},PlotLegends->{"one","two"}]

Provide an interactive (RefLink[Tooltip, paclet:ref/Tooltip]) for each curve:

LogLogPlot[{Tooltip[Log[x]],Tooltip[1/x]},{x,1,100}]

Create filled plots:

LogLogPlot[{x,1/x},{x,0.01,100},Filling->1]

Use a theme with a frame, grid lines, and an automatic legend:

LogLogPlot[{10/(x^2-6x+10),100/(x^2+100)},{x,0.1,1000},PlotTheme->"Detailed"]

Use a more vibrant theme:

LogLogPlot[{10/(x^2-6x+10),100/(x^2+100)},{x,0.1,1000},PlotTheme->"Marketing"]

Create an overlay mesh:

LogLogPlot[1/Abs[x-10],{x,1,1000},Mesh->20,MeshFunctions->{Log[#1]&}]

Style the curve segments between mesh points:

LogLogPlot[1/Abs[x-10],{x,1,1000},Mesh->15,MeshFunctions->{Log[#1]&},MeshShading->{Red,None,Blue}]

OpenersExampleSection2(Spacer1)Options  (80)

OpenersExampleSubsection3(Spacer1)ClippingStyle  (5)

Omit clipped regions of the plot:

LogLogPlot[Exp[Sin[(x-2)]/(x-2)^2],{x,1,5},ClippingStyle->None,PlotRange->{1*^-1,1*^1},AxesOrigin->{2,1}]

Show the clipped regions like the rest of the curve:

LogLogPlot[Exp[Sin[(x-2)]/(x-2)^2],{x,1,5},ClippingStyle->Automatic,PlotRange->{1*^-1,1*^1},AxesOrigin->{2,1}]

Show clipped regions with red lines:

LogLogPlot[Exp[Sin[(x-2)]/(x-2)^2],{x,1,5},ClippingStyle->Red,PlotRange->{1*^-1,1*^1},AxesOrigin->{2,1}]

Show clipped regions as thick at the bottom and red at the top:

LogLogPlot[Exp[Sin[(x-2)]/(x-2)^2],{x,1,5},ClippingStyle->{Red,Thick},PlotRange->{1*^-1,1*^1},AxesOrigin->{2,1}]

Show clipped regions as red and thick:

LogLogPlot[Exp[Sin[(x-2)]/(x-2)^2],{x,1,5},ClippingStyle->Directive[Thick,Red],PlotRange->{1*^-1,1*^1},AxesOrigin->{2,1}]

OpenersExampleSubsection4(Spacer1)ColorFunction  (5)

Color by scaled y coordinate and scaled x coordinate, respectively:

Table[LogLogPlot[10/(x^2-6x+10),{x,1,100},ColorFunction->Function[{x,y},Evaluate[f]],PlotLabel->f],{f,{Hue[x],Hue[y]}}]

Color a curve red when its absolute y coordinate is above 1:

LogLogPlot[10/(x^2-6x+10),{x,1,100},ColorFunction->Function[{x,y},If[y>1,Red,Black]],ColorFunctionScaling->False,PlotStyle->Thick]

Fill with the color used for the curve:

LogLogPlot[10/(x^2-6x+10),{x,1,100},ColorFunction->Function[{x,y},Hue[y]],Filling->Axis]

(RefLink[ColorFunction, paclet:ref/ColorFunction]) has higher priority than (RefLink[PlotStyle, paclet:ref/PlotStyle]) for coloring the curve:

LogLogPlot[10/(x^2-6x+10),{x,1,100},ColorFunction->"DarkRainbow",PlotStyle->Directive[Red,AbsoluteThickness[5]]]

Use a color function that is red at powers of 10:

LogLogPlot[10/(x^2-6x+10),{x,1,100},ColorFunction->Function[{x,y},Hue[Log[10,y]]],PlotStyle->Thick,ColorFunctionScaling->False]

OpenersExampleSubsection5(Spacer1)ColorFunctionScaling  (3)

No argument scaling on the left, automatic scaling on the right:

Table[LogLogPlot[10/(x^2-6x+10),{x,1,100},PlotStyle->Thick,ColorFunction->Function[{x,y},Hue[y]],ColorFunctionScaling->cf],{cf,{False,True}}]

Scaling is done on a linear scale in the original coordinates:

Table[LogLogPlot[t,{t,0.1,2^i},PlotStyle->Thick,ColorFunction->Function[{x,y},Hue[y]]],{i,{0,10,20}}]

Use a color function that is red at powers of 10:

LogLogPlot[10/(x^2-6x+10),{x,1,100},ColorFunction->Function[{x,y},Hue[Log[10,y]]],PlotStyle->Thick,ColorFunctionScaling->False]

OpenersExampleSubsection6(Spacer1)EvaluationMonitor  (3)

Find the list of values sampled by (RefLink[LogLogPlot, paclet:ref/LogLogPlot]):

Reap[LogLogPlot[10/(x^2-6x+10),{x,1,100},EvaluationMonitor:>Sow[x]];]//Short

Show where (RefLink[LogLogPlot, paclet:ref/LogLogPlot]) evaluates the function:

data=Reap[ LogLogPlot[10/(x^2-6x+10),{x,1,100},EvaluationMonitor:>Sow[{x,10/(x^2-6x+10)}]] ][[-1,1]];

ListLogLogPlot[data ,Filling->Axis]

Count how many times the function is evaluated:

Block[{k=0},LogLogPlot[10/(x^2-6x+10),{x,1,100},EvaluationMonitor:>k++];k]

OpenersExampleSubsection7(Spacer1)Exclusions  (2)

Use automatic methods for computing exclusions, in this case for a piecewise function:

LogLogPlot[Sum[Boole[2^(k-1)<x<2^k]x/(2^k-x),{k,5}],{x,1,2^5}]

Indicate that no exclusions should be computed:

LogLogPlot[Sum[Boole[2^(k-1)<x<2^k]x/(2^k-x),{k,5}],{x,1,2^5},Exclusions->None]

OpenersExampleSubsection8(Spacer1)ExclusionsStyle  (2)

Use dashed lines to indicate the vertical asymptotes:

LogLogPlot[Sum[Boole[2^(k-1)<x<2^k]x/(2^k-x),{k,5}],{x,1,2^5},ExclusionsStyle->Dashed]

Use blue points to highlight the exclusions:

LogLogPlot[Gamma[Floor[x]],{x,1,10},ExclusionsStyle->{None,Blue}]

OpenersExampleSubsection9(Spacer1)Filling  (7)

Use symbolic or explicit values:

Table[LogLogPlot[10/(x^2-6x+10),{x,1,100},Filling->f],{f,{Axis,Top,Bottom,1}}]

Overlapping fills by default combine using opacity:

LogLogPlot[{(x-5)^2/x,x/(x-5)^2},{x,1,25},Filling->Axis]

Fill between curve 1 and the axis:

LogLogPlot[{(x-5)^2/x,x/(x-5)^2},{x,1,25},Filling->{1->Axis}]

Fill between curves 1 and 2:

LogLogPlot[{(x-5)^2/x,x/(x-5)^2},{x,1,25},Filling->{1->{2}}]

Fill between curves 1 and 2 with a specific style:

LogLogPlot[{(x-5)^2/x,x/(x-5)^2},{x,1,25},Filling->{1->{{2},Yellow}}]

Fill between curves 1 and 2; use yellow when 1 is below 2 and green when 2 is above 1:

LogLogPlot[{(x-5)^2/x,x/(x-5)^2},{x,1,25},Filling->{1->{{2},{Yellow,Green}}}]

Fill between curves 1 and y==1 with yellow:

LogLogPlot[{(x-5)^2/x,x/(x-5)^2},{x,1,25},Filling->{1->{1,Yellow}}]

OpenersExampleSubsection10(Spacer1)FillingStyle  (4)

Use different fill colors:

Table[LogLogPlot[Abs[Tan[x]],{x,1,10},Filling->Bottom,FillingStyle->c],{c,{Red,Green,Blue,Yellow}}]

Fill with opacity 0.5 yellow:

LogLogPlot[10/(x^2-6x+10),{x,0.1,1000},Filling->Bottom,FillingStyle->Directive[Opacity[0.5],Yellow]]

Fill with red below y==5 and blue above:

LogLogPlot[10/(x^2-6x+10),{x,0.1,1000},Filling->1.,FillingStyle->{Red,Blue}]

Use a variable filling style obtained from a (RefLink[ColorFunction, paclet:ref/ColorFunction]):

LogLogPlot[10/(x^2-6x+10),{x,0.1,1000},ColorFunction->Function[{x,y},Hue[y]],Filling->Bottom,FillingStyle->Automatic]

LogLogPlot[10/(x^2-6x+10),{x,0.1,1000},ColorFunction->Function[{x,y},Hue[x]],Filling->Bottom,FillingStyle->Automatic]

OpenersExampleSubsection11(Spacer1)LabelingSize  (4)

Textual labels are shown at their actual sizes:

LogLogPlot[{Log[x],x},{x,1,10},PlotLabels->{"barcarole","perilously"}]

Image labels are automatically resized:

LogLogPlot[{Log[x],x},{x,1,10},PlotLabels->{,}]

Specify a maximum size for textual labels:

LogLogPlot[{Log[x],x},{x,1,10},PlotLabels->{"barcarole","perilously"},LabelingSize->30]

Specify a maximum size for image labels:

LogLogPlot[{Log[x],x},{x,1,10},PlotLabels->{,},LabelingSize->50]

Show image labels at their natural sizes:

LogLogPlot[{Log[x],x},{x,1,10},PlotLabels->{,},LabelingSize->Full]

OpenersExampleSubsection12(Spacer1)MaxRecursion  (2)

The default sampling mesh:

LogLogPlot[10/(x^2-6x+10),{x,0.1,1000},Mesh->All]

Each level of (RefLink[MaxRecursion, paclet:ref/MaxRecursion]) will subdivide the initial mesh into a finer mesh:

Table[LogLogPlot[1/Abs[(x^2-10x+10)],{x,0.5,25},MaxRecursion->i,Mesh->All,Ticks->None],{i,{0,3,6}}]

OpenersExampleSubsection13(Spacer1)Mesh  (3)

Show the initial and final sampling meshes:

Table[LogLogPlot[Sum[i/(x^2-2 i 0.99 x+i^2),{i,{1,10,100}}],{x,0.1,1000},Mesh->m,MeshStyle->Red],{m,{Full,All}}]

Use 20 mesh levels evenly spaced in the unscaled x direction:

LogLogPlot[Sum[i/(x^2-2 i 0.99 x+i^2),{i,{1,10,100}}],{x,0.1,1000},Mesh->20,MeshStyle->Red]

Use an explicit list of values for the mesh in the x direction:

LogLogPlot[Sum[i/(x^2-2 i 0.99 x+i^2),{i,{1,10,100}}],{x,0.1,1000},Mesh->{{0.5,1,5,10,50,100,500}},MeshStyle->PointSize[Medium]]

OpenersExampleSubsection14(Spacer1)MeshFunctions  (4)

Use a mesh evenly spaced in the x and y directions:

Table[LogLogPlot[Sum[i/(x^2-2 i 0.99 x+i^2),{i,{1,10,100}}],{x,0.1,1000},MeshFunctions->{Function[{x,y},Evaluate[f]]},Mesh->10,MeshStyle->PointSize[Medium]],{f,{x,y}}]

Mesh functions use the unscaled values in the x and y directions:

LogLogPlot[Sum[i/(x^2-2 i 0.99 x+i^2),{i,{1,10,100}}],{x,0.1,1000},Mesh->10,MeshFunctions->{#2&},MeshStyle->PointSize[Medium]]

Use (RefLink[Log, paclet:ref/Log]) to scale the mesh functions:

Table[LogLogPlot[Sum[i/(x^2-2 i 0.99 x+i^2),{i,{1,10,100}}],{x,0.1,1000},MeshFunctions->{Function[{x,y},Evaluate[f]]},Mesh->10,MeshStyle->PointSize[Medium]],{f,{Log[x],Log[y]}}]

Show 5 mesh levels in the x direction (red) and 10 in the y direction (blue):

LogLogPlot[Sum[i/(x^2-2 i 0.99 x+i^2),{i,{1,10,100}}],{x,0.1,1000},Mesh->{5,10},MeshFunctions->{#1&,#2&},MeshStyle->{Directive[PointSize[Medium],Red],Blue}]

OpenersExampleSubsection15(Spacer1)MeshShading  (6)

Alternate red and blue segments of equal width in the x direction:

LogLogPlot[Sum[i/(x^2-2 i 0.99 x+i^2),{i,{1,10,100}}],{x,0.1,1000},Mesh->{{0.5,1,5,10,50,100,500}},MeshShading->{Red,Blue}]

Use (RefLink[None, paclet:ref/None]) to remove segments:

LogLogPlot[Sum[i/(x^2-2 i 0.99 x+i^2),{i,{1,10,100}}],{x,0.1,1000},Mesh->{{0.5,1,5,10,50,100,500}},MeshShading->{Red,None}]

(RefLink[MeshShading, paclet:ref/MeshShading]) can be used with (RefLink[PlotStyle, paclet:ref/PlotStyle]):

LogLogPlot[Sum[i/(x^2-2 i 0.99 x+i^2),{i,{1,10,100}}],{x,0.1,1000},Mesh->{{0.5,1,5,10,50,100,500}},PlotStyle->Thick,MeshShading->{Red,Blue}]

(RefLink[MeshShading, paclet:ref/MeshShading]) has higher priority than (RefLink[PlotStyle, paclet:ref/PlotStyle]) for styling the curve:

LogLogPlot[Sum[i/(x^2-2 i 0.99 x+i^2),{i,{1,10,100}}],{x,0.1,1000},Mesh->{{0.5,1,5,10,50,100,500}},PlotStyle->Green,MeshShading->{Red,Blue}]

Use (RefLink[PlotStyle, paclet:ref/PlotStyle]) for some segments by setting (RefLink[MeshShading, paclet:ref/MeshShading]) to (RefLink[Automatic, paclet:ref/Automatic]):

LogLogPlot[Sum[i/(x^2-2 i 0.99 x+i^2),{i,{1,10,100}}],{x,0.1,1000},Mesh->{{0.5,1,5,10,50,100,500}},PlotStyle->Directive[Thick,Yellow],MeshShading->{Red,Automatic}]

(RefLink[MeshShading, paclet:ref/MeshShading]) can be used with (RefLink[ColorFunction, paclet:ref/ColorFunction]):

LogLogPlot[Sum[i/(x^2-2 i 0.99 x+i^2),{i,{1,10,100}}],{x,0.1,1000},Mesh->{2^Range[-3,10]},PlotStyle->Thick,MeshShading->{Black,Automatic},
ColorFunction->Function[{x,y},Hue[Log[x]/10]]]

OpenersExampleSubsection16(Spacer1)MeshStyle  (4)

Color the mesh the same color as the plot:

LogLogPlot[Sum[i/(x^2-2 i 0.99 x+i^2),{i,{1,10,100}}],{x,0.1,1000},Mesh->{{0.5,1,5,10,50,100,500}},MeshStyle->Automatic]

Use a red mesh in the x direction:

LogLogPlot[Sum[i/(x^2-2 i 0.99 x+i^2),{i,{1,10,100}}],{x,0.1,1000},Mesh->{{0.5,1,5,10,50,100,500}},MeshStyle->Red]

Use a red mesh in the x direction and a blue mesh in the y direction:

LogLogPlot[Sum[i/(x^2-2 i 0.99 x+i^2),{i,{1,10,100}}],{x,0.1,1000},Mesh->{{0.5,1,5,10,50,100,500},{0.001,0.01,0.1,1,10}},MeshStyle->{Red,Blue},MeshFunctions->{#1&,#2&}]

Use big red mesh points in the x direction:

LogLogPlot[Sum[i/(x^2-2 i 0.99 x+i^2),{i,{1,10,100}}],{x,0.1,1000},Mesh->{{0.5,1,5,10,50,100,500}},MeshStyle->Directive[PointSize[Large],Red]]

OpenersExampleSubsection17(Spacer1)PerformanceGoal  (2)

Generate a higher-quality plot:

Timing[LogLogPlot[Abs[Sin[1/x]],{x,0.00001,1},PerformanceGoal->"Quality"]]

Emphasize performance, possibly at the cost of quality:

Timing[LogLogPlot[Abs[Sin[1/x]],{x,0.00001,1},PerformanceGoal->"Speed"]]

OpenersExampleSubsection18(Spacer1)PlotLabel  (1)

Add an overall label to the plot:

LogLogPlot[Log[x]^x,{x,1,10},PlotLabel->Log[x]^x]

OpenersExampleSubsection19(Spacer1)PlotLabels  (5)

Specify text to label curves:

LogLogPlot[{Log[x],x^x},{x,1,2π},PlotLabels->{"log(x)","x^x"}]

Place the labels above the curves:

LogLogPlot[{x^Sin[x],x^Cos[x]},{x,1,2π},PlotLabels->Placed["Expressions",Above]]

Place the labels differently for each curve:

LogLogPlot[{x^Sin[x],x^Cos[x]},{x,1,2π},PlotLabels->{Placed[x^Sin[x],After],Placed[x^Cos[x],Above]}]

(RefLink[PlotLabels, paclet:ref/PlotLabels])->(StringTypeLink["Expression", paclet:ref/interpreter/Expression]) uses functions as curve labels:

LogLogPlot[{Log[x],x^x},{x,1,3},PlotLabels->"Expressions"]

Use callouts to identify the points:

LogLogPlot[{x,x^Sin[x]},{x,1,10},PlotLabels->{Callout[x,Scaled[0.33]],Callout[x^Sin[x],Scaled[0.5]]}]

Use (RefLink[None, paclet:ref/None]) to not add a label:

LogLogPlot[{x^Sin[x],x^Cos[x]},{x,1,2π},PlotLabels->{x^Sin[x],None}]

OpenersExampleSubsection20(Spacer1)PlotLegends  (7)

No legends are used by default:

LogLogPlot[{1/Abs[x-10],1/Abs[x-100]},{x,1,1000}]

Create a legend based on the functions:

LogLogPlot[{1/Abs[x-10],1/Abs[x-100]},{x,1,1000},PlotLegends->"Expressions"]

Create a legend with placeholder text:

LogLogPlot[{1/Abs[x-10],1/Abs[x-100]},{x,1,1000},PlotLegends->Automatic]

Specify labels for each curve:

LogLogPlot[{1/Abs[x-10],1/Abs[x-100]},{x,1,1000},PlotLegends->{"one","two"}]

(RefLink[PlotLegends, paclet:ref/PlotLegends]) picks up (RefLink[PlotStyle, paclet:ref/PlotStyle]) values automatically:

LogLogPlot[{1/Abs[x-10],1/Abs[x-100]},{x,1,1000},PlotStyle->{Red,Blue},PlotLegends->Automatic]

Use (RefLink[Placed, paclet:ref/Placed]) to position legends:

LogLogPlot[{1/Abs[x-10],1/Abs[x-100]},{x,1,1000},PlotStyle->{Red,Blue},PlotLegends->Placed[Automatic,Below]]

Place legends inside:

LogLogPlot[{1/Abs[x-10],1/Abs[x-100]},{x,1,1000},PlotStyle->{Red,Blue},PlotLegends->Placed[Automatic,{0.875,0.75}]]

Use (RefLink[LineLegend, paclet:ref/LineLegend]) to modify the appearance of the legend:

LogLogPlot[{1/Abs[x-10],1/Abs[x-100]},{x,1,1000},PlotLegends->LineLegend["Expressions",LegendFunction->Frame]]

OpenersExampleSubsection21(Spacer1)PlotPoints  (1)

Use more initial points to get a smoother curve:

Table[LogLogPlot[Sum[i/(x^2-2 i 0.99 x+i^2),{i,{1,10,100}}],{x,0.1,1000},PlotPoints->p,MaxRecursion->0],{p,{5,10,15,25}}]

OpenersExampleSubsection22(Spacer1)PlotRange  (1)

Show the curve only where it is positive:

LogLogPlot[1/(x-5),{x,1,10},PlotRange->Automatic]

OpenersExampleSubsection23(Spacer1)PlotStyle  (6)

Use different style directives:

Table[LogLogPlot[10/(x^2-19x+100),{x,0.1,100},PlotStyle->ps,Ticks->None],{ps,{Red,Thick,Dashed,Directive[Red,Thick]}}]

By default, different styles are chosen for multiple curves:

LogLogPlot[Evaluate[Table[i/(x^2-2 i 0.99 x+i^2),{i,{1,10,100}}]],{x,0.1,1000}]

Explicitly specify the style for different curves:

LogLogPlot[Evaluate[Table[i/(x^2-2 i 0.99 x+i^2),{i,{1,10,100}}]],{x,0.1,1000},PlotStyle->{Red,Green,Blue}]

(RefLink[PlotStyle, paclet:ref/PlotStyle]) can be combined with (RefLink[ColorFunction, paclet:ref/ColorFunction]):

LogLogPlot[10/(x^2-19x+100),{x,0.1,100},PlotStyle->Thick,ColorFunction->Function[{x,y},Hue[x]]]

(RefLink[PlotStyle, paclet:ref/PlotStyle]) can be combined with (RefLink[MeshShading, paclet:ref/MeshShading]):

LogLogPlot[10/(x^2-19x+100),{x,0.1,100},PlotStyle->Directive[Opacity[0.5],Thick],Mesh->10,MeshFunctions->{Log[#1]&},MeshShading->{Red,Blue}]

(RefLink[MeshStyle, paclet:ref/MeshStyle]) by default uses the same style as (RefLink[PlotStyle, paclet:ref/PlotStyle]):

LogPlot[x^Sin[x],{x,0,10},PlotStyle->Red,Mesh->All]

OpenersExampleSubsection24(Spacer1)PlotTheme  (1)

Use a theme with a frame, grid lines, and an automatic legend:

LogLogPlot[{10/(x^2-6x+10),100/(x^2+100)},{x,0.1,1000},PlotTheme->"Detailed"]

Turn off the grid lines:

LogLogPlot[{10/(x^2-6x+10),100/(x^2+100)},{x,0.1,1000},PlotTheme->"Detailed",GridLines->None]

OpenersExampleSubsection25(Spacer1)RegionFunction  (2)

Show the curve where x y<2:

LogLogPlot[Sum[i/(x^2-2 i 0.99 x+i^2),{i,{1,10,100}}],{x,0.1,1000},RegionFunction->Function[{x,y},x y<2]]

Exclude the region where (1/2)<y<2:

LogLogPlot[10/(x^2-19.8x+100),{x,0.1,100},RegionFunction->Function[{x,y},Not[1/2<y<2]]]

OpenersExampleSection3(Spacer1)Properties & Relations  (4)

(RefLink[LogLogPlot, paclet:ref/LogLogPlot]) samples more points where it needs to:

LogLogPlot[10/(x^2-6x+10),{x,1,10},Mesh->All]

(RefLink[LogLogPlot, paclet:ref/LogLogPlot]) is a special case of (RefLink[Plot, paclet:ref/Plot]) for curves:

{LogLogPlot[1/(x-5)^2,{x,1,10}],Plot[Log[1/(Exp[x]-5)^2],{x,Log[1],Log[10]},AxesOrigin->{0,-3}]}

Use (RefLink[LogPlot, paclet:ref/LogPlot]) and (RefLink[LogLinearPlot, paclet:ref/LogLinearPlot]) for logarithmic plots in the other directions:

LogPlot[Gamma[x],{x,0,10}]

Use (RefLink[ListLogPlot, paclet:ref/ListLogPlot]) for data:

{ListLogLogPlot[Table[{x,10/(x^2-6x+10)},{x,1,10,0.1}]],LogLogPlot[10/(x^2-6x+10),{x,1,10}]}

({{DocumentationFooterIconsRelatedFunction.png, ({{See Also}, {(RefLink[ListLogLogPlot, paclet:ref/ListLogLogPlot])  ▪  (RefLink[LogPlot, paclet:ref/LogPlot])  ▪  (RefLink[LogLinearPlot, paclet:ref/LogLinearPlot])  ▪  (RefLink[Plot, paclet:ref/Plot])  ▪  (RefLink[ParametricPlot, paclet:ref/ParametricPlot])}})}})

({{DocumentationFooterIconsRelatedTutorial.png, ({{Tutorials}, {▪(RefLinkPlain[Some Special Plots, paclet:tutorial/SomeSpecialPlots])}})}})

({{DocumentationFooterIconsRelatedGuide.png, ({{Related Guides}, {▪(RefLinkPlain[Function Visualization, paclet:guide/FunctionVisualization])}})}})