({{, (RefLink[LogLinearPlot, paclet:ref/LogLinearPlot])[f,{x,(Subscript[x, min]),(Subscript[x, max])}]
generates a log-linear plot of f as a function of x from (Subscript[x, min]) to (Subscript[x, max]). }, {, (RefLink[LogLinearPlot, paclet:ref/LogLinearPlot])[{(Subscript[f, 1]),(Subscript[f, 2]),…},{x,(Subscript[x, min]),(Subscript[x, max])}]
plots several functions (Subscript[f, i]). }, {, (RefLink[LogLinearPlot, paclet:ref/LogLinearPlot])[{…,w[(Subscript[f, i])],…},…]
plots (Subscript[f, i]) with features defined by the symbolic wrapper w.}, {, (RefLink[LogLinearPlot, paclet:ref/LogLinearPlot])[…,{x}∈reg]
takes the variable x to be in the geometric region reg.}})

OpenersNotesSection(Spacer1)Details and Options

(RefLink[LogLinearPlot, paclet:ref/LogLinearPlot]) effectively generates a curve in which f is plotted against (RefLink[Log, paclet:ref/Log])[x], but with tick marks indicating the original values of x.

(RefLink[LogLinearPlot, paclet:ref/LogLinearPlot]) makes logarithmic functions appear as straight lines.

(RefLink[LogLinearPlot, paclet:ref/LogLinearPlot]) evaluates f at different values of x to create a smooth curve of the form {x,f[x]}.

Gaps are left at any x where the (Subscript[f, i]) evaluate to anything other than real numbers or 
(RefLink[Quantity, paclet:ref/Quantity]).

The limits (Subscript[x, min]) and (Subscript[x, max]) can be real numbers or (RefLink[Quantity, paclet:ref/Quantity]) expressions.

The region reg can be any (RefLink[RegionQ, paclet:ref/RegionQ]) object in 1D.

(RefLink[LogLinearPlot, paclet:ref/LogLinearPlot]) treats the variable x as local, effectively using (RefLink[Block, paclet:ref/Block]).

(RefLink[LogLinearPlot, paclet:ref/LogLinearPlot]) has attribute (RefLink[HoldAll, paclet:ref/HoldAll]) and evaluates f only after assigning specific numerical values to x.

In some cases, it may be more efficient to use (RefLink[Evaluate, paclet:ref/Evaluate]) to evaluate f symbolically before specific numerical values are assigned to x.

The following wrappers w can be used for the (Subscript[f, i]):

Wrappers w can be applied at multiple levels:

(RefLink[Callout, paclet:ref/Callout]), (RefLink[Labeled, paclet:ref/Labeled]), and (RefLink[Placed, paclet:ref/Placed]) can use the following positions pos:

(RefLink[LogLinearPlot, paclet:ref/LogLinearPlot]) has the same options as (RefLink[Graphics, paclet:ref/Graphics]), with the following additions and changes:

Possible settings for (RefLink[ClippingStyle, paclet:ref/ClippingStyle]) are:

With the default settings (RefLink[Exclusions, paclet:ref/Exclusions])->(RefLink[Automatic, paclet:ref/Automatic]) and (RefLink[ExclusionsStyle, paclet:ref/ExclusionsStyle])->(RefLink[None, paclet:ref/None]), (RefLink[LogLinearPlot, paclet:ref/LogLinearPlot]) breaks curves at discontinuities and singularities it detects. (RefLink[Exclusions, paclet:ref/Exclusions])->(RefLink[None, paclet:ref/None]) joins across discontinuities and singularities.

(RefLink[Exclusions, paclet:ref/Exclusions])->{(Subscript[x, 1]),(Subscript[x, 2]),…} is equivalent to (RefLink[Exclusions, paclet:ref/Exclusions])->{x==(Subscript[x, 1]),x==(Subscript[x, 2]),…}.

(RefLink[PlotLegends, paclet:ref/PlotLegends])->"Expressions" uses the (Subscript[f, i]) as the legend text.

(RefLink[LogLinearPlot, paclet:ref/LogLinearPlot]) initially evaluates f at a number of equally spaced sample points specified by (RefLink[PlotPoints, paclet:ref/PlotPoints]). Then it uses an adaptive algorithm to choose additional sample points, subdividing a given interval at most (RefLink[MaxRecursion, paclet:ref/MaxRecursion]) times.

Since only a finite number of sample points are used, it is possible for (RefLink[LogLinearPlot, paclet:ref/LogLinearPlot]) to miss features of f. Increasing the settings for (RefLink[PlotPoints, paclet:ref/PlotPoints]) and (RefLink[MaxRecursion, paclet:ref/MaxRecursion]) will often catch such features.

Themes that affect curves include:

The arguments supplied to functions in (RefLink[MeshFunctions, paclet:ref/MeshFunctions]) and (RefLink[RegionFunction, paclet:ref/RegionFunction]) are x, y. Functions in (RefLink[ColorFunction, paclet:ref/ColorFunction]) are by default supplied with scaled versions of these arguments.

OpenersPrimaryExamplesSection(Spacer1)Examples  (109)

OpenersExampleSection0(Spacer1)Basic Examples  (4)

Make a plot with a logarithmic x scale:

LogLinearPlot[Tanh[x],{x,1,100}]

Plot several functions with a legend:

LogLinearPlot[{Tanh[x],Erf[x]},{x,1,100},PlotLegends->"Expressions"]

Label each curve:

LogLinearPlot[{Erf[x],Erfc[x]},{x,0.01,10},PlotLabels->"Expressions"]

Fill below a curve:

LogLinearPlot[Erf[x],{x,1,100},Filling->Bottom]

OpenersExampleSection1(Spacer1)Scope  (24)

OpenersExampleSubsection0(Spacer1)Sampling  (7)

More points are sampled when the function changes quickly:

LogLinearPlot[Cos[x],{x,0.1,10},Mesh->All]

The plot range is selected automatically:

LogLinearPlot[Abs[1/(x-5)],{x,1,10}]

Ranges where the function becomes nonreal are excluded:

LogLinearPlot[Sqrt[(x-3)(x-5)],{x,1,10}]

The curve is split when there are discontinuities in the function:

LogLinearPlot[Floor[Sqrt[x]],{x,1,100}]

Use (RefLink[PlotPoints, paclet:ref/PlotPoints]) and (RefLink[MaxRecursion, paclet:ref/MaxRecursion]) to control adaptive sampling:

Grid@Table[LogLinearPlot[Sin[x],{x,0.1,10},PlotPoints->pp,MaxRecursion->mr],{mr,{0,1,2}},{pp,{5,20}}]

Use (RefLink[PlotRange, paclet:ref/PlotRange]) to explore areas of interest:

{LogLinearPlot[{Erf[x]-Tanh[x]},{x,0.001,100}],LogLinearPlot[{Erf[x]-Tanh[x]},{x,0.001,100},PlotRange->{0,1}]}

Use (RefLink[Exclusions, paclet:ref/Exclusions]) to remove points or split the resulting curve:

LogLinearPlot[Tan[x],{x,1,15},Exclusions->{Cos[x]==0}]

OpenersExampleSubsection1(Spacer1)Labeling and Legending  (8)

Label curves with (RefLink[Labeled, paclet:ref/Labeled]):

LogLinearPlot[Evaluate@Table[Labeled[Log[n x]^2,Log[n x]^2],{n,1,3}],{x,0.1,3}]

Place the labels relative to the curves:

Table[LogLinearPlot[Labeled[x^Sin[x],"label",p],{x,1,6},PlotLabel->p],{p,{Above,Below,Before,After}}]

Label curves with (RefLink[PlotLabels, paclet:ref/PlotLabels]):

LogLinearPlot[{Log[x],1/x},{x,1,10},PlotLabels->{Log[x],1/x}]

Place the label near the curve at an x value:

LogLinearPlot[Labeled[Sin[x/Log[x]],"label",Log[5]],{x,2,100}]

Use a scaled position:

LogLinearPlot[Labeled[x^Sin[x],x^Sin[x],Scaled[0.3]],{x,1,2π}]

Specify the text position relative to the point:

LogLinearPlot[Labeled[x^Sin[x],x^Sin[x],{Scaled[0.3],Above}],{x,1,2π}]

Label curves automatically with (RefLink[Callout, paclet:ref/Callout]):

LogLinearPlot[{Callout[Erf[x],Erf[x]],Callout[Erfc[x],Erfc[x]]},{x,0.01,10}]

Place a label with specific locations:

LogLinearPlot[{Callout[Erf[x],Erf[x],5],Callout[Erfc[x],Erfc[x],0.05]},{x,0.01,10}]

Include legends for each curve:

LogLinearPlot[{x^Sin[x],x^Cos[x]},{x,1,2π},PlotLegends->{x^Sin[x],x^Cos[x]}]

Use (RefLink[Legended, paclet:ref/Legended]) to provide a legend for a specific curve:

LogLinearPlot[{x^Sin[x],Legended[Mean[{x^Sin[x],x^Cos[x]}],"average"],x^Cos[x]},{x,1,2π}]

Use (RefLink[Placed, paclet:ref/Placed]) to change the legend location:

LogLinearPlot[{x^Sin[x],Legended[Mean[{x^Sin[x],x^Cos[x]}],Placed["average",Below]],x^Cos[x]},{x,1,2π}]

OpenersExampleSubsection2(Spacer1)Presentation  (9)

Multiple curves are automatically colored to be distinct:

LogLinearPlot[{Erf[x],Erfc[x],Sech[x], 1/(x+1)},{x,0.01,100}]

Provide explicit styling to different curves:

LogLinearPlot[{Erf[x],Erfc[x],Sech[x], 1/(x+1)},{x,0.01,100},PlotStyle->{Thick,Automatic,Red,Dashed}]

Add labels:

LogLinearPlot[Erf[x],{x,10^-3,10^2},AxesLabel->Automatic,PlotLabel->Erf[x]]

Create legends from the functions:

LogLinearPlot[{Erf[x],Erfc[x]},{x,0.1,100},PlotLegends->"Expressions"]

Specify labels for legends:

LogLinearPlot[{Erf[x],Erfc[x]},{x,0.1,100},PlotLegends->{"one","two"}]

Provide an interactive (RefLink[Tooltip, paclet:ref/Tooltip]) for each curve:

LogLinearPlot[{Tooltip[Log[x]],Tooltip[1/x]},{x,10^-2,100}]

Create filled plots:

LogLinearPlot[{Erf[x],Erfc[x]},{x,0.01,100},Filling->Bottom]

Create an overlay mesh:

LogLinearPlot[Erf[x],{x,10^-3,10^2},Mesh->10,MeshFunctions->{#2&}]

Style the curve segments between mesh points:

LogLinearPlot[Erf[x],{x,10^-3,10^2},Mesh->{10^{-2,-1,0,1}},MeshFunctions->{#1&},MeshShading->{Purple,Orange},PlotStyle->Thick]

Use a theme with dark background in a high-contrast color scheme:

LogLinearPlot[{Log[x],1/x},{x,10^-2,100},PlotTheme->"Marketing"]

OpenersExampleSection2(Spacer1)Options  (76)

OpenersExampleSubsection3(Spacer1)ClippingStyle  (5)

Omit clipped regions of the plot:

LogLinearPlot[1/(x-3)^3,{x,1,10},AxesOrigin->{1,0},ClippingStyle->None]

Show the clipped regions like the rest of the curve:

LogLinearPlot[1/(x-3)^3,{x,1,10},AxesOrigin->{1,0},ClippingStyle->Automatic]

Show clipped regions with red lines:

LogLinearPlot[1/(x-3)^3,{x,1,10},AxesOrigin->{1,0},ClippingStyle->Red]

Show clipped regions as thick at the bottom and red at the top:

LogLinearPlot[1/(x-3)^3,{x,1,10},AxesOrigin->{1,0},ClippingStyle->{Red,Thick}]

Show clipped regions as red and thick:

LogLinearPlot[1/(x-3)^3,{x,1,10},AxesOrigin->{1,0},ClippingStyle->Directive[Red,Thick]]

OpenersExampleSubsection4(Spacer1)ColorFunction  (3)

Color by scaled x and y coordinates:

Table[LogLinearPlot[Sin[x/Log[x]],{x,2,100},ColorFunction->Function[{x,y},Evaluate[f]],PlotLabel->f],{f,{Hue[x],Hue[y]}}]

Color a curve red when its absolute y coordinate is above 0:

LogLinearPlot[Sin[x/Log[x]],{x,2,100},ColorFunction->Function[{x,y},If[y>0,Red,Black]],ColorFunctionScaling->False,PlotStyle->Thick]

Fill with the color used for the curve:

LogLinearPlot[Sin[x/Log[x]],{x,2,100},ColorFunction->Function[{x,y},Hue[y]],Filling->Bottom]

OpenersExampleSubsection5(Spacer1)ColorFunctionScaling  (1)

No argument scaling on the left, and automatic scaling on the right:

Table[LogLinearPlot[Sin[x]/Log[x],{x,2,100},PlotStyle->Thick,ColorFunction->Function[{x,y},Hue[y]],ColorFunctionScaling->cf],{cf,{False,True}}]

OpenersExampleSubsection6(Spacer1)EvaluationMonitor  (3)

Find the list of values sampled by (RefLink[LogPlot, paclet:ref/LogPlot]):

Reap[LogLinearPlot[Sin[x/Log[x]],{x,2,100},EvaluationMonitor:>Sow[x]];]//Short

Show where (RefLink[LogPlot, paclet:ref/LogPlot]) evaluates the function:

data=Reap[LogLinearPlot[Sin[x/Log[x]],{x,2,100},EvaluationMonitor:>Sow[{x,Sin[x/Log[x]]}]] ][[-1,1]];

ListLogLinearPlot[data ,Filling->Axis]

Count how many times the function is evaluated:

Block[{k=0},LogLinearPlot[Sin[x/Log[x]],{x,2,100},EvaluationMonitor:>k++];k]

OpenersExampleSubsection7(Spacer1)Exclusions  (2)

Use automatic methods for computing exclusions, in this case for a piecewise function:

LogPlot[Sum[Boole[2^(k-1)<x<2^k]x/(2^k-x),{k,5}],{x,0,2^5}]

Indicate that no exclusions should be computed:

LogPlot[Sum[Boole[2^(k-1)<x<2^k]x/(2^k-x),{k,5}],{x,0,2^5},Exclusions->None]

OpenersExampleSubsection8(Spacer1)ExclusionsStyle  (2)

Use dashed lines to indicate the vertical asymptotes:

LogPlot[Sum[Boole[2^(k-1)<x<2^k]x/(2^k-x),{k,5}],{x,0,2^5},ExclusionsStyle->Dashed]

Use blue points to highlight the exclusions:

LogPlot[Gamma[Floor[x]],{x,0,10},ExclusionsStyle->{None,Blue}]

OpenersExampleSubsection9(Spacer1)Filling  (7)

Use symbolic or explicit values:

Table[LogLinearPlot[Sin[x/Log[x]],{x,2,100},Filling->f],{f,{Axis,Top,Bottom,0}}]

Overlapping fills by default combine using opacity:

LogLinearPlot[{Sin[x],Cos[x]},{x,1,10},Filling->Axis]

Fill between curve 1 and the axis:

LogLinearPlot[{Sin[x],Cos[x]},{x,1,10},Filling->{1->Axis}]

Fill between curves 1 and 2:

LogLinearPlot[{Sin[x],Cos[x]},{x,1,10},Filling->{1->{2}}]

Fill between curves 1 and 2 with a specific style:

LogLinearPlot[{Sin[x],Cos[x]},{x,1,10},Filling->{1->{{2},Yellow}}]

Fill between curves 1 and 2; use yellow when 1 is below 2 and green when 1 is above 2:

LogLinearPlot[{Sin[x],Cos[x]},{x,1,10},Filling->{1->{{2},{Yellow,Green}}}]

Fill between curves 1 and y==0 with yellow:

LogLinearPlot[{Sin[x],Cos[x]},{x,1,10},Filling->{1->{0,Yellow}}]

OpenersExampleSubsection10(Spacer1)FillingStyle  (4)

Use different fill colors:

Table[LogLinearPlot[Sin[x],{x,1,10},Filling->Bottom,FillingStyle->c],{c,{Red,Green,Blue,Yellow}}]

Fill with opacity 0.5 yellow:

LogLinearPlot[Sin[x],{x,1,10},Filling->Bottom,FillingStyle->Directive[Opacity[0.5],Yellow]]

Fill with red below y==0 and blue above:

LogLinearPlot[Sin[x],{x,1,10},Filling->0,FillingStyle->{Red,Blue}]

Use a variable filling style obtained from a (RefLink[ColorFunction, paclet:ref/ColorFunction]):

LogLinearPlot[Sin[x],{x,1,10},ColorFunction->Function[{x,y},Hue[y]],Filling->0,FillingStyle->Automatic]

OpenersExampleSubsection11(Spacer1)LabelingSize  (4)

Textual labels are shown at their actual sizes:

LogLinearPlot[{Log[x],x},{x,1,10},PlotLabels->{"barcarole","perilously"}]

Image labels are automatically resized:

LogLinearPlot[{Log[x],x},{x,1,10},PlotLabels->{,}]

Specify a maximum size for textual labels:

LogLinearPlot[{Log[x],x},{x,1,10},PlotLabels->{"barcarole","perilously"},LabelingSize->30]

Specify a maximum size for image labels:

LogLinearPlot[{Log[x],x},{x,1,10},PlotLabels->{,},LabelingSize->50]

Show image labels at their natural sizes:

LogLinearPlot[{Log[x],x},{x,1,10},PlotLabels->{,},LabelingSize->Full]

OpenersExampleSubsection12(Spacer1)MaxRecursion  (2)

The default sampling mesh:

LogLinearPlot[Sin[x],{x,1,20},Mesh->All]

Each level of (RefLink[MaxRecursion, paclet:ref/MaxRecursion]) will subdivide the initial mesh into a finer mesh:

Table[LogLinearPlot[Sin[x],{x,1,20},MaxRecursion->i,Mesh->All,Ticks->None],{i,{0,3,6}}]

OpenersExampleSubsection13(Spacer1)Mesh  (3)

Show the initial and final sampling meshes:

Table[LogLinearPlot[Erf[x],{x,10^-2,10^2},Mesh->m],{m,{Full,All}}]

Use 20 mesh levels evenly spaced in the unscaled x direction:

LogLinearPlot[Erf[x],{x,10^-2,10^2},Mesh->20]

Use an explicit list of values for the mesh in the x direction:

LogLinearPlot[Erf[x],{x,10^-2,10^2},Mesh->{10^{-1,0,1}}]

OpenersExampleSubsection14(Spacer1)MeshFunctions  (4)

Use a mesh evenly spaced in the x and y directions:

Table[LogLinearPlot[Erf[x],{x,10^-2,10^2},MeshFunctions->{Function[{x,y},Evaluate[f]]},Mesh->10,MeshStyle->PointSize[Medium]],{f,{x,y}}]

Mesh functions use the unscaled values in the x direction:

LogLinearPlot[Erf[x],{x,10^-2,10^2},Mesh->10,MeshFunctions->{#1&},MeshStyle->PointSize[Medium]]

Use (RefLink[Log, paclet:ref/Log]) to scale the mesh functions:

LogLinearPlot[Erf[x],{x,10^-2,10^2},MeshFunctions->{Log[#1]&},Mesh->10,MeshStyle->PointSize[Medium]]

Show 5 mesh levels in the x direction (red) and 10 in the y direction (blue):

LogLinearPlot[Erf[x],{x,10^-2,10^2},Mesh->{5,10},MeshFunctions->{#1&,#2&},MeshStyle->{Directive[PointSize[Medium],Red],Blue}]

OpenersExampleSubsection15(Spacer1)MeshShading  (6)

Alternate red and blue segments of equal width in the x direction:

LogLinearPlot[Erf[x],{x,10^-2,10^2},MeshFunctions->{Log[#1]&},Mesh->15,MeshShading->{Red,Blue}]

Use (RefLink[None, paclet:ref/None]) to remove segments:

LogLinearPlot[Erf[x],{x,10^-2,10^2},MeshFunctions->{Log[#1]&},Mesh->15,MeshShading->{Red,None}]

(RefLink[MeshShading, paclet:ref/MeshShading]) can be used with (RefLink[PlotStyle, paclet:ref/PlotStyle]):

LogLinearPlot[Erf[x],{x,10^-2,10^2},MeshFunctions->{Log[#1]&},Mesh->15,PlotStyle->Thick,MeshShading->{Red,Blue}]

(RefLink[MeshShading, paclet:ref/MeshShading]) has higher priority than (RefLink[PlotStyle, paclet:ref/PlotStyle]) for styling the curve:

LogLinearPlot[Erf[x],{x,10^-2,10^2},MeshFunctions->{Log[#1]&},Mesh->15,PlotStyle->Green,MeshShading->{Red,Blue}]

Use (RefLink[PlotStyle, paclet:ref/PlotStyle]) for some segments by setting (RefLink[MeshShading, paclet:ref/MeshShading]) to (RefLink[Automatic, paclet:ref/Automatic]):

LogLinearPlot[Erf[x],{x,10^-2,10^2},MeshFunctions->{Log[#1]&},Mesh->15,PlotStyle->Directive[Thick,Yellow],MeshShading->{Red,Automatic}]

(RefLink[MeshShading, paclet:ref/MeshShading]) can be used with (RefLink[ColorFunction, paclet:ref/ColorFunction]):

LogLinearPlot[Erf[x],{x,10^-2,10^2},MeshFunctions->{Log[#1]&},Mesh->15,PlotStyle->Thick,MeshShading->{Black,Automatic},
ColorFunction->Function[{x,y},Hue[Log[x]/10]]]

OpenersExampleSubsection16(Spacer1)MeshStyle  (4)

Color the mesh the same color as the plot:

LogLinearPlot[Erf[x],{x,10^-2,10^2},MeshFunctions->{Log[#1]&},Mesh->15,MeshStyle->Automatic]

Use a red mesh in the x direction:

LogLinearPlot[Erf[x],{x,10^-2,10^2},MeshFunctions->{Log[#1]&},Mesh->15,MeshStyle->Red]

Use a red mesh in the x direction and a blue mesh in the y direction:

LogLinearPlot[Erf[x],{x,10^-2,10^2},MeshFunctions->{#1&,#2&},Mesh->15,MeshStyle->{Red,Blue}]

Use big red mesh points in the x direction:

LogLinearPlot[Erf[x],{x,10^-2,10^2},Mesh->{2^Range[-6,6]},MeshStyle->Directive[PointSize[Large],Red]]

OpenersExampleSubsection17(Spacer1)PerformanceGoal  (2)

Generate a higher-quality plot:

Timing[LogLinearPlot[Sin[1/x],{x,10^-5,1},PerformanceGoal->"Quality"]]

Emphasize performance, possibly at the cost of quality:

Timing[LogLinearPlot[Sin[1/x],{x,10^-5,1},PerformanceGoal->"Speed"]]

OpenersExampleSubsection18(Spacer1)PlotLabel  (1)

Add an overall label to the plot:

LogLinearPlot[Log[x],{x,1,10},PlotLabel->"logarithmic function"]

OpenersExampleSubsection19(Spacer1)PlotLabels  (5)

Specify text to label curves:

LogLinearPlot[{Log[x],x},{x,1,2π},PlotLabels->{"log(x)","x"}]

Place the labels above the curves:

LogLinearPlot[{x^Sin[x],x^Cos[x]},{x,1,2π},PlotLabels->Placed["Expressions",Above]]

Place the labels differently for each curve:

LogLinearPlot[{x^Sin[x],x^Cos[x]},{x,1,2π},PlotLabels->{Placed[x^Sin[x],After],Placed[x^Cos[x],Above]}]

(RefLink[PlotLabels, paclet:ref/PlotLabels])->"Expressions" uses functions as curve labels:

LogLinearPlot[{Log[x],1/x},{x,1,2π},PlotLabels->"Expressions"]

Use callouts to identify the curves:

LogLinearPlot[{Erf[x],Erfc[x]},{x,0.1,100},PlotLabels->{Callout[Erf[x],{Scaled[0.9],Below}],Callout[Erfc[x],{Scaled[0.9],Above}]}]

Use (RefLink[None, paclet:ref/None]) to not add a label:

LogLinearPlot[{x^Sin[x],x^Cos[x]},{x,1,2π},PlotLabels->{x^Sin[x],None}]

OpenersExampleSubsection20(Spacer1)PlotLegends  (6)

No legends are used by default:

LogLinearPlot[{Erf[x],Erfc[x]},{x,0.01,100}]

Create a legend based on the functions:

LogLinearPlot[{Erf[x],Erfc[x]},{x,0.01,100},PlotLegends->"Expressions"]

Create a legend with placeholder text:

LogLinearPlot[{Erf[x],Erfc[x]},{x,0.01,100},PlotLegends->Automatic]

(RefLink[PlotLegends, paclet:ref/PlotLegends]) picks up (RefLink[PlotStyle, paclet:ref/PlotStyle]) values automatically:

LogLinearPlot[{Erf[x],Erfc[x]},{x,0.01,100},PlotStyle->{Red,Blue},PlotLegends->Automatic]

Use (RefLink[Placed, paclet:ref/Placed]) to position legends:

LogLinearPlot[{Erf[x],Erfc[x]},{x,0.01,100},PlotStyle->{Red,Blue},PlotLegends->Placed[Automatic,Below]]

Place legends inside:

LogLinearPlot[{Erf[x],Erfc[x]},{x,0.01,100},PlotStyle->{Red,Blue},PlotLegends->Placed[Automatic,{0.85,0.5}]]

Use (RefLink[LineLegend, paclet:ref/LineLegend]) to modify the appearance of the legend:

LogLinearPlot[{Erf[x],Erfc[x]},{x,0.01,100},PlotLegends->LineLegend["Expressions",LegendFunction->Frame]]

OpenersExampleSubsection21(Spacer1)PlotPoints  (1)

Use more initial points to get a smoother curve:

Table[LogLinearPlot[Sin[x],{x,0.1,10},PlotPoints->p,MaxRecursion->0],{p,{5,10,15,50}}]

OpenersExampleSubsection22(Spacer1)PlotRange  (2)

Show the curve over the whole domain:

LogLinearPlot[Sqrt[(x-3)],{x,1,10}]

Show the curve only where it is real-valued:

LogLinearPlot[Sqrt[(x-3)],{x,1,10},PlotRange->Automatic]

OpenersExampleSubsection23(Spacer1)PlotStyle  (6)

Use different style directives:

Table[LogLinearPlot[Erf[x],{x,0.01,100},PlotStyle->ps],{ps,{Red,Thick,Dashed,Directive[Red,Thick]}}]

By default, different styles are chosen for multiple curves:

LogLinearPlot[{Erf[x],Erfc[x],Sech[x], 1/(x+1)},{x,0.01,100}]

Explicitly specify the style for different curves:

LogLinearPlot[{Erf[x],Erfc[x],Sech[x], 1/(x+1)},{x,0.01,100},PlotStyle->{Thick,Darker[Green],Purple,Dashing[{Medium,Small}]}]

(RefLink[PlotStyle, paclet:ref/PlotStyle]) can be combined with (RefLink[ColorFunction, paclet:ref/ColorFunction]):

LogLinearPlot[Erf[x],{x,0.01,100},PlotStyle->Thick,ColorFunction->Function[{x,y},Hue[y]]]

(RefLink[PlotStyle, paclet:ref/PlotStyle]) can be combined with (RefLink[MeshShading, paclet:ref/MeshShading]):

LogLinearPlot[Erf[x],{x,0.01,100},PlotStyle->Directive[Opacity[0.5],Thick],Mesh->10,MeshFunctions->{Log[#1]&},MeshShading->{Red,Blue}]

(RefLink[MeshStyle, paclet:ref/MeshStyle]) by default uses the same style as (RefLink[PlotStyle, paclet:ref/PlotStyle]):

LogLinearPlot[Erf[x],{x,0.01,100},PlotStyle->Red,Mesh->All]

OpenersExampleSubsection24(Spacer1)PlotTheme  (1)

Use a theme with grid lines and simple ticks:

LogLinearPlot[{Erfc[x],Erf[x]},{x,0.01,10},PlotTheme->"Business"]

Add another theme with legends:

LogLinearPlot[{Erfc[x],Erf[x]},{x,0.01,10},PlotTheme->{"Business","Detailed"}]

Change the plot style:

LogLinearPlot[{Erfc[x],Erf[x]},{x,0.01,10},PlotTheme->{"Business","Detailed"},PlotStyle->96]

OpenersExampleSubsection25(Spacer1)RegionFunction  (2)

Show the curve where 0<x (mod 2 π)<π:

LogLinearPlot[Cos[x],{x,1,50},RegionFunction->Function[{x,y},0<Mod[x,2Pi]<Pi]]

Exclude the region where (1/4)<y<(3/4):

LogLinearPlot[Erf[x],{x,0.01,100},RegionFunction->Function[{x,y},Not[1/4<y<3/4]]]

OpenersExampleSection3(Spacer1)Applications  (1)

The A-weighting curve used for measuring perceived loudness of sound:

Ra[f_]:=(((12200^2)(f^4))/(((f^2)+(20.6^2))(Sqrt[((f^2)+(107.7^2))((f^2)+(737.9^2))])((f^2)+(12200^2))))

LogLinearPlot[Ra[f],{f,10,10^5}]

OpenersExampleSection4(Spacer1)Properties & Relations  (4)

(RefLink[LogLinearPlot, paclet:ref/LogLinearPlot]) samples more points where it needs to:

LogLinearPlot[Sin[x],{x,1,10},Mesh->All]

(RefLink[LogLinearPlot, paclet:ref/LogLinearPlot]) is a special case of (RefLink[Plot, paclet:ref/Plot]) for curves:

{LogLinearPlot[Sin[x],{x,1,10}],Plot[Sin[Exp[x]],{x,Log[1],Log[10]},AxesOrigin->{0,-1}]}

Use (RefLink[LogPlot, paclet:ref/LogPlot]) and (RefLink[LogLogPlot, paclet:ref/LogLogPlot]) for logarithmic plots in the y direction:

LogLogPlot[Abs[10^2/((I ω)^2+100)],{ω,10^0,10^5}]

Use (RefLink[ListLogLinearPlot, paclet:ref/ListLogLinearPlot]) for data:

{ListLogLinearPlot[Table[{x,Erf[x]},{x,0.01,10,0.05}],PlotRange->All],LogLinearPlot[Erf[x],{x,0.01,10}]}

({{DocumentationFooterIconsRelatedFunction.png, ({{See Also}, {(RefLink[ListLogLinearPlot, paclet:ref/ListLogLinearPlot])  ▪  (RefLink[LogPlot, paclet:ref/LogPlot])  ▪  (RefLink[LogLogPlot, paclet:ref/LogLogPlot])  ▪  (RefLink[Plot, paclet:ref/Plot])  ▪  (RefLink[ParametricPlot, paclet:ref/ParametricPlot])}})}})

({{DocumentationFooterIconsRelatedTutorial.png, ({{Tutorials}, {▪(RefLinkPlain[Some Special Plots, paclet:tutorial/SomeSpecialPlots])}})}})

({{DocumentationFooterIconsRelatedGuide.png, ({{Related Guides}, {▪(RefLinkPlain[Function Visualization, paclet:guide/FunctionVisualization])}})}})