({{, (RefLink[ExampleData, paclet:ref/ExampleData])["type"]
gives a list of names of examples of the specified type.}, {, (RefLink[ExampleData, paclet:ref/ExampleData])[{"type","name"}] 
gives the default form of the named example of the specified type.}, {, (RefLink[ExampleData, paclet:ref/ExampleData])[{"type","name"},"elem"]
gives the specified element or property of an example.}})

OpenersNotesSection(Spacer1)Details

Typical types include:

(RefLink[ExampleData, paclet:ref/ExampleData])[{"type","name"},"Properties"] gives a list of the elements or properties available for a particular example.

In addition to elements specific to the content of an example, the following properties are typically included:

(RefLink[ExampleData, paclet:ref/ExampleData])[] gives a list of names of types of examples.

OpenersPrimaryExamplesSection(Spacer1)Examples  (54)

OpenersExampleSection0(Spacer1)Basic Examples  (4)

A standard image processing test image:

ExampleData[{"TestImage","House"}]

3D geometry for a space shuttle:

ExampleData[{"Geometry3D","SpaceShuttle"}]

The first 400 characters of the text of the US Declaration of Independence:

StringTake[ExampleData[{"Text","DeclarationOfIndependence"}],400]

A list of example texture images:

ExampleData["Texture"]

OpenersExampleSection1(Spacer1)Scope  (42)

OpenersExampleSubsection0(Spacer1)Image Data  (8)

An aerial image of the Pentagon:

ExampleData[{"AerialImage","Pentagon"}]

ExampleData[{"AerialImage","Pentagon"},"Properties"]

ExampleData[{"AerialImage","Pentagon"},"ImageSize"]

2D Fourier transform of raw data:

MatrixPlot[Abs[Fourier[ExampleData[{"AerialImage","Pentagon"},"Data"]]]]

Wood texture:

ExampleData[{"Texture","Wood"}]

Color wood texture:

ExampleData[{"ColorTexture","GoldenOak"}]

A color test image:

ExampleData[{"TestImage","Mandrill"}]

A monochrome test image:

ExampleData[{"TestImage","Couple2"}]

OpenersExampleSubsection1(Spacer1)Animation Data  (3)

ExampleData[{"TestAnimation","ToyVehicles"}]

ExampleData[{"TestAnimation","ToyVehicles"},"Properties"]

Find the names of the first four frames:

Take[ExampleData[{"TestAnimation","ToyVehicles"},"Frames"],4]

Extract the frames:

Show[ExampleData[#],ImageSize->Tiny]&/@%

OpenersExampleSubsection2(Spacer1)Image Collections  (2)

Images in a collection:

ExampleData[{"TestImageSet","Oxford2011"}]

All image collections:

ExampleData["TestImageSet"]

OpenersExampleSubsection3(Spacer1)3D Geometry  (3)

The Stanford bunny:

ExampleData[{"Geometry3D","StanfordBunny"}]

Get a list of possible properties:

ExampleData[{"Geometry3D","StanfordBunny"},"Properties"]

Length[%]

Geometric representation:

bunny=ExampleData[{"Geometry3D","StanfordBunny"},"Region"]

Bounds:

RegionBounds[bunny]

Surface area:

Area[bunny]

OpenersExampleSubsection4(Spacer1)3D Image Data  (2)

Example of a 3D image:

ExampleData[{"TestImage3D","CTengine"}]

Properties for 3D images:

ExampleData[{"TestImage3D","CTengine"},"Properties"]

OpenersExampleSubsection5(Spacer1)Numerical Data  (5)

Count the number of test matrices:

Length[ExampleData["Matrix"]]

Example of a sparse matrix:

MatrixPlot[ExampleData[{"Matrix","FIDAP007"}]]

Properties for example matrices:

ExampleData[{"Matrix","FIDAP007"},"Properties"]

Find a complete linear programming example:

ExampleData[{"LinearProgramming","afiro"}]

Plot the constraint matrix for a linear programming example:

MatrixPlot[ExampleData[{"LinearProgramming","bgetam"},"ConstraintMatrix"]]

OpenersExampleSubsection6(Spacer1)Statistical Data  (6)

Find the first 10 statistical datasets available:

Take[ExampleData["Statistics"],10]

List of available properties for a dataset:

ExampleData[{"Statistics","AnimalWeights"},"Properties"]

The first 5 rows of this dataset contain brain and body weights of various animals:

Take[ExampleData[{"Statistics","AnimalWeights"}],5]//MatrixForm

Alternatively, use the "DataElements" property:

Take[ExampleData[{"Statistics","AnimalWeights"},"DataElements"],5]//MatrixForm

Column types are either "Numeric" or "Categorical":

ExampleData[{"Statistics","AnimalWeights"},"ColumnTypes"]//TableForm

Description for Old Faithful dataset:

ExampleData[{"Statistics","OldFaithful"},"Description"]

ExampleData[{"Statistics","OldFaithful"},"LongDescription"]//TraditionalForm

Column headings:

ExampleData[{"Statistics","OldFaithful"},"ColumnHeadings"]//Column

Column descriptions:

ExampleData[{"Statistics","OldFaithful"},"ColumnDescriptions"]//Column

Dimension and number of observations for the dataset:

ExampleData[{"Statistics","OldFaithful"},"Dimensions"]

ExampleData[{"Statistics","OldFaithful"},"ObservationCount"]

Create a (RefLink[SmoothHistogram, paclet:ref/SmoothHistogram]) of a dataset:

SmoothHistogram[ExampleData[{"Statistics","BuffaloSnow"}],PlotLabel->ExampleData[{"Statistics","BuffaloSnow"},"Name"]]

Compute descriptive statistics of numerical entries:

data=ExampleData[{"Statistics","CPUPerformance"}];

types=ExampleData[{"Statistics","CPUPerformance"},"ColumnTypes"]

headings=ExampleData[{"Statistics","CPUPerformance"},"ColumnHeadings"]

Choose numeric columns:

numeric=Pick[Transpose@data,types,"Numeric"];

Calculate (RefLink[Mean, paclet:ref/Mean]) and (RefLink[StandardDeviation, paclet:ref/StandardDeviation]) for each characteristic:

mean=Mean/@numeric//N;
sd=StandardDeviation/@numeric//N;

TableForm[{mean,sd},TableHeadings->{{"Mean","StDev"},Pick[headings,types,"Numeric"]},TableSpacing->{2,1.2},TableAlignments->Center]

OpenersExampleSubsection7(Spacer1)Text  (8)

Find the first 10 example texts available:

Take[ExampleData["Text"],10]

First 400 characters of Darwin's On the Origin of Species:

StringTake[ExampleData[{"Text","OriginOfSpecies"}],400]

List of properties:

ExampleData[{"Text","OriginOfSpecies"},"Properties"]

Author and title:

ExampleData[{"Text","OriginOfSpecies"},"Author"]

ExampleData[{"Text","OriginOfSpecies"},"FullTitle"]

Number of words in On the Origin of Species:

Length[ExampleData[{"Text","OriginOfSpecies"},"Words"]]

Use "FormattedText" to get a string with line breaks etc.:

StringTake[ExampleData[{"Text","ToBeOrNotToBe"},"FormattedText"],200]

Generate a formatted notebook of the US Declaration of Independence:

NotebookPut[ExampleData[{"Text","DeclarationOfIndependence"},"NotebookExpression"]]

Generate "Latinized text":

StringTake[ExampleData[{"Text","LoremIpsum"}],200]

OpenersExampleSubsection8(Spacer1)Audio  (3)

Properties of an audio sample:

ExampleData[{"Audio","IRStairway"},"Properties"]

Import an audio sample:

ExampleData[{"Audio","Bird"},"Audio"]

Get the audio description:

ExampleData[{"Audio","Bird"},"Description"]

All audio samples:

ExampleData["Audio"]

OpenersExampleSubsection9(Spacer1)Sound  (2)

"Houston, we have a problem":

ExampleData[{"Sound","Apollo13Problem"}]

ExampleData[{"Sound","Apollo13Problem"},"Properties"]

OpenersExampleSection3(Spacer1)Applications  (5)

The Declaration of Independence, formatted very small:

Pane[Style[ExampleData[{"Text","DeclarationOfIndependence"},"FormattedText"],3]]

Recolor a test image:

ArrayPlot[ExampleData[{"TestImage","House"},"GrayLevels"],ColorFunction->"Rainbow"]

Make a contour plot of gray levels in a test image:

ListContourPlot[Reverse[ExampleData[{"TestImage","House"},"GrayLevels"]],ColorFunction->"Pastel",MaxPlotPoints->100]

Generate 3D graphics containing multiple space shuttles:

Graphics3D[Table[Translate[ExampleData[{"Geometry3D","SpaceShuttle"},"GraphicsComplex"],RandomReal[30,{3}]],{6}]]

Plot the word frequency distribution for On the Origin of Species:

ListLogLogPlot[Reverse[Sort[Last/@Tally[ExampleData[{"Text","OriginOfSpecies"},"Words"]]]],Joined->True,Filling->Axis,PlotRange->All,Frame->True]

OpenersExampleSection4(Spacer1)Neat Examples  (3)

Make a 3D graphic from a test image:

ListPlot3D[ExampleData[{"TestImage","Clock"},"GrayLevels"],PlotStyle->Yellow,Mesh->None]

Generate a vector field from the normals for a 3D object:

Graphics3D[Line[MapThread[{#,#+#2}&,{ExampleData[{"Geometry3D","Beethoven"},"VertexData"],ExampleData[{"Geometry3D","Beethoven"},"VertexNormals"]}]]]

Hamlet's soliloquy, with repeated words successively larger:

Text[Row[With[{data=ExampleData[{"Text","ToBeOrNotToBe"},"Words"]},MapIndexed[Style[#,2Count[Take[data,First[#2]],#]]&,data]]," "]]

({{DocumentationFooterIconsRelatedFunction.png, ({{See Also}, {(RefLink[ResourceData, paclet:ref/ResourceData])  ▪  (RefLink[Import, paclet:ref/Import])  ▪  (RefLink[RandomChoice, paclet:ref/RandomChoice])  ▪  (RefLink[RandomEntity, paclet:ref/RandomEntity])  ▪  (RefLink[WikipediaData, paclet:ref/WikipediaData])  ▪  (RefLink[PolyhedronData, paclet:ref/PolyhedronData])  ▪  (RefLink[GraphData, paclet:ref/GraphData])  ▪  (RefLink[KnotData, paclet:ref/KnotData])  ▪  (RefLink[CountryData, paclet:ref/CountryData])  ▪  (RefLink[PlanetData, paclet:ref/PlanetData])}})}})

({{DocumentationFooterIconsRelatedTutorial.png, ({{Tutorials}, {▪(RefLinkPlain[Sound, paclet:tutorial/Sound])}, {▪(RefLinkPlain[The Representation of Sound, paclet:tutorial/TheRepresentationOfSound])}, {▪(RefLinkPlain[Importing Graphics and Sounds, paclet:tutorial/ImportingGraphicsAndSounds])}})}})

({{DocumentationFooterIconsRelatedGuide.png, ({{Related Guides}, {▪(RefLinkPlain[Graph Construction & Representation, paclet:guide/GraphConstructionAndRepresentation])}, {▪(RefLinkPlain[Mathematical Data, paclet:guide/MathematicalData])}, {▪(RefLinkPlain[Random Variables, paclet:guide/RandomVariables])}, {▪(RefLinkPlain[Graphs & Networks, paclet:guide/GraphsAndNetworks])}, {▪(RefLinkPlain[Creating & Importing Images, paclet:guide/CreatingAndImportingImages])}, {▪(RefLinkPlain[Tuning & Debugging, paclet:guide/TuningAndDebugging])}, {▪(RefLinkPlain[Geometric Computation, paclet:guide/GeometricComputation])}, {▪(RefLinkPlain[3D Images, paclet:guide/3DImages])}, {▪(RefLinkPlain[Image Processing & Analysis, paclet:guide/ImageProcessing])}, {▪(RefLinkPlain[3D Printing, paclet:guide/3DPrinting])}, {▪(RefLinkPlain[Plotting Options, paclet:guide/PlottingOptions])}, {▪(RefLinkPlain[Text Analysis, paclet:guide/TextAnalysis])}, {▪(RefLinkPlain[Audio Representation, paclet:guide/AudioRepresentation])}, {▪(RefLinkPlain[Audio Processing, paclet:guide/AudioProcessing])}})}})

({{(Spacer1), ({{(Spacer1)Related Links}, {(Spacer1)▪(WebLink[(Spacer1)ExampleData Source Information, http://reference.wolfram.com/language/note/ExampleDataSourceInformation.html])}, {(WebLink[DocumentationFooterIconsRelatedLinks-EIWL.png(Spacer1)An Elementary Introduction to the Wolfram Language, https://www.wolfram.com/language/elementary-introduction/34-associations.html])(WebLink[: Associations, https://www.wolfram.com/language/elementary-introduction/34-associations.html])}})}})