({{, (RefLink[Epilog, paclet:ref/Epilog])
is an option for graphics functions that gives a list of graphics primitives to be rendered after the main part of the graphics is rendered. }})

OpenersNotesSection(Spacer1)Details

In three-dimensional graphics, two-dimensional graphics primitives can be specified by the (RefLink[Epilog, paclet:ref/Epilog]) option. The graphics primitives are rendered in a 0,1 coordinate system.

OpenersPrimaryExamplesSection(Spacer1)Examples  (11)

OpenersExampleSection0(Spacer1)Basic Examples  (2)

Draw the sample points on top of the plot:

data=Table[{i,RandomReal[i]},{i,10}];

ListLinePlot[data,Epilog->{PointSize[Medium],Point[data]},InterpolationOrder->2]

Place text at the right bottom corner of the 3D graphic:

SphericalPlot3D[ϕ,{θ,0,Pi},{ϕ,0,3Pi},Epilog->Inset[Framed[Style["Spiral",20],Background->LightYellow],{Right,Bottom},{Right,Bottom}]]

OpenersExampleSection1(Spacer1)Scope  (2)

The ordinary coordinate system is used for (RefLink[Epilog, paclet:ref/Epilog]) in 2D graphics:

Table[Graphics[{Pink,Disk[{0,0},10]},Axes->True,Epilog->Disk[p,2]],{p,{{-5,-5},{0,0},{5,5}}}]

A scaled 0,1 coordinate system is used for (RefLink[Epilog, paclet:ref/Epilog]) in 3D graphics:

Table[Graphics3D[Sphere[{0,0,0},10],Epilog->Disk[p,.1]],{p,{{.2,.2},{.5,.5},{.8,.8}}}]

OpenersExampleSection2(Spacer1)Applications  (3)

Display the sample points, as well as the lines joining them, on top of the interpolated plot:

data=Table[{i,RandomReal[i]},{i,10}];

ListLinePlot[data,Epilog->{Green,Line[data],PointSize[Medium],Red,Point[data]},InterpolationOrder->2]

The same result, using a duplicated dataset with linear interpolation and meshes:

ListLinePlot[{data,data},InterpolationOrder->{2,1},PlotStyle->{Automatic,Green},Mesh->Full,MeshStyle->Directive[PointSize[Medium],Red]]

Draw large points where the line and the curve intersect:

{f,g}={27 x+130,-12-58 x+(x^2)+(x^3)};

Plot[{f,g},{x,-10,10},Epilog->{PointSize[Large],(Point[{#,f/.x->#}]&)/@(x/.NSolve[f==g,x])}]

Alternatively, use (RefLink[MeshFunctions, paclet:ref/MeshFunctions]) to find the intersections:

Plot[{f,g},{x,-10,10},MeshFunctions->{(f-g)/.x->#&},Mesh->{{0}},MeshStyle->PointSize[Large]]

Put a watermark on top of the graphic:

watermark=Style["Watermark",36,Bold,FontFamily->"Helvetica",Opacity[.3]];

SphericalPlot3D[ϕ,{θ,0,Pi},{ϕ,0,3Pi},Mesh->None,PlotStyle->Directive[Specularity[White, 50], Yellow],Epilog->Inset[watermark,Automatic,Automatic,Automatic,{1,1}]]

OpenersExampleSection3(Spacer1)Properties & Relations  (3)

Objects in (RefLink[Epilog, paclet:ref/Epilog]) are not part of the (RefLink[PlotRange, paclet:ref/PlotRange]) computation:

Graphics[{Pink,Disk[]},Epilog->Circle[{0,1}],Frame->True]

In 2D, the axes are drawn on top of the graphics:

Graphics[{Pink,Disk[]},Axes->True]

Objects in (RefLink[Epilog, paclet:ref/Epilog]) are drawn on top of any graphics, including the axes:

Graphics[{Pink,Disk[]},Axes->True,Epilog->{Blue,Disk[{0,0},.4]}]

In plot functions, (RefLink[PlotRangeClipping, paclet:ref/PlotRangeClipping]) clips the graphics including (RefLink[Epilog, paclet:ref/Epilog]) by default:

Plot[2Sin[x],{x,0,10},Epilog->Circle[],AspectRatio->Automatic]

By setting (RefLink[PlotRangeClipping, paclet:ref/PlotRangeClipping]) to (RefLink[False, paclet:ref/False]), the graphic can be drawn outside of the plot range:

Plot[2Sin[x],{x,0,10},Epilog->Circle[],PlotRangeClipping->False,AspectRatio->Automatic]

OpenersExampleSection4(Spacer1)Neat Examples  (1)

Image mask generated by  RegionPlot:

g=RegionPlot[.45^10<(x-.5)^10+(y-.5)^10,{x,0,1},{y,0,1},ColorFunction->"TemperatureMap"]

Apply the mask on top of 3D graphics, like a "picture frame":

Graphics3D[Cylinder[],Boxed->False,SphericalRegion->True,Epilog->First[g]]

({{DocumentationFooterIconsRelatedFunction.png, ({{See Also}, {(RefLink[Prolog, paclet:ref/Prolog])  ▪  (RefLink[AxesStyle, paclet:ref/AxesStyle])  ▪  (RefLink[PlotStyle, paclet:ref/PlotStyle])  ▪  (RefLink[DisplayFunction, paclet:ref/DisplayFunction])  ▪  (RefLink[Overlay, paclet:ref/Overlay])}})}})

({{DocumentationFooterIconsRelatedTutorial.png, ({{Tutorials}, {▪(RefLinkPlain[Graphics Directives and Options, paclet:tutorial/GraphicsDirectivesAndOptions])}})}})

({{DocumentationFooterIconsRelatedGuide.png, ({{Related Guides}, {▪(RefLinkPlain[Combining Graphics, paclet:guide/CombiningGraphics])}, {▪(RefLinkPlain[Graphics Options & Styling, paclet:guide/GraphicsOptionsAndStyling])}, {▪(RefLinkPlain[Graphics Annotation & Appearance, paclet:guide/GraphicsAnnotationAndAppearance])}})}})