Minimize[{x-y,-3 (x^2)+2 x y-(y^2)≥-1},{x,y}]

NMinimize[{x-y,-3 (x^2)+2 x y-(y^2)≥-1},{x,y}]

FindMinimum[{x-y,-3 (x^2)+2 x y-(y^2)≥-1},{x,y}]

NMaximize[Sin[x+y]-(x^2)-(y^2),{x,y}]

NMinimize[{(x^2)+(((y-.5))^2),y≥0&&y≥x+1},{x,y}]

NMinimize[{(x^2)+(y^2),x≥1||y≥2},{x,y}]

NMinimize[{(((x-1/3))^2)+(((y-1/3))^2),x∈Integers},{x,y}]

NMinimize[(x^2),{{x,3,4}}]

NMinimize[{(x^2),3≤x≤4},{x}]

NMinimize[{(x^2)+(y^2)+(z^2),3≤x≤4},{x,{y,2,5},z}]

NMinimize[4(x^4)-4(x^2)+1, x, Method->"NelderMead"]

NMinimize[4(x^4)-4(x^2)+1, x, Method->{"NelderMead", "RandomSeed"->111}]

Clear[f];
f=(E^(Sin[50 x]))+Sin[60 (E^y)]+Sin[70 Sin[x]]+Sin[Sin[80 y]]-Sin[10 (x+y)]+(1/4) ((x^2)+(y^2));
Plot3D[f, {x, -1, 1}, {y, -1, 1}, PlotPoints->50, Mesh->False]

NMinimize[f,{x,y},Method->"RandomSearch"]

NMinimize[f,{x,y},Method->{"RandomSearch","SearchPoints"->250}]

NelderMead specific options.

NMinimize[{100 (((y-(x^2)))^2)+(((1-x))^2),(x^2)+(y^2)≤1},{x,y},Method->"NelderMead"]

Clear[a,f];a=Reverse/@Distribute[{{-32,-16,0,16,32},{-32,-16,0,16,32}},List];f=1/(0.002+Plus@@MapIndexed[1/(#2[[1]]+Plus@@(({x,y}-#1)^6))&,a]);Plot3D[f,{x,-50,50},{y,-50,50}, Mesh->None, PlotPoints->25]

Do[Print[NMinimize[f,{{x,-50,50},{y,-50,50}},Method->{"NelderMead","RandomSeed"->i}]],{i,5}]

Do[Print[NMinimize[f,{{x,-50,50},{y,-50,50}},Method->{"NelderMead", "ShrinkRatio"->0.95,"ContractRatio"->0.95,"ReflectRatio"->2,"RandomSeed"->i}]],{i,5}]

DifferentialEvolution specific options.

NMinimize[{100 (((y-(x^2)))^2)+(((1-x))^2),(x^2)+(y^2)≤1},{x,y},Method->"DifferentialEvolution"]

Clear[f,c,v,x1,x2,y1,y2,y3]

f=2 x1+3 x2+3 y1/2+2 y2-y3/2;
c={x1^2+y1==5/4,x2^(3/2)+3 y2/2==3,x1+y1≤8/5,4 x2/3+y2≤3,y3≤y1+y2,0≤x1≤10,0≤x2≤10,0≤y1≤1,0≤y2≤1,0≤y3≤1,{y1,y2,y3}∈Integers
};
v={x1,x2,y1,y2,y3};

NMinimize[{f,c},v,Method->"DifferentialEvolution"]

NMinimize[{f, c}, v, Method->{"DifferentialEvolution", "ScalingFactor"->1}]

SimulatedAnnealing specific options.

NMinimize[{100(((y-(x^2)))^2)+(((1-x))^2),-2.084≤x≤2.084&&-2.084≤y≤2.084},{x,y},Method->"SimulatedAnnealing"]

Clear[f]
f[x_,y_]:=20Sin[π/2(x-2π)]+20Sin[π/2(y-2π)]+(((x-2π))^2)+(((y-2π))^2);
Plot3D[f[x,y],{x,0,10},{y,0,10}]

NMinimize[f[x,y],{x,y},Method->"SimulatedAnnealing"]

NMinimize[f[x,y],{x,y},Method->{"SimulatedAnnealing","PerturbationScale"->3}]

NMinimize[f[x,y],{x,y},Method->{"SimulatedAnnealing","PerturbationScale"->3,"BoltzmannExponent"->Function[{i,df,f0},-df/(Exp[i/10])]}]

RandomSearch specific options.

NMinimize[{100(((y-(x^2)))^2)+(((1-x))^2),x^2+y^2≤1},{x,y},Method->"RandomSearch"]

Clear[a,f];a=Reverse/@Distribute[{{-32,-16,0,16,32},{-32,-16,0,16,32}},List];f=1/(0.002+Plus@@MapIndexed[1/(#2[[1]]+Plus@@(({x,y}-#1)^6))&,a]);Plot3D[f,{x,-50,50},{y,-50,50},Mesh->None, NormalsFunction->"Weighted", PlotPoints->50]

Do[Print[NMinimize[f,{{x,-50,50},{y,-50,50}},Method->{"RandomSearch","RandomSeed"->i}]],{i,5}]

Do[Print[NMinimize[f,{{x,-50,50},{y,-50,50}}, Method->{"RandomSearch","SearchPoints"->100, "RandomSeed"->i}]],{i,5}]

NMinimize[f,{{x,-50,50},{y,-50,50}},Method->{"RandomSearch","InitialPoints"->Flatten[Table[{i,j},{i,-45,45,5},{j,-45,45,5}],1]}]

n=10;
f=Sum[(((x[i]-Sin[i]))^2),{i,1,n}];
c=Table[-0.5<x[i]<0.5,{i,n}];
v=Array[x,n];
Timing[NMinimize[{f,c},v,Method->{"RandomSearch",Method->"InteriorPoint"}]]

Timing[NMinimize[{f,c},v,Method->{"RandomSearch",Method->"InteriorPoint", "SearchPoints"->1}]]