({{, (RefLink[WindSpeedData, paclet:ref/WindSpeedData])[] 
gives the most recent measurement for wind speed near the current location.}, {, (RefLink[WindSpeedData, paclet:ref/WindSpeedData])[datespec]
gives the wind speed value for the specified time near the current location.}, {, (RefLink[WindSpeedData, paclet:ref/WindSpeedData])[locationspec]
gives the most recent measurement for wind speed near the specified location.}, {, (RefLink[WindSpeedData, paclet:ref/WindSpeedData])[locationspec,datespec]
gives the value or values for the specified date and location.}, {, (RefLink[WindSpeedData, paclet:ref/WindSpeedData])[{{(Subscript[location, 1]),(Subscript[date, 1])},{(Subscript[location, 2]),(Subscript[date, 2])},…}]
gives values for all specified locations on the specified dates.}})

OpenersNotesSection(Spacer1)Details and Options

(RefLink[WindSpeedData, paclet:ref/WindSpeedData]) gives current and historical wind speed data for all standard weather stations worldwide.

(RefLink[WindSpeedData, paclet:ref/WindSpeedData])[] makes use of (RefLink[$GeoLocation, paclet:ref/$GeoLocation]) and (RefLink[$TimeZone, paclet:ref/$TimeZone]) to determine your location and time zone. It returns the most recent measurement of wind speed for the nearest high-reliability weather station to the location specified by (RefLink[$GeoLocation, paclet:ref/$GeoLocation]).

The location can be specified as an ICAO code such as "KNYC", a WMO code such as "WMO12345", an amateur weather station code such as "C1234", or another standardized weather station identifier.

The location can also be specified by latitude/longitude pairs, assuming degrees as units, a (RefLink[GeoPosition, paclet:ref/GeoPosition]) specification, or (RefLink[Entity, paclet:ref/Entity]) objects, assuming they represent objects with geographic coordinates. They can also be (RefLink[GeoGraphics, paclet:ref/GeoGraphics]) primitives such as (RefLink[GeoDisk, paclet:ref/GeoDisk]), or a city specification of the type used in (RefLink[CityData, paclet:ref/CityData]). (RefLink[WindSpeedData, paclet:ref/WindSpeedData]) gives results for the nearest high-reliability weather station to the location.

locationspec can be either individual locations or lists of them.

datespec can be specified as a date list, a string in (RefLink[DateString, paclet:ref/DateString]) format, or a (RefLink[DateObject, paclet:ref/DateObject]).

(RefLink[WindSpeedData, paclet:ref/WindSpeedData])[locationspec,datespec] by default takes datespec to be given in local time and uses UTC for all output times.

When specific times are given, an interpolated result for that time is returned. datespec specifications for a day or longer period return the interval of wind speed measurements.

datespec can be specified as {start,end,step} for compatibility with (RefLink[DateRange, paclet:ref/DateRange]) specifications. step can be (RefLink[All, paclet:ref/All]), "Day", "Week", "Month", or "Year". (RefLink[All, paclet:ref/All]) gives all recorded observations. If omitted, step is assumed to have the value (RefLink[All, paclet:ref/All]).

Location and date can also be specified together as (RefLink[Association, paclet:ref/Association])["Location"->locationspec,"Date"->datespec].

(RefLink[WindSpeedData, paclet:ref/WindSpeedData])[locationspec,datespec,func] is used to specify the format of output when locations are specified.

Possible settings for func include:

Wind speed is returned as a (RefLink[Quantity, paclet:ref/Quantity]) in either kilometers per hour or miles per hour.

The option (RefLink[UnitSystem, paclet:ref/UnitSystem]) controls output units. The default value is set by (RefLink[$UnitSystem, paclet:ref/$UnitSystem]). The following settings can also be used:

(RefLink[WindSpeedData, paclet:ref/WindSpeedData])[locationspec,"property"] returns the specified weather station property for the location corresponding to locationspec.

Properties related to identifying weather stations include:

(RefLink[WindSpeedData, paclet:ref/WindSpeedData]) can retrieve observational air temperature data from meteorological stations throughout the world.

OpenersPrimaryExamplesSection(Spacer1)Examples  (30)

OpenersExampleSection0(Spacer1)Basic Examples  (1)

Find the most recent wind speed measurement near your current location:

WindSpeedData[]

Wind speeds can be returned in kilometers per hour or miles per hour:

WindSpeedData[UnitSystem->"Imperial"]

Obtain the wind speed reading for a specific weather station:

WindSpeedData["KMCI"]

Find the interpolated wind speed at a specific date near a specified location:

WindSpeedData["KSAC",DateObject[{2012,1,2},TimeObject[{13,0,0}]]]

OpenersExampleSection1(Spacer1)Scope  (19)

OpenersExampleSubsection0(Spacer1)Location Specification  (6)

The current wind speed measurements from a high-reliability station at the approximate coordinates of "KBOS":

WindSpeedData["KBOS"]

Coordinates can be supplied for a location:

WindSpeedData[{40.67,-73.94}]

WindSpeedData[GeoPosition[{40.67,-73.94}]]

(RefLink[Entity, paclet:ref/Entity]) objects can be used:

WindSpeedData[Entity["Building","SearsTower"]]

Obtain the appropriate (RefLink[Entity, paclet:ref/Entity]) using free-form input ((Key1[ctrl, ==])):

WindSpeedData[(Entity["Willis Tower", Entity["Building","SearsTower"], "Entity[\"Building\", \"SearsTower\"]", "building"])]

Discover the range of wind speed readings in a 180-degree arc to the east of Paris:

WindSpeedData[GeoDisk[EntityValue[(Entity["Paris", Entity["City",{"Paris","IleDeFrance","France"}], "Entity[\"City\", {\"Paris\", \"IleDeFrance\", \"France\"}]", "city"]),"Coordinates"],Quantity[100,"Miles"],{0,180}]]

Find the wind speed measurement range across a geographic region:

WindSpeedData[Polygon[(Entity["Germany", Entity["Country","Germany"], "Entity[\"Country\", \"Germany\"]", "country"])]]

To return the station from coordinates or a city name, use the "StationName" property:

WindSpeedData[{42.3, -71.0}, "StationName"]

OpenersExampleSubsection1(Spacer1)Station Properties  (3)

Find the name and coordinates of the station used:

WindSpeedData["StationName"]

WindSpeedData["Coordinates"]

Discover the relative distance of the station used from a specified location:

WindSpeedData[{40.67,-73.94},"StationDistance"]

Learn a station's altitude:

WindSpeedData["KCMI","Elevation"]

OpenersExampleSubsection2(Spacer1)Date Specification  (3)

Dates can be input using (RefLink[DateObject, paclet:ref/DateObject]):

WindSpeedData["KSAC",DateObject[{2012,1,2},TimeObject[{13,0,0}]]]

Dates can also be specified in (RefLink[DateList, paclet:ref/DateList]) format:

WindSpeedData["KSAC",{2012,1,2,13,0,0}]

Date ranges in the format {start,end} will return all data within that range:

data=WindSpeedData["KMCI",{DateObject[{2012,1,1}],DateObject[{2012,1,2}]}]

DateListPlot[data]

Date specifications for a time period longer than an hour will return the (RefLink[Interval, paclet:ref/Interval]) for the wind speeds for that time period:

WindSpeedData["KSAC",DateObject[{2012,1,1}]]

OpenersExampleSubsection3(Spacer1)Lists of Locations  (3)

Lists of locations can be provided:

WindSpeedData[{"KSAC",Entity["Building","EmpireStateBuilding"],{40.11`,-88.24`}}]

Determine the interpolated wind speeds for multiple locations at a specific time:

WindSpeedData[{"KSAC",Entity["Building","EmpireStateBuilding"],{40.11`,-88.24`}},DateObject[{2012,6,17},TimeObject[{17}]]]

Find the wind speed interpolations of multiple locations and dates:

WindSpeedData[{{"KCMI",DateObject[{2008,8,4},TimeObject[{12}]]},{"KSAC",DateObject[{2008,8,4},TimeObject[{12}]]},{"KISP",DateObject[{2012,6,6},TimeObject[{13}]]}}]

OpenersExampleSubsection4(Spacer1)Format Specification  (2)

Find the wind speed for an extended location:

WindSpeedData[GeoDisk[{40,-90},Quantity[25,"Miles"]],DateObject[{2011,9,4},TimeObject[{12}]]]

Obtain the maximum or minimum pressure:

WindSpeedData[GeoDisk[{40,-90},Quantity[25,"Miles"]],DateObject[{2011,9,4},TimeObject[{12}]],Max]

WindSpeedData[GeoDisk[{40,-90},Quantity[25,"Miles"]],DateObject[{2011,9,4},TimeObject[{12}]],Min]

Use the setting (RefLink[Mean, paclet:ref/Mean]) to obtain the average wind speed:

WindSpeedData[GeoDisk[{40,-90},Quantity[25,"Miles"]],DateObject[{2011,9,4},TimeObject[{12}]],Mean]

Return the station for all displayed values:

WindSpeedData[Polygon[{{-99.24`,39.11`},{-99.24`,41.11`},{-101.24`,41.11`},{-101.24`,39.11`}}],DateObject[{2011,8,4},TimeObject[{12}]],"Stations"]

OpenersExampleSubsection5(Spacer1)Association Specification  (2)

Date and location can be specified together using (RefLink[Association, paclet:ref/Association]):

WindSpeedData[Association["Location"->"KSAC","Date"->DateObject[{2012,1,1}]]]

(RefLink[Association, paclet:ref/Association]) specification works with format arguments:

WindSpeedData[Association["Location"->"KSAC","Date"->DateObject[{2012,1,1}]], Mean]

OpenersExampleSection2(Spacer1)Options  (2)

OpenersExampleSubsection6(Spacer1)UnitSystem  (2)

By default, results use the format given by (RefLink[$UnitSystem, paclet:ref/$UnitSystem]):

$UnitSystem

Set (RefLink[UnitSystem, paclet:ref/UnitSystem]) to "Imperial" to specify miles per hour:

WindSpeedData[UnitSystem->"Imperial"]

Or set (RefLink[UnitSystem, paclet:ref/UnitSystem]) to "Metric" to specify kilometers per hour:

WindSpeedData[UnitSystem->"Metric"]

(RefLink[UnitConvert, paclet:ref/UnitConvert]) can also be used to adjust the units:

UnitConvert[WindSpeedData[],"Meters"/"Seconds"]

OpenersExampleSection3(Spacer1)Applications  (2)

Plot wind speed readings over time:

data=WindSpeedData["KISP",{{2012,10,28},{2012,10,30}},UnitSystem->"Imperial"];

DateListPlot[data,Joined->True,FrameLabel->Automatic]

Examine the averaged wind speed measurements for each day over a year:

data=WindSpeedData["KCMI",{{2012,1,1},{2012,12,31}}];

tv={DateList[#[[1]]],#[[2]]}&/@First[data["Paths"]];

Remove any missing values and then take the mean of all values for a particular day:

averaged={#[[1,1,;;3]],Mean[#[[All,2]]]}&/@GatherBy[DeleteCases[tv,{_,_Missing}],#[[1,;;3]]&];

DateListPlot[averaged]

OpenersExampleSection4(Spacer1)Properties & Relations  (4)

By default, location is specified by (RefLink[$GeoLocation, paclet:ref/$GeoLocation]):

WindSpeedData[]

WindSpeedData[$GeoLocation]

Use the output of (RefLink[WindSpeedData, paclet:ref/WindSpeedData]) in (RefLink[IconData, paclet:ref/IconData]):

IconData["WindSpeed",WindSpeedData[]]

Use (RefLink[GeoGraphics, paclet:ref/GeoGraphics]) and (RefLink[IconData, paclet:ref/IconData]) to map the wind speeds at select cities within Germany:

cities={(Entity["Berlin", Entity["City",{"Berlin","Berlin","Germany"}], "Entity[\"City\", {\"Berlin\", \"Berlin\", \"Germany\"}]", "city"]),(Entity["Hamburg", Entity["City",{"Hamburg","Hamburg","Germany"}], "Entity[\"City\", {\"Hamburg\", \"Hamburg\", \"Germany\"}]", "city"]),(Entity["Munich", Entity["City",{"Munich","Bavaria","Germany"}], "Entity[\"City\", {\"Munich\", \"Bavaria\", \"Germany\"}]", "city"]),(Entity["Cologne", Entity["City",{"Cologne","NorthRhineWestphalia","Germany"}], "Entity[\"City\", {\"Cologne\", \"NorthRhineWestphalia\", \"Germany\"}]", "city"]),(Entity["Frankfurt", Entity["City",{"Frankfurt","Hesse","Germany"}], "Entity[\"City\", {\"Frankfurt\", \"Hesse\", \"Germany\"}]", "city"]),(Entity["Stuttgart", Entity["City",{"Stuttgart","BadenWurttemberg","Germany"}], "Entity[\"City\", {\"Stuttgart\", \"BadenWurttemberg\", \"Germany\"}]", "city"]),(Entity["Dortmund", Entity["City",{"Dortmund","NorthRhineWestphalia","Germany"}], "Entity[\"City\", {\"Dortmund\", \"NorthRhineWestphalia\", \"Germany\"}]", "city"]),(Entity["Bremen", Entity["City",{"Bremen","Bremen","Germany"}], "Entity[\"City\", {\"Bremen\", \"Bremen\", \"Germany\"}]", "city"]),(Entity["Dresden", Entity["City",{"Dresden","Saxony","Germany"}], "Entity[\"City\", {\"Dresden\", \"Saxony\", \"Germany\"}]", "city"]),(Entity["Hanover", Entity["City",{"Hanover","LowerSaxony","Germany"}], "Entity[\"City\", {\"Hanover\", \"LowerSaxony\", \"Germany\"}]", "city"]),(Entity["Nuremberg", Entity["City",{"Nuremberg","Bavaria","Germany"}], "Entity[\"City\", {\"Nuremberg\", \"Bavaria\", \"Germany\"}]", "city"])};

data={CityData[#,"Coordinates"],CityData[#,"Name"],WindSpeedData[#]}&/@cities;

GeoGraphics[{GeoStyling["ReliefMap"],EdgeForm[Thin],Opacity[0.5],Polygon[Entity["Country","Germany"]],PointSize[Large],Opacity[1],{Black,Text[#[[2]],GeoPosition[#[[1]]],{-1.5,0}],Red,Point[GeoPosition[#[[1]]]],Inset[IconData["WindSpeed",#[[3]]],GeoPosition[#[[1]]],Bottom,2]}&/@data}]

Find all stations in a region with (RefLink[GeoEntities, paclet:ref/GeoEntities]):

stations=GeoEntities[(Entity["Delaware, United States", Entity["AdministrativeDivision",{"Delaware","UnitedStates"}], "Entity[\"AdministrativeDivision\", {\"Delaware\", \"UnitedStates\"}]", "administrative division"]),"WeatherStation"]

Find the wind speed at all stations:

WindSpeedData/@stations

OpenersExampleSection5(Spacer1)Neat Examples  (2)

Find the windiest location in Kansas based on the most recent measurements:

stations=WindSpeedData[Polygon[(Entity["Kansas, United States", Entity["AdministrativeDivision",{"Kansas","UnitedStates"}], "Entity[\"AdministrativeDivision\", {\"Kansas\", \"UnitedStates\"}]", "administrative division"])],"StationName"];

data=Last@SortBy[DeleteCases[{#,WindSpeedData[#]}&/@stations,{_,Missing[_]}],Last]

Given typical values for a wind turbine, determine how much energy it would generate at that location:

FormulaData["WindTurbine",{(QuantityVariable["A", "Area"])->Quantity[100,"Meters"^2],(QuantityVariable["V", "Speed"])->data[[2]],(QuantityVariable["μ", "Unitless"])->0.4,(QuantityVariable["ρ", "MassDensity"])->Quantity[1.257,"Kilograms"/"Meters"^3]}]

Fit the recorded wind speeds for Denver to a (RefLink[WeibullDistribution, paclet:ref/WeibullDistribution]):

data = QuantityMagnitude[
   Cases[WindSpeedData[(Entity["Denver", Entity["City",{"Denver","Colorado","UnitedStates"}], "Entity[\"City\", {\"Denver\", \"Colorado\", \"UnitedStates\"}]", "city"]), {{2000, 1, 1}, {2009, 12, 31}}][
     "Values"], _Quantity]];
hg = Histogram[data, 45, "PDF"];
ed = EstimatedDistribution[DeleteCases[data, 0. | 0],
  WeibullDistribution[α, β]]

Show[{hg, Plot[PDF[ed, x], {x, 0, 100}]}]

({{DocumentationFooterIconsRelatedFunction.png, ({{See Also}, {(RefLink[WeatherData, paclet:ref/WeatherData])  ▪  (RefLink[WeatherForecastData, paclet:ref/WeatherForecastData])  ▪  (RefLink[AirPressureData, paclet:ref/AirPressureData])  ▪  (RefLink[AirTemperatureData, paclet:ref/AirTemperatureData])  ▪  (RefLink[WindDirectionData, paclet:ref/WindDirectionData])  ▪  (RefLink[WindVectorData, paclet:ref/WindVectorData])  ▪  (RefLink[IconData, paclet:ref/IconData])}})}})

({{DocumentationFooterIconsRelatedGuide.png, ({{Related Guides}, {▪(RefLinkPlain[Weather Data, paclet:guide/WeatherData])}, {▪(RefLinkPlain[Earth Sciences: Data & Computation, paclet:guide/EarthSciencesDataAndComputation])}})}})