({{, (RefLink[WheelGraph, paclet:ref/WheelGraph])[n] 
gives the wheel graph with n vertices (Subscript[W, n]).}})

OpenersNotesSection(Spacer1)Details and Options

A wheel graph of order n is a graph formed by connecting a single vertex to all the vertices of a cycle of order n-1.

(RefLink[WheelGraph, paclet:ref/WheelGraph])[…,(RefLink[DirectedEdges, paclet:ref/DirectedEdges])->(RefLink[True, paclet:ref/True])] gives a directed wheel graph.

(RefLink[WheelGraph, paclet:ref/WheelGraph]) takes the same options as (RefLink[Graph, paclet:ref/Graph]).

OpenersPrimaryExamplesSection(Spacer1)Examples  (94)

OpenersExampleSection0(Spacer1)Basic Examples  (2)

The first few wheel graphs (Subscript[W, i]):

Table[WheelGraph[i,PlotLabel->(Subscript[W, i])],{i,5,7}]

Directed wheel graphs:

Table[WheelGraph[i,DirectedEdges->True,EdgeStyle->Arrowheads[Medium],PlotLabel->(Subscript[W, i])],{i,5,7}]

OpenersExampleSection1(Spacer1)Options  (80)

OpenersExampleSubsection0(Spacer1)DirectedEdges  (1)

By default, an undirected graph is generated:

WheelGraph[8]

Use (RefLink[DirectedEdges, paclet:ref/DirectedEdges])->(RefLink[True, paclet:ref/True]) to generate a directed graph:

WheelGraph[8,DirectedEdges->True,EdgeStyle->Arrowheads[Medium]]

OpenersExampleSubsection1(Spacer1)EdgeLabels  (7)

Label the edge 1<->2:

WheelGraph[4,EdgeLabels->{1\[UndirectedEdge]2->"Hello"}]

Label all edges individually:

el=EdgeList[WheelGraph[4]]

WheelGraph[4,EdgeLabels->Table[el[[i]]->(Subscript["e", i]),{i,Length[el]}]]

Use any expression as a label:

WheelGraph[4,EdgeLabels->{2\[UndirectedEdge]4->,3\[UndirectedEdge]4->,1\[UndirectedEdge]3-> }]

Use (RefLink[Placed, paclet:ref/Placed]) with symbolic locations to control label placement along an edge:

Table[WheelGraph[4,EdgeLabels->{3\[UndirectedEdge]4->Placed["■■■",p]},PlotLabel->p],{p,{"Start","Middle","End"}}]

Use explicit coordinates to place labels:

Table[WheelGraph[4,EdgeLabels->{2\[UndirectedEdge]3->Placed["■■■",p]},PlotLabel->p,BaselinePosition->Bottom],{p,{0,1/4,1/3}}]

Vary positions within the label:

Table[WheelGraph[4,EdgeLabels->{2\[UndirectedEdge]3->Placed["■■■",{1/2,p}]},PlotLabel->p,BaselinePosition->Bottom],{p,{{0,0},{1/2,1/2},{1,1}}}]

Place multiple labels:

WheelGraph[6,EdgeLabels->{3\[UndirectedEdge]1->Placed[{"lbl1","lbl2"},{"Start","End"}]}]

WheelGraph[6,EdgeLabels->{3\[UndirectedEdge]1->Placed[{"lbl1","lbl2","lbl3"},{"Start","Middle","End"}]}]

Use automatic labeling by values through (RefLink[Tooltip, paclet:ref/Tooltip]) and (RefLink[StatusArea, paclet:ref/StatusArea]):

WheelGraph[6,EdgeLabels->Placed["Name",Tooltip]]

WheelGraph[6,EdgeLabels->Placed["Name",StatusArea]]

OpenersExampleSubsection2(Spacer1)EdgeShapeFunction  (6)

Get a list of built-in settings for (RefLink[EdgeShapeFunction, paclet:ref/EdgeShapeFunction]):

GraphElementData["Edge"]

Undirected edges including the basic line:

WheelGraph[6,EdgeShapeFunction->"Line"]

Lines with different glyphs on the edges:

Table[WheelGraph[6,EdgeShapeFunction->GraphElementData[ef,"ArrowSize"->0.1],PlotLabel->ef],{ef,{"BoxLine","DiamondLine","DotLine"}}]

Directed edges including solid arrows:

Table[WheelGraph[6,EdgeShapeFunction->GraphElementData[ef,"ArrowSize"->0.1],PlotLabel->ef],{ef,GraphElementData["Edge","FilledArrow"]}]

Line arrows:

Table[WheelGraph[6,EdgeShapeFunction->GraphElementData[ef,"ArrowSize"->0.1],PlotLabel->ef],{ef,GraphElementData["Edge","UnfilledArrow"]}]

Open arrows:

Table[WheelGraph[6,EdgeShapeFunction->GraphElementData[ef,"ArrowSize"->0.1],PlotLabel->ef],{ef,GraphElementData["Edge","CarvedArrow"]}]

Specify an edge function for an individual edge:

WheelGraph[6,EdgeShapeFunction->{1\[UndirectedEdge]2->"DotLine"}]

Combine with a different default edge function:

WheelGraph[6,EdgeShapeFunction->{1\[UndirectedEdge]2->"BoxLine","DotLine"}]

Draw edges by running a program:

ef[pts_List,e_]:=
Block[{s=0.015,g=},{Arrowheads[{{s,0.33,g},{s,0.67,g}}],Arrow[pts]}]

WheelGraph[6,EdgeShapeFunction->ef]

(RefLink[EdgeShapeFunction, paclet:ref/EdgeShapeFunction]) can be combined with (RefLink[EdgeStyle, paclet:ref/EdgeStyle]):

WheelGraph[6,EdgeStyle->Blue,EdgeShapeFunction->(Line[#1]&)]

(RefLink[EdgeShapeFunction, paclet:ref/EdgeShapeFunction]) has higher priority than (RefLink[EdgeStyle, paclet:ref/EdgeStyle]):

WheelGraph[6,EdgeStyle->Blue,EdgeShapeFunction->({Red,Line[#1]}&)]

OpenersExampleSubsection3(Spacer1)EdgeStyle  (2)

Style all edges:

Table[WheelGraph[6,EdgeStyle->style,PlotLabel->style],{style,{Gray,Dashed,Thick}}]

Style individual edges:

WheelGraph[6,EdgeStyle->{1\[UndirectedEdge]2->Blue,1\[UndirectedEdge]3->Dashed}]

OpenersExampleSubsection4(Spacer1)EdgeWeight  (2)

Specify a weight for all edges:

WheelGraph[4,EdgeWeight->RandomInteger[5,6]]

WeightedAdjacencyMatrix[%]//MatrixForm

Use any numeric expression as a weight:

WheelGraph[4,EdgeWeight->{a,b,c,d,e,f}]

WeightedAdjacencyMatrix[%]//MatrixForm

OpenersExampleSubsection5(Spacer1)GraphHighlight  (3)

Highlight the vertex 1:

WheelGraph[4,VertexSize->Tiny,GraphHighlight->{1}]

Highlight the edge 2<->3:

WheelGraph[4,VertexSize->Tiny,GraphHighlight->{2\[UndirectedEdge]3}]

Highlight vertices and edges:

WheelGraph[4,VertexSize->Tiny,GraphHighlight->{1,2,1\[UndirectedEdge]3,1\[UndirectedEdge]4}]

OpenersExampleSubsection6(Spacer1)GraphHighlightStyle  (2)

Get a list of built-in settings for (RefLink[GraphHighlightStyle, paclet:ref/GraphHighlightStyle]):

GraphElementData["GraphHighlightStyle"]

Use built-in settings for (RefLink[GraphHighlightStyle, paclet:ref/GraphHighlightStyle]):

WheelGraph[4,GraphHighlight->{1,2\[UndirectedEdge]3},VertexSize->Small,GraphHighlightStyle->#,PlotLabel->#]&/@Select[GraphElementData["GraphHighlightStyle"],#=!=Automatic&]

OpenersExampleSubsection7(Spacer1)GraphLayout  (5)

By default, the layout is chosen automatically:

WheelGraph[10,GraphLayout->Automatic]

Specify layouts on special curves:

Table[WheelGraph[20,GraphLayout->l,PlotLabel->l],{l,{"CircularEmbedding","SpiralEmbedding"}}]

Specify layouts that satisfy optimality criteria:

Table[WheelGraph[20,GraphLayout->l,PlotLabel->l],{l,{"SpringEmbedding","SpringElectricalEmbedding","HighDimensionalEmbedding"}}]

(RefLink[VertexCoordinates, paclet:ref/VertexCoordinates]) overrides (RefLink[GraphLayout, paclet:ref/GraphLayout]) coordinates:

{WheelGraph[5,GraphLayout->"SpringElectricalEmbedding"],
WheelGraph[5,GraphLayout->"SpringElectricalEmbedding",VertexCoordinates->Table[{i,i},{i,0,4}]]}

Use (RefLink[AbsoluteOptions, paclet:ref/AbsoluteOptions]) to extract (RefLink[VertexCoordinates, paclet:ref/VertexCoordinates]) computed using a layout algorithm:

WheelGraph[5]

AbsoluteOptions[%,VertexCoordinates]

OpenersExampleSubsection8(Spacer1)PlotTheme  (4)

OpenersExampleSubsubsection0(Spacer1)Base Themes  (2)

Use a common base theme:

WheelGraph[4,PlotTheme->"Business"]

Use a monochrome theme:

WheelGraph[4,PlotTheme->"Monochrome"]

OpenersExampleSubsubsection1(Spacer1)Feature Themes  (2)

Use a large graph theme:

WheelGraph[4,PlotTheme->"LargeGraph"]

Use a classic diagram theme:

WheelGraph[4,PlotTheme->"ClassicDiagram"]

OpenersExampleSubsection9(Spacer1)Properties  (2)

Specify a property for vertices:

WheelGraph[4,Properties->{1->{VertexLabels-> "hello"}}]

Edges:

WheelGraph[4,Properties->{1\[UndirectedEdge]2->{EdgeLabels-> "hello"}}]

OpenersExampleSubsection10(Spacer1)VertexCoordinates  (3)

By default, any vertex coordinates are computed automatically:

WheelGraph[6]

Extract the resulting vertex coordinates using (RefLink[AbsoluteOptions, paclet:ref/AbsoluteOptions]):

AbsoluteOptions[%,VertexCoordinates]

Specify a layout function along an ellipse:

ellipseLayout[n_,{a_,b_}]:=Table[{a Cos[2Pi/n u],b Sin[2Pi/n u]},{u,1,n}]

Graphics[Point[ellipseLayout[20,{2,1}]]]

Use it to generate vertex coordinates for a graph:

WheelGraph[20,VertexCoordinates->ellipseLayout[20,{2,1}]]

(RefLink[VertexCoordinates, paclet:ref/VertexCoordinates]) has higher priority than (RefLink[GraphLayout, paclet:ref/GraphLayout]):

WheelGraph[4,VertexCoordinates->Table[{i,i},{i,4}],GraphLayout->"CircularEmbedding"]

OpenersExampleSubsection11(Spacer1)VertexLabels  (13)

Use vertex names as labels:

WheelGraph[4,VertexLabels->"Name"]

Label individual vertices:

WheelGraph[4,VertexLabels->{2->"one"}]

Label all vertices:

WheelGraph[4,VertexLabels->Table[i->(Subscript[v, i]),{i,4}]]

Use any expression as a label:

WheelGraph[4,VertexLabels->{1->,2->,3->},ImagePadding->20]

Use (RefLink[Placed, paclet:ref/Placed]) with symbolic locations to control label placement, including outside positions:

Table[WheelGraph[4,VertexSize->0.1,VertexShapeFunction->"Square",VertexLabels->Table[i->Placed["■■■",p],{i,4}],PlotLabel->p,ImagePadding->20],{p,{Before,After,Below,Above}}]

Symbolic outside corner positions:

pl={{Before,Below},{After,Below},{Before,Above},{After,Above}};

Table[WheelGraph[4,VertexSize->0.1,VertexShapeFunction->"Square",ImagePadding->20,VertexLabels->Table[i->Placed["■■■",p],{i,4}],PlotLabel->p],{p,pl}]

Symbolic inside positions:

Table[WheelGraph[4,VertexSize->0.45,VertexLabels->Table[i->Placed["■■■",p],{i,4}],VertexShapeFunction->"Square",PlotLabel->p],{p,{Left,Top,Right,Bottom}}]

Symbolic inside corner positions:

pl={{Left,Bottom},{Right,Bottom},{Left,Top},{Right,Top}};

Table[WheelGraph[4,VertexSize->0.45,VertexShapeFunction->"Square",VertexLabels->Table[i->Placed["■■■",p],{i,4}],PlotLabel->p],{p,pl}]

Use explicit coordinates to place the center of labels:

Table[WheelGraph[4,VertexSize->0.25,VertexShapeFunction->"Square",VertexLabels->Table[i->Placed[,p],{i,4}],PlotLabel->p,BaselinePosition->Bottom],{p,{{0,0},{1/2,1/2},{1,1}}}]

Place all labels at the upper-right corner of the vertex and vary the coordinates within the label:

Table[WheelGraph[4,VertexSize->0.35,VertexShapeFunction->"Square",VertexLabels->Table[i->Placed[,{{1,1},p}],{i,4}],PlotLabel->p,BaselinePosition->Bottom],{p,{{0,0},{1/2,1/2},{1,1}}}]

Place multiple labels:

WheelGraph[4,VertexLabels->{1->Placed[{"lbl1","lbl2"},{Above,Below}]}]

Any number of labels can be used:

WheelGraph[4,VertexLabels->{1->Placed[{"lbl1","lbl2","lbl3","lbl4"},{Above,After,Below,Before}]}]

Use the argument to (RefLink[Placed, paclet:ref/Placed]) to control formatting including (RefLink[Tooltip, paclet:ref/Tooltip]):

WheelGraph[4,VertexLabels->Placed["Name",Tooltip]]

Or (RefLink[StatusArea, paclet:ref/StatusArea]):

WheelGraph[4,VertexLabels->Placed["Name",StatusArea]]

Use more elaborate formatting functions:

rotateLabel[lbl_]:=Rotate[lbl,45Degree]

WheelGraph[4,VertexLabels->Table[i->Placed["xxx",Below,rotateLabel],{i,4}]]

panelLabel[lbl_]:=Panel[lbl,FrameMargins->0,Background->Lighter[Yellow,0.7]]

WheelGraph[4,VertexLabels->Table[i->Placed["xxx",Center,panelLabel],{i,4}]]

hyperlinkLabel[lbl_]:=Hyperlink[lbl,"http://www.wolfram.com"]

WheelGraph[4,VertexLabels->Table[i->Placed["xxx",Center,hyperlinkLabel],{i,4}]]

OpenersExampleSubsection12(Spacer1)VertexShape  (5)

Use any (RefLink[Graphics, paclet:ref/Graphics]), (RefLink[Image, paclet:ref/Image]), or (RefLink[Graphics3D, paclet:ref/Graphics3D]) as a vertex shape:

Table[WheelGraph[6,VertexShape->s,VertexSize->Medium],{s,{,,}}]

Specify vertex shapes for individual vertices:

WheelGraph[6,VertexShape->{2->},VertexSize->Medium]

(RefLink[VertexShape, paclet:ref/VertexShape]) can be combined with (RefLink[VertexSize, paclet:ref/VertexSize]):

Table[WheelGraph[6,VertexSize->s,VertexShape->,PlotLabel->s],{s,{Small,Large}}]

(RefLink[VertexShape, paclet:ref/VertexShape]) is not affected by (RefLink[VertexStyle, paclet:ref/VertexStyle]):

WheelGraph[6,VertexSize->0.2,VertexShape->,VertexStyle->Blue]

(RefLink[VertexShapeFunction, paclet:ref/VertexShapeFunction]) has higher priority than (RefLink[VertexShape, paclet:ref/VertexShape]):

WheelGraph[6,VertexSize->0.2,VertexShapeFunction->"Square",VertexShape->]

OpenersExampleSubsection13(Spacer1)VertexShapeFunction  (10)

Get a list of built-in collections for (RefLink[VertexShapeFunction, paclet:ref/VertexShapeFunction]):

GraphElementData["Vertex"]

Use built-in settings for (RefLink[VertexShapeFunction, paclet:ref/VertexShapeFunction]) in the "Basic" collection:

GraphElementData["Vertex","Basic"]

Simple basic shapes:

Table[WheelGraph[6,VertexShapeFunction->vf,VertexSize->0.2,PlotLabel->vf],{vf,{"Triangle","Square","Rectangle","Pentagon","Hexagon","Octagon"}}]

Common basic shapes:

Table[WheelGraph[6,VertexShapeFunction->vf,VertexSize->0.2,PlotLabel->vf],{vf,{"DownTrapezoid","UpTrapezoid","Parallelogram","FiveDown","Circle","Diamond","Star","Capsule"}}]

Use built-in settings for (RefLink[VertexShapeFunction, paclet:ref/VertexShapeFunction]) in the "Rounded" collection:

GraphElementData["Vertex","Rounded"]

Table[WheelGraph[6,VertexShapeFunction->vf,VertexSize->0.2,PlotLabel->vf],{vf,GraphElementData["Vertex","Rounded"]}]

Use built-in settings for (RefLink[VertexShapeFunction, paclet:ref/VertexShapeFunction]) in the "Concave" collection:

GraphElementData["Vertex","Concave"]

Table[WheelGraph[6,VertexShapeFunction->vf,VertexSize->0.2,PlotLabel->vf],{vf,GraphElementData["Vertex","Concave"]}]

Draw individual vertices:

WheelGraph[6,VertexShapeFunction->{ 1->"Square"},VertexSize->0.2]

Combine with a default vertex function:

WheelGraph[6,VertexShapeFunction->{ 1->"Square","Triangle"},VertexSize->0.2]

Draw vertices using a predefined graphic:

WheelGraph[6,VertexShapeFunction->(Inset[,#]&)]

Draw vertices by running a program:

vf[{xc_,yc_},name_,{w_,h_}]:=
Block[{xmin=xc-w,xmax=xc+w,ymin=yc-h,ymax=yc+h},
Polygon[{{xmin,ymin},{xmax,ymax},{xmin,ymax},{xmax,ymin}}]
];

WheelGraph[6,VertexShapeFunction->vf,VertexSize->0.2]

(RefLink[VertexShapeFunction, paclet:ref/VertexShapeFunction]) can be combined with (RefLink[VertexStyle, paclet:ref/VertexStyle]):

vf1[{xc_,yc_},name_,{w_,h_}]:=Rectangle[{xc-w,yc-h},{xc+w,yc+h}]

WheelGraph[6,VertexSize->0.2,VertexStyle->Blue,VertexShapeFunction->vf1]

(RefLink[VertexShapeFunction, paclet:ref/VertexShapeFunction]) has higher priority than (RefLink[VertexStyle, paclet:ref/VertexStyle]):

vf2[{xc_,yc_},name_,{w_,h_}]:={Red,Rectangle[{xc-w,yc-h},{xc+w,yc+h}]}

WheelGraph[6,VertexSize->0.2,VertexStyle->Blue,VertexShapeFunction->vf2]

(RefLink[VertexShapeFunction, paclet:ref/VertexShapeFunction]) has higher priority than (RefLink[VertexSize, paclet:ref/VertexSize]):

WheelGraph[6,VertexShapeFunction->"Star",VertexSize->{1->Small,Medium}]

(RefLink[VertexShapeFunction, paclet:ref/VertexShapeFunction]) has higher priority than (RefLink[VertexShape, paclet:ref/VertexShape]):

WheelGraph[6,VertexSize->0.3,VertexShapeFunction->"Star",VertexShape->]

OpenersExampleSubsection14(Spacer1)VertexSize  (8)

By default, the size of vertices is computed automatically:

WheelGraph[6,VertexSize->Automatic]

Specify the size of all vertices using symbolic vertex size:

Table[WheelGraph[6,VertexSize->s,PlotLabel->s],{s,{Tiny,Small,Medium,Large}}]

Use a fraction of the minimum distance between vertex coordinates:

Table[WheelGraph[6,VertexSize->s,PlotLabel->s],{s,0.1,1,0.3}]

Use a fraction of the overall diagonal for all vertex coordinates:

Table[WheelGraph[6,VertexSize->{"Scaled", s},PlotLabel->{"Scaled", s}],{s,0.1,1,0.3}]

Specify size in both the x and y directions:

Table[WheelGraph[6,VertexSize->s,PlotLabel->s],{s,{{0.1,0.2},{0.2,0.1}}}]

Specify the size for individual vertices:

WheelGraph[6,VertexSize->{1->0.2,2->0.3}]

(RefLink[VertexSize, paclet:ref/VertexSize]) can be combined with (RefLink[VertexShapeFunction, paclet:ref/VertexShapeFunction]):

Table[WheelGraph[5,VertexSize->s,VertexShapeFunction->"Square",PlotLabel->s],{s,{0.05,0.1,0.2}}]

(RefLink[VertexSize, paclet:ref/VertexSize]) can be combined with (RefLink[VertexShape, paclet:ref/VertexShape]):

Table[WheelGraph[5,VertexSize->s,VertexShape->,PlotLabel->s],{s,{0.1,0.2,0.4}}]

OpenersExampleSubsection15(Spacer1)VertexStyle  (5)

Style all vertices:

Table[WheelGraph[6,VertexStyle->style,VertexSize->0.3,PlotLabel->style],{style,{Yellow,EdgeForm[Dashed]}}]

Style individual vertices:

WheelGraph[6,VertexStyle->{1->Blue,2->Red},VertexSize->0.2]

(RefLink[VertexShapeFunction, paclet:ref/VertexShapeFunction]) can be combined with (RefLink[VertexStyle, paclet:ref/VertexStyle]):

vf1[{xc_,yc_},name_,{w_,h_}]:=Rectangle[{xc-w,yc-h},{xc+w,yc+h}]

WheelGraph[6,VertexSize->0.2,VertexStyle->Blue,VertexShapeFunction->vf1]

(RefLink[VertexShapeFunction, paclet:ref/VertexShapeFunction]) has higher priority than (RefLink[VertexStyle, paclet:ref/VertexStyle]):

vf2[{xc_,yc_},name_,{w_,h_}]:={Red,Rectangle[{xc-w,yc-h},{xc+w,yc+h}]}

WheelGraph[6,VertexSize->0.2,VertexStyle->Blue,VertexShapeFunction->vf2]

(RefLink[VertexStyle, paclet:ref/VertexStyle]) can be combined with (RefLink[BaseStyle, paclet:ref/BaseStyle]):

WheelGraph[6,VertexStyle->LightBlue,BaseStyle->EdgeForm[Dotted],VertexSize->0.2]

(RefLink[VertexStyle, paclet:ref/VertexStyle]) has higher priority than (RefLink[BaseStyle, paclet:ref/BaseStyle]):

WheelGraph[6,VertexStyle->LightBlue,BaseStyle->Gray,VertexSize->0.2]

(RefLink[VertexShape, paclet:ref/VertexShape]) is not affected by (RefLink[VertexStyle, paclet:ref/VertexStyle]):

WheelGraph[6,VertexSize->0.2,VertexShape->,VertexStyle->Blue]

OpenersExampleSubsection16(Spacer1)VertexWeight  (2)

Set the weight for all vertices:

WheelGraph[4,VertexWeight->{2,3,4,5}]

PropertyValue[{%,1},VertexWeight]

Use any numeric expression as a weight:

WheelGraph[4,VertexWeight->{a,b,c,d}]

PropertyValue[{%,1},VertexWeight]

OpenersExampleSection2(Spacer1)Applications  (7)

The (RefLink[GraphCenter, paclet:ref/GraphCenter]) of wheel graphs:

Table[HighlightGraph[#,GraphCenter[#]]&[WheelGraph[i,VertexSize->Small]],{i,4,7}]

The (RefLink[GraphPeriphery, paclet:ref/GraphPeriphery]):

Table[HighlightGraph[#,GraphPeriphery[#]]&[WheelGraph[i,VertexSize->Small]],{i,4,7}]

The (RefLink[VertexEccentricity, paclet:ref/VertexEccentricity]):

VertexEccentricity[WheelGraph[6],#]&/@VertexList[WheelGraph[6]]

Highlight the vertex eccentricity path:

FindVertexEccentricityPath[g_?UndirectedGraphQ,u_]/;MemberQ[VertexList[g],u]:=Module[{d=GraphDistanceMatrix[g],v,posu,posv,vl=VertexList[g]},posu=VertexIndex[g,u];
posv=First@First@Position[d[[posu]],Max[d[[posu]]]];
PathGraph[FindShortestPath[g,u,vl[[posv]]]]]

Table[HighlightGraph[g=WheelGraph[6],FindVertexEccentricityPath[g,u]],{u,Range[4]}]

The (RefLink[GraphRadius, paclet:ref/GraphRadius]):

Table[GraphRadius[WheelGraph[i]],{i,4,7}]

Highlight the radius path:

FindRadiusPath[g_?UndirectedGraphQ]:=Module[{c=First@GraphCenter[g],d,v,pos},d=Table[GraphDistance[g,c,u],{u,VertexList[g]}];
pos=First@Position[d,Max[d]];
v=First@Part[VertexList[g],pos];
PathGraph[FindShortestPath[g,c,v]]]

Table[HighlightGraph[#,FindRadiusPath[#]]&[WheelGraph[i,VertexSize->Tiny]],{i,4,7}]

The (RefLink[GraphDiameter, paclet:ref/GraphDiameter]):

Table[GraphDiameter[CycleGraph[i]],{i,4,7}]

Highlight the diameter path:

FindDiameterPath[g_?UndirectedGraphQ]:=Module[{d=GraphDistanceMatrix[g],u,v,pos},pos=First@Position[d,Max[d]];
{u,v}=Part[VertexList[g],pos];
PathGraph[FindShortestPath[g,u,v]]]

Table[HighlightGraph[#,FindDiameterPath[#]]&[WheelGraph[i,VertexSize->Tiny]],{i,4,7}]

Highlight the vertex degree for (RefLink[WheelGraph, paclet:ref/WheelGraph]):

HighlightCentrality[g_, cc_]:=HighlightGraph[g,Table[Style[VertexList[g][[i]],ColorData["TemperatureMap"][cc[[i]]/Max[cc]]],{i,VertexCount[g]}]];

g=WheelGraph[8,VertexSize->Large];

HighlightCentrality[g,VertexDegree[g]]

Highlight the closeness centrality:

HighlightCentrality[g,ClosenessCentrality[g]]

Highlight the eigenvector centrality:

HighlightCentrality[g,EigenvectorCentrality[g]]

Vertex connectivity from s to t is the number of vertex-independent paths from s to t:

g=WheelGraph[6,VertexLabels->"Name"]

The vertex connectivity is 3 from the center to any outer vertex:

{HighlightGraph[g,PathGraph[{6,1}]],
HighlightGraph[g,PathGraph[{6,5,1}]],
HighlightGraph[g,PathGraph[{6,2,1}]]}

The vertex connectivity is also 3 from between any outer vertices:

{HighlightGraph[g,PathGraph[{6,2}]],
HighlightGraph[g,PathGraph[{6,1,2}]],
HighlightGraph[g,PathGraph[{6,5,4,3,2}]]}

OpenersExampleSection3(Spacer1)Properties & Relations  (4)

(RefLink[WheelGraph, paclet:ref/WheelGraph])[n] has n vertices:

VertexCount[WheelGraph[n]]

(RefLink[WheelGraph, paclet:ref/WheelGraph])[n] has 2 n-2 edges:

EdgeCount[WheelGraph[n]]

The number of graph cycles in the wheel graph (Subscript[W, n]) is  (n^2)-3n+3:

WheelGraph[4]

(RefLink[WheelGraph, paclet:ref/WheelGraph])[4] is a complete graph:

{WheelGraph[4],CompleteGraph[4]}

OpenersExampleSection4(Spacer1)Neat Examples  (1)

Random collage of wheel graphs:

Graphics[Table[Inset[WheelGraph[RandomInteger[{6,10}]],RandomReal[{0,10},2],Automatic,1],{100}]]

({{DocumentationFooterIconsRelatedFunction.png, ({{See Also}, {(RefLink[Graph, paclet:ref/Graph])  ▪  (RefLink[GraphData, paclet:ref/GraphData])  ▪  (RefLink[CycleGraph, paclet:ref/CycleGraph])  ▪  (RefLink[StarGraph, paclet:ref/StarGraph])}})}})

({{DocumentationFooterIconsRelatedGuide.png, ({{Related Guides}, {▪(RefLinkPlain[Graph Construction & Representation, paclet:guide/GraphConstructionAndRepresentation])}})}})