({{, (RefLink[TradingChart, paclet:ref/TradingChart])[{{(Subscript[date, 1]),{(Subscript[open, 1]),(Subscript[high, 1]),(Subscript[low, 1]),(Subscript[close, 1]),(Subscript[volume, 1])}},…}] 
makes a chart showing prices and volume for each date. }, {, (RefLink[TradingChart, paclet:ref/TradingChart])[{"name",daterange}]
makes a financial chart for the financial entity "name" over the daterange. }, {, (RefLink[TradingChart, paclet:ref/TradingChart])[{…},{(Subscript[ind, 1]),(Subscript[ind, 2]),…}]
makes a financial chart with indicators (Subscript[ind, 1]), (Subscript[ind, 2]), …. }})

OpenersNotesSection(Spacer1)Details and Options

(RefLink[TradingChart, paclet:ref/TradingChart]) by default includes a candlestick chart and a volume indicator.

The dates (Subscript[date, i]) are considered an ordered sequence of events, and are not shown on an absolute time scale. The date formats for (Subscript[date, i]) are the same as used in (RefLink[DateListPlot, paclet:ref/DateListPlot]).

The "name" and daterange are the same as used in (RefLink[FinancialData, paclet:ref/FinancialData]).

The indicators (Subscript[ind, i]) can be any (RefLink[FinancialIndicator, paclet:ref/FinancialIndicator]) object.

Wrappers can be applied to indicators using the form w[(Subscript[ind, i])].

Wrappers can be applied to the entire dataset using the form w[{{(Subscript[date, 1]),(Subscript[ohlcv, 1])},…}] or w[{"name",daterange}].

The following wrappers can be used:

(RefLink[TradingChart, paclet:ref/TradingChart]) has the same options as (RefLink[Graphics, paclet:ref/Graphics]) with the following additions and changes:

Possible settings for (RefLink[Appearance, paclet:ref/Appearance]) include: "Candlestick", "OHLC", "Line", and (RefLink[None, paclet:ref/None]).

The arguments supplied to (RefLink[ChartElementFunction, paclet:ref/ChartElementFunction]) are the box region {{(Subscript[x, min]),(Subscript[x, max])},{(Subscript[y, min]),(Subscript[y, max])}}, {(Subscript[date, i]),{(Subscript[o, i]),(Subscript[h, i]),(Subscript[l, i]),(Subscript[c, i])}}, and metadata {(Subscript[m, 1]),(Subscript[m, 2]),…}.

A list of built-in settings for (RefLink[ChartElementFunction, paclet:ref/ChartElementFunction]) can be obtained from ChartElementData["TradingChart"].

The arguments supplied to (RefLink[ColorFunction, paclet:ref/ColorFunction]) are date,open,high,low,close,volume,close-open.

With (RefLink[ScalingFunctions, paclet:ref/ScalingFunctions])->(Subscript[s, y]), the function (Subscript[s, y]) is applied to all prices (open, high, low, close). (RefLink[ScalingFunctions, paclet:ref/ScalingFunctions]) only affect the display and none of the controls.

Style and other specifications from options and other constructs in (RefLink[TradingChart, paclet:ref/TradingChart]) are effectively applied in the order (RefLink[TrendStyle, paclet:ref/TrendStyle]), (RefLink[ColorFunction, paclet:ref/ColorFunction]), (RefLink[Style, paclet:ref/Style]) and other wrappers, and (RefLink[ChartElementFunction, paclet:ref/ChartElementFunction]), with later specifications overriding earlier ones.

OpenersPrimaryExamplesSection(Spacer1)Examples  (88)

OpenersExampleSection0(Spacer1)Basic Examples  (4)

Chart the prices from a list of values:

data=FinancialData["IBM","OHLCV",{{2009,5,1},{2010,4,30}}];

TradingChart[data]

Use three months of prices from (RefLink[FinancialData, paclet:ref/FinancialData]) entities:

TradingChart["SP500"]

Specify a date range for (RefLink[FinancialData, paclet:ref/FinancialData]) entities:

TradingChart[{"SP500",{{2009,1,1},{2009,12,31}}}]

Show a chart with financial indicators:

TradingChart["SP500",{"Volume","SimpleMovingAverage","BollingerBands"}]

OpenersExampleSection1(Spacer1)Scope  (25)

OpenersExampleSubsection0(Spacer1)Data and Wrappers  (9)

Automatically get quarterly data from today:

TradingChart["GOOG"]

Get data from a specific date range:

TradingChart[{"IBM", {{2009,10,1},{2010,3,31}}}]

Get data from (RefLink[FinancialData, paclet:ref/FinancialData]):

data=FinancialData["IBM","OHLCV",{{2009,10,1},{2010,3,31}}];

TradingChart[data]

Use wrappers on individual data:

TradingChart[{{{2010,10,1},{530.`,530.62`,523.`,525.62`,2225000}},{{2010,10,4},{524.95`,528.25`,518.85`,522.35`,1940500}},Style[{{2010,10,5},{528.38`,540.`,526.55`,538.23`,3507100}},FaceForm[Yellow]],{{2010,10,6},{539.26`,539.95`,529.94`,534.35`,2762300}},{{2010,10,7},{536.1`,537.2`,529.14`,530.01`,2395800}},{{2010,10,8},{532.77`,537.6`,527.62`,536.35`,2859200}}}]

Use wrappers on entire datasets:

TradingChart[Style[{{{2010,10,1},{530.`,530.62`,523.`,525.62`,2225000}},{{2010,10,4},{524.95`,528.25`,518.85`,522.35`,1940500}},{{2010,10,5},{528.38`,540.`,526.55`,538.23`,3507100}},{{2010,10,6},{539.26`,539.95`,529.94`,534.35`,2762300}},{{2010,10,6},{539.26`,539.95`,529.94`,534.35`,2762300}},{{2010,10,7},{536.1`,537.2`,529.14`,530.01`,2395800}},{{2010,10,8},{532.77`,537.6`,527.62`,536.35`,2859200}}},EdgeForm[Dashed]]]

Wrappers can be nested:

TradingChart[Style[{{{2010,10,1},{530.`,530.62`,523.`,525.62`,2225000}},{{2010,10,4},{524.95`,528.25`,518.85`,522.35`,1940500}},Style[{{2010,10,5},{528.38`,540.`,526.55`,538.23`,3507100}},FaceForm[Yellow]],{{2010,10,6},{539.26`,539.95`,529.94`,534.35`,2762300}},{{2010,10,7},{536.1`,537.2`,529.14`,530.01`,2395800}},{{2010,10,8},{532.77`,537.6`,527.62`,536.35`,2859200}}},EdgeForm[Dashed]]]

Override the default tooltips:

TradingChart[{{{2010,10,1},{530.`,530.62`,523.`,525.62`,2225000}},{{2010,10,4},{524.95`,528.25`,518.85`,522.35`,1940500}},Tooltip[{{2010,10,5},{528.38`,540.`,526.55`,538.23`,3507100}},"label"],{{2010,10,6},{539.26`,539.95`,529.94`,534.35`,2762300}},{{2010,10,7},{536.1`,537.2`,529.14`,530.01`,2395800}},{{2010,10,8},{532.77`,537.6`,527.62`,536.35`,2859200}}}]

Use (RefLink[PopupWindow, paclet:ref/PopupWindow]) to provide additional drilldown information:

TradingChart[PopupWindow[{{{2010,10,1},{530.`,530.62`,523.`,525.62`,2225000}},{{2010,10,4},{524.95`,528.25`,518.85`,522.35`,1940500}},{{2010,10,5},{528.38`,540.`,526.55`,538.23`,3507100}},{{2010,10,6},{539.26`,539.95`,529.94`,534.35`,2762300}},{{2010,10,7},{536.1`,537.2`,529.14`,530.01`,2395800}},{{2010,10,8},{532.77`,537.6`,527.62`,536.35`,2859200}}},DateListPlot[FinancialData["IBM","Jan. 1, 2005"], PlotLabel->"IBM"]]]

(RefLink[Button, paclet:ref/Button]) can be used to trigger any action:

TradingChart[{{{2010,10,1},{530.`,530.62`,523.`,525.62`,2225000}},{{2010,10,4},{524.95`,528.25`,518.85`,522.35`,1940500}},Button[{{2010,10,5},{528.38`,540.`,526.55`,538.23`,3507100}},Speak["Close at 538.23"]],{{2010,10,6},{539.26`,539.95`,529.94`,534.35`,2762300}},{{2010,10,7},{536.1`,537.2`,529.14`,530.01`,2395800}},{{2010,10,8},{532.77`,537.6`,527.62`,536.35`,2859200}}}]

OpenersExampleSubsection1(Spacer1)Indicators  (4)

(RefLink[TradingChart, paclet:ref/TradingChart]) automatically includes the volume indicator:

TradingChart[{"MSFT",{{2010,1,1},{2010,6,1}}}]

Add a simple moving average:

TradingChart[{"GS",{{2010,1,1},{2010,6,1}}}, {"Volume","SimpleMovingAverage"}]

Specify how many periods to use for the simple moving average using (RefLink[FinancialIndicator, paclet:ref/FinancialIndicator]):

TradingChart[{"GS",{{2010,1,1},{2010,6,1}}},{FinancialIndicator["SimpleMovingAverage",25],"Volume"}]

Indicators may be shown in the main plot or as an additional plot:

TradingChart[{"GS",{{2010,1,1},{2010,6,1}}},{"Volume","SimpleMovingAverage","HighestHigh","RelativeStrengthIndex"}]

OpenersExampleSubsection2(Spacer1)Styling and Appearance  (8)

Specify styles for up and down trends:

TradingChart[{"MSFT",{{2010,1,1},{2010,1,15}}},TrendStyle->{Green,Red}]

Use named preset styles:

TradingChart[{"MSFT",{{2010,1,1},{2010,1,15}}},TrendStyle->"RedGreen"]

TradingChart[{"BRK-B",{{2010,1,1},{2010,1,15}}},TrendStyle->"BlackWhite"]

(RefLink[ChartBaseStyle, paclet:ref/ChartBaseStyle]) can be used to set a style for all chart elements:

TradingChart[{"AAPL",{{2010,1,1},{2010,1,15}}},TrendStyle->{Green,Red},ChartBaseStyle->EdgeForm[]]

(RefLink[Style, paclet:ref/Style]) can be used to override styles:

TradingChart[Style[{{{2010,10,1},{530.`,530.62`,523.`,525.62`,2225000}},{{2010,10,4},{524.95`,528.25`,518.85`,522.35`,1940500}},{{2010,10,5},{528.38`,540.`,526.55`,538.23`,3507100}},{{2010,10,6},{539.26`,539.95`,529.94`,534.35`,2762300}},{{2010,10,7},{536.21`,537.2`,529.14`,530.01`,2395800}},{{2010,10,8},{532.77`,537.6`,527.62`,536.35`,2859200}}},EdgeForm[None]],ChartBaseStyle->EdgeForm[Dashed]]

Use built-in programmatically generated bars:

ChartElementData["TradingChart"]

TradingChart[{"FB",{{2013,1,1},{2014,1,15}}},ChartElementFunction->"FadingOHLC"]

Space between candlesticks is automatically adjusted based on the number of data points:

{TradingChart[{"MSFT",{{2010,1,1},{2010,1,15}}}],TradingChart[{"MSFT",{{2010,1,1},{2010,2,1}}}]}

Appearance changes based on the number of data points:

{TradingChart[{"MSFT",{{2010,1,1},{2010,1,15}}}],TradingChart[{"MSFT",{{2009,2,1},{2010,2,1}}},PlotRange->{{{2010,1,1},{2010,1,15}},All}],
TradingChart[{"MSFT",{{2008,2,1},{2010,2,1}}},PlotRange->{{{2010,1,1},{2010,1,15}},All}]}

Use a theme with detailed frame ticks and grid lines:

TradingChart["GOOGL",PlotTheme->"Detailed"]

Use a theme with a high-contrast color scheme and edge-fading rectangles:

TradingChart["GOOGL",PlotTheme->"Marketing"]

OpenersExampleSubsection3(Spacer1)Labeling  (4)

Use (RefLink[Labeled, paclet:ref/Labeled]) to add a label to a candlestick:

TradingChart[{{{2010,10,1},{530.`,530.62`,523.`,525.62`,2225000}},{{2010,10,4},{524.95`,528.25`,518.85`,522.35`,1940500}},Labeled[{{2010,10,5},{528.38`,540.`,526.55`,538.23`,3507100}},"label"],{{2010,10,6},{539.26`,539.95`,529.94`,534.35`,2762300}},{{2010,10,7},{536.21`,537.2`,529.14`,530.01`,2395800}},{{2010,10,8},{532.77`,537.6`,527.62`,536.35`,2859200}}}]

Use symbolic positions for label placement:

Table[TradingChart[{{{2010,10,1},{530.`,530.62`,523.`,525.62`,2225000}},{{2010,10,4},{524.95`,528.25`,518.85`,522.35`,1940500}},Labeled[{{2010,10,5},{528.38`,540.`,526.55`,538.23`,3507100}},"label",p],{{2010,10,6},{539.26`,539.95`,529.94`,534.35`,2762300}},{{2010,10,7},{536.21`,537.2`,529.14`,530.01`,2395800}},{{2010,10,8},{532.77`,537.6`,527.62`,536.35`,2859200}}},PlotLabel->p],{p,{Bottom,Center,Top}}]

Table[TradingChart[{{{2010,10,1},{530.`,530.62`,523.`,525.62`,2225000}},{{2010,10,4},{524.95`,528.25`,518.85`,522.35`,1940500}},{{2010,10,5},{528.38`,540.`,526.55`,538.23`,3507100}},{{2010,10,6},{539.26`,539.95`,529.94`,534.35`,2762300}},
Labeled[{{2010,10,7},{536.21`,537.2`,529.14`,530.01`,2395800}},"label",p],{{2010,10,8},{532.77`,537.6`,527.62`,536.35`,2859200}}},PlotLabel->p],{p,{Above,Below}}]

Table[TradingChart[{{{2010,10,1},{530.`,530.62`,523.`,525.62`,2225000}},{{2010,10,4},{524.95`,528.25`,518.85`,522.35`,1940500}},{{2010,10,5},{528.38`,540.`,526.55`,538.23`,3507100}},{{2010,10,6},{539.26`,539.95`,529.94`,534.35`,2762300}},
Labeled[{{2010,10,7},{536.21`,537.2`,529.14`,530.01`,2395800}},"label",p],{{2010,10,8},{532.77`,537.6`,527.62`,536.35`,2859200}}},PlotLabel->p],{p,{"High","Low","Open","Close"}}]

Label a list of date events:

TradingChart[{"AMZN",{{2010,2,9},{2010,2,17}}},EventLabels->{{2010,2,9}->"label1",{2010,2,11}->"label2",{2010,2,16}->"label3"}]

Use (RefLink[Placed, paclet:ref/Placed]) to control the positioning of labels, using the same positions as for (RefLink[Labeled, paclet:ref/Labeled]):

TradingChart[{"IRDM",{{2010,2,9},{2010,2,17}}},EventLabels->{{2010,2,9}->Placed["label1",Above],{2010,2,11}->Placed["label2","Low"],{2010,2,16}->Placed["label3",Bottom]}]

OpenersExampleSection2(Spacer1)Options  (56)

OpenersExampleSubsection4(Spacer1)Appearance  (3)

(RefLink[TradingChart, paclet:ref/TradingChart]) uses "Candlestick" when there are fewer data points:

TradingChart[{"ADI",{{2009,1,1},{2009,6,31}}}]

(RefLink[TradingChart, paclet:ref/TradingChart]) uses "OHLC" when there are more data points:

TradingChart[{"IBM",{{2009,1,1},{2009,9,30}}}]

Change the appearance of the chart:

Table[TradingChart[{"FOX",{{2010,1,1},{2010,2,28}}},Appearance->a,PlotLabel->Row[{a}]],{a,{"Candlestick","OHLC","Line",None}}]

(RefLink[None, paclet:ref/None]) can be used to show only indicators:

TradingChart[{"DIS",{{2010,1,1},{2010,2,28}}},{"Volume","SimpleMovingAverage","BollingerBands"},Appearance->None]

OpenersExampleSubsection5(Spacer1)AxesOrigin  (2)

The axes origin is on the right by default:

TradingChart[{"AAL",{{2010,1,1},{2010,1,31}}}]

Place the axes on the left:

TradingChart[{"ORCL",{{2010,1,1},{2010,1,31}}}, AxesOrigin->Left]

OpenersExampleSubsection6(Spacer1)BarSpacing  (4)

Use automatically determined spacing between candlesticks:

Table[TradingChart[{"GOOGL",{{2010,1,1},DatePlus[{2010,1,1},{w,"Week"}]}},BarSpacing->Automatic],{w,{1,2,4,8}}]

Use no spacing:

TradingChart[{"GOOGL",{{2010,1},{2010,1,15}}},BarSpacing->None]

Use symbolic presets:

Table[TradingChart[{"GOOGL",{{2010,1},{2010,1,15}}},BarSpacing->s, PlotLabel->s], {s,{Tiny, Small, Medium, Large}}]

Use explicit spacing between candlesticks:

Table[TradingChart[{"GOOGL",{{2010,1},{2010,1,15}}},BarSpacing->s, PlotLabel->s], {s,{0.1,0.5,1,2}}]

OpenersExampleSubsection7(Spacer1)ChartBaseStyle  (5)

Use (RefLink[ChartBaseStyle, paclet:ref/ChartBaseStyle]) to style candlesticks:

TradingChart[{"GOOGL",{{2010,1},{2010,1,15}}},ChartBaseStyle->Directive[EdgeForm[Dashed],Black]]

TradingChart[{"GOOGL",{{2010,1},{2010,1,15}}},ChartBaseStyle->Directive[CapForm[None],Thickness[0.01]]]

(RefLink[ChartBaseStyle, paclet:ref/ChartBaseStyle]) combines with (RefLink[TrendStyle, paclet:ref/TrendStyle]):

TradingChart[{"GOOGL",{{2010,1},{2010,1,15}}},TrendStyle->{Blue,Orange},ChartBaseStyle->EdgeForm[Dashed]]

(RefLink[TrendStyle, paclet:ref/TrendStyle]) may override settings for (RefLink[ChartBaseStyle, paclet:ref/ChartBaseStyle]):

TradingChart[{"GOOGL",{{2010,1},{2010,1,15}}},TrendStyle->{Directive[LightGreen,EdgeForm[Green]],Directive[LightRed,EdgeForm[Red]]},ChartBaseStyle->Directive[EdgeForm[Dashed],Black]]

(RefLink[Style, paclet:ref/Style]) may override settings for (RefLink[ChartBaseStyle, paclet:ref/ChartBaseStyle]):

TradingChart[Style[{{{2010,1,4},{626.95`,629.51`,624.24`,626.75`,1956200}},{{2010,1,5},{627.18`,627.84`,621.54`,623.99`,3004700}},{{2010,1,6},{625.86`,625.86`,606.36`,608.26`,3978700}},{{2010,1,7},{609.4`,610.`,592.65`,594.1`,6414300}},{{2010,1,8},{592.`,603.25`,589.11`,602.02`,4724300}},{{2010,1,11},{604.46`,604.46`,594.04`,601.11`,7212900}},{{2010,1,12},{597.65`,598.16`,588.`,590.48`,4853300}},{{2010,1,13},{576.49`,588.38`,573.9`,587.09`,6496600}},{{2010,1,14},{583.9`,594.2`,582.81`,589.85`,4240100}},{{2010,1,15},{593.34`,593.56`,578.04`,580.`,5434500}}},EdgeForm[Blue]],ChartBaseStyle->EdgeForm[Dashed]]

(RefLink[ChartBaseStyle, paclet:ref/ChartBaseStyle]) combines with (RefLink[ColorFunction, paclet:ref/ColorFunction]):

TradingChart[{"GOOGL",{{2010,1,1},{2010,1,15}}},ColorFunction->(ColorData["RedGreenSplit"][#6]&)]

OpenersExampleSubsection8(Spacer1)ChartElementFunction  (3)

Get a list of built-in settings for (RefLink[ChartElementFunction, paclet:ref/ChartElementFunction]):

ChartElementData["TradingChart"]

For detailed settings, use Palettes ▶ ChartElementSchemes:

Table[TradingChart[{"GOOGL",{{2010,1},{2010,1,15}}},BarSpacing->Tiny,ChartElementFunction->f,PlotLabel->f,PerformanceGoal->"Speed"],{f,{"FadingCandlestick", "GlassCandlestick","ArrowCandlestick","FadingOHLC"}}]

Table[TradingChart[{"GOOGL",{{2010,1},{2010,1,31}}},ChartElementFunction->f,PlotLabel->f,PerformanceGoal->"Speed"],{f,{"OHLC", "HLC"}}]

Write a custom (RefLink[ChartElementFunction, paclet:ref/ChartElementFunction]):

zigzag[{{x0_,x1_},{y0_,y1_}},{o_,h_,l_,c_},__]:=
If[o<c,Line[Transpose[{x0+{0,1/3,2/3,1}*(x1-x0),{o,l,h,c}}]],Line[Transpose[{x0+{0,1/3,2/3,1}*(x1-x0),{o,h,l,c}}]]]

TradingChart[{"GOOGL",{{2010,1},{2010,1,31}}},ChartElementFunction->zigzag,BarSpacing->Tiny]

OpenersExampleSubsection9(Spacer1)ColorFunction  (4)

Color the candlesticks by scaled date, open, high, low, close, or trend value:

Table[TradingChart[{"GOOGL", {{2010,1},{2010,1,15}}},ColorFunction->Function[{date,open,high,low,close,trend},Evaluate[ColorData["DeepSeaColors"][cf]]],PlotLabel->cf],{cf,{date,open,high,low,close,trend}}]

Color by the size and direction of price changes:

TradingChart[{"GOOGL",{{2009,12,15},{2010,1,15}}},ColorFunction->(ColorData["RedGreenSplit"][#6]&)]

Color by a trigger point:

TradingChart[{"GOOGL",{{2009,12,15},{2010,1,15}}},ColorFunction->Function[{date,open,high,low,close, trend},If[close>600, Orange, Opacity[0.3]]],ColorFunctionScaling->False]

(RefLink[ColorFunction, paclet:ref/ColorFunction]) overrides styles in (RefLink[TrendStyle, paclet:ref/TrendStyle]):

TradingChart[{"GOOGL",{{2010,1,1},{2010,1,15}}},TrendStyle->{Blue,Orange},ColorFunction->(ColorData["RedGreenSplit"][#6]&)]

OpenersExampleSubsection10(Spacer1)ColorFunctionScaling  (2)

By default scaled values are used:

TradingChart[{"GOOGL",{{2010,1,1},{2010,1,15}}},ColorFunction->Function[{date,open,high,low,close, trend},ColorData["Rainbow"][open]]]

Use (RefLink[ColorFunctionScaling, paclet:ref/ColorFunctionScaling])->(RefLink[False, paclet:ref/False]) to get unscaled values:

TradingChart[{"GOOGL",{{2010,1,1},{2010,1,15}}},ColorFunctionScaling->False,ColorFunction->Function[{date,open,high,low,close, trend},If[open<600,  {Opacity[0.25]}, None]]]

OpenersExampleSubsection11(Spacer1)EventLabels  (6)

Label a date event:

TradingChart[{"GOOGL",{{2010,1,1},{2010,1,15}}},EventLabels->{{2010,1,6}->Column[{"↑","label"},Center]}]

Use (RefLink[Placed, paclet:ref/Placed]) to control label placement outside the candlestick:

Table[TradingChart[{"GOOGL",{{2010,1,1},{2010,1,15}}},EventLabels->{{2010,1,6}->Placed["label",i]},PlotLabel->i],{i,{Above,Below,Before,After}}]

Use positions inside the candlestick:

Table[TradingChart[{"GOOGL",{{2010,1,1},{2010,1,15}}},EventLabels->{{2010,1,6}->Placed["◆",i]},PlotLabel->i],{i,{Top,Bottom}}]

Place labels at the open, high, low, and close prices:

Table[TradingChart[{"GOOGL",{{2010,1,4},{2010,1,10}}},EventLabels->{{2010,1,7}->Placed["◆",i]},PlotLabel->i],{i,{"Open","Close","High","Low"}}]

Use callouts:

Table[TradingChart[{"GOOGL", {{2010,1,1},{2010,1,15}}},EventLabels->{{2010,1,7}->Placed["label",i]},PlotLabel->i],{i,{"CalloutHigh","CalloutLow","CalloutOpen","CalloutClose"}}]

Use (RefLink[Placed, paclet:ref/Placed]) to control label appearance:

Table[TradingChart[{"GOOGL", {{2010,1,1},{2010,1,15}}},EventLabels->{{2010,1,7}->Placed["label",i,"GlassBubble"]},PlotLabel->i],{i,{"CalloutHigh","CalloutLow","CalloutOpen","CalloutClose"}}]

OpenersExampleSubsection12(Spacer1)GridLines  (4)

(RefLink[GridLines, paclet:ref/GridLines]) are used by default:

TradingChart[{"GOOGL", {{2009,12},{2010,3}}}]

Turn off date grid lines:

TradingChart[{"GOOGL", {{2009,12},{2010,3}}},GridLines->{None,Automatic}]

Turn off price grid lines:

TradingChart[{"GOOGL", {{2009,12},{2010,3}}},GridLines->{Automatic,None}]

Place grid lines at month or year boundaries:

Table[TradingChart[{"GOOGL", {{2009,11,20},{2010,2,10}}}, GridLines->{i,Automatic}],{i, {"Month", "Year"}}]

Use dotted grid lines for months and red grid lines for years:

TradingChart[{"GOOGL", {{2009,10,20},{2010,4,10}}},GridLines->{{{"Year",Directive[Dashing[{}],Red]},"Month"},Automatic}]

OpenersExampleSubsection13(Spacer1)GridLinesStyle  (3)

By default (RefLink[GridLinesStyle, paclet:ref/GridLinesStyle]) uses dotted grid lines with emphasized year grid lines:

TradingChart[{"IBM",{{2009,11,1},{2010,5,20}}}]

Use blue grid lines for dates and dotted grid lines for prices:

TradingChart[{"IBM",{{2009,11,1},{2010,5,20}}}, GridLinesStyle->{Blue,Dotted}]

(RefLink[GridLines, paclet:ref/GridLines]) overrides (RefLink[GridLinesStyle, paclet:ref/GridLinesStyle]):

TradingChart[{"IBM",{{2009,11,1},{2010,5,20}}}, GridLines->{{{"Month",Blue}},None}, GridLinesStyle->Red]

OpenersExampleSubsection14(Spacer1)Method  (4)

The default mouseover effect is a bouncing ball and axis highlight:

TradingChart[{"GOOGL",{{2010,5,1},{2010,5,20}}},Method->{"MouseoverEffect"->Automatic}]

Use no mouseover effect:

TradingChart[{"GOOGL",{{2010,5,1},{2010,5,20}}},Method->{"MouseoverEffect"->None}]

Use only the bouncing ball:

TradingChart[{"GOOGL",{{2010,5,1},{2010,5,20}}},Method->{"MouseoverEffect"->"BouncingBall"}]

Style the bouncing ball with "HighlightStyle":

TradingChart[{"GOOGL",{{2010,5,1},{2010,5,20}}},Method->{"HighlightStyle"->Directive[PointSize[Large],Orange],"MouseoverEffect"->"BouncingBall"}]

Use only axis highlight:

TradingChart[{"GOOGL",{{2010,5,1},{2010,5,20}}},Method->{"MouseoverEffect"->"AxisHighlight"}]

Style the axis highlight:

TradingChart[{"GOOGL",{{2010,5,1},{2010,5,20}}},Method->{"AxisHighlightStyle"->Yellow}]

Specify the height in pixels for the axis highlight:

TradingChart[{"GOOGL",{{2010,5,1},{2010,5,20}}},Method->{"AxisHighlightHeight"->5,"AxisHighlightStyle"->Orange}]

OpenersExampleSubsection15(Spacer1)PerformanceGoal  (3)

Generate a candlestick chart with interactive highlighting:

TradingChart[{"GOOGL", {{2009,12,15},{2010,1,15}}},PerformanceGoal->"Quality"]

Emphasize performance by disabling interactive behaviors:

TradingChart[{"GOOGL", {{2009,12,15},{2010,1,15}}},PerformanceGoal->"Speed"]

Typically less memory is required for non-interactive charts:

Table[ByteCount@TradingChart[{"GOOGL", {{2009,12,15},{2010,1,15}}},PerformanceGoal->p],{p,{"Quality","Speed"}}]

OpenersExampleSubsection16(Spacer1)PlotRange  (3)

(RefLink[TradingChart, paclet:ref/TradingChart]) automatically draws all price dates:

TradingChart[{"GOOGL",{{2010,2},{2010,5}}}]

Limit to a specific date range:

TradingChart[{"GOOGL",{{2010,2},{2010,5}}}, PlotRange->{{{2010,3,1},{2010,3,12}},Automatic}]

(RefLink[PlotRange, paclet:ref/PlotRange]) only includes dates for which there is data:

TradingChart[{"GOOGL",{{2010,2,1},{2010,3,31}}}, PlotRange->{{{2010,2,1},{2010,4,30}},Automatic}]

OpenersExampleSubsection17(Spacer1)ScalingFunctions  (2)

Prices are normally shown on a linear scale:

TradingChart[{"AAPL",{{2000,1,1},{2006,1,1}}}]

Show prices on a logarithmic scale:

TradingChart[{"AAPL",{{2000,1,1},{2006,1,1}}},ScalingFunctions->"Log"]

OpenersExampleSubsection18(Spacer1)PlotTheme  (2)

Use a theme with simple ticks and grid lines in a high-contrast color scheme:

TradingChart["GOOGL",PlotTheme->"Business"]

Change the color scheme:

TradingChart["GOOGL",PlotTheme->"Business",TrendStyle->"PurpleGold"]

OpenersExampleSubsection19(Spacer1)TrendStyle  (6)

(RefLink[TrendStyle, paclet:ref/TrendStyle]) uses green for up trends and red for down trends by default:

TradingChart[{"FORD",{{2010,1,1},{2010,1,31}}}]

Use black for up trends and red for down trends:

TradingChart[{"FORD",{{2010,1,1},{2010,1,31}}},TrendStyle->{Black,Red}]

Use named styles:

Table[TradingChart[{"FORD",{{2010,1,1},{2010,1,31}}},TrendStyle->ts,PlotLabel->ts],{ts,{"BlueYellow","PurpleGold","BrownYellow","Blue","Gold","BlackSilver"}}]

(RefLink[TrendStyle, paclet:ref/TrendStyle]) combines with (RefLink[ChartBaseStyle, paclet:ref/ChartBaseStyle]):

TradingChart[{"FORD",{{2010,1,1},{2010,1,31}}}, TrendStyle->{EdgeForm[Green], EdgeForm[Red]},ChartBaseStyle->FaceForm[]]

With (RefLink[TrendStyle, paclet:ref/TrendStyle]) set to (RefLink[None, paclet:ref/None]), the base style is used for up trends and empty bars for down trends:

TradingChart[{"FORD",{{2010,1,1},{2010,1,31}}},TrendStyle->None,ChartBaseStyle->EdgeForm[Directive[Opacity[0.5],Gray]]]

(RefLink[TrendStyle, paclet:ref/TrendStyle])->style uses style for up trends and empty bars for down trends:

TradingChart[{"FORD",{{2010,1,1},{2010,1,31}}},TrendStyle->Purple,ChartBaseStyle->EdgeForm[Directive[Opacity[0.5],Gray]]]

OpenersExampleSection4(Spacer1)Properties & Relations  (3)

Use (RefLink[InteractiveTradingChart, paclet:ref/InteractiveTradingChart]) to visualize and interactively analyze financial data:

InteractiveTradingChart[{"GOOGL",{{2009,6,1},{2010,6,1}}}]

Use (RefLink[PointFigureChart, paclet:ref/PointFigureChart]), (RefLink[LineBreakChart, paclet:ref/LineBreakChart]), (RefLink[RenkoChart, paclet:ref/RenkoChart]), and (RefLink[KagiChart, paclet:ref/KagiChart]) to analyze the relation of financial prices and time:

{PointFigureChart["GOOGL"],LineBreakChart["GOOGL"],RenkoChart["GOOGL"],KagiChart["GOOGL"]}

Use (RefLink[DateListPlot, paclet:ref/DateListPlot]) to visualize financial data:

DateListPlot[FinancialData["MSFT",{{2010,1,1},{2010,6,1}}]]

({{DocumentationFooterIconsRelatedFunction.png, ({{See Also}, {(RefLink[InteractiveTradingChart, paclet:ref/InteractiveTradingChart])  ▪  (RefLink[DateListPlot, paclet:ref/DateListPlot])  ▪  (RefLink[FinancialData, paclet:ref/FinancialData])  ▪  (RefLink[CandlestickChart, paclet:ref/CandlestickChart])  ▪  (RefLink[RenkoChart, paclet:ref/RenkoChart])  ▪  (RefLink[KagiChart, paclet:ref/KagiChart])  ▪  (RefLink[LineBreakChart, paclet:ref/LineBreakChart])  ▪  (RefLink[PointFigureChart, paclet:ref/PointFigureChart])}})}})

({{DocumentationFooterIconsRelatedGuide.png, ({{Related Guides}, {▪(RefLinkPlain[Financial Visualization, paclet:guide/FinancialVisualization])}, {▪(RefLinkPlain[Date & Time, paclet:guide/DateAndTime])}, {▪(RefLinkPlain[Date & Time Visualization, paclet:guide/DateAndTimeVisualization])}, {▪(RefLinkPlain[Financial Computation, paclet:guide/Finance])}})}})