({{, (RefLink[SumConvergence, paclet:ref/SumConvergence])[f,n] 
gives conditions for the sum (∑_n^∞)f to be convergent.}, {, (RefLink[SumConvergence, paclet:ref/SumConvergence])[f,{(Subscript[n, 1]),(Subscript[n, 2]),…}]
gives conditions for the multiple sum (∑_(Subscript[n, 1])^∞)(∑_(Subscript[n, 2])^∞)… f to be convergent.}})

OpenersNotesSection(Spacer1)Details and Options

The following options can be given:

Possible values for (RefLink[Method, paclet:ref/Method]) include:

With the default setting (RefLink[Method, paclet:ref/Method])->(RefLink[Automatic, paclet:ref/Automatic]), a number of additional tests specific to different classes of sequences are used.

For multiple sums, convergence tests are performed for each independent variable.

OpenersPrimaryExamplesSection(Spacer1)Examples  (33)

OpenersExampleSection0(Spacer1)Basic Examples  (2)

Test for convergence of the sum (∑_n^∞)(1/n):

SumConvergence[1/n,n]

Test the convergence of (∑_n^∞)(((3^n) (n^2))/(n!)):

SumConvergence[3^n n^2/n!,n]

Find the condition for convergence of (∑_n^∞)(1/(n^α)):

SumConvergence[1/n^α,n]

OpenersExampleSection1(Spacer1)Scope  (14)

OpenersExampleSubsection0(Spacer1)Numerical Sums  (8)

Exponential or geometric sums:

SumConvergence[(-1/2)^n,n]

SumConvergence[2^n,n]

Plot the partial sums:

DiscretePlot[Sum[(-1/2)^n,{n,0,k}],{k,25},PlotRange->All,AxesOrigin->{0,0}]

Polynomial exponential sums:

SumConvergence[(1/2)^n n^3,n]

SumConvergence[(1/2)^n n^10,n]

DiscretePlot[Sum[(1/2)^n n^10,{n,0,k}],{k,50}]

Rational sums:

SumConvergence[1/n,n]

SumConvergence[(n+3)/((n^2+2)(n+1)),n]

Convergence picture:

{DiscretePlot[Sum[1/n,{n,1,k}],{k,25}],DiscretePlot[Sum[(n+3)/((n^2+2)(n+1)),{n,1,k}],{k,1,25}]}

Special functions:

SumConvergence[HarmonicNumber[n]/((2n+1)(3n+1)),n]

SumConvergence[PolyGamma[n]/n!,n]

SumConvergence[Zeta[n] (-1)^n/Log[n],n]

DiscretePlot[Sum[Zeta[n] (-1)^n/Log[n],{n,2,k}],{k,25}]

Piecewise functions:

SumConvergence[Max[1/n,1/n^2]+UnitStep[7-n]/n^4, n]

SumConvergence[(1/((n^2)+Floor[(n/(1+n))+Floor[(12/(1+(n^2)))]])),n]

SumConvergence[Boole[n^2<1000]n,n]

DiscretePlot[Sum[Boole[n^2<1000] n,{n,k}],{k,50}]

Slowly converging sums in the Abel–Dini scale:

SumConvergence[1/(n Log[n] Log[Log[n]]),n]

SumConvergence[1/(n Log[n]Log[Log[n]]^2),n]

DiscretePlot[Sum[1/(n Log[n]Log[Log[n]]^2),{n,10,k}],{k,10,100}]

Alternating sums:

SumConvergence[(-1)^n,n]

SumConvergence[(-1)^n/(2n+1),n]

DiscretePlot[Sum[(-1)^n/(2n+1),{n,0,k}],{k,25}]

Complex-valued sums:

SumConvergence[Exp[n 2Pi I/8]/n,n]

SumConvergence[1/(n^2+I n+2I),n]

{DiscretePlot[s=Sum[Exp[n 2Pi I/8]/n,{n,k}];{Re[s],Im[s]},{k,25}],DiscretePlot[s=Sum[1/(n^2+I n+2I),{n,k}];{Re[s],Im[s]},{k,25}]}

OpenersExampleSubsection1(Spacer1)Parametric Sums  (6)

Exponential or geometric series:

SumConvergence[x^n,n]

SumConvergence[1/x^n,n]

Parameter region for convergence:

{With[{x=u+I v},RegionPlot[Abs[x]<1,{u,-2,2},{v,-2,2}]],With[{x=u+I v},RegionPlot[Abs[x]>1,{u,-2,2},{v,-2,2}]]}

Power series:

SumConvergence[x^n/n!,n]

SumConvergence[(-3)^n x^(2 n)/n,n]

The convergence region for (∑_(n=-∞)^(-1))(x^n)+(∑_(n=0)^∞)((((x/2)))^n):

SumConvergence[(x/2)^n,n]&&SumConvergence[x^(-n),n]

With[{x=u+I v},RegionPlot[Abs[x]<2&&Abs[x]>1,{u,-2,2},{v,-2,2}]]

Combined series:

SumConvergence[1/n^(x+1),n]&&SumConvergence[(x/2)^n,n]&&SumConvergence[1/x^n,n]

With[{x=u+I v},RegionPlot[Re[x]>0&&Abs[x]<2&&Abs[x]>1,{u,-2,2},{v,-2,2}]]

Piecewise sums:

SumConvergence[Piecewise[{{a^n,n≥0},{b^n,n<0}}]z^n,n]

RegionPlot[Abs[a z]<1,{a,-2,2},{z,-2,2}]

Assuming z=u+i v to be complex:

With[{z=u+I v},RegionPlot3D[Abs[a z]<1,{a,-2,2},{u,-2,2},{v,-2,2},AxesLabel->{a,u,v}]]

A multivariate sum:

SumConvergence[a^n b^m,{n,m}]

RegionPlot[Abs[a]<1&&Abs[b]<1,{a,-2,2},{b,-2,2}]

OpenersExampleSection2(Spacer1)Options  (9)

OpenersExampleSubsection2(Spacer1)Method  (9)

SumConvergence[a^n/n!,n,Method->"RatioTest"]

SumConvergence[(2n+1)!/((5 n)! n),n,Method->"RatioTest"]

In this case the ratio test is inconclusive:

SumConvergence[1/n,n,Method->"RatioTest"]

SumConvergence[x^n/n,n,Method->"RootTest"]

SumConvergence[(((((2n+3)/(5n-4))))^n),n,Method->"RootTest"]

In this case the root test is inconclusive:

SumConvergence[(1-1/n)^n,n,Method->"RootTest"]

The Raabe test works well for rational functions:

SumConvergence[n/(n^3+2n+1),n,Method -> "RaabeTest"]

SumConvergence[1/Sqrt[n],n,Method -> "RaabeTest"]

SumConvergence[(((∏_(k=1)^n)(2 k-1))/((∏_(k=1)^n)2 k)),n,Method->"RaabeTest"]

In this case the Raabe test is inconclusive:

SumConvergence[x^n,n,Method->"RaabeTest"]

SumConvergence[1/Log[n]^2,n,Method->"IntegralTest"]

SumConvergence[1/(n Log[n] Log[Log[n]]^2),n,Method->"IntegralTest"]

In this case the integral test is inconclusive:

SumConvergence[1/Prime[n],n,Method->"IntegralTest"]

OpenersExampleSection3(Spacer1)Applications  (3)

Find the radius of convergence of a power series:

SumConvergence[x^n,n]

Sum[x^n,{n,0,Infinity},GenerateConditions->True]

Find the interval of convergence for a real power series:

SumConvergence[(x^n)/(n 3^n),n]

As a real power series, this converges on the interval [-3,3):

SumConvergence[(x^n)/(n 3^n),n,Assumptions->x∈Reals]

Prove convergence of Ramanujan's formula for (1/π):

SumConvergence[Sqrt[8]/9801(4n)!(1103+26390n)/(n!)^4/396^(4n),n]

Sum it:

Sqrt[8]/9801Sum[(4n)!(1103+26390n)/(n!)^4/396^(4n),{n,0,Infinity}]

OpenersExampleSection4(Spacer1)Properties & Relations  (4)

Convergence properties are not affected by multiplication of constants:

{SumConvergence[2 1/n,n],SumConvergence[1/n,n]}

Convergence is not affected by translating arguments:

{SumConvergence[1/n^2,n],SumConvergence[1/(n-5)^2,n]}

(RefLink[SumConvergence, paclet:ref/SumConvergence]) is automatically called by (RefLink[Sum, paclet:ref/Sum]):

SumConvergence[1/n^2,n]

Sum[1/n^2,{n,∞}]

Many conditions generated by (RefLink[Sum, paclet:ref/Sum]) are in effect convergence conditions:

Sum[x^n,{n,∞},GenerateConditions->True]

SumConvergence[x^n,n]

With the setting (RefLink[VerifyConvergence, paclet:ref/VerifyConvergence])->(RefLink[False, paclet:ref/False]), typically a regularized value is returned:

Sum[(-1)^n,{n,∞},VerifyConvergence->False]

(RefLink[SumConvergence, paclet:ref/SumConvergence]) is used in sum transforms such as (RefLink[ZTransform, paclet:ref/ZTransform]):

ZTransform[a^n,n,z,GenerateConditions->True]

SumConvergence[a^n z^(-n),n]

(RefLink[GeneratingFunction, paclet:ref/GeneratingFunction]):

GeneratingFunction[a^n,n,x,GenerateConditions->True]

SumConvergence[a^n x^n,n]

(RefLink[ExponentialGeneratingFunction, paclet:ref/ExponentialGeneratingFunction]):

ExponentialGeneratingFunction[a^n n!,n,x,GenerateConditions->True]

SumConvergence[a^n n! x^n/n!,n]

(RefLink[FourierSequenceTransform, paclet:ref/FourierSequenceTransform]):

FourierSequenceTransform[a^n UnitStep[n],n,ω,GenerateConditions->True]

SumConvergence[a^n Exp[-I n ω],n]

OpenersExampleSection6(Spacer1)Neat Examples  (1)

Conditionally convergent periodic sums:

f[n_,p_]:=(Mod[n,p]-Mean[Mod[Range[0,p-1],p]])/Log[n]

Table[SumConvergence[f[n,p],n],{p,3,30,5}]

Table[DiscretePlot[Sum[f[n,p],{n,2,m}],{m,2,75},PlotLabel->(Mod[n,p]-Mean[Mod[Range[0,p-1],p]])/Log[n]],{p,3,30,5}]

({{DocumentationFooterIconsRelatedFunction.png, ({{See Also}, {(RefLink[Sum, paclet:ref/Sum])  ▪  (RefLink[Limit, paclet:ref/Limit])  ▪  (RefLink[DiscreteLimit, paclet:ref/DiscreteLimit])  ▪  (RefLink[DiscreteMaxLimit, paclet:ref/DiscreteMaxLimit])  ▪  (RefLink[Series, paclet:ref/Series])  ▪  (RefLink[Reduce, paclet:ref/Reduce])  ▪  (RefLink[VerifyConvergence, paclet:ref/VerifyConvergence])  ▪  (RefLink[Regularization, paclet:ref/Regularization])  ▪  (RefLink[DiscretePlot, paclet:ref/DiscretePlot])}})}})

({{DocumentationFooterIconsRelatedGuide.png, ({{Related Guides}, {▪(RefLinkPlain[Discrete Calculus, paclet:guide/DiscreteCalculus])}})}})