({{, (RefLink[ReImPlot, paclet:ref/ReImPlot])[f,{x,(Subscript[x, min]),(Subscript[x, max])}] 
generates a plot of (RefLink[Re, paclet:ref/Re])[f] and (RefLink[Im, paclet:ref/Im])[f] as functions of x∈ℝ from (Subscript[x, min]) to (Subscript[x, max]).}, {, (RefLink[ReImPlot, paclet:ref/ReImPlot])[{(Subscript[f, 1]),(Subscript[f, 2]),…},{x,(Subscript[x, min]),(Subscript[x, max])}]
plots several functions.}, {, (RefLink[ReImPlot, paclet:ref/ReImPlot])[{…,w[(Subscript[f, i])],…},…]
plots (Subscript[f, i]) with features defined by the symbolic wrapper w.}, {, (RefLink[ReImPlot, paclet:ref/ReImPlot])[…,{x}∈reg]
takes the variable x to be in the geometric region reg.}})

OpenersNotesSection(Spacer1)Details and Options

(RefLink[ReImPlot, paclet:ref/ReImPlot]) evaluates f at different values of x to create smooth curves of the form {x,Re[f[x]]} and {x,Im[f[x]]}.

Gaps are left at any x where the (Subscript[f, i]) evaluate to non-numeric values.

The region reg can be any (RefLink[RegionQ, paclet:ref/RegionQ]) object in 1D.

(RefLink[ReImPlot, paclet:ref/ReImPlot]) treats the variable x as local, effectively using (RefLink[Block, paclet:ref/Block]).

(RefLink[ReImPlot, paclet:ref/ReImPlot]) has attribute (RefLink[HoldAll, paclet:ref/HoldAll]) and evaluates f only after assigning specific numerical values to x.

In some cases, it may be more efficient to use (RefLink[Evaluate, paclet:ref/Evaluate]) to evaluate f symbolically before specific numerical values are assigned to x.

Wrappers apply to both (RefLink[Re, paclet:ref/Re])[f] and (RefLink[Im, paclet:ref/Im])[f].

The following wrappers w can be used for the (Subscript[f, i]):

Wrappers w can be applied at multiple levels:

(RefLink[Callout, paclet:ref/Callout]), (RefLink[Labeled, paclet:ref/Labeled]) and (RefLink[Placed, paclet:ref/Placed]) can use the following positions pos:

(RefLink[ReImPlot, paclet:ref/ReImPlot]) has the same options as (RefLink[Plot, paclet:ref/Plot]), with the following additions and changes:

Possible settings for (RefLink[ClippingStyle, paclet:ref/ClippingStyle]) are:

With the default settings (RefLink[Exclusions, paclet:ref/Exclusions])->(RefLink[Automatic, paclet:ref/Automatic]) and (RefLink[ExclusionsStyle, paclet:ref/ExclusionsStyle])->(RefLink[None, paclet:ref/None]), (RefLink[Plot, paclet:ref/Plot]) breaks curves at discontinuities and singularities it detects. (RefLink[Exclusions, paclet:ref/Exclusions])->(RefLink[None, paclet:ref/None]) joins across discontinuities and singularities.

(RefLink[Exclusions, paclet:ref/Exclusions])->{(Subscript[x, 1]),(Subscript[x, 2]),…} is equivalent to (RefLink[Exclusions, paclet:ref/Exclusions])->{x==(Subscript[x, 1]),x==(Subscript[x, 2]),…}.

(RefLink[PlotLegends, paclet:ref/PlotLegends])->"Expressions" uses the (Subscript[f, i]) as the legend text.

(RefLink[ReImPlot, paclet:ref/ReImPlot]) initially evaluates f at a number of equally spaced sample points specified by (RefLink[PlotPoints, paclet:ref/PlotPoints]). Then it uses an adaptive algorithm to choose additional sample points, subdividing a given interval at most (RefLink[MaxRecursion, paclet:ref/MaxRecursion]) times.

Since only a finite number of sample points are used, it is possible for (RefLink[ReImPlot, paclet:ref/ReImPlot]) to miss features of f. Increasing the settings for (RefLink[PlotPoints, paclet:ref/PlotPoints]) and (RefLink[MaxRecursion, paclet:ref/MaxRecursion]) will often catch such features.

Themes that affect curves include:

The arguments supplied to functions in (RefLink[MeshFunctions, paclet:ref/MeshFunctions]) and (RefLink[RegionFunction, paclet:ref/RegionFunction]) are x, y. Functions in (RefLink[ColorFunction, paclet:ref/ColorFunction]) are by default supplied with scaled versions of these arguments.

(RefLink[ScalingFunctions, paclet:ref/ScalingFunctions])->"scale" scales the y coordinate; (RefLink[ScalingFunctions, paclet:ref/ScalingFunctions])->{"scalex","scaley"} scales both the x and y coordinates.

OpenersPrimaryExamplesSection(Spacer1)Examples  (86)

OpenersExampleSection0(Spacer1)Basic Examples  (3)

Plot the real and imaginary parts of a complex-valued function of a real variable:

ReImPlot[(Sqrt[((x^2)-1)((x^2)-4)]),{x,-3,3}]

Plot several functions:

ReImPlot[{ArcSin[x],ArcCos[x]},{x,-4,4}]

Label each curve:

ReImPlot[{ArcSin[x],ArcCos[x]},{x,-4,4},PlotLabels->"Expressions"]

OpenersExampleSection1(Spacer1)Scope  (18)

OpenersExampleSubsection0(Spacer1)Sampling  (8)

More points are sampled where the function changes quickly:

ReImPlot[Exp[30I Sin[x]],{x,0,10}]

The plot range is selected automatically:

ReImPlot[Exp[(1/2+I) t],{t,-2π,3π}]

Use (RefLink[PlotRange, paclet:ref/PlotRange]) to focus in on areas of interest:

ReImPlot[Exp[(1/2+I) t],{t,-2π,3π},PlotRange->{-70,70}]

The curve is split when there are discontinuities in the function:

ReImPlot[Floor[Sqrt[x]],{x,-100,100}]

Use (RefLink[Exclusions, paclet:ref/Exclusions])->(RefLink[None, paclet:ref/None]) to draw connected curves:

ReImPlot[Floor[Sqrt[x]],{x,-100,100},Exclusions->None]

Use (RefLink[PlotPoints, paclet:ref/PlotPoints]) and (RefLink[MaxRecursion, paclet:ref/MaxRecursion]) to control adaptive sampling:

Grid@Table[ReImPlot[Exp[I x],{x,0,15},PlotPoints->pp,MaxRecursion->mr],{mr,{0,1,2}},{pp,{5,10}}]

The domain can be specified by a region:

𝒟=ImplicitRegion[-4≤x≤-1∨1≤x≤4,{x}];

ReImPlot[Exp[I x],{x}∈𝒟]

Specify a domain using a (RefLink[MeshRegion, paclet:ref/MeshRegion]):

𝒟=MeshRegion[{{-2},{-1},{-1/2},{1/2},{1},{2}},Line[{{1,2},{3,4},{5,6}}]];

ReImPlot[Sin[(x^2)]-I,{x}∈𝒟]

OpenersExampleSubsection1(Spacer1)Labeling and Legending  (4)

There are two standard legends:

ReImPlot[{ArcCos[x],ArcSin[x]},{x,-3,3},PlotLegends->{"Expressions","ReIm"}]

Show the legends together:

ReImPlot[{ArcCos[x],ArcSin[x]},{x,-3,3},PlotLegends->"ReImExpressions"]

Explicitly label the individual curves:

ReImPlot[{ArcCos[x],ArcSin[x]},{x,-3,3},PlotLabels->Automatic]

Identify curves with wrappers:

ReImPlot[{Callout[ArcCos[x]],Tooltip[ArcSin[x],ArcSin[x]],Legended[ArcCos[x]+ArcSin[x],"sum"]},{x,-3,3}]

OpenersExampleSubsection2(Spacer1)Presentation  (6)

Multiple pairs of curves are automatically colored to be distinct:

ReImPlot[{Sqrt[1-(x^2)],-Sqrt[(x^2)-1]},{x,-3,3}]

Provide explicit styling to different curves:

ReImPlot[{Sqrt[1-(x^2)],-Sqrt[(x^2)-1]},{x,-3,3},PlotStyle->{Red,Blue}]

Add labels and a legend:

ReImPlot[Sqrt[1-(x^2)],{x,-3,3},AxesLabel->{x,I y},PlotLabel->Sqrt[1-(x^2)],PlotLegends->"ReIm"]

Create filled plots:

{ReImPlot[{Sqrt[1-(x^2)],-Sqrt[(x^2)-1]},{x,-3,3},Filling->Axis],ReImPlot[{Sqrt[1-(x^2)],-Sqrt[(x^2)-1]},{x,-3,3},Filling->{{2->{3}},{1->{4}}}]}

Use a plot theme:

ReImPlot[{Sqrt[1-(x^2)],-Sqrt[(x^2)-1]},{x,-3,3},PlotTheme->"Marketing"]

Use (RefLink[ScalingFunctions, paclet:ref/ScalingFunctions]) to scale the axes:

ReImPlot[x+I Exp[x],{x,0,5},ScalingFunctions->"Log"]

OpenersExampleSection2(Spacer1)Options  (56)

OpenersExampleSubsection3(Spacer1)ClippingStyle  (2)

Omit clipped regions of the plot:

ReImPlot[Exp[I x]/x,{x,-10,10},ClippingStyle->None]

Show clipped regions with red lines:

ReImPlot[Exp[I x]/x,{x,-10,10},ClippingStyle->Red]

OpenersExampleSubsection4(Spacer1)ColorFunction  (4)

Color by a scaled y coordinate and scaled x coordinate, respectively:

{ReImPlot[{(Sqrt[1-(x^2)]),-(Sqrt[1-(x^2)])},{x,-3,3},ColorFunction->Function[{x,y},Hue[y]]],
ReImPlot[{(Sqrt[1-(x^2)]),-(Sqrt[1-(x^2)])},{x,-3,3},ColorFunction->Function[{x,y},Hue[x]]]}

Use a named color gradient:

ReImPlot[{(Sqrt[1-(x^2)]),-(Sqrt[1-(x^2)])},{x,-3,3},ColorFunction->"DarkRainbow"]

(RefLink[ColorFunction, paclet:ref/ColorFunction]) has higher priority than (RefLink[PlotStyle, paclet:ref/PlotStyle]):

ReImPlot[{(Sqrt[1-(x^2)]),-(Sqrt[1-(x^2)])},{x,-3,3},ColorFunction->"DarkRainbow",PlotStyle->Directive[Red,Thick]]

Highlight part of the plot:

ReImPlot[{(Sqrt[1-(x^2)]),-(Sqrt[1-(x^2)])},{x,-3,3},ColorFunction->Function[{x,y},If[Abs[y]≤1,Red,Black]],ColorFunctionScaling->False,PlotStyle->Thick]

OpenersExampleSubsection5(Spacer1)ColorFunctionScaling  (1)

No argument scaling on the left; automatic scaling on the right:

Table[ReImPlot[Exp[4Pi I x],{x,0,1/2},ColorFunction->Function[{x,y},Hue[x]],ColorFunctionScaling->cf],{cf,{False,True}}]

OpenersExampleSubsection6(Spacer1)Exclusions  (2)

In this case, the exclusion comes from a branch cut discontinuity:

ReImPlot[Sqrt[-1+I (y+1)],{y,-2,0}]

Indicate that no exclusions should be computed:

ReImPlot[Sqrt[-1+I (y+1)],{y,-2,0},Exclusions->None]

OpenersExampleSubsection7(Spacer1)ExclusionStyle  (1)

Use red lines to connect portions of the curve and black points to indicate exclusions:

ReImPlot[LogGamma[x],{x,-5,5},ExclusionsStyle->{Red,Black}]

OpenersExampleSubsection8(Spacer1)Filling  (4)

Use symbolic or explicit values:

Table[ReImPlot[Exp[I x],{x,0,2Pi},Filling->f],{f,{Axis,Top,Bottom,.3}}]

Fill between curve 1 and the x axis:

ReImPlot[Exp[I x],{x,0,2Pi},Filling->{1->Axis}]

Fill between curves 1 and 2:

ReImPlot[Exp[I x],{x,0,2Pi},Filling->{1->{2}}]

Fill between the real and imaginary parts of each function:

ReImPlot[{Exp[I x],Exp[2I x]},{x,0,2Pi},Filling->{{1->{3}},{2->{4}}}]

OpenersExampleSubsection9(Spacer1)FillingStyle  (3)

Use different fill colors:

Table[ReImPlot[Exp[I x],{x,0,2Pi},Filling->Axis,FillingStyle->c],{c,{Red,Green,Blue,Yellow}}]

Fill with red below the x axis and blue above:

ReImPlot[Exp[I x],{x,0,2Pi},Filling->Axis,FillingStyle->{Red,Blue}]

Use a variable filling style obtained from a (RefLink[ColorFunction, paclet:ref/ColorFunction]):

ReImPlot[Exp[I x],{x,0,2Pi},ColorFunction->Function[{x,y},Hue[x]],Filling->{1->{2}},FillingStyle->Automatic]

OpenersExampleSubsection10(Spacer1)MaxRecursion  (1)

Each level of (RefLink[MaxRecursion, paclet:ref/MaxRecursion]) adaptively subdivides the initial mesh into a finer mesh:

Table[ReImPlot[Sin[1/x]+10 x I,{x,0.001,.1},MaxRecursion->i,Mesh->All,Ticks->None],{i,{0,3,6}}]

OpenersExampleSubsection11(Spacer1)Mesh  (3)

Show the initial and final sampling meshes:

{ReImPlot[Exp[I x],{x,0,2Pi},Mesh->Full,MeshStyle->Red],ReImPlot[Exp[I x],{x,0,2Pi},Mesh->All,MeshStyle->Red]}

Use 10 mesh points evenly spaced in the x direction:

ReImPlot[Exp[I x],{x,0,2Pi},Mesh->10,MeshStyle->Red]

Use an explicit list of values for the mesh in the x direction:

ReImPlot[Exp[I x],{x,0,2Pi},Mesh->{Range[0,2Pi,Pi/4]},MeshStyle->Red]

OpenersExampleSubsection12(Spacer1)MeshFunctions  (2)

Use a mesh evenly spaced in the x and y directions:

Table[ReImPlot[Exp[I x],{x,0,2Pi},MeshFunctions->{f},Mesh->15,MeshStyle->Red],{f,{Function[{x,y,t,r},x],Function[{x,y,t,r},y]}}]

Show seven mesh levels in the x direction (red) and 15 in the y direction (blue):

ReImPlot[Exp[I x],{x,0,2Pi},MeshFunctions->{#1&,#2&},Mesh->{7,15},MeshStyle->{Red,Blue}]

OpenersExampleSubsection13(Spacer1)MeshShading  (3)

Alternate red and blue arcs in the x direction:

ReImPlot[Exp[I x],{x,0,2Pi},Mesh->7,MeshShading->{Red,Blue}]

(RefLink[MeshShading, paclet:ref/MeshShading]) has higher priority than (RefLink[PlotStyle, paclet:ref/PlotStyle]) for styling:

ReImPlot[Exp[I x],{x,0,2Pi},Mesh->7,MeshShading->{Red,Blue},PlotStyle->Black]

Use (RefLink[PlotStyle, paclet:ref/PlotStyle]) for some segments by setting (RefLink[MeshShading, paclet:ref/MeshShading]) to (RefLink[Automatic, paclet:ref/Automatic]):

ReImPlot[Exp[I x],{x,0,2Pi},Mesh->7,MeshShading->{Red,Automatic},PlotStyle->Black]

OpenersExampleSubsection14(Spacer1)MeshStyle  (2)

Use a red mesh in the x direction:

ReImPlot[Exp[I x],{x,0,2Pi},Mesh->7,MeshStyle->Red]

Use a red mesh in the x direction and a blue mesh in the y direction:

ReImPlot[Exp[I x],{x,0,2Pi},Mesh->7,MeshFunctions->{#1&,#2&},MeshStyle->{Red,Blue}]

OpenersExampleSubsection15(Spacer1)PerformanceGoal  (2)

Generate a higher-quality plot:

ReImPlot[Exp[I/ x],{x,0,1},PerformanceGoal->"Quality"]//Timing

Emphasize performance, possibly at the cost of quality:

ReImPlot[Exp[I /x],{x,0,1},PerformanceGoal->"Speed"]//Timing

OpenersExampleSubsection16(Spacer1)PlotLabel  (1)

Add an overall label to the plot:

ReImPlot[Exp[I x],{x,0,2Pi},PlotLabel->"Exponential function"]

OpenersExampleSubsection17(Spacer1)PlotLabels  (6)

Specify text to label curves:

ReImPlot[{ArcSin[x],ArcCos[x]},{x,-3,3},PlotLabels->{"arcsine","arccosine"}]

Modify the appearance of the labels:

ReImPlot[{ArcSin[x],ArcCos[x]},{x,-3,3},PlotLabels->Placed[{"arcsine","arccosine"},Above]]

Place the labels differently for each curve:

ReImPlot[{ArcSin[x],ArcCos[x]},{x,-3,3},PlotLabels->{Placed["arcsine",Below],Placed["arccosine",Above]}]

(RefLink[PlotLabels, paclet:ref/PlotLabels])->"Expressions" uses functions as curve labels:

ReImPlot[{ArcSin[x],ArcCos[x]},{x,-3,3},PlotLabels->"Expressions"]

Use callouts to identify the curves:

ReImPlot[{ArcSin[x],ArcCos[x]},{x,-3,3},PlotLabels->{Callout["arcsine",Above],Callout["arccosine",Below]}]

Use (RefLink[None, paclet:ref/None]) to not add a label:

ReImPlot[{ArcSin[x],ArcCos[x]},{x,-3,3},PlotLabels->{"arcsine",None}]

OpenersExampleSubsection18(Spacer1)PlotLegends  (6)

Create a legend based on the functions:

ReImPlot[{ArcSin[x],ArcCos[x]},{x,-3,3},PlotLegends->"Expressions"]

Use "ReIm" to distinguish between the real and imaginary parts of the function:

ReImPlot[{ArcSin[x],ArcCos[x]},{x,-3,3},PlotLegends->"ReIm"]

Use "ReImExpressions" to expand the legend:

ReImPlot[{ArcSin[x],ArcCos[x]},{x,-3,3},PlotLegends->"ReImExpressions"]

Make two different legends:

ReImPlot[{ArcSin[x],ArcCos[x]},{x,-3,3},PlotLegends->{"Expressions","ReIm"}]

Modify the legend labels:

ReImPlot[{ArcSin[x],ArcCos[x]},{x,-3,3},PlotLegends->{{"arcsine","arccosine"},"ReIm"},ReImLabels->{"real","imaginary"}]

Generate a third legend:

ReImPlot[{ArcSin[x],ArcCos[x],ArcSin[x]+ArcCos[x]},{x,-3,3},PlotLegends->{{"arcsine","arccosine"},"ReIm",{None,None,"sum"}}]

OpenersExampleSubsection19(Spacer1)PlotPoints  (1)

Use more initial points to get smoother curves:

Table[ReImPlot[Exp[I x],{x,0,2Pi},PlotPoints->i,MaxRecursion->0],{i,{5,10,15,25}}]

OpenersExampleSubsection20(Spacer1)PlotRange  (1)

The plot range is selected automatically:

ft=FourierTransform[Exp[-x]UnitStep[x],x,k];

ReImPlot[ft,{k,-15,15}]

Focus on a specified range of y values:

ReImPlot[ft,{k,-15,15},PlotRange->{-0.25,0.45}]

OpenersExampleSubsection21(Spacer1)PlotStyle  (3)

Explicitly specify the style for different curves and regions:

ReImPlot[{ArcSinh[x],ArcCosh[x]},{x,-3,3},PlotStyle->{Red,Blue}]

(RefLink[ReImStyle, paclet:ref/ReImStyle]) takes precedence over (RefLink[PlotStyle, paclet:ref/PlotStyle]):

ReImPlot[{ArcSinh[x],ArcCosh[x]},{x,-3,3},PlotStyle->{Red,Directive[Blue,Dashed]}]

Combine with (RefLink[ReImStyle, paclet:ref/ReImStyle]):

ReImPlot[{ArcSinh[x],ArcCosh[x]},{x,-3,3},PlotStyle->{Red,Blue},ReImStyle->{Dashing[{}],DotDashed}]

OpenersExampleSubsection22(Spacer1)PlotTheme  (3)

Use a theme with bright colors:

ReImPlot[{ArcSinh[x],ArcCosh[x]},{x,-3,3},PlotTheme->"Business"]

Add a theme with a legend:

ReImPlot[{ArcSinh[x],ArcCosh[x]},{x,-3,3},PlotTheme->{"Business","Detailed"}]

Change plot styles:

ReImPlot[{ArcSinh[x],ArcCosh[x]},{x,-3,3},PlotTheme->{"Business","Detailed"},PlotStyle->96]

OpenersExampleSubsection23(Spacer1)RegionFunction  (1)

Show the curve where (π/2)<x (mod 2 π)<((3 π)/2):

ReImPlot[Exp[I x],{x,0,8Pi},RegionFunction->Function[{x,y},Pi/2<Mod[x,2Pi]<3Pi/2]]

OpenersExampleSubsection24(Spacer1)ReImLabels  (2)

Modify the labels for the real and imaginary parts of a function using predetermined option values:

Table[ReImPlot[Exp[I x],{x,0,8Pi},ReImLabels->s,PlotLegends->{"ReIm"}],{s,{Automatic,"Text","Gothic"}}]

Specify custom labels for the real and imaginary parts of a function:

ReImPlot[Callout[Exp[I x]],{x,0,8Pi},ReImLabels->{"ℛ","ℐ"}]

OpenersExampleSubsection25(Spacer1)ReImStyle  (2)

By default, the real and imaginary parts are solid and dashed, respectively:

ReImPlot[{ArcSin[x],ArcCos[x]},{x,-3,3}]

Modify the real and imaginary styles:

ReImPlot[{ArcSin[x],ArcCos[x]},{x,-3,3},ReImStyle->{Thickness[.02],Dashing[{0.03,0.01}]}]

OpenersExampleSection3(Spacer1)Applications  (7)

Plot Fourier transforms:

ft=FourierTransform[Exp[-x]UnitStep[x],x,k];

ReImPlot[ft,{k,-5,5}]

Plot the solution of a complex differential equation with initial conditions:

sol=NDSolveValue[{y''[x]-I Sin[y[x]]==0,y[0]==1,y'[0]==2},y[x],{x,0,10}];

ReImPlot[sol,{x,0,10},PlotRange->All]

Plot the eigenvalues of a matrix as a function of a parameter:

ReImPlot[Eigenvalues[{{b-1,1},{-b,-1}}],{b,-2,6}]

Plot solutions of an equation as a function of a parameter:

ReImPlot[Evaluate[x/.Solve[a +2(x^2)-(x^3)==0,x]],{a,-3,3},PlotLegends->{"Expressions","ReIm"}]

Graph special functions:

ReImPlot[JacobiZeta[x,10],{x,-2Pi,2Pi},Ticks->{Range[-2Pi,2Pi,Pi/2],Automatic},PlotLegends->"AllExpressions"]

Plot fractional derivatives of (x^2):

Grid[Partition[Table[ReImPlot[{(x^2),((Gamma[2+1])/(Gamma[2-b+1]))(x^(2-b))},{x,-5,5},PlotRange->{-10,10},PlotLabel->Derivative[b][y][x]],{b,1/3,3,1/3}],3],Dividers->All]

Plot the complex solution of the Schrödinger equation for a particle in a box:

Manipulate[
ReImPlot[(Sqrt[2]) (E^(-(1/2) I (n^2) (π^2) t)) Sin[n π x],{x,0,1},PlotRange->{-2,2},AxesLabel->{(x/L),(Sqrt[L])ψ}],
{{t,0,((ℏ (π^2))/(2m (L^2)))t},0,(4/((n^2)π))},{{n,3},1,10,1}]

OpenersExampleSection4(Spacer1)Properties & Relations  (1)

(RefLink[ReImPlot, paclet:ref/ReImPlot]) is a special case of (RefLink[Plot, paclet:ref/Plot]):

{Plot[ReIm[ArcSin[x]],{x,-3,3}],
ReImPlot[ArcSin[x],{x,-3,3}]}

OpenersExampleSection5(Spacer1)Possible Issues  (1)

(RefLink[ScalingFunctions, paclet:ref/ScalingFunctions]) applies to the real and imaginary parts:

ReImPlot[Exp[t]+I t,{t,-3π,3π},ScalingFunctions->"Log"]

({{DocumentationFooterIconsRelatedFunction.png, ({{See Also}, {(RefLink[AbsArgPlot, paclet:ref/AbsArgPlot])  ▪  (RefLink[ComplexListPlot, paclet:ref/ComplexListPlot])  ▪  (RefLink[ComplexPlot, paclet:ref/ComplexPlot])  ▪  (RefLink[ComplexPlot3D, paclet:ref/ComplexPlot3D])  ▪  (RefLink[ReIm, paclet:ref/ReIm])  ▪  (RefLink[AbsArg, paclet:ref/AbsArg])  ▪  (RefLink[Plot, paclet:ref/Plot])  ▪  (RefLink[ParametricPlot, paclet:ref/ParametricPlot])}})}})

({{DocumentationFooterIconsRelatedGuide.png, ({{Related Guides}, {▪(RefLinkPlain[Complex Visualization, paclet:guide/ComplexVisualization])}, {▪(RefLinkPlain[Function Visualization, paclet:guide/FunctionVisualization])}, {▪(RefLinkPlain[Functions of Complex Variables, paclet:guide/FunctionsOfComplexVariables])}})}})