({{, (RefLink[PowerDistribution, paclet:ref/PowerDistribution])[k,a] 
represents a power distribution with domain parameter k and shape parameter a.}})

OpenersNotesSection(Spacer1)Details

The probability density for value x in a power distribution is proportional to (x^(a-1)) for 0<x≤1/k and zero otherwise.

(RefLink[PowerDistribution, paclet:ref/PowerDistribution]) allows k and a to be any positive real numbers.

(RefLink[PowerDistribution, paclet:ref/PowerDistribution]) allows k to be a quantity of any unit dimension, and a to be a dimensionless quantity. »

(RefLink[PowerDistribution, paclet:ref/PowerDistribution]) can be used with such functions as (RefLink[Mean, paclet:ref/Mean]), (RefLink[CDF, paclet:ref/CDF]), and (RefLink[RandomVariate, paclet:ref/RandomVariate]).

OpenersPrimaryExamplesSection(Spacer1)Examples  (23)

OpenersExampleSection0(Spacer1)Basic Examples  (4)

Probability density function:

Plot[Table[PDF[PowerDistribution[k,2.5],x],{k,{1,1.5,2}}]//Evaluate,{x,0,1},Filling->Axis]

Plot[Table[PDF[PowerDistribution[2,a],x],{a,{1,2,3}}]//Evaluate,{x,0,0.5},Filling->Axis]

PDF[PowerDistribution[k,a],x]

Cumulative distribution function:

Plot[Table[CDF[PowerDistribution[k,2.5],x],{k,{1,1.5,2}}]//Evaluate,{x,0,1},Filling->Axis,Exclusions->None]

Plot[Table[CDF[PowerDistribution[2,a],x],{a,{1,2,3}}]//Evaluate,{x,0,0.5},Filling->Axis,Exclusions->None]

CDF[PowerDistribution[k,a],x]

Mean and variance:

Mean[PowerDistribution[k,a]]

Variance[PowerDistribution[k,a]]

Median:

Median[PowerDistribution[k,a]]

OpenersExampleSection1(Spacer1)Scope  (8)

Generate a sample of pseudorandom numbers from a power distribution:

data=RandomVariate[PowerDistribution[2.5,3],10^6];

Compare its histogram to the PDF:

Show[
Histogram[data,15,"PDF"],
Plot[PDF[PowerDistribution[2.5,3],x],{x,0,1/2.5},PlotStyle->Thick]]

Distribution parameters estimation:

sample=RandomVariate[PowerDistribution[3,1.5],10^3];

Estimate the distribution parameters from sample data:

edist=EstimatedDistribution[sample, PowerDistribution[k,a]]

Compare a density histogram of the sample with the PDF of the estimated distribution:

Show[Histogram[sample,Automatic,"PDF"],Plot[PDF[edist,x],{x,0,0.5},PlotStyle->Thick]]

Skewness depends only on the shape parameter:

Plot[Skewness[PowerDistribution[k,a]],{a,0,3}]

Skewness[PowerDistribution[k,a]]

Limiting values:

Limit[Skewness[PowerDistribution[k,a]],a->0,Direction->-1]

Limit[Skewness[PowerDistribution[k,a]],a->∞]

Kurtosis depends only on the shape parameter:

Plot[Kurtosis[PowerDistribution[k,a]],{a,0,3}]

Kurtosis[PowerDistribution[k,a]]

Limiting values:

Limit[Kurtosis[PowerDistribution[k,a]],a->0,Direction->-1]

Limit[Kurtosis[PowerDistribution[k,a]],a->∞]

Kurtosis attains its minimum:

FindMinimum[Kurtosis[PowerDistribution[k,a]],a]

Different moments with closed forms as functions of parameters:

FormulaGrid[list_,type_]:=Grid[Transpose[{list}],Alignment->{Left,Automatic},Background->{None,{{Lighter[Blend[Switch[type,M,{Blue,Green},CM,{Red,Orange},FM,{Magenta,Cyan},C,{Purple,Red}]],.8],White}}},Dividers->{None,{Darker[Gray,.6],{False},Darker[Gray,.6]}},ItemSize->30]

(RefLink[Moment, paclet:ref/Moment]):

FormulaGrid[Table[Moment[PowerDistribution[k,a],r]//Together,{r,3}],M]

Closed form for symbolic order:

Moment[PowerDistribution[k,a],r]

(RefLink[CentralMoment, paclet:ref/CentralMoment]):

FormulaGrid[Table[CentralMoment[PowerDistribution[k,a],r]//Together,{r,3}],CM]

Closed form for symbolic order:

CentralMoment[PowerDistribution[k,a],r]

(RefLink[FactorialMoment, paclet:ref/FactorialMoment]):

FormulaGrid[Table[FactorialMoment[PowerDistribution[k,a],r]//FullSimplify,{r,3}],FM]

(RefLink[Cumulant, paclet:ref/Cumulant]):

FormulaGrid[Table[Cumulant[PowerDistribution[k,a],r]//FullSimplify,{r,3}],C]

Hazard function:

Plot[Table[HazardFunction[PowerDistribution[k,3],x],{k,{1,2,3}}]//Evaluate,{x,0,1},Filling->Axis]

Plot[Table[HazardFunction[PowerDistribution[2,a],x],{a,{1,2,3}}]//Evaluate,{x,0,1/2},Filling->Axis]

HazardFunction[PowerDistribution[k,a],x]

Quantile function:

Plot[Table[Quantile[PowerDistribution[k,3],q],{k,{1,2,3}}]//Evaluate,{q,0,1},Filling->Axis]

Plot[Table[Quantile[PowerDistribution[2,a],q],{a,{1,2,3}}]//Evaluate,{q,0,1},Filling->Axis]

Quantile[PowerDistribution[k,a],q]

Consistent use of (RefLink[Quantity, paclet:ref/Quantity]) in parameters yields (RefLink[QuantityDistribution, paclet:ref/QuantityDistribution]):

vol𝒟=PowerDistribution[1/Quantity[2,"Meters"^3],3]

Find the median volume:

Median[vol𝒟]//N

OpenersExampleSection2(Spacer1)Applications  (1)

Suppose the variance of normal distribution follows (RefLink[PowerDistribution, paclet:ref/PowerDistribution]) defined on the unit interval. Find the resulting distribution:

𝓂𝒩[μ_,a_]=ParameterMixtureDistribution[NormalDistribution[μ,(Sqrt[σ2])],σ2\[Distributed]PowerDistribution[1,a]];

PDF[𝓂𝒩[μ,a],x]

Generate random variates:

data=RandomVariate[𝓂𝒩[0,3],10^5];

Compare sample histogram to the distribution density:

Show[Histogram[data,Automatic,"PDF"],Plot[PDF[𝓂𝒩[0,3],x]//Evaluate,{x,-4,4},PlotStyle->Thick,PlotRange->All]]

OpenersExampleSection3(Spacer1)Properties & Relations  (9)

Power distribution is closed under scaling by a positive factor:

TransformedDistribution[p u,u\[Distributed]PowerDistribution[k,a]]

Power distribution is closed under (RefLink[Max, paclet:ref/Max]):

TransformedDistribution[Max[u,v],{u\[Distributed]PowerDistribution[p,a1],v\[Distributed]PowerDistribution[p,a2]}]

OrderDistribution[{PowerDistribution[p,a],5},5]

Relationships to other distributions:

(RefLink[KumaraswamyDistribution, paclet:ref/KumaraswamyDistribution]) simplifies to a special case of power distribution:

PDF[KumaraswamyDistribution[α,1],x]

PDF[PowerDistribution[1,α ],x]

FullSimplify[%-%%,0<x<1]

Power distribution is a transformation of (RefLink[ExponentialDistribution, paclet:ref/ExponentialDistribution]):

TransformedDistribution[  Exp[- u]/k,u\[Distributed]ExponentialDistribution[a]]

(RefLink[ExponentialDistribution, paclet:ref/ExponentialDistribution]) can be obtained from power distribution:

TransformedDistribution[-Log[u],u\[Distributed]PowerDistribution[1,λ]]

Power distribution is a distribution of an inverse of (RefLink[ParetoDistribution, paclet:ref/ParetoDistribution]):

TransformedDistribution[1/u,u\[Distributed]ParetoDistribution[k,α]]

(RefLink[UniformDistribution, paclet:ref/UniformDistribution]) is a transformation of (RefLink[PowerDistribution, paclet:ref/PowerDistribution]):

TransformedDistribution[u^a,u\[Distributed]PowerDistribution[1,a]]

(RefLink[PowerDistribution, paclet:ref/PowerDistribution]) is a special case of (RefLink[PearsonDistribution, paclet:ref/PearsonDistribution]):

PDF[PearsonDistribution[1,1-α,(α-1)  /k,1,-1/k,0],x]//FullSimplify[#,k>0]&

PDF[PowerDistribution[k,α],x]//PowerExpand

FullSimplify[%-%%,0<x<1/k]

OpenersExampleSection4(Spacer1)Neat Examples  (1)

PDFs for different a values with CDF contours:

dist=PowerDistribution[3,a];cdf=Function[{x,a},Evaluate[CDF[dist,x]]];
ql={0.025,0.10,0.25,0.5,0.75,0.90,0.975};
cl=Table[ColorData["Rainbow"][q],{q,Join[{0.0},ql]}];

Legended[Plot3D[PDF[dist,x],{x,0.1,1/3},{a,0.1,2},PlotTheme->"Marketing",MeshFunctions->{cdf},Mesh->{ql},MeshStyle->GrayLevel[0.8],MeshShading->cl,AxesLabel->Automatic,BaseStyle->Opacity[0.9],ImageSize->400],BarLegend["Rainbow",ql,LegendLabel->"prob"]]

({{DocumentationFooterIconsRelatedFunction.png, ({{See Also}, {(RefLink[BetaDistribution, paclet:ref/BetaDistribution])  ▪  (RefLink[UniformDistribution, paclet:ref/UniformDistribution])  ▪  (RefLink[ParetoDistribution, paclet:ref/ParetoDistribution])}})}})

({{DocumentationFooterIconsRelatedGuide.png, ({{Related Guides}, {▪(RefLinkPlain[Bounded Domain Distributions, paclet:guide/BoundedDomainDistributions])}})}})