({{, (RefLink[NormalDistribution, paclet:ref/NormalDistribution])[μ,σ] 
represents a normal (Gaussian) distribution with mean μ and standard deviation σ.}, {, (RefLink[NormalDistribution, paclet:ref/NormalDistribution])[]
represents a normal distribution with zero mean and unit standard deviation.}})

OpenersNotesSection(Spacer1)Details

The probability density for value x in a normal distribution is proportional to (e^(-(((x-μ))^2)/(2(σ^2)))). »

(RefLink[NormalDistribution, paclet:ref/NormalDistribution]) allows μ to be any real number and σ to be any positive real number.

(RefLink[NormalDistribution, paclet:ref/NormalDistribution]) allows μ and σ to be any quantities of the same unit dimensions. »

(RefLink[NormalDistribution, paclet:ref/NormalDistribution]) can be used with such functions as (RefLink[Mean, paclet:ref/Mean]), (RefLink[CDF, paclet:ref/CDF]), and (RefLink[RandomVariate, paclet:ref/RandomVariate]). »

OpenersPrimaryExamplesSection(Spacer1)Examples  (61)

OpenersExampleSection0(Spacer1)Basic Examples  (4)

Probability density function:

Plot[Table[PDF[NormalDistribution[0,σ],x],{σ,{.75,1,2}}]//Evaluate,{x,-6,6},Filling->Axis]

Plot[Table[PDF[NormalDistribution[μ,1.5],x],{μ,{-1,1,2}}]//Evaluate,{x,-6,6},Filling->Axis]

PDF[NormalDistribution[μ,σ],x]

Cumulative distribution function:

Plot[Table[CDF[NormalDistribution[0,σ],x],{σ,{.75,1,2}}]//Evaluate,{x,-6,6},Filling->Axis]

Plot[Table[CDF[NormalDistribution[μ,1.5],x],{μ,{-1,1,2}}]//Evaluate,{x,-6,6},Filling->Axis]

CDF[NormalDistribution[μ,σ],x]

Mean and variance:

Mean[NormalDistribution[μ,σ]]

Variance[NormalDistribution[μ,σ]]

Median:

Median[NormalDistribution[μ,σ]]

OpenersExampleSection1(Spacer1)Scope  (7)

Generate a sample of pseudorandom numbers from a normal distribution:

data=RandomVariate[NormalDistribution[1,3],10^4];

Compare its histogram to the PDF:

Show[
Histogram[data,20,"PDF"],
Plot[PDF[NormalDistribution[1,3],x],{x,-9,9},PlotStyle->Thick]]

Distribution parameters estimation:

sample=RandomVariate[NormalDistribution[2,3],10^3];

Estimate the distribution parameters from sample data:

edist=EstimatedDistribution[sample, NormalDistribution[μ,σ]]

Compare the density histogram of the sample with the PDF of the estimated distribution:

Show[Histogram[sample,Automatic,"PDF"],Plot[PDF[edist,x],{x,-6,11},PlotStyle->Thick]]

Skewness and kurtosis are constant:

Skewness[NormalDistribution[μ,σ]]

Kurtosis[NormalDistribution[μ,σ]]

Different moments with closed forms as functions of parameters:

FormulaGrid[list_,type_]:=Grid[Transpose[{list}],Alignment->{Left,Automatic},Background->{None,{{Lighter[Blend[Switch[type,M,{Blue,Green},CM,{Red,Orange},FM,{Magenta,Cyan},C,{Purple,Red}]],.8],White}}},Dividers->{None,{Darker[Gray,.6],{False},Darker[Gray,.6]}},ItemSize->30]

(RefLink[Moment, paclet:ref/Moment]):

FormulaGrid[Table[Moment[NormalDistribution[μ,σ],k]//Expand,{k,5}],M]

Closed form for symbolic order:

Moment[NormalDistribution[μ,σ],r]

(RefLink[CentralMoment, paclet:ref/CentralMoment]):

FormulaGrid[Table[CentralMoment[NormalDistribution[μ,σ],k],{k,5}],CM]

Closed form for symbolic order:

CentralMoment[NormalDistribution[μ,σ],r]

(RefLink[FactorialMoment, paclet:ref/FactorialMoment]):

FormulaGrid[Table[FactorialMoment[NormalDistribution[μ,σ],k]//Expand,{k,5}],FM]

(RefLink[Cumulant, paclet:ref/Cumulant]):

FormulaGrid[Table[Cumulant[NormalDistribution[μ,σ],k],{k,5}],C]

Closed form for symbolic order:

Cumulant[NormalDistribution[μ,σ],r]

Hazard function of a normal distribution is increasing:

Plot[Table[HazardFunction[NormalDistribution[-1,σ],x],{σ,{2,3,4}}]//Evaluate,{x,-8,-2},Filling->Axis]

Plot[Table[HazardFunction[NormalDistribution[μ,2],x],{μ,{-2,0,1}}]//Evaluate,{x,-4,4},Filling->Axis]

HazardFunction[NormalDistribution[μ,σ],x]

Quantile function:

Plot[Table[Quantile[NormalDistribution[-2,σ],q],{σ,{1/2,1,2}}]//Evaluate,{q,0,1},Filling->Median[NormalDistribution[-2,σ]]]

Plot[Table[Quantile[NormalDistribution[μ,2],q],{μ,{-1,1,4}}]//Evaluate,{q,0,1},Filling->Axis]

Quantile[NormalDistribution[μ,σ],q]

Consistent use of (RefLink[Quantity, paclet:ref/Quantity]) in parameters yields (RefLink[QuantityDistribution, paclet:ref/QuantityDistribution]):

height𝒟=NormalDistribution[(QuantityMixedUnit2[5, 9, \[Null]', \[Null]'', feet,inches, {"Feet","Inches"}]),(Quantity[5., "in", inches, "Inches"])]

Find height quartiles:

Quartiles[%]

OpenersExampleSection2(Spacer1)Applications  (11)

Find the percentage of values that lie between μ-σ and μ+σ:

Probability[μ-σ<x<μ+σ,x\[Distributed] NormalDistribution[μ,σ]]

Between μ-2 σ and μ+2 σ:

Probability[μ-2 σ<x<μ+2σ,x\[Distributed] NormalDistribution[μ,σ]]

Between μ-3 σ and μ+3 σ:

Probability[μ-3 σ<x<μ+3σ,x\[Distributed] NormalDistribution[μ,σ]]

Package it up as a function:

percentage[n_]:=Probability[μ-n σ<x<μ+n σ,x\[Distributed] NormalDistribution[μ,σ]]

Table[N[percentage[n],10],{n,6}]

Compute p-values for a z-test under the null hypothesis X==z and the alternative X<z:

CDF[NormalDistribution[],z]

Alternative hypothesis X>z:

1-CDF[NormalDistribution[],z]

Alternative hypothesis \[LeftBracketingBar]X\[RightBracketingBar]>z:

2 CDF[NormalDistribution[],-Abs[z]]

A battery has a lifetime that is approximately normally distributed with a mean of 1000 hours and a standard deviation of 50 hours. Find the fraction with a lifetime between 800 and 1000 hours:

p=Probability[(Quantity[800, "h", hours, "Hours"])<x<(Quantity[1000, "h", hours, "Hours"]),x\[Distributed]NormalDistribution[(Quantity[1000, "h", hours, "Hours"]),(Quantity[50, "h", hours, "Hours"])]]

Out of 100 batteries, compute how many have a lifetime between 800 and 1000 hours:

Mean[BinomialDistribution[100,p]]

N[%]

Coffee beans are sold in 5 lb sacks that have true weight normally distributed with a mean of 5 lbs and a variance of 0.01 lb2. Find the probability that a given sack weighs at least 4 lbs, 15 oz:

Probability[x>(QuantityMixedUnit2[4, 15,  "lb",  "oz", pounds,ounces, {"Pounds","Ounces"}]),x\[Distributed]NormalDistribution[(Quantity[5, "lb", pounds, "Pounds"]),Sqrt[(Quantity[0.01, (("lb")^2), pounds squared, (("Pounds")^2)])]]]

This can be directly computed from the (RefLink[SurvivalFunction, paclet:ref/SurvivalFunction]):

SurvivalFunction[NormalDistribution[(Quantity[5, "lb", pounds, "Pounds"]),Sqrt[(Quantity[0.01, (("lb")^2), pounds squared, (("Pounds")^2)])]],(QuantityMixedUnit2[4, 15,  "lb",  "oz", pounds,ounces, {"Pounds","Ounces"}])]

A company manufactures nails with length normally distributed, mean 0.497 inches, and standard deviation 0.002 inches. Find the fraction that satisfies the specification of length equal to 0.5 inches plus/minus 0.004 inches:

len𝒟=NormalDistribution[LinguisticAssistant,LinguisticAssistant]

minlen=LinguisticAssistant -LinguisticAssistant;maxlen=LinguisticAssistant +LinguisticAssistant;

Probability[minlen<len<maxlen,len\[Distributed] len𝒟]

Direct computation with (RefLink[CDF, paclet:ref/CDF]):

CDF[ len𝒟,maxlen]-CDF[ len𝒟,minlen]

A company manufactures nails with length normally distributed and a mean of 0.5 inches. If 50% of the produced nails have lengths between 0.495 and 0.505, find the standard deviation:

Probability[(Quantity[0.495, "in", inches, "Inches"])<x<(Quantity[0.505, "in", inches, "Inches"]),x\[Distributed]NormalDistribution[(Quantity[0.5, "in", inches, "Inches"]),(Quantity[σ, "in", inches, "Inches"])],Assumptions->σ>0]

Find the standard deviation:

FindRoot[%==0.5,{σ,1.5}]

A sample is selected from a distribution with mean 5 and standard deviation 1.5. Find the minimum size n of the sample so that with probability 0.97 the sample mean is within 0.8 of the distribution mean:

prob=Probability[-0.8+5<m<0.8+5,m\[Distributed]NormalDistribution[5,1.5/Sqrt[n]]]

The probability as a function of sample size:

DiscretePlot[prob,{n,1,30}]

Find the minimum sample size n:

NMinimize[{n,prob≥0.97},{n,12,25}]

The weight of a person, including luggage, has normal distribution with mean 225 lbs and standard deviation 50 lbs. A plane's load limit is 10000 lbs and it can take 44 passengers. With the maximum number of passengers on board, find the probability of the plane being overloaded:

totalWeightDist=TransformedDistribution[(∑_(k=1)^44)(Subscript[x, k]),Table[(Subscript[x, k])\[Distributed]NormalDistribution[Quantity[225,"Pounds"],Quantity[50,"Pounds"]],{k,44}]]

Probability[x>Quantity[10000,"Pounds"],x\[Distributed]totalWeightDist]

N[%]

Normally distributed points in the plane:

Graphics[{AbsolutePointSize[1],Point[RandomVariate[NormalDistribution[],{10^4,2}]]}]

Normally distributed points in 3D:

Graphics3D[{AbsolutePointSize[1],Point[RandomVariate[NormalDistribution[],{10^4,3}]]}]

Normal distribution was traditionally used to analyze the fractional stock price changes from the previous closing price. Find the estimated distribution for the daily fractional price changes of the S&P 500 index from January 1, 2000, to January 1, 2009:

sp500 = FinancialData["SP500", "FractionalChange", 
    {{2000, 1, 1}, {2009, 1, 1}, "Day"}]

The range of fractional prices falls within the range of the normal distribution:

MinMax[sp500]

Fit normal distribution:

edist=EstimatedDistribution[sp500,NormalDistribution[μ,σ]]

Compare the histogram of the data with the PDF of the estimated distribution:

hist=Histogram[sp500,Automatic,"PDF"];
Show[hist,Plot[PDF[edist,Quantity[x,"%"]],{x,-10,12},PlotStyle->Thick,PlotRange->All]]

Find the probability of the fractional price change being greater than 0.5%:

NProbability[x>0.5,x\[Distributed]edist]

Find the mean fractional price change:

Mean[edist]

Simulate fractional price changes for 30 days:

ListLinePlot[RandomVariate[edist,30],AxesLabel->Automatic]

Show that using (RefLink[LogisticDistribution, paclet:ref/LogisticDistribution]) provides better fit than using normal distribution:

LogisticEstimate=EstimatedDistribution[sp500,LogisticDistribution[μ,β]]

Show[hist,Plot[{PDF[edist,Quantity[x,"%"]],PDF[LogisticEstimate,Quantity[x,"%"]]},{x,-10,12},PlotStyle->Thick,PlotRange->All,PlotLegends->{"Fit with normal distribution","Fit with logistic distribution"}]]

Generate Gaussian white noise:

𝒫=WhiteNoiseProcess[]

data=RandomFunction[𝒫,{0,40}];

ListPlot[data,Filling->Axis]

OpenersExampleSection3(Spacer1)Properties & Relations  (36)

Normal distribution is closed under translation and scaling:

TransformedDistribution[a z+b,z\[Distributed]NormalDistribution[μ,σ]]

In general, affine transformations of independent normals are normal:

TransformedDistribution[a1 z1+a2 z2+c,{z1\[Distributed]NormalDistribution[μ1,σ1],z2\[Distributed]NormalDistribution[μ2,σ2]}]

Normal distribution is closed under addition:

TransformedDistribution[x+y,{x\[Distributed]NormalDistribution[(Subscript[μ, 1]),(Subscript[σ, 1])],y\[Distributed]NormalDistribution[(Subscript[μ, 2]),(Subscript[σ, 2])]}]

The normal distribution is symmetric about its mean:

Probability[u<-x+Mean[NormalDistribution[μ,σ]],u\[Distributed]NormalDistribution[μ,σ]]

Probability[u>x+Mean[NormalDistribution[μ,σ]],u\[Distributed]NormalDistribution[μ,σ]]

%-%%

Parameter mixture of a normal distribution with a normal distribution is again a normal distribution:

ParameterMixtureDistribution[NormalDistribution[p,(Subscript[σ, 1])],p\[Distributed]NormalDistribution[μ,(Subscript[σ, 2])]]

Relationships to other distributions:

Normal (SN) (RefLink[JohnsonDistribution, paclet:ref/JohnsonDistribution]) is a normal distribution:

PDF[JohnsonDistribution["SN",μ,σ,γ,δ],x]

PDF[NormalDistribution[γ-μ δ/σ,δ/σ],x]

%-%%//FullSimplify[#,σ>0&&δ>0]&

(RefLink[StudentTDistribution, paclet:ref/StudentTDistribution]) goes to a normal distribution as ν goes to ∞:

Limit[PDF[StudentTDistribution[ν],x],ν->∞]

PDF[NormalDistribution[0,1],x]

%-%%

Normal distribution is a transformation of (RefLink[LogNormalDistribution, paclet:ref/LogNormalDistribution]):

TransformedDistribution[Log[u],u\[Distributed]LogNormalDistribution[μ,σ]]

The inverse transformation of normal distribution yields (RefLink[LogNormalDistribution, paclet:ref/LogNormalDistribution]):

TransformedDistribution[Exp[u],u\[Distributed]NormalDistribution[μ,σ]]

(RefLink[HalfNormalDistribution, paclet:ref/HalfNormalDistribution]) is a truncated normal distribution:

PDF[HalfNormalDistribution[θ],x]

PDF[TruncatedDistribution[{0,∞},NormalDistribution[0,1/(θ(Sqrt[2/π]))]],x]

FullSimplify[%%-%]

The normal and half-normal distributions:

Block[{θ=1},Plot[{Legended[PDF[NormalDistribution[0,1/(θ(Sqrt[2/π]))],x],"normal"],Legended[PDF[HalfNormalDistribution[θ],x],"half-normal"]},{x,-3,3},Filling->Axis]]

(RefLink[HalfNormalDistribution, paclet:ref/HalfNormalDistribution]) is a transformation of normal distribution:

TransformedDistribution[Abs[x],x\[Distributed]NormalDistribution[0,Sqrt[π/2]/θ]]

(RefLink[HalfNormalDistribution, paclet:ref/HalfNormalDistribution]) is a transformation of normal distribution:

TransformedDistribution[Abs[x-μ],x\[Distributed]NormalDistribution[μ,Sqrt[π/2]/θ]]

(RefLink[NormalDistribution, paclet:ref/NormalDistribution]) is a special case of (RefLink[ExponentialPowerDistribution, paclet:ref/ExponentialPowerDistribution]):

PDF[ExponentialPowerDistribution[2,μ,σ],x]

PDF[NormalDistribution[μ,σ],x]

%-%%//FullSimplify

Normal distribution is a special case of (RefLink[SkewNormalDistribution, paclet:ref/SkewNormalDistribution]) with shape parameter α==0:

PDF[SkewNormalDistribution[0,σ,0],x]

PDF[NormalDistribution[0,σ],x]

%-%%

(RefLink[SkewNormalDistribution, paclet:ref/SkewNormalDistribution]) is a transformation of normal distribution:

TransformedDistribution[α Abs[u]+v,{u,v}\[Distributed]ProductDistribution[{NormalDistribution[0,σ/Sqrt[1+α^2] ],2}]]

Sum of squares of n standard normally distributed variables follows (RefLink[ChiSquareDistribution, paclet:ref/ChiSquareDistribution]):

𝒟=TransformedDistribution[x^2+y^2+w^2+z^2,{x,y,w,z}\[Distributed]ProductDistribution[{NormalDistribution[],4}]]

Sum of squares of normally distributed variables has (RefLink[NoncentralChiSquareDistribution, paclet:ref/NoncentralChiSquareDistribution]):

TransformedDistribution[u^2+v^2+w^2,{u\[Distributed]NormalDistribution[μ1,1],v\[Distributed]NormalDistribution[μ2,1],w\[Distributed]NormalDistribution[μ3,1]}]

The norm of n standard normally distributed variables follows (RefLink[ChiDistribution, paclet:ref/ChiDistribution]):

TransformedDistribution[Norm[{x,y,w,z}],{x,y,w,z}\[Distributed]ProductDistribution[{NormalDistribution[],4}]]

The norm of three standard normal variables has (RefLink[MaxwellDistribution, paclet:ref/MaxwellDistribution]), a case of (RefLink[ChiDistribution, paclet:ref/ChiDistribution]):

𝒟=TransformedDistribution[Norm[{x,y,z}],{x,y,z}\[Distributed]ProductDistribution[{NormalDistribution[],3}]]

PDF[𝒟,x]

PDF[MaxwellDistribution[1],x]

%-%%

The norm of two standard normally distributed variables follows (RefLink[RayleighDistribution, paclet:ref/RayleighDistribution]):

TransformedDistribution[Norm[{x,y}],{x,y}\[Distributed]ProductDistribution[{NormalDistribution[],2}]]

The norm of two normally distributed variables follows (RefLink[RiceDistribution, paclet:ref/RiceDistribution]):

𝒟=TransformedDistribution[Norm[{u,v}],{u,v}\[Distributed]ProductDistribution[{NormalDistribution[α/(Sqrt[2]),β],2}]];

Block[{α=.3,β=2},Show[Histogram[RandomVariate[𝒟,10^4],20,"PDF"],Plot[PDF[RiceDistribution[α ,β],x],{x,0,12},PlotStyle->Thick]]]

(RefLink[NormalDistribution, paclet:ref/NormalDistribution]) is the limiting case of (RefLink[HyperbolicDistribution, paclet:ref/HyperbolicDistribution]) of α->∞ for δ/α==(σ^2) and β==0:

Limit[With[{β=0,δ=(σ^2)α},PDF[HyperbolicDistribution[λ,α,β,δ,μ],x]],α->Infinity,Assumptions->σ>0&&{λ,μ,x}∈Reals]

PDF[NormalDistribution[μ,σ],x]

%-%%

If x, y, u, and v are independent and normal, then u v + x y has (RefLink[LaplaceDistribution, paclet:ref/LaplaceDistribution]):

𝒟=TransformedDistribution[x y+ u v,{x,y,u,v}\[Distributed]ProductDistribution[{NormalDistribution[],4}]];

Show[Histogram[RandomVariate[𝒟,10^4],{-5,5,0.5},"PDF"],Plot[PDF[TruncatedDistribution[{-5,5},LaplaceDistribution[0,1]],x],{x,-6,6},PlotStyle->Thick]]

Confirm via equality of (RefLink[CharacteristicFunction, paclet:ref/CharacteristicFunction]):

CharacteristicFunction[𝒟,t]==CharacteristicFunction[LaplaceDistribution[],t]

If x, y, u, and v are independent and normal, then u v-x y has (RefLink[LaplaceDistribution, paclet:ref/LaplaceDistribution]):

𝒟=TransformedDistribution[w z- u v,{w,z,u,v}\[Distributed]ProductDistribution[{NormalDistribution[],4}]];

Show[Histogram[RandomVariate[𝒟,10^4],30,"PDF"],Plot[PDF[LaplaceDistribution[0,1],x],{x,-6,6},PlotRange->All,PlotStyle->Thick]]

Confirm via equality of (RefLink[CharacteristicFunction, paclet:ref/CharacteristicFunction]):

CharacteristicFunction[𝒟,t]==CharacteristicFunction[LaplaceDistribution[],t]

Ratio of two normally distributed variables has (RefLink[CauchyDistribution, paclet:ref/CauchyDistribution]):

TransformedDistribution[u/v,{u,v}\[Distributed]ProductDistribution[{NormalDistribution[],2}]]

Square of a normally distributed variable is a special case of (RefLink[GammaDistribution, paclet:ref/GammaDistribution]), and also of (RefLink[ChiSquareDistribution, paclet:ref/ChiSquareDistribution]):

𝒟=TransformedDistribution[u^2,u\[Distributed]NormalDistribution[]]

PDF[𝒟,x]

PDF[GammaDistribution[1/2,2],x]

Simplify[%-%%]

(RefLink[LaplaceDistribution, paclet:ref/LaplaceDistribution]) is a parameter mixture of a normal distribution with (RefLink[RayleighDistribution, paclet:ref/RayleighDistribution]):

𝒟=ParameterMixtureDistribution[NormalDistribution[μ,σ],σ\[Distributed]RayleighDistribution[ν]]

(RefLink[StudentTDistribution, paclet:ref/StudentTDistribution]) is a parameter mixture of a normal distribution with (RefLink[GammaDistribution, paclet:ref/GammaDistribution]):

ParameterMixtureDistribution[NormalDistribution[μ,1/Sqrt[λ2]],λ2\[Distributed]GammaDistribution[ν/2,2/ν/(σ^2)],Assumptions->σ>0]

(RefLink[LevyDistribution, paclet:ref/LevyDistribution]) is a transformation of a normal distribution:

TransformedDistribution[(1/(x^2)),x\[Distributed]NormalDistribution[]]

With mean and scale:

TransformedDistribution[(x-μ)^-2,x\[Distributed]NormalDistribution[μ,σ]]

Normal distribution is a special case of type 3 (RefLink[PearsonDistribution, paclet:ref/PearsonDistribution]):

PDF[PearsonDistribution[3,(σ^(-2)),-μ (σ^(-2)),0,0,1],x]//FullSimplify[#,σ>0]&

PDF[NormalDistribution[μ,σ],x]

%-%%

Normal distribution is a (RefLink[StableDistribution, paclet:ref/StableDistribution]):

PDF[NormalDistribution[μ,σ],x]

PDF[StableDistribution[0,2,0,μ,σ/(Sqrt[2])],x]

%-%%//Simplify

Normal distribution is the marginal distribution of (RefLink[BinormalDistribution, paclet:ref/BinormalDistribution]):

MarginalDistribution[BinormalDistribution[{μ1,μ2},{σ1,σ2},ρ],1]

MarginalDistribution[BinormalDistribution[{μ1,μ2},{σ1,σ2},ρ],2]

Normal distribution is the marginal distribution of (RefLink[MultinormalDistribution, paclet:ref/MultinormalDistribution]):

Σ=(({{((σ1)^2), ρ12 σ1 σ2, ρ13 σ1 σ3}, {ρ12 σ1 σ2, ((σ2)^2), ρ23 σ2 σ3}, {ρ13 σ1 σ3, ρ23 σ2 σ3, ((σ3)^2)}}));

MarginalDistribution[MultinormalDistribution[{μ1,μ2,μ3},Σ],1]

MarginalDistribution[MultinormalDistribution[{μ1,μ2,μ3},Σ],2]

MarginalDistribution[MultinormalDistribution[{μ1,μ2,μ3},Σ],3]

(RefLink[NormalDistribution, paclet:ref/NormalDistribution]) can be obtained from (RefLink[MultinormalDistribution, paclet:ref/MultinormalDistribution]):

Σ={{((Subscript[σ, 1])^2),ρ (Subscript[σ, 1])(Subscript[σ, 2])},{ρ (Subscript[σ, 1])(Subscript[σ, 2]),((Subscript[σ, 2])^2)}};TransformedDistribution[u+v,{u,v}\[Distributed]MultinormalDistribution[{(Subscript[μ, 1]),(Subscript[μ, 2])},Σ]]

(RefLink[StudentTDistribution, paclet:ref/StudentTDistribution]) can be obtained from (RefLink[NormalDistribution, paclet:ref/NormalDistribution]) and (RefLink[ChiSquareDistribution, paclet:ref/ChiSquareDistribution]):

𝒟=TransformedDistribution[z (Sqrt[ν /w]),{z\[Distributed]NormalDistribution[],w\[Distributed]ChiSquareDistribution[ν]}];

PDF[𝒟,x]//FullSimplify[#,ν>0]&

PDF[StudentTDistribution[ν],x]//FunctionExpand//PowerExpand

FullSimplify[%-%%,x≠0]

(RefLink[NoncentralStudentTDistribution, paclet:ref/NoncentralStudentTDistribution]) can be obtained from (RefLink[NormalDistribution, paclet:ref/NormalDistribution]) and (RefLink[ChiSquareDistribution, paclet:ref/ChiSquareDistribution]):

𝒟=TransformedDistribution[(z+δ)(Sqrt[ν /w]),{z\[Distributed]NormalDistribution[],w\[Distributed]ChiSquareDistribution[ν]}];

Block[{δ=3,ν=15},Show[Histogram[RandomVariate[𝒟,10^4],20,"PDF"],Plot[PDF[NoncentralStudentTDistribution[ν,δ],x],{x,-10,10},PlotStyle->Thick]]]

(RefLink[VarianceGammaDistribution, paclet:ref/VarianceGammaDistribution]) can be obtained from (RefLink[GammaDistribution, paclet:ref/GammaDistribution]) and normal distribution:

dist=TransformedDistribution[μ+β*v+Sqrt[v]*u,{u\[Distributed]NormalDistribution[0,1],v\[Distributed]GammaDistribution[λ, 2/(α-β)/(α+β)]}];

MomentGeneratingFunction[dist,x]

Rewrite to simplify:

(E^(x μ))(((1/(1+((2 x β)/(-(α^2)+(β^2))))/(1+((x^2)/(-(α^2)+β (2 x+β))))))^λ)//Simplify

MomentGeneratingFunction[VarianceGammaDistribution[λ,α,β,μ],x]//Simplify

%%/%//FullSimplify[#,λ>0&&β>0]&

OpenersExampleSection4(Spacer1)Possible Issues  (2)

(RefLink[NormalDistribution, paclet:ref/NormalDistribution]) is not defined when μ is not a real number:

Mean[NormalDistribution[3+I,6]]

(RefLink[NormalDistribution, paclet:ref/NormalDistribution]) is not defined when σ is not a positive real number:

Mean[NormalDistribution[3,-6]]

Substitution of invalid parameters into symbolic outputs gives results that are not meaningful:

Mean[NormalDistribution[μ,σ]]/.{μ->I,σ->-1}

OpenersExampleSection5(Spacer1)Neat Examples  (1)

PDFs for different σ values with CDF contours:

cdf=Function[{x,σ},Evaluate[CDF[NormalDistribution[0,σ],x]]];
ql={0.025,0.10,0.25,0.5,0.75,0.90,0.975};
cl=Table[ColorData["Rainbow"][q],{q,Join[{0.0},ql]}];

Legended[Plot3D[PDF[NormalDistribution[0,σ],x],{x,-5,5},{σ,1,5},PlotTheme->"Marketing",MeshFunctions->{cdf},Mesh->{ql},MeshStyle->GrayLevel[0.8],MeshShading->cl,AxesLabel->Automatic,PlotPoints->100,BaseStyle->Opacity[0.9],ImageSize->400,PlotRange->All,Exclusions->None],BarLegend["Rainbow",ql,LegendLabel->"prob"]]

({{DocumentationFooterIconsRelatedFunction.png, ({{See Also}, {(RefLink[StudentTDistribution, paclet:ref/StudentTDistribution])  ▪  (RefLink[ChiDistribution, paclet:ref/ChiDistribution])  ▪  (RefLink[ChiSquareDistribution, paclet:ref/ChiSquareDistribution])  ▪  (RefLink[MaxwellDistribution, paclet:ref/MaxwellDistribution])  ▪  (RefLink[RayleighDistribution, paclet:ref/RayleighDistribution])  ▪  (RefLink[RiceDistribution, paclet:ref/RiceDistribution])  ▪  (RefLink[HalfNormalDistribution, paclet:ref/HalfNormalDistribution])  ▪  (RefLink[SkewNormalDistribution, paclet:ref/SkewNormalDistribution])  ▪  (RefLink[BinormalDistribution, paclet:ref/BinormalDistribution])  ▪  (RefLink[MultinormalDistribution, paclet:ref/MultinormalDistribution])  ▪  (RefLink[Erf, paclet:ref/Erf])  ▪  (RefLink[InverseErf, paclet:ref/InverseErf])  ▪  (RefLink[GaussianMatrix, paclet:ref/GaussianMatrix])  ▪  (RefLink[Around, paclet:ref/Around])}})}})

({{DocumentationFooterIconsRelatedTutorial.png, ({{Tutorials}, {▪(RefLinkPlain[Continuous Distributions, paclet:tutorial/ContinuousDistributions])}})}})

({{DocumentationFooterIconsRelatedGuide.png, ({{Related Guides}, {▪(RefLinkPlain[Probability & Statistics, paclet:guide/ProbabilityAndStatistics])}, {▪(RefLinkPlain[Random Variables, paclet:guide/RandomVariables])}, {▪(RefLinkPlain[Probability & Statistics with Quantities, paclet:guide/ProbabilityWithQuantities])}, {▪(RefLinkPlain[Mathematical Functions, paclet:guide/MathematicalFunctions])}, {▪(RefLinkPlain[Numbers with Uncertainty, paclet:guide/NumbersWithUncertainty])}, {▪(RefLinkPlain[Normal and Related Distributions, paclet:guide/NormalRelatedDistributions])}, {▪(RefLinkPlain[Scientific Models, paclet:guide/ScientificModels])}, {▪(RefLinkPlain[Parametric Statistical Distributions, paclet:guide/ParametricStatisticalDistributions])}, {▪(RefLinkPlain[Functions Used in Statistics, paclet:guide/FunctionsUsedInStatistics])}, {▪(RefLinkPlain[Actuarial Computation, paclet:guide/ActuarialComputation])}, {▪(RefLinkPlain[Distributions in Communication Systems, paclet:guide/DistributionsInCommunicationSystems])}})}})

({{(Spacer1), ({{(Spacer1)Related Links}, {(WebLink[DocumentationFooterIconsRelatedLinks-EIWL.png(Spacer1)An Elementary Introduction to the Wolfram Language, https://www.wolfram.com/language/elementary-introduction/23-more-about-numbers.html])(WebLink[: More about Numbers, https://www.wolfram.com/language/elementary-introduction/23-more-about-numbers.html])}})}})