({{, (RefLink[MultivariatePoissonDistribution, paclet:ref/MultivariatePoissonDistribution])[(Subscript[μ, 0]),{(Subscript[μ, 1]),(Subscript[μ, 2]),…}]
represents a multivariate Poisson distribution with mean vector {(Subscript[μ, 0])+(Subscript[μ, 1]),(Subscript[μ, 0])+(Subscript[μ, 2]),…}.}})

OpenersNotesSection(Spacer1)Details

The multivariate Poisson distribution corresponds to the distribution of {(Subscript[x, 0])+(Subscript[x, 1]),(Subscript[x, 0])+(Subscript[x, 2]),…}, where (Subscript[x, i]) is Poisson distributed with mean (Subscript[μ, i]).

The parameters (Subscript[μ, i]) can be any positive numbers.

(RefLink[MultivariatePoissonDistribution, paclet:ref/MultivariatePoissonDistribution]) can be used with such functions as (RefLink[Mean, paclet:ref/Mean]), (RefLink[CDF, paclet:ref/CDF]), and (RefLink[RandomVariate, paclet:ref/RandomVariate]).

OpenersPrimaryExamplesSection(Spacer1)Examples  (18)

OpenersExampleSection0(Spacer1)Basic Examples  (4)

Probability mass function:

Table[DiscretePlot3D[PDF[MultivariatePoissonDistribution[μ,{2,3}],{x,y}],{x,0,15},{y,0,15},ExtentSize->0.5,PlotRange->All,PlotLabel->Row[{"μ = ",μ}]],{μ,{1,3,5,8}}]

PDF[MultivariatePoissonDistribution[μ,{(Subscript[μ, 1]),(Subscript[μ, 2])}],{x,y}]

Cumulative distribution function:

Table[DiscretePlot3D[CDF[MultivariatePoissonDistribution[μ,{2,3}],{x,y}],{x,0,15},{y,0,15},ExtentSize->Right,PlotLabel->Row[{"μ = ",μ}]],{μ,{1,3,5,8}}]

Mean and variance:

Mean[MultivariatePoissonDistribution[μ,{(Subscript[μ, 1]),(Subscript[μ, 2]),(Subscript[μ, 3])}]]

Variance[MultivariatePoissonDistribution[μ,{(Subscript[μ, 1]),(Subscript[μ, 2]),(Subscript[μ, 3])}]]

Covariance matrix:

Covariance[MultivariatePoissonDistribution[μ,{(Subscript[μ, 1]),(Subscript[μ, 2]),(Subscript[μ, 3])}]]//MatrixForm

OpenersExampleSection1(Spacer1)Scope  (8)

Generate a sample of pseudorandom vectors from a multivariate Poisson distribution:

sample=RandomVariate[𝒹=MultivariatePoissonDistribution[1,{2,3}],10^4];

Row[{Histogram3D[sample,{-0.5,10.5,1},"PDF",ColorFunction->"Rainbow"],DiscretePlot3D[PDF[𝒹,{x,y}],{x,0,10},{y,0,10},ColorFunction->"Rainbow",PlotRange->All,ExtentSize->1]}]

Distribution parameters estimation:

s=RandomVariate[MultivariatePoissonDistribution[2,{3,6,9}],10^2];

Estimate the distribution parameters from sample data:

e𝒟=EstimatedDistribution[s,MultivariatePoissonDistribution[μ,{μ1,μ2,μ3}]]

Goodness-of-fit test:

DistributionFitTest[s,e𝒟]

Skewness for each component depends on μ and (Subscript[μ, i]):

Plot3D[Skewness[MultivariatePoissonDistribution[μ,{μ1}]],{μ,0,6},{μ1,0,6},MeshFunctions->{#3&},MeshShading->ColorData[35,"ColorList"],AxesLabel->Automatic]

Skewness[MultivariatePoissonDistribution[μ,{(Subscript[μ, 1]),(Subscript[μ, 2]),(Subscript[μ, 3])}]]

Kurtosis for each component depends on μ and (Subscript[μ, i]):

Plot3D[Kurtosis[MultivariatePoissonDistribution[μ,{μ1}]],{μ,0,6},{μ1,0,6},MeshFunctions->{#3&},MeshShading->ColorData[35,"ColorList"],AxesLabel->Automatic]

Kurtosis[MultivariatePoissonDistribution[μ,{(Subscript[μ, 1]),(Subscript[μ, 2]),(Subscript[μ, 3])}]]

Correlation:

Correlation[MultivariatePoissonDistribution[μ,{(Subscript[μ, 1]),(Subscript[μ, 2]),(Subscript[μ, 3])}]]//MatrixForm

Different mixed moments for a bivariate Poisson distribution:

FormulaGrid[list_,type_]:=Grid[Transpose[{list}],Alignment->{Left,Automatic},Background->{None,{{Lighter[Blend[Switch[type,M,{Blue,Green},CM,{Red,Orange},FM,{Magenta,Cyan},C,{Purple,Red}]],.8],White}}},Dividers->{None,{Darker[Gray,.6],{False},Darker[Gray,.6]}},ItemSize->35]

FormulaGrid[Table[Moment[MultivariatePoissonDistribution[μ,{(Subscript[μ, 1]),(Subscript[μ, 2])}],{2,k}]//FullSimplify,{k,0,3}],M]

Mixed central moments:

FormulaGrid[Table[CentralMoment[MultivariatePoissonDistribution[μ,{(Subscript[μ, 1]),(Subscript[μ, 2])}],{3,k}]//Factor,{k,0,3}],CM]

Mixed factorial moments:

FormulaGrid[Table[FactorialMoment[MultivariatePoissonDistribution[μ,{(Subscript[μ, 1]),(Subscript[μ, 2])}],{2,k}]//Factor,{k,0,3}],FM]

Mixed cumulants:

FormulaGrid[Table[Cumulant[MultivariatePoissonDistribution[μ,{(Subscript[μ, 1]),(Subscript[μ, 2])}],{2,k}],{k,0,3}],C]

Closed form for a symbolic order:

Cumulant[MultivariatePoissonDistribution[μ,{(Subscript[μ, 1]),(Subscript[μ, 2])}],{r,k}]

Hazard function:

Table[DiscretePlot3D[HazardFunction[MultivariatePoissonDistribution[μ,{1,2}],{x,y}]//Evaluate,{x,0,10+μ},{y,0,10+μ},ExtentSize->1/2,PlotLabel->Row[{"μ = ",μ}]],{μ,{1,3,5,8}}]

Marginal distributions:

𝒟=MultivariatePoissonDistribution[μ,{(Subscript[μ, 1]),(Subscript[μ, 2]),(Subscript[μ, 3])}];

MarginalDistribution[𝒟,1]

MarginalDistribution[𝒟,{2,3}]

OpenersExampleSection2(Spacer1)Applications  (2)

In clinical studies, medicine A on average caused an adverse reaction in 12 people per 100000 and medicine B in 9 people per 100000. It has also been determined that while some people will show no adverse reaction to medicine A or B alone, the combination of both caused an adverse reaction on average in 1 person per 500000. Assuming a Poisson model, find the adverse reaction distribution in the population of 10000:

𝒟=Block[{n=10^4},MultivariatePoissonDistribution[n 1/500000,{n 12/100000,n 9/100000}]];

Table[DiscretePlot[PDF[MarginalDistribution[𝒟,i],x],{x,0,6},PlotRange->{Full,{0,0.4}},ExtentSize->1/2,PlotLabel->{"A","B"}[[i]]],{i,2}]

Find the probability that there are at most 3 adverse reactions to medicine A and at most 4 adverse reactions to medicine B:

CDF[𝒟,{3,4}]//N

A university campus lies completely within twin cities A and B. On a given day there are, on average, 10 car accidents on campus; outside of campus there are 5 more in city A and 10 more in city B. Find the joint distribution of the number of accidents in the twin cities:

𝒟=MultivariatePoissonDistribution[10,{5,10}];

Probability density function:

DiscretePlot3D[PDF[𝒟,{x,y}],{x,5,25},{y,5,35},ExtentSize->2/3]

PDF[𝒟,{x,y}]

Find the average number of accidents in each city:

Mean[𝒟]

Find the average total number of accidents in the twin cities:

Total@Mean[𝒟]

Find the probability that on a given day there are more accidents in city A than in city B:

NProbability[x>y,{x,y}\[Distributed]𝒟,Method->{"NSum",Method->"WynnEpsilon"}]

Use a random sample to find the probability that there are at least 12 accidents per day in the twin cities:

Probability[x+y≥12,{x,y}\[Distributed]RandomVariate[𝒟,10^5]]//N

OpenersExampleSection3(Spacer1)Properties & Relations  (4)

Multivariate Poisson distribution is closed under addition:

CharacteristicFunction[MultivariatePoissonDistribution[μ,{(Subscript[μ, 1]),(Subscript[μ, 2])}],{(Subscript[t, 1]),(Subscript[t, 2])}]CharacteristicFunction[MultivariatePoissonDistribution[λ,{(Subscript[λ, 1]),(Subscript[λ, 2])}],{(Subscript[t, 1]),(Subscript[t, 2])}]//FullSimplify

CharacteristicFunction[MultivariatePoissonDistribution[μ+λ,{(Subscript[μ, 1])+(Subscript[λ, 1]),(Subscript[μ, 2])+(Subscript[λ, 2])}],{(Subscript[t, 1]),(Subscript[t, 2])}]

FullSimplify[%/%%]

One-dimensional multivariate Poisson distribution is a (RefLink[PoissonDistribution, paclet:ref/PoissonDistribution]):

PDF[MultivariatePoissonDistribution[μ,{(Subscript[μ, 1])}],{x}]

PDF[PoissonDistribution[μ+(Subscript[μ, 1])],x]

%-%%

The components are correlated for all allowed values of parameters:

Correlation[MultivariatePoissonDistribution[μ,{(Subscript[μ, 1]),(Subscript[μ, 2])}]]//MatrixForm

Multivariate Poisson cannot be represented as a product of its marginal distributions:

𝒟=MultivariatePoissonDistribution[μ,{μ1,μ2}];

Find marginal distributions:

{ℳ1,ℳ2}={MarginalDistribution[𝒟,1],MarginalDistribution[𝒟,2]}

Find (RefLink[ProductDistribution, paclet:ref/ProductDistribution]) of marginal distributions:

𝒫=ProductDistribution[ℳ1,ℳ2];

Compare covariance matrices:

MatrixForm/@{Covariance[𝒟],Covariance[𝒫]}

Compare PDFs:

Block[{μ=20,μ1=6,μ2=3},{DiscretePlot3D[PDF[𝒟,{x,y}],{x,10,40},{y,10,40},ExtentSize->Full],DiscretePlot3D[PDF[𝒫,{x,y}],{x,10,40},{y,10,40},ExtentSize->Full]}]

({{DocumentationFooterIconsRelatedFunction.png, ({{See Also}, {(RefLink[PoissonDistribution, paclet:ref/PoissonDistribution])  ▪  (RefLink[SkellamDistribution, paclet:ref/SkellamDistribution])}})}})

({{DocumentationFooterIconsRelatedGuide.png, ({{Related Guides}, {▪(RefLinkPlain[Parametric Statistical Distributions, paclet:guide/ParametricStatisticalDistributions])}})}})