({{, (RefLink[ModularLambda, paclet:ref/ModularLambda])[τ]
gives the modular lambda elliptic function λ(τ). }})

OpenersNotesSection(Spacer1)Details

Mathematical function, suitable for both symbolic and numerical manipulation.

(RefLink[ModularLambda, paclet:ref/ModularLambda]) is defined only in the upper half of the complex τ plane. It is not defined for real τ.

The argument τ is the ratio of Weierstrass half-periods ω'/ω.

(RefLink[ModularLambda, paclet:ref/ModularLambda]) gives the parameter m for elliptic functions in terms of τ according to m=λ(τ).

(RefLink[ModularLambda, paclet:ref/ModularLambda]) is related to (RefLink[EllipticTheta, paclet:ref/EllipticTheta]) by λ(τ)=(Subscript[ϑ, 2]^4)(0,q)/(Subscript[ϑ, 3]^4)(0,q) where the nome q is given by (e^(iπτ)).

λ(τ) is invariant under any combination of the modular transformations τ->τ+2 and τ->τ/(1-2τ). »

For certain special arguments, (RefLink[ModularLambda, paclet:ref/ModularLambda]) automatically evaluates to exact values.

(RefLink[ModularLambda, paclet:ref/ModularLambda]) can be evaluated to arbitrary numerical precision.

(RefLink[ModularLambda, paclet:ref/ModularLambda]) automatically threads over lists.

OpenersPrimaryExamplesSection(Spacer1)Examples  (26)

OpenersExampleSection0(Spacer1)Basic Examples  (2)

Evaluate numerically:

ModularLambda[1+3.I]

Plot[Re[ModularLambda[x+I]],{x,-2,2}]

OpenersExampleSection1(Spacer1)Scope  (16)

OpenersExampleSubsection0(Spacer1)Numerical Evaluation  (3)

Evaluate numerically:

ModularLambda[14.3+I]

ModularLambda[1.5+I]

Evaluate to high precision:

N[ModularLambda[1/7+I],50]

The precision of the output tracks the precision of the input:

ModularLambda[0.2000000000000000000+I]

Evaluate efficiently at high precision:

ModularLambda[I+12`100]//Timing

ModularLambda[I+8`100000];//Timing

OpenersExampleSubsection1(Spacer1)Specific Values   (2)

Value at a fixed point:

ModularLambda[I ]

Find the first positive minimum of (RefLink[ModularLambda, paclet:ref/ModularLambda])[x+I]:

xmin=x/.FindRoot[Re[D[ModularLambda[x+I],x]]==0,{x,1}]

Plot[Re[ModularLambda[x+I]],{x,-1,4},Epilog->{PointSize[Large],Red,Point[{xmin,Re[ModularLambda[xmin+I]]}]}]

OpenersExampleSubsection2(Spacer1)Visualization  (3)

Plot the real part of (RefLink[ModularLambda, paclet:ref/ModularLambda]):

Plot[Re[ModularLambda[t+I]],{t,-5,5}]

Plot the absolute value of (RefLink[ModularLambda, paclet:ref/ModularLambda]):

Plot[Abs[ModularLambda[t+I]],{t,-5,5}]

Plot the real part of (RefLink[ModularLambda, paclet:ref/ModularLambda]) function:

ContourPlot[Re[ModularLambda[x+I y]],{x,-3,3},{y,-.1,3},Contours->24]

Plot the imaginary part of (RefLink[ModularLambda, paclet:ref/ModularLambda]) function:

ContourPlot[Im[ModularLambda[x+I y]],{x,-3,3},{y,0,3},Contours->24]

OpenersExampleSubsection3(Spacer1)Function Properties  (4)

Complex domain of (RefLink[ModularLambda, paclet:ref/ModularLambda]):

FunctionDomain[ModularLambda[x],x,Complexes]

(RefLink[ModularLambda, paclet:ref/ModularLambda]) is a periodic function:

FunctionPeriod[ModularLambda[x+I],x]

(RefLink[ModularLambda, paclet:ref/ModularLambda]) threads elementwise over lists:

ModularLambda[{0.2+2I, 0.3+2I, 0.4+2I}]

(RefLink[TraditionalForm, paclet:ref/TraditionalForm]) formatting:

ModularLambda[τ]//TraditionalForm

OpenersExampleSubsection4(Spacer1)Differentiation  (2)

First derivative with respect to z:

D[ModularLambda[z],z]

Higher derivatives with respect to z:

Table[D[ModularLambda[z+I],{z,k}],{k,1,3}]//FullSimplify

Plot the higher derivatives with respect to z:

Plot[Evaluate[Re[%]],{z,-3,3},PlotLegends->{"First Derivative","Second Derivative","Third Derivative"}]

OpenersExampleSubsection5(Spacer1)Series Expansions  (2)

Find the Taylor expansion using (RefLink[Series, paclet:ref/Series]):

Series[ModularLambda[x+I],{x,0,3}]//Normal//FullSimplify

Plots of the first three approximations around x=0:

terms=Re@Normal[Table[Series[ModularLambda[x+I],{x,0,m}],{m,1,5,2}]];
Plot[terms,{x,-2,2},PlotRange->{-1,1},PlotLegends->"Expressions"]

Taylor expansion at a generic point:

Series[ModularLambda[x+I],{x,x0,2}]// Normal//FullSimplify

OpenersExampleSection2(Spacer1)Applications  (4)

Some modular properties of (RefLink[ModularLambda, paclet:ref/ModularLambda]) are automatically applied:

ModularLambda[τ+2]

Verify a more complicated identity numerically:

ModularLambda[τ/(1-2 τ)]==ModularLambda[τ]/.τ->RandomComplex[{-3+I/10,3+10 I},{100},WorkingPrecision->20]

(RefLink[ModularLambda, paclet:ref/ModularLambda]) is a modular function. Make an ansatz for a modular equation:

(ansatz=With[{u=ModularLambda[z],v=ModularLambda[2z]},Sum[(Subscript[c, i,j])u^i v^j,{i,0,2},{j,0,2}]/.(Subscript[c, 2,0])->1]==0)//TraditionalForm

Form an overdetermined system of equations and solve it:

eqs=Table[N[ansatz/.z->N[1/3+1/k+I/3,250],50],{k,3,24}];

sol=Solve[eqs,Flatten[Table[(Subscript[c, i,j]),{i,0,2},{j,0,2}]]]//Chop//Rationalize

This is the modular equation of order 2:

ansatz/.First[sol]//TraditionalForm

Solution of the Darboux–Halphen system:

w1[τ_]=1/2 D[Log[ModularLambda'[τ]/ModularLambda[τ]],τ];
w2[τ_]=1/2 D[Log[ModularLambda'[τ]/(ModularLambda[τ]-1)],τ];
w3[τ_]=1/2D[Log[ModularLambda'[τ]/(ModularLambda[τ](ModularLambda[τ]-1))],τ];

Check:

{D[w1[τ],τ]-(w1[τ](w2[τ]+w3[τ])-w2[τ] w3[τ]),D[w2[τ],τ]-(w2[τ](w1[τ]+w3[τ])-w1[τ] w3[τ]),D[w3[τ],τ]-(w3[τ](w1[τ]+w2[τ])-w1[τ] w2[τ])}//FullSimplify

Plot the real part in the complex plane:

ContourPlot[Re[ModularLambda[x+I y]],{x,-1,1},{y,0.2,1.5},AspectRatio->Automatic]

OpenersExampleSection3(Spacer1)Properties & Relations  (2)

Find derivatives:

D[ModularLambda[τ],τ]

Find a numerical root:

FindRoot[ModularLambda[z]+ModularLambda[z^2]+z==1,{z,1+I}]

OpenersExampleSection4(Spacer1)Possible Issues  (2)

Machine-precision input is insufficient to give a correct answer:

ModularLambda[10.^22 Pi+I]

With exact input, the answer is correct:

N[ModularLambda[10^22 Pi+I],20]

(RefLink[ModularLambda, paclet:ref/ModularLambda]) remains unevaluated outside of its domain of analyticity:

ModularLambda[1]

N[%]

({{DocumentationFooterIconsRelatedFunction.png, ({{See Also}, {(RefLink[DedekindEta, paclet:ref/DedekindEta])  ▪  (RefLink[KleinInvariantJ, paclet:ref/KleinInvariantJ])  ▪  (RefLink[WeierstrassHalfPeriods, paclet:ref/WeierstrassHalfPeriods])  ▪  (RefLink[EllipticTheta, paclet:ref/EllipticTheta])}})}})

({{DocumentationFooterIconsRelatedTutorial.png, ({{Tutorials}, {▪(RefLinkPlain[Elliptic Integrals and Elliptic Functions, paclet:tutorial/EllipticIntegralsAndEllipticFunctions])}})}})

({{DocumentationFooterIconsRelatedGuide.png, ({{Related Guides}, {▪(RefLinkPlain[Special Functions, paclet:guide/SpecialFunctions])}, {▪(RefLinkPlain[q Functions, paclet:guide/QFunctions])}})}})

({{(Spacer1), ({{(Spacer1)Related Links}, {(WebLink[DocumentationFooterIconsRelatedLinks-MathWorld.png(Spacer1)MathWorld, http://mathworld.wolfram.com/EllipticLambdaFunction.html])}, {(WebLink[DocumentationFooterIconsRelatedLinks-Functions.png(Spacer1)The Wolfram Functions Site, http://functions.wolfram.com/EllipticFunctions/ModularLambda/])}, {(WebLink[DocumentationFooterIconsRelatedLinks-NKS.png(Spacer1)NKS|Online, http://www.wolframscience.com/nksonline/index/search.cgi?SearchIndex=ModularLambda]) ((WebLink[A New Kind of Science, http://www.wolframscience.com/nksonline/]))}})}})