({{, (RefLink[ListLinePlot, paclet:ref/ListLinePlot])[{(Subscript[y, 1]),(Subscript[y, 2]),…}]
plots a line through the points {1,(Subscript[y, 1])},{2,(Subscript[y, 2])},….}, {, (RefLink[ListLinePlot, paclet:ref/ListLinePlot])[{{(Subscript[x, 1]),(Subscript[y, 1])},{(Subscript[x, 2]),(Subscript[y, 2])},…}]
plots a line through a list of points with specific x and y positions. }, {, (RefLink[ListLinePlot, paclet:ref/ListLinePlot])[{(Subscript[data, 1]),(Subscript[data, 2]),…}]
plots data from all the (Subscript[data, i]). }, {, (RefLink[ListLinePlot, paclet:ref/ListLinePlot])[{…,w[(Subscript[data, i]),…],…}]
plots (Subscript[data, i]) with features defined by the symbolic wrapper w.}})

OpenersNotesSection(Spacer1)Details and Options

Data values (Subscript[x, i]) and (Subscript[y, i]) can be given in the following forms:

Values (Subscript[x, i]) and (Subscript[y, i]) that are not of the form above are taken to be missing and are not shown.

The (Subscript[data, i]) have the following forms and interpretations:

The following wrappers w can be used for the (Subscript[data, i]):

Wrappers w can be applied at multiple levels:

(RefLink[Callout, paclet:ref/Callout]), (RefLink[Labeled, paclet:ref/Labeled]), and (RefLink[Placed, paclet:ref/Placed]) can use the following positions pos:

(RefLink[ListLinePlot, paclet:ref/ListLinePlot]) has the same options as (RefLink[Graphics, paclet:ref/Graphics]), with the following additions and changes:

(RefLink[DataRange, paclet:ref/DataRange]) determines how values {(Subscript[y, 1]),…,(Subscript[y, n])} are interpreted into {{(Subscript[x, 1]),(Subscript[y, 1])},…,{(Subscript[x, n]),(Subscript[y, n])}}. Possible settings include:

In general a list of pairs {{(Subscript[x, 1]),(Subscript[y, 1])},{(Subscript[x, 2]),(Subscript[y, 2])},…} is interpreted as a list of points, but the setting (RefLink[DataRange, paclet:ref/DataRange])->(RefLink[All, paclet:ref/All]) forces it to be interpreted as multiple data sources {{(Subscript[y, 11]),(Subscript[y, 12])},{(Subscript[y, 21]),(Subscript[y, 23])},…}.  »

(RefLink[LabelingFunction, paclet:ref/LabelingFunction])->f specifies that each point should have a label given by f[value,index,lbls], where value is the value associated with the point, index is its position in the data, and lbls is the list of relevant labels.

Typical settings for (RefLink[PlotLegends, paclet:ref/PlotLegends]) include:

(RefLink[ScalingFunctions, paclet:ref/ScalingFunctions])->"scale" scales the y coordinate; (RefLink[ScalingFunctions, paclet:ref/ScalingFunctions])->{"scalex","scaley"} scales both the x and y coordinates.

OpenersPrimaryExamplesSection(Spacer1)Examples  (190)

OpenersExampleSection0(Spacer1)Basic Examples  (5)

Plot a list of y values:

ListLinePlot[{1,1,2,3,5,8}]

Adding filling under the line:

ListLinePlot[Prime[Range[25]],Filling->Axis]

Plot a list of x, y pairs:

ListLinePlot[Table[{Cos[k 2Pi/7],Sin[k 2Pi/7]},{k,0,21,3}],Frame->True,Axes->False]

Plot multiple datasets with a legend:

ListLinePlot[Table[Accumulate[RandomReal[{-1,1},250]],{3}],Filling->Axis,PlotLegends->{"one","two","three"}]

Plot values including units:

ListLinePlot[Quantity[{0,3,6,8,10,11,11,16,20,22},"Centimeters"],AxesLabel->Automatic]

OpenersExampleSection1(Spacer1)Scope  (49)

OpenersExampleSubsection0(Spacer1)Data  (10)

Lines are drawn through the data points:

ListLinePlot[{1,2,3,5,8,13,21}]

Use x, y pairs:

ListLinePlot[{{1,1},{2,2},{3,4},{5,8},{8,16},{13,32},{21,64}}]

Show multiple sets of data:

ListLinePlot[{{1,2,3,5,8,13,21},{1,2,4,8,16,32,64}}]

The plot range is selected automatically:

ListLinePlot[{1,2,3,4,25,8,9}]

Specify what values the data ranges over:

ListLinePlot[{1,2,4,3,5,9,8,7},DataRange->{0,1}]

Ranges where the data is nonreal are excluded:

ListLinePlot[{1,2,3,None,5,6,Missing["NotAvailable"],8,9}]

Use (RefLink[InterpolationOrder, paclet:ref/InterpolationOrder]) to smooth the data:

{ListLinePlot[{1,2,4,7,3,5,8,10,9}],ListLinePlot[{1,2,4,7,3,5,8,10,9},InterpolationOrder->2]}

Use (RefLink[MaxPlotPoints, paclet:ref/MaxPlotPoints]) to limit the number of points used:

ListLinePlot[Table[Sin[5x],{x,0,2Pi,0.1}],MaxPlotPoints->10]

ListLinePlot[Table[{x,Sin[5x]},{x,0,2Pi,0.1}],MaxPlotPoints->10]

Use (RefLink[PlotRange, paclet:ref/PlotRange]) to focus in on areas of interest:

{ListLinePlot[Table[x^4-x^2+1,{x,-2,2,0.1}]],ListLinePlot[Table[x^4-x^2+1,{x,-2,2,0.1}],PlotRange->{0,2}]}

Use (RefLink[ScalingFunctions, paclet:ref/ScalingFunctions]) to scale the axes:

ListLinePlot[Factorial[Range[20]],ScalingFunctions->"Log"]

OpenersExampleSubsection1(Spacer1)Special Data  (9)

Use (RefLink[Quantity, paclet:ref/Quantity]) to include units with the data:

ListLinePlot[Quantity[Sqrt[Range[10]],"Meters"],AxesLabel->Automatic]

Include different units for the x and y coordinates:

data=EntityValue[(EntityClass["elements", EntityClass["Element",All], "EntityClass[\"Element\", All]", "elements"]),{"AtomicMass","MeltingPoint"}];

ListLinePlot[data,AxesLabel->Automatic]

Plot data in a (RefLink[QuantityArray, paclet:ref/QuantityArray]):

data=QuantityArray[EntityValue[(EntityClass["elements", EntityClass["Element",All], "EntityClass[\"Element\", All]", "elements"]),{"AtomicMass","MeltingPoint"}]]

ListLinePlot[data,AxesLabel->Automatic]

Specify the units used with (RefLink[TargetUnits, paclet:ref/TargetUnits]):

ListLinePlot[data,TargetUnits->{Automatic,"Kelvin"},AxesLabel->Automatic]

Plot data with uncertainty:

ListLinePlot[Table[Around[RandomReal[5],RandomReal[0.5]],20]]

Use intervals:

ListLinePlot[Table[Interval[RandomReal[5]+{-0.5,0.5}],20]]

Use bands to represent uncertainty:

ListLinePlot[Table[Interval[RandomReal[5]+{-0.5,0.5}],20],IntervalMarkers->"Bands"]

Specify strings to use as labels:

ListLinePlot[{2->"a",3->"b",5->"c",7->"d",11->"e",13->"f",17->"g"}]

ListLinePlot[{2,3,5,7,11,13,17}->{"a","b","c","d","e","f","g"}]

Specify a location for labels:

ListLinePlot[{2,3,5,7,11,13,17}->{"a","b","c","d","e","f","g"},LabelingFunction->Below]

Numeric values in an (RefLink[Association, paclet:ref/Association]) are used as the y coordinates:

ListLinePlot[<|"a"->2,"b"->3,"c"->5,"d"->7,"e"->11,"f"->13|>]

Numeric keys and values in an (RefLink[Association, paclet:ref/Association]) are used as the x and y coordinates:

ListLinePlot[<|2->1,3->2,5->3,7->4,11->5,13->6|>]

Plot (RefLink[TimeSeries, paclet:ref/TimeSeries]) directly:

data=CountryData["UnitedStates",{{"Population"},{1988,2013}}]

ListLinePlot[data,AxesLabel->Automatic]

Plot data in a (RefLink[SparseArray, paclet:ref/SparseArray]):

ListLinePlot[SparseArray[Table[Prime[i]->1,{i,25}]]]

The weights in (RefLink[WeightedData, paclet:ref/WeightedData]) are ignored:

ListLinePlot[WeightedData[{2,3,5,7,11,13,17,19,23,29},{1,2,3,4,5,6,7,8,9,10}]]

OpenersExampleSubsection2(Spacer1)Wrappers  (7)

Use wrappers on data sources or collections of data sources:

{ListLinePlot[{Style[{1,2,3},Green],{4,5,6}}],ListLinePlot[Style[{{1,2,3},{4,5,6}},Blue]]}

Use the value of each point as a tooltip:

ListLinePlot[Tooltip[Prime[Range[20]]],Mesh->Full]

Use a specific tooltip for the curve:

ListLinePlot[Tooltip[Prime[Range[20]],"primes"]]

Use (RefLink[PopupWindow, paclet:ref/PopupWindow]) to provide additional drilldown information:

ListLinePlot[PopupWindow[{1,2,3},DateListPlot[FinancialData["IBM","Jan. 1, 2004"]]]]

(RefLink[Button, paclet:ref/Button]) can be used to trigger any action:

ListLinePlot[Button[{1,2,3},Speak["Hello"]]]

Use (RefLink[Annotation, paclet:ref/Annotation]) for dynamic action when the mouse enters the plot:

{ListLinePlot[Annotation[Prime[Range[20]],"label","Mouse"]],Dynamic[MouseAnnotation[]]}

Use (RefLink[Hyperlink, paclet:ref/Hyperlink]) to jump to the specified link when clicked:

ListLinePlot[Hyperlink[Prime[Range[20]], "http://www.wolfram.com"]]

Use (RefLink[StatusArea, paclet:ref/StatusArea]) to display a string in the status area of the current notebook:

ListLinePlot[StatusArea[Prime[Range[20]], "String"]]

OpenersExampleSubsection3(Spacer1)Labeling and Legending  (11)

Label data sources with (RefLink[Labeled, paclet:ref/Labeled]):

data=Table[Table[{x,f},{x,0,2Pi,0.1}],{f,{Sin[x],Sin[2x]}}];

ListLinePlot[MapThread[Labeled[#1,#2]&,{data,{Sin[x],Sin[2x]}}]]

Specify the labels with (RefLink[PlotLabels, paclet:ref/PlotLabels]):

data=Table[Table[{x,f},{x,0,2Pi,0.1}],{f,{Sin[x],Sin[2x]}}];

ListLinePlot[data,PlotLabels->{Sin[x],Sin[2x]}]

Place the label near the points at an x value:

ListLinePlot[Labeled[Table[{x,Sin[x]},{x,0,2Pi,0.1}],"sin(x)",3]]

Use a scaled position:

ListLinePlot[Labeled[Table[{x,Sin[x]},{x,0,2Pi,0.1}],"sin(x)",Scaled[0.25]]]

Specify the text position relative to the point:

ListLinePlot[Labeled[Table[{x,Sin[x]},{x,0,2Pi,0.1}],Sin[x],{Scaled[0.25],Above}]]

Label data automatically with (RefLink[Callout, paclet:ref/Callout]):

ListLinePlot[{Callout[Table[PartitionsQ[n],{n,18}],PartitionsQ[n]],Callout[Table[n,{n,18}],n]}]

Place a label with specific locations:

ListLinePlot[Callout[Table[n^Sin[n],{n,1,10,0.25}],"label",Above]]

ListLinePlot[Callout[Table[n^Sin[n],{n,1,10,0.25}],"label",25]]

Specify label names with (RefLink[LabelingFunction, paclet:ref/LabelingFunction]):

ListLinePlot[Prime[Range[10]],LabelingFunction->(#1 &)]

Specify the maximum size of labels:

data=Table[Labeled[Prime[i],RandomWord[]],{i,10}];

ListLinePlot[data,LabelingSize->30]

Use the full label:

ListLinePlot[data,LabelingSize->Full]

Include legends for each curve:

data=Table[Table[{x,f},{x,0,2Pi,0.1}],{f,{Sin[x],Sin[2x]}}];

ListLinePlot[data,PlotLegends->{Sin[x],Sin[2x]}]

Use (RefLink[Legended, paclet:ref/Legended]) to provide a legend for a specific dataset:

upper=RandomReal[{1.5,2},50];
lower=RandomReal[0.5,50];

ListLinePlot[{lower,Legended[Mean[{lower,upper}],"average"],upper}]

Use (RefLink[Placed, paclet:ref/Placed]) to change the legend location:

ListLinePlot[{lower,Legended[Mean[{lower,upper}],Placed["average",Below]],upper}]

Use association keys as labels:

ListLinePlot[<|"fibonacci"->Fibonacci[Range[10]],"primes"->Prime[Range[10]]|>,PlotLabels->Automatic,PlotLegends->None]

OpenersExampleSubsection4(Spacer1)Presentation  (12)

Multiple curves are automatically colored to be distinct:

data=Table[Table[{x,f},{x,0,2Pi,0.1}],{f,{Sin[x],Sin[2x]}}];

ListLinePlot[data]

Provide explicit styling to different curves:

data=Table[Table[{x,f},{x,0,2Pi,0.1}],{f,{Sin[x],Sin[2x]}}];

ListLinePlot[data,PlotStyle->{Dashed,Red}]

Use a theme with simple ticks in a bold color scheme:

ListLinePlot[{Prime[Range[20]],Range[20]},PlotTheme->"Marketing"]

Include legends for each curve:

data=Table[Table[{x,f},{x,0,2Pi,0.1}],{f,{Sin[x],Sin[2x]}}];

ListLinePlot[data,PlotLegends->{Sin[x],Sin[2x]}]

Use (RefLink[Legended, paclet:ref/Legended]) to provide a legend for a specific dataset:

upper=RandomReal[{1.5,2},50];
lower=RandomReal[0.5,50];

ListLinePlot[{lower,Legended[Mean[{lower,upper}],"average"],upper}]

Add labels:

ListLinePlot[Table[{k,Binomial[15,k]},{k,0,15}],AxesLabel->{k,None},PlotLabel->Binomial[15,k]]

Provide an interactive (RefLink[Tooltip, paclet:ref/Tooltip]) for the data:

ListLinePlot[Tooltip[Table[If[PrimeQ[x],Tooltip[x,Row[{"prime: ",x}]],x],{x,1,25}]],Mesh->All]

ListLinePlot[{Tooltip[{1,2,4,8,16,32,64},TraditionalForm[2^k]],Tooltip[{1,2,3,5,8,13,21},TraditionalForm[Fibonacci[k]]]},Mesh->Full]

Create filled plots:

ListLinePlot[{{1,2,4,8,16,32,64},{1,2,3,5,8,13,21}},Filling->{1->{2}}]

Create an overlay mesh:

ListLinePlot[{1,2,3,5,8,13,21},Mesh->10]

Use shapes to distinguish different datasets:

ListLinePlot[{Tooltip[{1,2,4,8,16,32,64},TraditionalForm[2^k]],Tooltip[{1,2,3,5,8,13,21},TraditionalForm[Fibonacci[k]]]},Mesh->Full,PlotMarkers->Automatic]

Style the curve segments between mesh points:

ListLinePlot[{1,2,3,5,8,13,21},Mesh->10,MeshShading->{Red,None,Blue}]

Plot the data in a stacked layout:

data={{10,9,4,3,5,3,5,5,2,6},{2,10,5,6,9,4,9,3,7,2},{7,8,3,4,4,2,6,3,8,7}};

ListLinePlot[data,PlotLayout->"Stacked",Joined->True]

Plot the data as percentiles of the total of the values:

ListLinePlot[data,PlotLayout->"Percentile",Joined->True]

OpenersExampleSection2(Spacer1)Options  (113)

OpenersExampleSubsection5(Spacer1)AspectRatio  (1)

Use the default aspect ratio:

ListLinePlot[Table[{2Cos[t],Sin[t]},{t,0,Pi,0.1}]]

Use the aspect ratio as derived from data:

ListLinePlot[Table[{2Cos[t],Sin[t]},{t,0,Pi,0.1}],AspectRatio->Automatic]

OpenersExampleSubsection6(Spacer1)AxesOrigin  (2)

The position of the axes is determined automatically:

ListLinePlot[Table[x!,{x,1,5}]]

Specify an explicit origin for the axes:

ListLinePlot[Table[x!,{x,1,5}],AxesOrigin->{1,-20}]

OpenersExampleSubsection7(Spacer1)ClippingStyle  (5)

Omit clipped regions of the plot:

ListLinePlot[Table[{x,Sin[x]/x^2},{x,-10,10,0.2}],ClippingStyle->None]//Quiet

Show the clipped regions like the rest of the curve:

ListLinePlot[Table[{x,Sin[x]/x^2},{x,-10,10,0.2}],ClippingStyle->Automatic,PlotStyle->Thick]//Quiet

Show clipped regions with red lines:

ListLinePlot[Table[{x,Sin[x]/x^2},{x,-10,10,0.2}],ClippingStyle->Red]//Quiet

Show clipped regions as red at the bottom and thick at the top:

ListLinePlot[Table[{x,Sin[x]/x^2},{x,-10,10,0.2}],ClippingStyle->{Red,Thick}]//Quiet

Show clipped regions as red and thick:

ListLinePlot[Table[{x,Sin[x]/x^2},{x,-10,10,0.2}],ClippingStyle->Directive[Red,Thick]]//Quiet

OpenersExampleSubsection8(Spacer1)ColorFunction  (5)

Color by scaled x and y coordinates:

Table[ListLinePlot[Sinc[Range[0,10,0.1]],ColorFunction->Function[{x,y},f],PlotLabel->f,PlotStyle->Thick],{f,{Hue[x],Hue[y]}}]

Color with a named color scheme:

ListLinePlot[Sinc[Range[0,10,0.1]],ColorFunction->"DarkRainbow"]

Fill with the color used for the curve:

ListLinePlot[Sinc[Range[0,10,0.1]],ColorFunction->Function[{x,y},Hue[x]],Filling->Axis]

ListLinePlot[Array[Prime,100],ColorFunction->Function[{x,y},Blend[{Yellow,Red},x]],Filling->Axis]

(RefLink[ColorFunction, paclet:ref/ColorFunction]) has higher priority than (RefLink[PlotStyle, paclet:ref/PlotStyle]) for coloring the curve:

ListLinePlot[Sinc[Range[0,10,0.1]],ColorFunction->"DarkRainbow",PlotStyle->Directive[Red,Thick]]

Use (RefLink[Automatic, paclet:ref/Automatic]) in (RefLink[MeshShading, paclet:ref/MeshShading]) to use the (RefLink[ColorFunction, paclet:ref/ColorFunction]):

ListLinePlot[Sin[Range[0,10,0.1]],ColorFunction->"Rainbow",PlotStyle->Directive[Red,Thick],Mesh->10,MeshShading->{Automatic,Black},MeshStyle->None]

OpenersExampleSubsection9(Spacer1)ColorFunctionScaling  (2)

Color the line based on scaled y value:

ListLinePlot[Table[x^2Exp[-x^2],{x,-5,5,0.1}],ColorFunction->Function[{x,y},Hue[y]],PlotStyle->Thick,ColorFunctionScaling->True]

Color the line based on unscaled y value:

ListLinePlot[Table[x^2Exp[-x^2],{x,-5,5,0.1}],ColorFunction->Function[{x,y},Hue[y]],PlotStyle->Thick,ColorFunctionScaling->False]

OpenersExampleSubsection10(Spacer1)DataRange  (5)

Lists of height values are displayed against the number of elements:

ListLinePlot[Table[Sin[x],{x,0,2Pi,0.1}]]

Rescale to the sampling space:

ListLinePlot[Table[Sin[x],{x,0,2Pi,0.1}],DataRange->{0,2Pi}]

Each dataset is scaled to the same domain:

ListLinePlot[{{1,2,3},{4,5,6,7},{8,9,10,11,12}},DataRange->{0,1}]

Pairs are interpreted as x, y coordinates:

ListLinePlot[{{1,1},{2,2},{3,2}}]

Specifying (RefLink[DataRange, paclet:ref/DataRange]) in this case has no effect, since x values are part of the data:

ListLinePlot[{{1,1},{2,2},{3,2}},DataRange->{0,1}]

Force interpretation as multiple datasets:

ListLinePlot[{{1,1},{2,2},{3,2}},DataRange->All,AxesOrigin->{0,0}]

OpenersExampleSubsection11(Spacer1)Filling  (8)

Use symbolic or explicit values:

Table[ListLinePlot[Table[Prime[n],{n,30}],Filling->c],{c,{Top,Bottom,Axis,Prime[15]}}]

Fills that overlap by default combine using opacity:

ListLinePlot[{Table[Sin[n/3],{n,20}],Table[Cos[n/3],{n,20}]},Filling->Axis]

Fill between the first curve and the axis:

ListLinePlot[{Table[Sin[n/3],{n,20}],Table[Cos[n/3],{n,20}]},Filling->{1->Axis}]

Fill between two lines:

ListLinePlot[{Table[Sin[n/3],{n,20}],Table[Cos[n/3],{n,20}]},Filling->{1->{2}}]

Fill between curves 1 and 2 with a specific style:

ListLinePlot[{Table[Sin[n/3],{n,20}],Table[Cos[n/3],{n,20}]},Filling->{1->{{2},LightOrange}}]

Fill between curves 1 and y=(1/2) with light orange:

ListLinePlot[{Table[Sin[n/3],{n,20}],Table[Cos[n/3],{n,20}]},Filling->{1->{1/2,LightOrange}}]

Fill between curves 1 and 2; use yellow when 1 is below 2, and green when 1 is above 2:

ListLinePlot[{Table[Sin[n/3],{n,20}],Table[Cos[n/3],{n,20}]},Filling->{1->{{2},{Yellow,Green}}}]

Filling between curves applies where the curves overlap:

ListLinePlot[{Table[{i,i^2+1},{i,0,5}],Table[{i,i^2-20},{i,2,7}]}, Filling->{1->{2}}]

OpenersExampleSubsection12(Spacer1)FillingStyle  (4)

Use different fill colors:

Table[ListLinePlot[Table[{x,Sin[x]},{x,0,2Pi,0.1}],Filling->Axis,FillingStyle->c],{c,{Red,Green,Blue,Yellow}}]

Fill with opacity 0.5 orange:

ListLinePlot[{Table[{x,Sin[x]},{x,0,2Pi,0.1}],Table[{x,Cos[x]},{x,0,2Pi,0.1}]},Filling->Axis,FillingStyle->Directive[Opacity[0.5],Orange]]

Fill with red below the axis, and with blue above:

ListLinePlot[Table[{x,Sin[x]},{x,0,2Pi,0.1}],Filling->Axis,FillingStyle->{Red,Blue}]

Use a variable filling style obtained from (RefLink[ColorFunction, paclet:ref/ColorFunction]):

ListLinePlot[Table[{x,Sin[x]},{x,0,2Pi,0.1}],ColorFunction->Function[{x,y},Hue[y]],Filling->Axis,FillingStyle->Automatic]

OpenersExampleSubsection13(Spacer1)InterpolationOrder  (3)

Points are normally joined with straight lines:

ListLinePlot[{{1,4,2,3,10,8,2}},Mesh->Full]

Use quadratic spline interpolation to fit the data:

ListLinePlot[{{1,4,2,3,10,8,2}},InterpolationOrder->2,Mesh->Full]

Use flat regions with steps at each data point:

ListLinePlot[{{1,4,2,3,10,8,2}},InterpolationOrder->0,Mesh->Full]

OpenersExampleSubsection14(Spacer1)IntervalMarkers  (3)

By default, uncertainties are capped:

ListLinePlot[Table[Around[RandomReal[],0.1],10]]

Use bars to denote uncertainties without caps:

ListLinePlot[Table[Around[RandomReal[],0.1],10],IntervalMarkers->"Bars"]

Use bands to represent uncertainties:

ListLinePlot[Table[Around[RandomReal[],.1],10],IntervalMarkers->"Bands"]

OpenersExampleSubsection15(Spacer1)IntervalMarkersStyle  (2)

Uncertainties automatically inherit the plot style:

ListLinePlot[{Table[Around[RandomReal[20],1],10],Table[Around[RandomReal[20],1],10]},PlotStyle->{Red,Blue}]

Specify the style for uncertainties:

ListLinePlot[{Table[Around[RandomReal[20],1],10],Table[Around[RandomReal[20],1],10]},IntervalMarkersStyle->Gray]

OpenersExampleSubsection16(Spacer1)LabelingFunction  (6)

By default, points are automatically labeled with strings:

ListLinePlot[{1,1,2,3,5,8}->{"a","b","c","d","e","f"}]

Use (RefLink[LabelingFunction, paclet:ref/LabelingFunction])->(RefLink[None, paclet:ref/None]) to suppress the labels:

ListLinePlot[{1,1,2,3,5,8}->{"a","b","c","d","e","f"},LabelingFunction->None]

Put the labels above the points:

ListLinePlot[{1,1,2,3,5,8}->{"a","b","c","d","e","f"},LabelingFunction->Above]

Use callouts to label the points:

ListLinePlot[{1,1,2,3,5,8}->{"a","b","c","d","e","f"},LabelingFunction->Callout[Automatic,Automatic]]

Label the points with their values:

ListLinePlot[{1,1,2,3,5,8}->{"a","b","c","d","e","f"},LabelingFunction->(#1&)]

Label the points with their indices:

ListLinePlot[{1,1,2,3,5,8}->{"a","b","c","d","e","f"},LabelingFunction->(#2&)]

OpenersExampleSubsection17(Spacer1)LabelingSize  (4)

Textual labels are shown at their actual sizes:

ListLinePlot[{1,1,2,3,5,8}->{"healthfulness","obstreperous","spectrogram","vestige","coinage","limey"},ImageSize->Medium]

Image labels are automatically resized:

ListLinePlot[{1,1,2,3,5,8}->{,,,,,},ImageSize->Medium]

Specify a maximum size for textual labels:

ListLinePlot[{1,1,2,3,5,8}->{"healthfulness","obstreperous","spectrogram","vestige","coinage","limey"},ImageSize->Medium,LabelingSize->30]

Specify a maximum size for image labels:

ListLinePlot[{1,1,2,3,5,8}->{,,,,,},ImageSize->Medium,LabelingSize->20]

Show image labels at their natural sizes:

ListLinePlot[{1,1,2,3,5,8}->{,,,,,},ImageSize->Medium,LabelingSize->Full]

OpenersExampleSubsection18(Spacer1)MaxPlotPoints  (4)

All points are included by default:

ListLinePlot[Table[Sin[10x],{x,0,2Pi,0.1}]]

Uniformly spaced data is downsampled:

Table[ListLinePlot[Table[Sin[2Pi n/10],{n,100}],MaxPlotPoints->mp],{mp,{Infinity,50,30}}]

In this case, downsampling from (10^6) to (10^3) points:

ListLinePlot[Sin[Range[(10^6)]2.Pi/(10^5)]+RandomReal[0.3,(10^6)],MaxPlotPoints->(10^3)]

Nonuniform data topologically subsampled, to preserve features:

Table[ListLinePlot[Table[{n,Sin[2Pi n/10]},{n,100}],MaxPlotPoints->mp],{mp,{Infinity,50,30}}]

Table[ListLinePlot[Table[{Sqrt[n]Cos[n/5],Sqrt[n]Sin[n/5]},{n,100}],MaxPlotPoints->mp],{mp,{Infinity,50,30}}]

Points on either side of nonreal data are always included:

ListLinePlot[{1,2,3,None,5,6,7,8,None,10,11,12},MaxPlotPoints->3,Mesh->All]

OpenersExampleSubsection19(Spacer1)Mesh  (5)

The initial and final sampling meshes are typically the same:

{ListLinePlot[Table[Sin[x],{x,8}],Mesh->Full],ListLinePlot[Table[Sin[x],{x,8}],Mesh->All]}

Interpolated data may introduce points:

{ListLinePlot[Table[Sin[x],{x,8}],Mesh->Full,InterpolationOrder->2],ListLinePlot[Table[Sin[x],{x,8}],Mesh->All,InterpolationOrder->2]}

Use 20 mesh levels evenly spaced in the x direction:

ListLinePlot[Table[Sin[x],{x,0,2Pi,0.1}],Mesh->20]

Use an explicit list of values for the mesh in the x direction:

ListLinePlot[Table[{x,Sin[x]},{x,0,2Pi,0.1}],Mesh->{Range[0,2Pi,Pi/4]},MeshStyle->PointSize[Medium]]

Specify style and mesh levels in the x direction:

ListLinePlot[Table[{x,Sin[x]},{x,0,2Pi,2Pi/20}],Mesh->{Table[{x,Hue[x/(2Pi)]},{x,0.,2Pi,2Pi/8}]}]

OpenersExampleSubsection20(Spacer1)MeshFunctions  (2)

Use a mesh evenly spaced in the x and y directions:

Table[ListLinePlot[Table[Binomial[15,k],{k,0,15}],MeshFunctions->{Function[{x,y},Evaluate[f]]},Mesh->9,PlotLabel->f],{f,{x,y}}]

Show 5 mesh levels in the x direction (red) and 10 in the y direction (blue):

ListLinePlot[Table[Binomial[15,k],{k,0,15}],Mesh->{5,10},MeshFunctions->{#1&,#2&},MeshStyle->{Directive[PointSize[Medium],Red],Blue}]

OpenersExampleSubsection21(Spacer1)MeshShading  (6)

Alternate red and blue segments of equal width in the x direction:

ListLinePlot[Table[Binomial[15,k],{k,0,15}],Mesh->10,MeshFunctions->{#1&},MeshShading->{Red,Blue}]

Use (RefLink[None, paclet:ref/None]) to remove segments:

ListLinePlot[Table[Binomial[15,k],{k,0,15}],Mesh->10,MeshFunctions->{#1&},MeshShading->{Red,None}]

(RefLink[MeshShading, paclet:ref/MeshShading]) can be used with (RefLink[PlotStyle, paclet:ref/PlotStyle]):

ListLinePlot[Table[Binomial[15,k],{k,0,15}],Mesh->10,PlotStyle->Thick,MeshFunctions->{#1&},MeshShading->{Red,Blue}]

(RefLink[MeshShading, paclet:ref/MeshShading]) has higher priority than (RefLink[PlotStyle, paclet:ref/PlotStyle]) for styling the curve:

ListLinePlot[Table[Binomial[15,k],{k,0,15}],Mesh->10,PlotStyle->Black,MeshFunctions->{#1&},MeshShading->{Red,Blue}]

Use (RefLink[PlotStyle, paclet:ref/PlotStyle]) for some segments by setting (RefLink[MeshShading, paclet:ref/MeshShading]) to (RefLink[Automatic, paclet:ref/Automatic]):

ListLinePlot[Table[Binomial[15,k],{k,0,15}],Mesh->10,PlotStyle->Directive[Thick,Yellow],MeshFunctions->{#1&},MeshShading->{Red,Automatic}]

(RefLink[MeshShading, paclet:ref/MeshShading]) can be used with (RefLink[ColorFunction, paclet:ref/ColorFunction]):

ListLinePlot[Table[Binomial[15,k],{k,0,15}],Mesh->10,PlotStyle->Thick,MeshFunctions->{#1&},MeshShading->{Black,Automatic},
ColorFunction->Function[{x,y},Hue[x]]]

OpenersExampleSubsection22(Spacer1)MeshStyle  (4)

Color the mesh the same color as the plot:

ListLinePlot[Table[Binomial[15,k],{k,0,15}],Mesh->10,MeshStyle->Automatic]

Use a red mesh in the x direction:

ListLinePlot[Table[Binomial[15,k],{k,0,15}],Mesh->10,MeshStyle->Red]

Use a red mesh in the x direction and a blue mesh in the y direction:

ListLinePlot[Table[Binomial[15,k],{k,0,15}],Mesh->10,MeshStyle->{Red,Blue},MeshFunctions->{#1&,#2&}]

Use big red mesh points in the x direction:

ListLinePlot[Table[Binomial[15,k],{k,0,15}],Mesh->10,MeshStyle->Directive[PointSize[Large],Red]]

OpenersExampleSubsection23(Spacer1)PlotLabel  (1)

Add an overall label to the plot:

ListLinePlot[Prime[Range[100]],PlotLabel->"prime numbers"]

OpenersExampleSubsection24(Spacer1)PlotLabels  (5)

Specify text to label sets of points:

ListLinePlot[{Sin[Range[0,2Pi,0.1]],Cos[Range[0,2Pi,0.1]]},PlotLabels->{"sine","cosine"}]

Place the labels above the points:

ListLinePlot[{Sin[Range[0,2Pi,0.1]],Cos[Range[0,2Pi,0.1]]},PlotLabels->Placed[{"sine","cosine"},Above]]

Use callouts to identify the points:

ListLinePlot[{Sin[Range[0,2Pi,0.1]],Cos[Range[0,2Pi,0.1]]},PlotLabels->{Callout["sin",{Scaled[0.25],Above}],Callout["cos",{Scaled[0.5],Below}]}]

Label curves with the keys from an association:

ListLinePlot[<|"sine"->Sin[Range[0,2Pi,0.1]],"cosine"->Cos[Range[0,2Pi,0.1]]|>,PlotLabels->Automatic,PlotLegends->None]

Use (RefLink[None, paclet:ref/None]) to not label a data source:

ListLinePlot[{Sin[Range[0,2Pi,0.1]],Cos[Range[0,2Pi,0.1]]},PlotLabels->{"sine",None}]

OpenersExampleSubsection25(Spacer1)PlotLayout  (1)

By default, curves are overlaid on each other:

data={{10,9,4,3,5,3,5,5,2,6},{2,10,5,6,9,4,9,3,7,2},{7,8,3,4,4,2,6,3,8,7}};

ListLinePlot[data]

Plot the data in a stacked layout:

ListLinePlot[data,PlotLayout->"Stacked"]

Plot the data as percentiles of the total of the values:

ListLinePlot[data,PlotLayout->"Percentile"]

Place each curve in a separate panel using shared axes:

ListLinePlot[data,PlotLayout->"Column",ImageSize->Medium]

Use rows instead of columns:

ListLinePlot[data,PlotLayout->"Row",ImageSize->Medium]

OpenersExampleSubsection26(Spacer1)PlotLegends  (5)

Generate a legend using labels:

ListLinePlot[{Sqrt[Range[40]],Log[Range[40]]},PlotLegends->{"sqrt","log"}]

Generate a legend using placeholders:

ListLinePlot[{Sqrt[Range[40]],Log[Range[40]]},PlotLegends->Automatic]

Legends use the same styles as the plot:

ListLinePlot[{Sqrt[Range[40]],Log[Range[40]]},PlotStyle->{Red,Blue},PlotLegends->{"sqrt","log"}]

Use (RefLink[Placed, paclet:ref/Placed]) to specify legend placement:

Table[ListLinePlot[{Sqrt[Range[40]],Log[Range[40]]},PlotLabel->pos,PlotLegends->Placed[{"sqrt","log"},pos]],{pos,{Above,Below,Before,After}}]

Place the legend inside the plot:

ListLinePlot[{Sqrt[Range[40]],Log[Range[40]]},PlotStyle->{Red,Blue},PlotLegends->Placed[{"sqrt","log"},{0.85,0.3}]]

Use (RefLink[LineLegend, paclet:ref/LineLegend]) to change the legend appearance:

ListLinePlot[{Sqrt[Range[40]],Log[Range[40]]},PlotStyle->{Red,Blue},PlotLegends->LineLegend[{"sqrt","log"},LegendMarkerSize->10,LegendFunction->Frame]]

OpenersExampleSubsection27(Spacer1)PlotMarkers  (8)

(RefLink[ListLinePlot, paclet:ref/ListLinePlot]) normally uses distinct colors to distinguish different sets of data:

ListLinePlot[Table[n^(1/p),{p,4},{n,10}],PlotMarkers->None]

Automatically use colors and shapes to distinguish sets of data:

ListLinePlot[Table[n^(1/p),{p,4},{n,10}],PlotMarkers->Automatic]

Use shapes only:

ListLinePlot[Table[n^(1/p),{p,4},{n,10}],PlotMarkers->Automatic,PlotStyle->Black]

Change the size of the default plot markers:

Table[ListLinePlot[Table[n^(1/p),{p,4},{n,5}],PlotMarkers->{Automatic,s}],{s,{Small,Medium}}]

Use arbitrary text for plot markers:

ListLinePlot[Table[n^(1/p),{p,4},{n,10}],PlotMarkers->{"1","2","3","4"}]

Use explicit graphics for plot markers:

{m1,m2,m3,m4}=Graphics/@{Circle[{0,0},1],Disk[{0,0},1],Line[{{-0.5,-0.5},{0.5,-0.5},{0.5,0.5},{-0.5,0.5},{-0.5,-0.5}}],Polygon[{{-0.5,-0.5},{0.5,-0.5},{0.5,0.5},{-0.5,0.5}}]}

ListLinePlot[Table[n^(1/p),{p,4},{n,10}],PlotMarkers->Table[{s,0.05},{s,{m1,m2,m3,m4}}]]

Use the same symbol for all the sets of data:

ListLinePlot[Table[n^(1/p),{p,4},{n,10}],PlotMarkers->"●"]

Explicitly use a symbol and size:

Table[ListLinePlot[Table[n^(1/p),{p,4},{n,10}],PlotMarkers->{"●",s}],{s,{4,8,12}}]

OpenersExampleSubsection28(Spacer1)PlotRange  (2)

(RefLink[PlotRange, paclet:ref/PlotRange]) is automatically calculated:

ListLinePlot[{1,2,3,45,6,7,8}]

Show the whole dataset:

ListLinePlot[{1,2,3,45,6,7,8},PlotRange->All]

OpenersExampleSubsection29(Spacer1)PlotStyle  (6)

Use different style directives:

Table[ListLinePlot[Table[Binomial[10,k],{k,0,10}],PlotStyle->ps],{ps,{Red,Thick,Dashed,Directive[Red,Thick]}}]

By default, different styles are chosen for multiple curves:

ListLinePlot[Table[Table[Sin[k x],{x,0,2Pi,0.1}],{k,{1,2,3}}]]

Explicitly specify the style for different curves:

ListLinePlot[Table[Table[Sin[k x],{x,0,2Pi,0.1}],{k,{1,2,3}}],PlotStyle->{Red,Green,Blue}]

(RefLink[PlotStyle, paclet:ref/PlotStyle]) can be combined with (RefLink[ColorFunction, paclet:ref/ColorFunction]):

ListLinePlot[Table[Sin[x],{x,0,2Pi,0.1}],PlotStyle->Thick,ColorFunction->Function[{x,y},Hue[y]]]

(RefLink[PlotStyle, paclet:ref/PlotStyle]) can be combined with (RefLink[MeshShading, paclet:ref/MeshShading]):

ListLinePlot[Table[Sin[x],{x,0,2Pi,0.1}],PlotStyle->Directive[Opacity[0.5],Thick],Mesh->10,MeshFunctions->{#1&},MeshShading->{Red,Blue}]

(RefLink[MeshStyle, paclet:ref/MeshStyle]) by default uses the same style as (RefLink[PlotStyle, paclet:ref/PlotStyle]):

ListLinePlot[Table[Sin[x],{x,0,2Pi,0.1}],PlotStyle->Red,Mesh->All]

OpenersExampleSubsection30(Spacer1)PlotTheme  (3)

Use a theme with simple styling and plot markers in a bright color scheme:

ListLinePlot[{Prime[Range[10]],Fibonacci[Range[10]],Range[10]},PlotTheme->"Business"]

Change the color scheme:

ListLinePlot[{Prime[Range[10]],Fibonacci[Range[10]],Range[10]},PlotTheme->"Business",PlotStyle->96]

Use a theme with minimal styling:

ListLinePlot[{Prime[Range[10]],Fibonacci[Range[10]],Range[10]},PlotTheme->"Minimal"]

OpenersExampleSubsection31(Spacer1)ScalingFunctions  (9)

By default, plots have linear scales in each direction:

ListLinePlot[{1,5,10,35,60,75,140}]

Use a log scale in the y direction:

ListLinePlot[{1,5,10,35,60,75,140},ScalingFunctions->"Log"]

Use a linear scale in the y direction that shows smaller numbers at the top:

ListLinePlot[{1,5,10,35,60,75,140},ScalingFunctions->"Reverse"]

Use a reciprocal scale in the y direction:

ListLinePlot[{1,5,10,35,60,75,140},ScalingFunctions->"Reciprocal"]

Use different scales in the x and y directions:

ListLinePlot[{1,5,10,35,60,75,140},ScalingFunctions->{"Reverse","Log"}]

Reverse the x axis without changing the y axis:

ListLinePlot[{1,5,10,35,60,75,140},ScalingFunctions->{"Reverse",None}]

Use a scale defined by a function and its inverse:

ListLinePlot[{1,5,10,35,60,75,140},ScalingFunctions->{None,{-Log[#]&,Exp[-#]&}}]

Positions in (RefLink[Ticks, paclet:ref/Ticks]) and (RefLink[GridLines, paclet:ref/GridLines]) are automatically scaled:

ListLinePlot[{1,5,10,35,60,75,140},ScalingFunctions->"Log",Ticks->{Automatic,2^Range[10]},GridLines->{None,2^Range[10]}]

(RefLink[PlotRange, paclet:ref/PlotRange]) and (RefLink[AxesOrigin, paclet:ref/AxesOrigin]) are automatically scaled:

ListLinePlot[{1,5,10,35,60,75,140},ScalingFunctions->"Log",PlotRange->{1,100},AxesOrigin->{Automatic,10}]

OpenersExampleSubsection32(Spacer1)TargetUnits  (2)

Automatically detect units:

ListLinePlot[Quantity[Range[10],"Hours"],AxesLabel->Automatic]

Specify alternate units:

ListLinePlot[Quantity[Range[10],"Hours"],TargetUnits->"Minutes",AxesLabel->Automatic]

OpenersExampleSection3(Spacer1)Applications  (9)

Compare the n(^th) prime to an estimate:

ListLinePlot[{Table[Prime[n],{n,80}],Table[n Log[n],{n,80}]}]

Show a random walk in one dimension:

ListLinePlot[Accumulate[RandomReal[{-1,1},250]]]

Show a random walk in two dimensions:

ListLinePlot[Accumulate[RandomReal[{-1,1},{250,2}]]]

Random walk on a lattice:

ListLinePlot[Accumulate[RandomChoice[{{1,0},{-1,0},{0,1},{0,-1}},250]],AspectRatio->Automatic]

Compute and plot the shortest tour through 100 random points:

pts=RandomReal[10,{100,2}];

ListLinePlot[pts[[Last@FindShortestTour[pts]]],Mesh->All]

Create a stacked line chart:

data={{2,3,3,4,8,8,8,8,9,10},{1,1,4,5,5,6,7,9,9,10},{1,2,4,5,7,7,8,9,9,10}};

ListLinePlot[Accumulate[data],Filling->{1->Axis,2->{1},3->{2}},PlotStyle->{Red,Orange,Blue}]

Show the numbers of graphs with different numbers of nodes available in (RefLink[GraphData, paclet:ref/GraphData]):

ListLinePlot[Table[Length[GraphData[n]],{n,50}]]

Show the density at standard temperature and pressure for the elements:

ListLinePlot[Table[ElementData[z,"Density"],{z,118}]]

Distribution of Wolfram Language symbols by length:

n=StringLength/@Names["System`*"];

ListLinePlot[Sort[Tally[n]]]

Plot the sample behavior for different Wolfram Language functions:

Table[ListLinePlot[Sort@Reap[f[Sinc[x],{x,0,15},EvaluationMonitor:>Sow[{x,Sinc[x]}]]][[2,1]],Filling->Axis,Mesh->All,PlotLabel->f,PlotRange->All],{f,{NIntegrate,Plot,NSum}}]

Plot the sample order in the x, y space used by (RefLink[Plot3D, paclet:ref/Plot3D]):

Reap[Plot3D[Sin[x y],{x,0,2},{y,0,2},EvaluationMonitor:>Sow[{x,y}]],_,ListLinePlot[#2,AspectRatio->Automatic]&]

OpenersExampleSection4(Spacer1)Properties & Relations  (12)

By default, pairs are interpreted as (x,y) values:

ListLinePlot[{{1,2},{3,6},{7,5}}]

Interpret the data as multiple data sources:

ListLinePlot[{{1,2},{3,6},{7,5}},DataRange->All]

(RefLink[ListLinePlot, paclet:ref/ListLinePlot]) is a special case of (RefLink[ListPlot, paclet:ref/ListPlot]):

{ListLinePlot[Table[Binomial[9,k],{k,0,9}]],
ListPlot[Table[Binomial[9,k],{k,0,9}],Joined->True]}

Use (RefLink[Plot, paclet:ref/Plot]) to visualize functions:

{Plot[Sin[x^2],{x,0,5}],ListLinePlot[Table[{x,Sin[x^2]},{x,0,5,0.1}]]}

Use (RefLink[ListLogPlot, paclet:ref/ListLogPlot]), (RefLink[ListLogLogPlot, paclet:ref/ListLogLogPlot]), and (RefLink[ListLogLinearPlot, paclet:ref/ListLogLinearPlot]) for logarithmic data plots:

ListLogPlot[Table[Binomial[25,k],{k,0,25}],Joined->True]

Use (RefLink[ListPolarPlot, paclet:ref/ListPolarPlot]) for polar plots:

ListPolarPlot[Table[{x,Sqrt[x]},{x,0,2Pi,0.1}],Joined->True]

Use (RefLink[DateListPlot, paclet:ref/DateListPlot]) to show data over time:

DateListPlot[{34,51,11,5,39,47,28,42, 66, 13,24, 31},{2006,1},Joined->True]

Use (RefLink[ListPointPlot3D, paclet:ref/ListPointPlot3D]) to show three-dimensional data plots:

ListPointPlot3D[Table[Sin[j^2+i],{i,0,Pi,0.1},{j,0,Pi,0.1}]]

Use (RefLink[ListPlot3D, paclet:ref/ListPlot3D]) to create surfaces from data:

ListPlot3D[Table[Sin[j^2+i],{i,0,Pi,0.1},{j,0,Pi,0.1}]]

Use (RefLink[ListContourPlot, paclet:ref/ListContourPlot]) to create contours from continuous data:

ListContourPlot[Table[Sin[j^2+i],{i,0,Pi,0.1},{j,0,Pi,0.1}]]

Use (RefLink[ListDensityPlot, paclet:ref/ListDensityPlot]) to create densities from continuous data:

ListDensityPlot[Table[Sin[j^2+i],{i,0,Pi,0.1},{j,0,Pi,0.1}]]

Use (RefLink[ArrayPlot, paclet:ref/ArrayPlot]) and (RefLink[MatrixPlot, paclet:ref/MatrixPlot]) for arrays of discrete values:

ArrayPlot[Table[GCD[i,j],{i,1,20},{j,1,20}]]

Use (RefLink[ParametricPlot, paclet:ref/ParametricPlot]) for parametric curves:

{ParametricPlot[{Cos[θ],Sin[θ]},{θ,0,2Pi}],ListLinePlot[Table[{Cos[θ],Sin[θ]},{θ,0,2Pi,0.1}],AspectRatio->1]}

OpenersExampleSection5(Spacer1)Possible Issues  (2)

Limiting the number of points may introduce artifacts:

ListLinePlot[Table[Sin[10x],{x,0,2Pi,0.1}],MaxPlotPoints->30]

Use more points to have fewer artifacts:

ListLinePlot[Table[Sin[10x],{x,0,2Pi,0.1}],MaxPlotPoints->50]

Unordered data may display in unexpected ways:

data=Table[{x,Sin[x]},{x,RandomReal[{0,2Pi},100]}];

ListLinePlot[data]

Sort the data to interpret as a function:

ListLinePlot[Sort[data]]

({{DocumentationFooterIconsRelatedFunction.png, ({{See Also}, {(RefLink[ListPlot, paclet:ref/ListPlot])  ▪  (RefLink[StackedListPlot, paclet:ref/StackedListPlot])  ▪  (RefLink[ListStepPlot, paclet:ref/ListStepPlot])  ▪  (RefLink[DiscretePlot, paclet:ref/DiscretePlot])  ▪  (RefLink[Plot, paclet:ref/Plot])  ▪  (RefLink[ListPlot3D, paclet:ref/ListPlot3D])  ▪  (RefLink[Graphics, paclet:ref/Graphics])  ▪  (RefLink[Fit, paclet:ref/Fit])}})}})

({{DocumentationFooterIconsRelatedGuide.png, ({{Related Guides}, {▪(RefLinkPlain[Data Visualization, paclet:guide/DataVisualization])}, {▪(RefLinkPlain[Signal Processing, paclet:guide/SignalProcessing])}, {▪(RefLinkPlain[Scientific Data Analysis, paclet:guide/ScientificDataAnalysis])}, {▪(RefLinkPlain[Charting and Information Visualization, paclet:guide/ChartingAndInformationVisualization])}, {▪(RefLinkPlain[Function Visualization, paclet:guide/FunctionVisualization])}, {▪(RefLinkPlain[Numbers with Uncertainty, paclet:guide/NumbersWithUncertainty])}, {▪(RefLinkPlain[System Model Analytics & Design, paclet:guide/SystemModelAnalyticsDesign])}})}})

({{(Spacer1), ({{(Spacer1)Related Links}, {(WebLink[DocumentationFooterIconsRelatedLinks-EIWL.png(Spacer1)An Elementary Introduction to the Wolfram Language, https://www.wolfram.com/language/elementary-introduction/04-displaying-lists.html])(WebLink[: Displaying Lists, https://www.wolfram.com/language/elementary-introduction/04-displaying-lists.html])}, {(WebLink[DocumentationFooterIconsRelatedLinks-EIWL.png(Spacer1)An Elementary Introduction to the Wolfram Language, https://www.wolfram.com/language/elementary-introduction/11-strings-and-text.html])(WebLink[: Strings and Text, https://www.wolfram.com/language/elementary-introduction/11-strings-and-text.html])}, {(WebLink[DocumentationFooterIconsRelatedLinks-EIWL.png(Spacer1)An Elementary Introduction to the Wolfram Language, https://www.wolfram.com/language/elementary-introduction/14-coordinates-and-graphics.html])(WebLink[: Coordinates and Graphics, https://www.wolfram.com/language/elementary-introduction/14-coordinates-and-graphics.html])}})}})