({{, (RefLink[GroupStabilizer, paclet:ref/GroupStabilizer])[group,{(Subscript[p, 1]),…,(Subscript[p, n])}] 
returns the subgroup of elements of group that move none of the points (Subscript[p, 1]), …, (Subscript[p, n]).}, {, (RefLink[GroupStabilizer, paclet:ref/GroupStabilizer])[group,{(Subscript[p, 1]),…,(Subscript[p, n])},f]
returns the stabilizer subgroup under the action given by the function f.}})

OpenersNotesSection(Spacer1)Details

The output is a subgroup of group defined by generators, but possibly using different generators.

The stabilizer group is also known as the little group or isotropy group.

The stabilizer of a list of points is a subgroup of the setwise stabilizer of the same list of points.

Evaluation of f[p,g] for an action function f, a point p and a permutation g of the given group, is assumed to return another point p'.

For permutation groups, the default group action is taken to be (RefLink[PermutationReplace, paclet:ref/PermutationReplace]).

OpenersPrimaryExamplesSection(Spacer1)Examples  (9)

OpenersExampleSection0(Spacer1)Basic Examples  (1)

A stabilizer subgroup of an alternating group:

GroupStabilizer[AlternatingGroup[6],{1,5}]

None of the permutations move any of the points {1,5}:

GroupElements[%]

OpenersExampleSection1(Spacer1)Scope  (4)

Compute the stabilizer of a permutation group defined by generators:

GroupStabilizer[PermutationGroup[{Cycles[{{2,5,9},{3,7,6}}],Cycles[{{2,9}}],Cycles[{{3,10}}]}],{2}]

Compute the stabilizer of a named permutation group:

GroupStabilizer[AlternatingGroup[10],{10}]

%==AlternatingGroup[9]

The stabilizer of a group can be trivial:

GroupStabilizer[PermutationGroup[{Cycles[{{1,2,3},{4,5,6}}]}],{1}]

Subgroup of permutations that leave invariant a list of objects under (RefLink[Permute, paclet:ref/Permute]) action:

subgroup=GroupStabilizer[SymmetricGroup[5],{{a,a,b,a,b}},Permute]

Check that the corresponding orbit under (RefLink[Permute, paclet:ref/Permute]) action contains only that list:

GroupOrbits[subgroup,{{a,a,b,a,b}},Permute]

OpenersExampleSection2(Spacer1)Applications  (1)

The symmetric group (Subscript[S, n]) is n-transitive and the alternating group (Subscript[A, n]) is (n-2)-transitive. It is known that any other group can be at most 5-transitive. The Mathieu group (Subscript[M, 24]) is 5-transitive:

group=MathieuGroupM24[];

{GroupOrder[group],domain=PermutationSupport[group]}

There is just one orbit, and hence it is transitive:

GroupOrbits[group,domain]

The stabilizer of 1 acts transitively on the remaining 23 points, and hence (Subscript[M, 24]) is 2-transitive:

GroupOrbits[GroupStabilizer[group,{1}],domain]

It is also 3-transitive, 4-transitive, and 5-transitive:

GroupOrbits[GroupStabilizer[group,{1,2}],domain]

GroupOrbits[GroupStabilizer[group,{1,2,3}],domain]

GroupOrbits[GroupStabilizer[group,{1,2,3,4}],domain]

But it is not 6-transitive, because there are two nontrivial orbits now:

GroupOrbits[GroupStabilizer[group,{1,2,3,4,5}],domain]

OpenersExampleSection3(Spacer1)Properties & Relations  (3)

The orbit-stabilizer theorem states that the size of the orbit of a point p under a group equals the number of cosets of the stabilizer of p in group.

Take the 3×3×3 Rubik group and compute the stabilizer of point 20:

rot1=Cycles[{{1,3,8,6},{2,5,7,4},{9,48,15,12},{10,47,16,13},{11,46,17,14}}];
rot2=Cycles[{{6,15,35,26},{7,22,34,19},{8,30,33,11},{12,14,29,27},{13,21,28,20}}];
rot3=Cycles[{{1,12,33,41},{4,20,36,44},{6,27,38,46},{9,11,26,24},{10,19,25,18}}];
rot4=Cycles[{{1,24,40,17},{2,18,39,23},{3,9,38,32},{41,43,48,46},{42,45,47,44}}];
rot5=Cycles[{{3,43,35,14},{5,45,37,21},{8,48,40,29},{15,17,32,30},{16,23,31,22}}];
rot6=Cycles[{{24,27,30,43},{25,28,31,42},{26,29,32,41},{33,35,40,38},{34,37,39,36}}];
GroupOrder[Rubikgroup=PermutationGroup[{rot1,rot2,rot3,rot4,rot5,rot6}]]

GroupOrder[stab=GroupStabilizer[Rubikgroup,{20}]]

The number of cosets of the stabilizer in the full group, using the Lagrange theorem:

%%/%

The orbit of point 20 has length 24:

GroupOrbits[Rubikgroup,{20}]

Length[First[%]]

A stabilizer subgroup computed with (RefLink[GroupStabilizer, paclet:ref/GroupStabilizer]) might be described using more generators than the original group:

AlternatingGroup[10]//GroupGenerators//Length

GroupStabilizer[AlternatingGroup[10],{8}]//GroupGenerators//Length

The stabilizer of a permutation under conjugation action coincides with the centralizer of that permutation:

group=AlternatingGroup[6];
g=Cycles[{{1,3,4},{2,5,6}}];

GroupStabilizer[group,{g},PermutationReplace]

%==GroupCentralizer[group,g]

({{DocumentationFooterIconsRelatedFunction.png, ({{See Also}, {(RefLink[PermutationGroup, paclet:ref/PermutationGroup])  ▪  (RefLink[GroupSetwiseStabilizer, paclet:ref/GroupSetwiseStabilizer])  ▪  (RefLink[GroupOrbits, paclet:ref/GroupOrbits])}})}})

({{DocumentationFooterIconsRelatedTutorial.png, ({{Tutorials}, {▪(RefLinkPlain[Permutations, paclet:tutorial/Permutations])}, {▪(RefLinkPlain[Permutation Groups, paclet:tutorial/PermutationGroups])}, {▪(RefLinkPlain[Named Groups, paclet:tutorial/NamedGroups])}, {▪(RefLinkPlain[Group Theory Algorithms, paclet:tutorial/GroupTheoryAlgorithms])}})}})

({{DocumentationFooterIconsRelatedGuide.png, ({{Related Guides}, {▪(RefLinkPlain[Group Theory, paclet:guide/GroupTheory])}})}})