({{, (RefLink[Graphics, paclet:ref/Graphics])[primitives,options]
represents a two-dimensional graphical image. }})

OpenersNotesSection(Spacer1)Details and Options

(RefLink[Graphics, paclet:ref/Graphics]) is displayed in (RefLink[StandardForm, paclet:ref/StandardForm]) as a graphical image. In (RefLink[InputForm, paclet:ref/InputForm]), it is displayed as an explicit list of primitives.

The following graphics primitives can be used: »

The following graphics directives can be used: »

The following wrappers can be used at any level:

The following options can be given:

Nested lists of graphics constructs can be given. Directive specifications such as (RefLink[GrayLevel, paclet:ref/GrayLevel]) remain in effect only until the end of the list that contains them. »

(RefLink[Style, paclet:ref/Style])[obj,opts] can be used to apply the options or directives opts to obj. »

The following (RefLink[Method, paclet:ref/Method]) options can be given:

The settings for (RefLink[BaseStyle, paclet:ref/BaseStyle]) are appended to the default style typically given by the "Graphics" style in the current stylesheet. The settings for (RefLink[AxesStyle, paclet:ref/AxesStyle]), (RefLink[LabelStyle, paclet:ref/LabelStyle]), etc. are appended to the default styles given for "GraphicsAxes", "GraphicsLabel", etc.

(RefLink[Graphics, paclet:ref/Graphics])[] gives an empty graphic with the default image size.

OpenersPrimaryExamplesSection(Spacer1)Examples  (94)

OpenersExampleSection0(Spacer1)Basic Examples  (2)

Use lines, polygons, circles, etc. to build up a graphics image:

Graphics[{Thick,Green,Rectangle[{0,-1},{2,1}],Red,Disk[],Blue,Circle[{2,0}],Yellow,Polygon[{{2,0},{4,1},{4,-1}}],Purple,Arrowheads[Large],Arrow[{{4,3/2},{0,3/2},{0,0}}],Black,Dashed,Line[{{-1,0},{4,0}}]}]

Use plot functions to automatically create (RefLink[Graphics, paclet:ref/Graphics]) from different types of data:

Plot[Evaluate[Table[BesselJ[n,x],{n,4}]],{x,0,10},Filling->Axis]

GraphPlot[Table[i->Mod[i^2,102],{i,0,102}]]

ReliefPlot[Table[i+Sin[i^2+j^2],{i,-4,4,.03},{j,-4,4,.03}],ColorFunction->"SunsetColors"]

OpenersExampleSection1(Spacer1)Scope  (13)

OpenersExampleSubsection0(Spacer1)Primitives  (4)

Graphics primitives are drawn in the order in which they are given in (RefLink[Graphics, paclet:ref/Graphics]):

Graphics[{Red,Disk[],Green,Rectangle[{0,0},{2,2}],Blue,Disk[{2,2}]}]

Polygons can fold over themselves:

Graphics[Polygon[{{0,0},{1,1},{0,1},{1,0}}]]

Vertices can be shared by using (RefLink[GraphicsComplex, paclet:ref/GraphicsComplex]):

v=Table[15{Cos[t],Sin[t]},{t,0,4Pi,4Pi/5}];

Graphics[GraphicsComplex[v,{Point[{1,2,3,4,5,6}],Green,Line[{1,2,3,4,5,6}]}]]

Inset an expression in a graphic:

Graphics[{Circle[],Inset[x^2+y^2==1,{0,0}]}]

OpenersExampleSubsection1(Spacer1)Directives  (5)

Directives can specify color and opacity of faces:

{Graphics[{Red,Disk[]}],Graphics[{Green,Disk[],Yellow,Opacity[.7],Disk[{0,1}]}],
Graphics[{Hue[2/3,1/2,1],Rectangle[]}]}

Colors, thickness, and dashing directives affect lines, arrows, and edges:

{Graphics[{Blue,Arrow[{{0,0},{2,1}}]}],Graphics[{Thick,Blue,Line[{{0,0},{2,1}}]}],Graphics[{Dashed,Red,Arrow[{{0,0},{2,1}}]}],Graphics[{Thick,Dashed,Red,Line[{{0,0},{2,1}}]}]}

{Graphics[{Pink,Rectangle[]}],Graphics[{EdgeForm[Thick],Pink,Rectangle[]}],Graphics[{EdgeForm[Dashed],Pink,Rectangle[]}],Graphics[{EdgeForm[Directive[Thick,Dashed,Blue]],Pink,Rectangle[]}]}

Some primitives have special directives to specify various properties:

{Graphics[{Dashed,Red,Arrowheads[{-.1,.1}],Arrow[{{0,0},{2,1}}]}],Graphics[{Blue,PointSize[Large],Point[{{0,0},{1,1/2},{2,1}}]}]}

Directives can be applied to individual objects using (RefLink[Style, paclet:ref/Style]):

Graphics[{Style[Disk[],Pink],Style[Rectangle[{2,-1},{4,1}],Blue]}]

Graphics directives remain in effect only until the end of the list that contains them:

Graphics[{Pink,Disk[],{Blue,Disk[{1,0}]},Disk[{2,0}]}]

OpenersExampleSubsection2(Spacer1)Coordinates  (4)

Use an ordinary coordinate system:

Graphics[Rectangle[{0,4},{10,6}],Frame->True,PlotRange->{{0,10},{0,10}}]

Specify coordinates by fractions of the plot range:

Graphics[Rectangle[Scaled[{0,.4}],Scaled[{1,.6}]],Frame->True,PlotRange->{{0,10},{0,10}}]

Specify coordinates by fractions of the whole image:

Graphics[Rectangle[ImageScaled[{0,.4}],ImageScaled[{1,.6}]],Frame->True,PlotRange->{{0,10},{0,10}}]

Offset coordinates by printer's points:

Graphics[Rectangle[Offset[{10,20},{0,0}],Offset[{-10,-20},{1,1}]],Frame->True]

OpenersExampleSection2(Spacer1)Options  (71)

OpenersExampleSubsection3(Spacer1)AlignmentPoint  (1)

Specify the coordinates within (RefLink[Inset, paclet:ref/Inset]) to be aligned with the center of the enclosing graphic:

Table[Graphics[{Inset[Graphics[Circle[],ImageSize->30,AlignmentPoint->{a,0}],Center]},ImageSize->70,Axes->True,Ticks->None],{a,{-1,0,1}}]

Table[Graphics[{Inset[Graphics[Circle[],ImageSize->30,AlignmentPoint->{0,a}],Center]},ImageSize->70,Axes->True,Ticks->None],{a,{-1,0,1}}]

OpenersExampleSubsection4(Spacer1)AspectRatio  (1)

Use numerical values for (RefLink[AspectRatio, paclet:ref/AspectRatio]):

Table[Graphics[Circle[],AspectRatio->1/k],{k,1,3}]

OpenersExampleSubsection5(Spacer1)Axes  (2)

Draw all the axes:

Graphics[Circle[],Axes->True]

Draw the y axis but not the x axis:

Graphics[Circle[],Axes->{False,True}]

OpenersExampleSubsection6(Spacer1)AxesLabel  (2)

Place a label for the y axis:

Graphics[Circle[],Axes->True,AxesLabel->y]

Specify a label for each axis:

Graphics[Circle[],Axes->True,AxesLabel->{x,y}]

OpenersExampleSubsection7(Spacer1)AxesOrigin  (2)

Determine where the axes cross automatically:

Graphics[Circle[],Axes->True,AxesOrigin->Automatic]

Specify the axes' origin explicitly:

Graphics[Circle[],Axes->True,AxesOrigin->{0,-1}]

OpenersExampleSubsection8(Spacer1)AxesStyle  (1)

Specify the overall axes style, including the ticks and the tick labels:

Graphics[Circle[],Axes->True,AxesStyle->Directive[Orange,12]]

Specify the style of each axis:

Graphics[Circle[],Axes->True,AxesStyle->{Directive[Dashed,Red],Blue}]

OpenersExampleSubsection9(Spacer1)Background  (1)

Specify a background color:

Graphics[Circle[],Background->LightBlue]

OpenersExampleSubsection10(Spacer1)BaselinePosition  (3)

Align the center of a graphic with the baseline of the text:

{x,Graphics[Circle[],ImageSize->50,BaselinePosition->Center],y}

Specify the baseline of a graphic as a fraction of the height by using (RefLink[Scaled, paclet:ref/Scaled]):

Table[{x,Graphics[Circle[],BaselinePosition->Scaled[b],ImageSize->50]},{b,{0,0.5,1}}]

Use the axis of a graphic as the baseline:

{x,Graphics[Circle[],Axes->True,BaselinePosition->Axis],y}

{x,Graphics[Circle[{0,1}],Axes->True,BaselinePosition->Axis],y}

OpenersExampleSubsection11(Spacer1)BaseStyle  (2)

Set the starting style:

Graphics[{Circle[{0,0},1],Disk[{3,0},1]},BaseStyle->Blue]

Set multiple starting styles:

Graphics[{Circle[{0,0},1],Disk[{3,0},1]},BaseStyle->{Green,Thick,EdgeForm[Dashed]}]

OpenersExampleSubsection12(Spacer1)ContentSelectable  (3)

Allow the individual graphics objects to be selectable by a single click:

Graphics[{Pink,Disk[],Rectangle[{2,-1},{4,1}]},ContentSelectable->True]

No individual object is selectable; the whole graphic appears as one object:

Graphics[{Pink,Disk[],Rectangle[{2,-1},{4,1}]},ContentSelectable->False]

The first click selects the whole graphic, and subsequent ones select individual objects:

Graphics[{Pink,Disk[],Rectangle[{2,-1},{4,1}]},ContentSelectable->Automatic]

OpenersExampleSubsection13(Spacer1)Epilog  (1)

Draw a disk above the graphic, including the axes:

Graphics[{Pink,Disk[]},Axes->True,Epilog->{Blue,Disk[{0,0},.4]}]

OpenersExampleSubsection14(Spacer1)FormatType  (3)

By default, expressions are displayed using (RefLink[TraditionalForm, paclet:ref/TraditionalForm]) in graphics:

Graphics[{Circle[],Text[Style[x^2+y^2==1,20]]}]

Display expressions using (RefLink[StandardForm, paclet:ref/StandardForm]):

Graphics[{Circle[],Text[Style[x^2+y^2==1,20]]},FormatType->StandardForm]

Labels are also affected by (RefLink[FormatType, paclet:ref/FormatType]) setting:

Graphics[Circle[],Axes->True,AxesLabel->{Cos[θ],Sin[θ]},FormatType->StandardForm]

OpenersExampleSubsection15(Spacer1)Frame  (2)

Draw a frame around the whole graphic:

Graphics[Circle[],Frame->True]

Draw a frame on the left and the right edges:

Graphics[Circle[],Frame->{{True,True},{False,False}}]

OpenersExampleSubsection16(Spacer1)FrameLabel  (1)

Specify frame labels for the bottom and the left edges:

Graphics[Circle[],Frame->True,FrameLabel->{x,y}]

Specify labels for each edge:

Graphics[Circle[],Frame->True,FrameLabel->{{a,b},{c,d}}]

OpenersExampleSubsection17(Spacer1)FrameStyle  (2)

Specify the overall frame style:

Graphics[Circle[],Frame->True,FrameStyle->Directive[Thick,Gray]]

Specify the style of each frame edge:

Graphics[Circle[],Frame->True,FrameStyle->{{Thick,Directive[Thick,Dashed]},{Blue,Red}}]

OpenersExampleSubsection18(Spacer1)FrameTicks  (2)

Put a frame, but no ticks:

Graphics[Circle[],Frame->True,FrameTicks->None]

Tick mark labels on the bottom and the left frame edges:

Graphics[Circle[],Frame->True,FrameTicks->Automatic]

Frame ticks on the bottom and the right edges:

Graphics[Circle[],Frame->True,FrameTicks->{{None,Automatic},{Automatic,None}}]

OpenersExampleSubsection19(Spacer1)FrameTicksStyle  (2)

Specify frame tick and frame tick label style:

Graphics[{},Frame->True,FrameTicksStyle->Directive[Orange,12]]

Specify frame tick style for each edge:

Graphics[{},Frame->True,FrameTicks->All,FrameTicksStyle->{{Black,Blue},{Red,Green}}]

OpenersExampleSubsection20(Spacer1)GridLines  (3)

Put grids across a 2D graphic:

Graphics[Circle[],GridLines->Automatic]

Draw grid lines at specific positions:

Graphics[Circle[],Axes->True,GridLines->{{-1,1},{-1,1}}]

Specify the style of each grid:

Graphics[Circle[],Axes->True,GridLines->{{{-1,Orange},{-.5,Dotted},{.5,Dotted},{1,Orange}},{-1,{-.5,Dotted},{.5,Dotted},1}}]

OpenersExampleSubsection21(Spacer1)GridLinesStyle  (1)

Specify the overall grid style:

Graphics[Circle[],Axes->True,GridLines->Automatic,GridLinesStyle->Directive[Red,Dotted]]

OpenersExampleSubsection22(Spacer1)ImageMargins  (3)

Allow no margins outside of (RefLink[ImageSize, paclet:ref/ImageSize]):

Framed[Graphics[Disk[]]]

Have 20-point margins on all sides:

Framed[Graphics[Disk[],ImageMargins->20]]

Leave different margins on each side:

Framed[Graphics[Disk[],ImageMargins->{{5,10},{20,30}}]]

OpenersExampleSubsection23(Spacer1)ImagePadding  (4)

Leave no padding outside of the plot range:

Graphics[{Thickness[.3],Pink,Circle[]},ImagePadding->None,Frame->True,FrameLabel->{x,y}]

Leave enough padding for all objects and labels that are present:

Framed[Graphics[{Thickness[.3],Pink,Circle[]},ImagePadding->All,Frame->True,FrameLabel->{x,y}],FrameMargins->0]

Specify the same padding for all sides in printer's points:

Framed[Graphics[{Thickness[.3],Pink,Circle[]},ImagePadding->40,Frame->True]]

Specify different padding on each side:

Framed[Graphics[{Thickness[.2],Pink,Circle[]},ImagePadding->{{40,10},{20,5}},Frame->True]]

OpenersExampleSubsection24(Spacer1)ImageSize  (3)

Use predefined symbolic sizes:

Table[Graphics[Circle[],ImageSize->s],{s,{Tiny,Small}}]

Use an explicit image width:

{Graphics[Circle[],ImageSize->100],Graphics[Circle[{0,0},{1,2}],ImageSize->100]}

Use an explicit image width and height:

{Graphics[Circle[],ImageSize->{100,100}],Graphics[Circle[{0,0},{1,2}],ImageSize->{100,100}]}

OpenersExampleSubsection25(Spacer1)LabelStyle  (1)

Specify the overall style of all the label-like elements:

Graphics[Circle[],Axes->True,AxesLabel->{x,y},LabelStyle->Orange]

OpenersExampleSubsection26(Spacer1)Method  (4)

OpenersExampleSubsubsection0(Spacer1)"AxesInFront"  (1)

Force axes to be behind drawing primitives:

Graphics[{Red,Table[Disk[{i,i}],{i,-1,1}]},Axes->True,Method->{"AxesInFront"->False}]

OpenersExampleSubsubsection1(Spacer1)"FrameInFront"  (1)

By default, frames draw in front of graphics primitives:

Graphics[{Red,Polygon[{{0.5,0},{.5,1},{-.5,1}}]},Frame->True,PlotRange->{{0,1},{0,1}}]

Force the frame to draw behind graphics primitives:

Show[%, Method->{"FrameInFront"->False}]

OpenersExampleSubsubsection2(Spacer1)"GridLinesInFront"  (1)

Force grid lines to be rendered in front of graphics primitives:

Graphics[{Green,PointSize[.6],Point[{0,0}]},GridLines->Automatic,Method->{"GridLinesInFront"->True}]

OpenersExampleSubsubsection3(Spacer1)"TransparentPolygonMesh"  (1)

By default, polygon meshes double-paint their edges for efficiency reasons:

Graphics[{Blue,Opacity[0.2],EdgeForm[None],
Polygon[{{{0,0},{0,1},{1,0}},{{1,1},{0,1},{1,0}}}]}]

The behavior can be turned off using the "TransparentPolygonMesh" method option:

Show[%,Method->{"TransparentPolygonMesh"->True}]

OpenersExampleSubsection27(Spacer1)PlotLabel  (2)

Display a label on the top of the graphic in (RefLink[TraditionalForm, paclet:ref/TraditionalForm]):

Graphics[Circle[],PlotLabel->x^2+y^2==1]

Use (RefLink[Style, paclet:ref/Style]) and other typesetting functions to modify how the label appears:

Graphics[Circle[],PlotLabel->Style[Framed[x^2+y^2==1],16,Red,Background->Yellow]]

OpenersExampleSubsection28(Spacer1)PlotRange  (3)

Display all objects:

Graphics[{Pink,Disk[{0,0},5]},Frame->True,PlotRange->All]

Explicitly choose x and y ranges:

Graphics[{Pink,Disk[]},PlotRange->{{-1,1},{0,1}},Frame->True]

Force clipping at the (RefLink[PlotRange, paclet:ref/PlotRange]):

Graphics[{Pink,Disk[]},PlotRange->{{-1,1},{0,1}},PlotRangeClipping->True,Frame->True]

(RefLink[PlotRange, paclet:ref/PlotRange])->s is equivalent to (RefLink[PlotRange, paclet:ref/PlotRange])->{{-s,s},{-s,s}}:

Graphics[{Pink,Disk[{0,0},5]},Frame->True,PlotRange->4]

OpenersExampleSubsection29(Spacer1)PlotRangeClipping  (2)

Allow graphics objects to spread beyond (RefLink[PlotRange, paclet:ref/PlotRange]):

Graphics[{Pink,Disk[{0,0},5]},Frame->True,PlotRange->4,PlotRangeClipping->False]

Clip all graphics objects at (RefLink[PlotRange, paclet:ref/PlotRange]):

Graphics[{Pink,Disk[{0,0},5]},Frame->True,PlotRange->4,PlotRangeClipping->True]

OpenersExampleSubsection30(Spacer1)PlotRangePadding  (3)

Include 1 coordinate unit of padding on all sides:

Graphics[{Pink,Rectangle[]},PlotRangePadding->1,Frame->True]

Include padding using (RefLink[Scaled, paclet:ref/Scaled]) coordinates:

Graphics[{Pink,Rectangle[]},PlotRangePadding->Scaled[0.1],Frame->True]

Specify different padding on each side:

Graphics[{Pink,Rectangle[]},PlotRangePadding->{{0.5,1},{0.3,0.3}},Frame->True]

OpenersExampleSubsection31(Spacer1)PlotRegion  (3)

The contents of a graphic use the whole region:

Graphics[{Pink,Disk[]},Frame->True,FrameTicks->False,Background->LightBlue]

Limit the contents of the graphic to the middle half of the region in each direction:

Graphics[{Pink,Disk[]},Frame->True,FrameTicks->False,PlotRegion->{{0.25,0.75},{0.25,0.75}},Background->LightBlue]

(RefLink[ImagePadding, paclet:ref/ImagePadding]) can also be used to add padding around a graphic:

Graphics[{Pink,Disk[]},Frame->True,FrameTicks->False,ImagePadding->30,Background->LightBlue]

OpenersExampleSubsection32(Spacer1)Prolog  (1)

Define a simple graphic to use as a background:

bg=Graphics[Polygon[{{0,0},{1,0},{1,1},{0,1}},VertexColors->{Orange,Orange,White,White}],AspectRatio->Full];

Use it in multiple graphics:

Graphics[Circle[],Prolog->Inset[bg,Scaled[{0,0}],Scaled[{0,0}]]]

Plot[Sin[x],{x,0,10},Prolog->Inset[bg,Scaled[{0,0}],Scaled[{0,0}],Scaled[{1,1}]]]

OpenersExampleSubsection33(Spacer1)RotateLabel  (2)

Specify that vertical frame labels should be rotated:

Graphics[Circle[],Frame->True,FrameLabel->{None,"y axis"},RotateLabel->True]

Specify that vertical frame labels should not be rotated:

Graphics[Circle[],Frame->True,FrameLabel->{None,"y axis"},RotateLabel->False]

OpenersExampleSubsection34(Spacer1)Ticks  (3)

Draw the axes but no tick marks:

Graphics[Circle[],Axes->True,Ticks->None]

Place tick marks automatically:

Graphics[Circle[],Axes->True,Ticks->Automatic]

Draw tick marks at the specific positions:

Graphics[Circle[{0,0},3],Ticks->{{1,2,3},{1,3}},Axes->True]

OpenersExampleSubsection35(Spacer1)TicksStyle  (2)

Specify the styles of the ticks and tick labels:

Graphics[Circle[],Axes->True,TicksStyle->Directive[Red,Bold]]

Specify the styles of x and y axis ticks separately:

Graphics[Circle[],Axes->True,TicksStyle->{Directive[Red,Bold],Directive[Blue,12]}]

OpenersExampleSection3(Spacer1)Applications  (1)

Draw a complete graph with 9 vertices:

pts=Table[{Cos[2n π/9],Sin[2 n π/9]},{n,0,8}];

Graphics[{Opacity[0.7],Red,Line[Tuples[pts,2]],Blue,PointSize[0.05],Point[pts]}]

OpenersExampleSection4(Spacer1)Properties & Relations  (5)

The (RefLink[StandardForm, paclet:ref/StandardForm]) of (RefLink[Graphics, paclet:ref/Graphics]) is its rendered form:

Graphics[Disk[]]

The (RefLink[InputForm, paclet:ref/InputForm]) is the textual expression form:

InputForm[%]

(RefLink[Graphics, paclet:ref/Graphics]) can be used as input to functions:

makeDashed[ g_Graphics ]:=g/.l_Line:>{Dashed,l}

makeDashed[]

Two-dimensional plot functions return (RefLink[Graphics, paclet:ref/Graphics]):

ParametricPlot[{(v+u) Cos[u],(v+u) Sin[u]},{u,0,4Pi},{v,0,5},Mesh->False]

ContourPlot[y+Sin[x^2+3y],{x,-3,3},{y,-3,3},ColorFunction->"Rainbow"]

Several integrated data sources return (RefLink[Graphics, paclet:ref/Graphics]):

CountryData["World","Shape"]

GraphData["DoubleStarSnark"]

Many (RefLink[Import, paclet:ref/Import]) and (RefLink[Export, paclet:ref/Export]) formats support (RefLink[Graphics, paclet:ref/Graphics]):

First@Import["ExampleData/mathematica.pdf"]

Import["ExampleData/coneflower.jpg", "Graphics"]

OpenersExampleSection5(Spacer1)Neat Examples  (2)

Display an analog clock with current system time:

Dynamic@Module[{hour,min,sec,ht,mt,st},Clock[];{hour,min,sec}=Take[DateList[],-3];ht=Pi/2-2Pi hour/12-2Pi min/720;mt=Pi/2-2Pi min/60;st=Pi/2-2Pi Floor[sec]/60;Graphics[{Arrowheads[0.1],Arrow[{{0,0},0.6{Cos[ht],Sin[ht]}}],Arrow[{{0,0},0.85{Cos[mt],Sin[mt]}}],Line[{{0,0},0.85{Cos[st],Sin[st]}}],PointSize[Medium],Table[Point[0.9{Cos[i],Sin[i]}],{i,0,2Pi,Pi/6}],Point[{0,0}],Circle[]}]]

Digital dahlias:

Graphics[Table[{Hue[t/20],Circle[{Cos[2Pi t/20],Sin[2Pi t/20]}]},{t,20}]]

({{DocumentationFooterIconsRelatedFunction.png, ({{See Also}, {(RefLink[Plot, paclet:ref/Plot])  ▪  (RefLink[ListPlot, paclet:ref/ListPlot])  ▪  (RefLink[ListLinePlot, paclet:ref/ListLinePlot])  ▪  (RefLink[ParametricPlot, paclet:ref/ParametricPlot])  ▪  (RefLink[DensityPlot, paclet:ref/DensityPlot])  ▪  (RefLink[ArrayPlot, paclet:ref/ArrayPlot])  ▪  (RefLink[RegionPlot, paclet:ref/RegionPlot])  ▪  (RefLink[ContourPlot, paclet:ref/ContourPlot])  ▪  (RefLink[Show, paclet:ref/Show])  ▪  (RefLink[Graphics3D, paclet:ref/Graphics3D])  ▪  (RefLink[Image, paclet:ref/Image])  ▪  (RefLink[Import, paclet:ref/Import])  ▪  (RefLink[GeometricScene, paclet:ref/GeometricScene])  ▪  (RefLink[Sound, paclet:ref/Sound])}})}})

({{DocumentationFooterIconsRelatedTutorial.png, ({{Tutorials}, {▪(RefLinkPlain[The Structure of Graphics, paclet:tutorial/TheStructureOfGraphics])}})}})

({{DocumentationFooterIconsRelatedGuide.png, ({{Related Guides}, {▪(RefLinkPlain[Plane Geometry, paclet:guide/PlaneGeometry])}, {▪(RefLinkPlain[Symbolic Graphics Language, paclet:guide/SymbolicGraphicsLanguage])}, {▪(RefLinkPlain[Polygons, paclet:guide/Polygons])}, {▪(RefLinkPlain[WDF (Wolfram Data Framework), paclet:guide/WDFWolframDataFramework])}})}})

({{(Spacer1), ({{(Spacer1)Related Links}, {(WebLink[DocumentationFooterIconsRelatedLinks-FastIntro.png(Spacer1)Fast Introduction for Programmers: Graphics, http://www.wolfram.com/language/fast-introduction-for-programmers/graphics/])}, {(WebLink[DocumentationFooterIconsRelatedLinks-EIWL.png(Spacer1)An Elementary Introduction to the Wolfram Language, https://www.wolfram.com/language/elementary-introduction/08-basic-graphics-objects.html])(WebLink[: Basic Graphics Objects, https://www.wolfram.com/language/elementary-introduction/08-basic-graphics-objects.html])}, {(WebLink[DocumentationFooterIconsRelatedLinks-EIWL.png(Spacer1)An Elementary Introduction to the Wolfram Language, https://www.wolfram.com/language/elementary-introduction/09-interactive-manipulation.html])(WebLink[: Interactive Manipulation, https://www.wolfram.com/language/elementary-introduction/09-interactive-manipulation.html])}, {(WebLink[DocumentationFooterIconsRelatedLinks-EIWL.png(Spacer1)An Elementary Introduction to the Wolfram Language, https://www.wolfram.com/language/elementary-introduction/14-coordinates-and-graphics.html])(WebLink[: Coordinates and Graphics, https://www.wolfram.com/language/elementary-introduction/14-coordinates-and-graphics.html])}, {(WebLink[DocumentationFooterIconsRelatedLinks-EIWL.png(Spacer1)An Elementary Introduction to the Wolfram Language, https://www.wolfram.com/language/elementary-introduction/25-ways-to-apply-functions.html])(WebLink[: Ways to Apply Functions, https://www.wolfram.com/language/elementary-introduction/25-ways-to-apply-functions.html])}, {(WebLink[DocumentationFooterIconsRelatedLinks-EIWL.png(Spacer1)An Elementary Introduction to the Wolfram Language, https://www.wolfram.com/language/elementary-introduction/37-layout-and-display.html])(WebLink[: Layout and Display, https://www.wolfram.com/language/elementary-introduction/37-layout-and-display.html])}})}})