({{, (RefLink[GeoProjectionData, paclet:ref/GeoProjectionData])["projection","property"] 
gives the value of the specified property for the specified cartographic projection.}, {, (RefLink[GeoProjectionData, paclet:ref/GeoProjectionData])["projection"]
gives the complete options for the default form of the specified projection.}})

OpenersNotesSection(Spacer1)Details

(RefLink[GeoProjectionData, paclet:ref/GeoProjectionData])[] gives the list of available cartographic projections.

(RefLink[GeoProjectionData, paclet:ref/GeoProjectionData])["projection","Properties"] gives the names of all parameters and properties available for the projection specified by "name".

(RefLink[GeoProjectionData, paclet:ref/GeoProjectionData])["projection"] returns a result of the form {"projection",{(Subscript[prop, 1])->(Subscript[val, 1]),… }}, giving the default values (Subscript[val, i]) of the parameters and properties (Subscript[prop, i]). Common properties include:

Typical settings for "Centering" include:

Valid settings for "ReferenceModel":

Naming-related properties include:

Available projections for a spherical reference model include:

Available projections for an ellipsoidal reference model include:

(RefLink[GeoProjectionData, paclet:ref/GeoProjectionData])["Classes"] gives a list of all supported classes of projections.

(RefLink[GeoProjectionData, paclet:ref/GeoProjectionData])["class"] lists all projections belonging to the given class.

(RefLink[GeoProjectionData, paclet:ref/GeoProjectionData])["proj","Classes"] gives a list of all the classes of which projection "proj" is a member.

Classes of projections based on their properties include:

(RefLink[GeoProjectionData, paclet:ref/GeoProjectionData]) contains both general projections like "TransverseMercator" and explicit realizations of those general projections, like the members of the "UTMZone" family.

(RefLink[GeoProjectionData, paclet:ref/GeoProjectionData])["Spherical"] gives the list of all projections that refer to a spherical model.

(RefLink[GeoProjectionData, paclet:ref/GeoProjectionData])["Ellipsoidal"] gives the list of all projections that refer to an ellipsoidal model.

(RefLink[GeoProjectionData, paclet:ref/GeoProjectionData]) supports all projections used by the US State Plane Coordinate Systems from 1927 to 1983.

(RefLink[GeoProjectionData, paclet:ref/GeoProjectionData])["SPCS27"] and (RefLink[GeoProjectionData, paclet:ref/GeoProjectionData])["SPCS83"] give the names of all state plane zones.

(RefLink[GeoProjectionData, paclet:ref/GeoProjectionData])["UTMZone"] gives names for all UTM zones, both North and South zones.

(RefLink[GeoProjectionData, paclet:ref/GeoProjectionData])["UPSZone"] gives the names of the two UPS zones.

For any state plane, UTM zone, or UPS zone, (RefLink[GeoProjectionData, paclet:ref/GeoProjectionData])["zone"] gives the name and the standard parameters of the projection used.

A geo projection proj can be used in (RefLink[GeoGridPosition, paclet:ref/GeoGridPosition])[pos,proj] or in (RefLink[GeoGraphics, paclet:ref/GeoGraphics])[prims,(RefLink[GeoProjection, paclet:ref/GeoProjection])->proj].

OpenersPrimaryExamplesSection(Spacer1)Examples  (38)

OpenersExampleSection0(Spacer1)Basic Examples  (4)

Default parameters used for the spherical Bonne projection, referenced to a unit sphere:

GeoProjectionData["Bonne"]

Use a geo projection to convert a {lat,lon} location into map coordinates:

GeoGridPosition[GeoPosition[{40.,30.}],"Bonne"]

Use a geo projection to produce a map of the world:

GeoGraphics[{},GeoRange->"World",GeoProjection->"Bonne",GeoGridLines->Automatic]

Default parameters used for one of the UTM zones:

GeoProjectionData["UTMZone45"]

OpenersExampleSection1(Spacer1)Scope  (26)

OpenersExampleSubsection0(Spacer1)Names and Classes  (9)

List of all available cartographic projections:

Short[GeoProjectionData[],5]

Length[%]

English name of a cartographic projection:

GeoProjectionData["Albers","Name"]

List of available classes:

GeoProjectionData["Classes"]

List of all projections with a spherical reference model:

GeoProjectionData["Spherical"]

Projections for the 60 North zones and 60 South zones of the Universal Transverse Mercator coordinate system:

GeoProjectionData["UTMZone"]

All UTM North zones have the same parameters, except for the centering longitude, which is 6 n-183 for zone n:

GeoProjectionData["UTMZone48"]

6 48-183

The corresponding South zones change the grid origin northing from 0 to 10000 kilometers:

GeoProjectionData["UTMZone48South"]

The two Universal Polar Stereographic projections:

GeoProjectionData["UPSZone"]

They are based on the stereographic projection for an ellipsoidal model:

GeoProjectionData["UPSNorth"]

List of the US State Plane Coordinate Systems of 1927:

spcs27=GeoProjectionData["SPCS27"]

Depending on the shape of the states, the coordinate systems are based on these three projections:

Tally[First/@GeoProjectionData/@spcs27]

Map of respective centering positions:

point[cs_]:=Tooltip[Switch[GeoProjectionData[cs][[1]],
"TransverseMercator",{Red,Point[GeoProjectionData[cs,"Centering"]]},
"LambertConicConformal",{Blue,Point[GeoProjectionData[cs,"Centering"]]},
"ObliqueMercator",{Black,Point[GeoProjectionData[cs,"Centering"][[1]]]}],cs]

GeoGraphics[point/@spcs27,GeoGridLines->True,ImageSize->Medium]

List of the US State Plane Coordinate Systems of 1983:

spcs83=GeoProjectionData["SPCS83"]

They all use the "GRS80" ellipsoid:

GeoProjectionData[#,"ReferenceModel"]&/@spcs83//Union

Alternate names:

GeoProjectionData["SPCS83MS02","AlternateNames"]

Ellipsoidal projections, other than those realized in the "UTMZone", "UPSZone", "SPCS27", and "SPCS83" systems:

Complement[GeoProjectionData["Ellipsoidal"],GeoProjectionData["UTMZone"],GeoProjectionData["UPSZone"],GeoProjectionData["SPCS27"],GeoProjectionData["SPCS83"]]

OpenersExampleSubsection1(Spacer1)Properties and Values  (6)

List of available properties:

GeoProjectionData["Properties"]

The default parameters of a projection method are generic values, like a sphere of unit radius:

GeoProjectionData["Albers"]

The "Centering" parameter is returned as a (RefLink[GeoPosition, paclet:ref/GeoPosition]) object:

GeoProjectionData["Albers","Centering"]

Conic projections may have one or two standard parallels, returned as angular (RefLink[Quantity, paclet:ref/Quantity]) objects:

GeoProjectionData["Bonne","StandardParallels"]

GeoProjectionData["Albers","StandardParallels"]

The "GridOrigin" option gives false easting and northing, frequently used to avoid negative coordinates:

GeoProjectionData["UTMZone23","GridOrigin"]

The "Centering" position gets assigned that value, instead of {0,0}:

GeoProjectionData["UTMZone23","Centering"]

GeoGridPosition[%,"UTMZone23"]

The reference model is a numeric object for projections with a spherical reference model:

GeoProjectionData["Bonne","ReferenceModel"]

GeoGridPosition[GeoPosition[{80.,170.}],"Bonne"]

For cylindrical projections, a value 180/π is used to keep longitude given in degrees:

GeoProjectionData["Mercator","ReferenceModel"]

GeoGridPosition[GeoPosition[{80.,170.}],"Mercator"]

For ellipsoidal coordinate systems, the reference model is a (RefLink[GeodesyData, paclet:ref/GeodesyData]) specification of an ellipsoid:

GeoProjectionData["UTMZone23","ReferenceModel"]

GeoGridPosition[GeoPosition[{70.,-44.}],"UTMZone23"]

OpenersExampleSubsection2(Spacer1)Types of Projections  (11)

OpenersExampleSubsubsection0(Spacer1)Projection Surface  (5)

These are cylindrical projections, mapping points onto a cylinder:

GeoProjectionData["Cylindrical"]

GeoGraphics[GeoRange->"World",GeoProjection->"Equirectangular"]

GeoGraphics[GeoRange->"World",GeoProjection->"Mercator"]

GeoGraphics[GeoRange->"World",GeoProjection->"CylindricalEqualArea"]

These are pseudo-cylindrical projections:

GeoProjectionData["PseudoCylindrical"]

GeoGraphics[GeoRange->"World",GeoProjection->"Robinson"]

GeoGraphics[GeoRange->"World",GeoProjection->"WinkelTripel"]

GeoGraphics[GeoRange->"World",GeoProjection->"Mollweide"]

These are azimuthal projections, mapping points onto a plane tangent at a point:

GeoProjectionData["Azimuthal"]

GeoGraphics[GeoRange->"World",GeoProjection->"Airy"]

GeoGraphics[GeoRange->"World",GeoProjection->"Orthographic"]

GeoGraphics[GeoRange->"World",GeoProjection->"LambertAzimuthal"]

These are conic projections, mapping points onto a tangent or secant cone:

GeoProjectionData["Conic"]

GeoGraphics[GeoRange->"World",GeoProjection->"Albers"]

GeoGraphics[GeoRange->"World",GeoProjection->"LambertConicConformal"]

GeoGraphics[GeoRange->"World",GeoProjection->"ConicEquidistant"]

Other types of projections:

GeoGraphics[GeoRange->"World",GeoProjection->"Bonne"]

GeoGraphics[GeoRange->"World",GeoProjection->"AmericanPolyconic"]

GeoGraphics[GeoRange->"World",GeoProjection->"Armadillo"]

GeoGraphics[GeoRange->"World",GeoProjection->{"CraigRetroazimuthal","Centering"->{20,0}}]

OpenersExampleSubsubsection1(Spacer1)Aspect  (3)

A cylindrical projection of normal aspect maps onto a cylinder whose axis is aligned with the Earth's axis:

GeoGraphics[GeoRange->"World",GeoProjection->"Equirectangular"]

A cylindrical projection of transverse aspect maps onto a cylinder whose axis is on the equatorial plane:

GeoGraphics[GeoRange->"World",GeoProjection->"Cassini"]

A cylindrical projection of oblique aspect maps onto a cylinder whose axis is tilted:

GeoGraphics[GeoRange->"World",GeoProjection->"ObliqueMercator"]

OpenersExampleSubsubsection2(Spacer1)Projection Properties  (3)

Conformal projections preserve angles and shapes. For example, geo disks are circular:

GeoGraphics[{Opacity[0.3],Table[GeoDisk[{lat,lon},10^6],{lat,-70,70,20},{lon,-160,160,40}]},GeoProjection->"Mercator",ImageSize->Medium]

GeoGraphics[{Opacity[0.3],Table[GeoDisk[{lat,lon},10^6],{lat,-50,70,20},{lon,-160,160,40}]},GeoProjection->"LambertConicConformal",ImageSize->Medium]

Equidistant projections preserve distances along some directions (meridians in these cases):

GeoGraphics[{Thick,Table[GeoPath[{{lat,lon},10^6,0}],{lat,-70,70,20},{lon,-160,160,40}]},GeoProjection->"CylindricalEquidistant",ImageSize->Medium]

GeoGraphics[{Thick,Table[GeoPath[{{lat,lon},10^6,0}],{lat,-70,70,20},{lon,-160,160,40}]},GeoProjection->"ConicEquidistant",ImageSize->Medium]

Equivalent or equal-area projections preserve areas of certain regions:

geoRectangle[lat_,area_]:=Module[{dlat},
dlat=dlat/.FindRoot[area/(2Pi)==Sin[(lat+dlat)Degree]-Sin[(lat-dlat)Degree],{dlat,0}];
GeoBoundsRegion[{lat+{-dlat,dlat},{-180,180}}]
]

GeoGraphics[{Opacity[0.3],Table[geoRectangle[lat,1],{lat,-60,60,30}]},GeoRange->"World",GeoProjection->"CylindricalEqualArea",ImageSize->Medium]

GeoGraphics[{Opacity[0.3],Table[geoRectangle[lat,1],{lat,-60,60,30}]},GeoRange->"World",GeoProjection->"Albers"]

OpenersExampleSection3(Spacer1)Applications  (3)

Perform projections of geo locations with (RefLink[GeoGridPosition, paclet:ref/GeoGridPosition]):

GeoGridPosition[GeoPosition[{30.,-40.}],"Bonne"]

GeoPositionXYZ[$GeoLocation]

GeoGridPosition[GeoPositionXYZ[{150000.,-4882543.,4087334.}],"Mercator"]

GeoGridPosition[GeoPositionENU[{1000.,-2000.,100.},GeoPosition[{0,0}]],"WinkelTripel"]

Use projections in (RefLink[GeoGraphics, paclet:ref/GeoGraphics]) maps, with automatic choice of projection parameters:

GeoGraphics[Polygon[(Entity["Canada", Entity["Country","Canada"], "Entity[\"Country\", \"Canada\"]", "country"])],GeoProjection->"Mercator"]

GeoGraphics[Polygon[(Entity["Canada", Entity["Country","Canada"], "Entity[\"Country\", \"Canada\"]", "country"])],GeoProjection->"CylindricalEqualArea"]

GeoGraphics[Polygon[(Entity["Canada", Entity["Country","Canada"], "Entity[\"Country\", \"Canada\"]", "country"])],GeoProjection->"LambertAzimuthal"]

Discover the actual parameters chosen for the projection:

AbsoluteOptions[%,GeoProjection]

Specify your own parameters for the projection:

GeoGraphics[Polygon[(Entity["Canada", Entity["Country","Canada"], "Entity[\"Country\", \"Canada\"]", "country"])],GeoProjection->{"LambertAzimuthal","Centering"->GeoPosition[{90,-90}]},GeoRange->{{40,90},{-180,0}},GeoGridLines->Automatic]

Tilted perspective of the United Kingdom and Ireland:

UKandIreland={(Entity["England, United Kingdom", Entity["AdministrativeDivision",{"England","UnitedKingdom"}], "Entity[\"AdministrativeDivision\", {\"England\", \"UnitedKingdom\"}]", "administrative division"]),(Entity["Northern Ireland, United Kingdom", Entity["AdministrativeDivision",{"NorthernIreland","UnitedKingdom"}], "Entity[\"AdministrativeDivision\", {\"NorthernIreland\", \"UnitedKingdom\"}]", "administrative division"]),(Entity["Scotland, United Kingdom", Entity["AdministrativeDivision",{"Scotland","UnitedKingdom"}], "Entity[\"AdministrativeDivision\", {\"Scotland\", \"UnitedKingdom\"}]", "administrative division"]),(Entity["Wales, United Kingdom", Entity["AdministrativeDivision",{"Wales","UnitedKingdom"}], "Entity[\"AdministrativeDivision\", {\"Wales\", \"UnitedKingdom\"}]", "administrative division"]),(Entity["Ireland", Entity["Country","Ireland"], "Entity[\"Country\", \"Ireland\"]", "country"])};

GeoGraphics[{EdgeForm[Black],Polygon[UKandIreland]},GeoRange->{{51,80},{-15,2}},GeoProjection->{"TiltedPerspective","Centering"->{{50,-1,0.025},-30,20}},GeoGridLines->(QuantityPostfix[1, "°", degrees, "AngularDegrees"]),GeoRangePadding->Full,GeoBackground->None]

OpenersExampleSection4(Spacer1)Properties & Relations  (4)

A general projection typically assumes standard parameters, like a sphere of radius 1:

GeoProjectionData["TransverseMercator"]

A realization of that projection assumes explicit values:

GeoProjectionData["UTMZone12"]

In the US State Plane Coordinate System, the ellipsoidal transverse Mercator projection is used for states that are long in the north-south direction:

GeoProjectionData["SPCS27IL01"]

A Lambert conic conformal projection with ellipsoidal reference frame is used for states that extend in the east-west direction:

GeoProjectionData["SPCS27TN00"]

The ellipsoidal oblique Mercator projection is used for Alaska:

GeoProjectionData["SPCS27AK01"]

OpenersExampleSection5(Spacer1)Neat Examples  (1)

GeoGraphics[GeoRange->{{-70,40},{-140,-74}},GeoProjection->{"VerticalPerspective","Centering"->{41.5,-74,0.725}},GeoGridLines->Quantity[5,"AngularDegrees"],GeoGridLinesStyle->Directive[Thin,Opacity[0.5],Black],GeoRangePadding->Full,GeoBackground->GeoStyling["ReliefMap"],Background->Black,PlotRangePadding->{{0.03,0},{0.05,0}}]

({{DocumentationFooterIconsRelatedFunction.png, ({{See Also}, {(RefLink[GeoGridPosition, paclet:ref/GeoGridPosition])  ▪  (RefLink[GeoProjection, paclet:ref/GeoProjection])  ▪  (RefLink[GeoGraphics, paclet:ref/GeoGraphics])  ▪  (RefLink[GeoPosition, paclet:ref/GeoPosition])  ▪  (RefLink[GeodesyData, paclet:ref/GeodesyData])  ▪  (RefLink[CountryData, paclet:ref/CountryData])}})}})

({{DocumentationFooterIconsRelatedTutorial.png, ({{Tutorials}, {▪(RefLinkPlain[GeoGraphics, paclet:tutorial/GeoGraphics])}})}})

({{DocumentationFooterIconsRelatedGuide.png, ({{Related Guides}, {▪(RefLinkPlain[Maps & Cartography, paclet:guide/MapsAndCartography])}, {▪(RefLinkPlain[Earth Sciences: Data & Computation, paclet:guide/EarthSciencesDataAndComputation])}, {▪(RefLinkPlain[Geodesy, paclet:guide/Geodesy])}})}})