({{, (RefLink[GeoProjection, paclet:ref/GeoProjection]) 
is an option for (RefLink[GeoGraphics, paclet:ref/GeoGraphics]) that specifies the cartographic projection to use for the map.}})

OpenersNotesSection(Spacer1)Details

(RefLink[GeoProjection, paclet:ref/GeoProjection]) can use any projection "proj" or {"proj",params}, where "proj" is any of the entities of (RefLink[GeoProjectionData, paclet:ref/GeoProjectionData]) and params are parameter rules like "StandardParallels"->{33,60}. (RefLink[GeoProjectionData, paclet:ref/GeoProjectionData])["proj"] gives the default values of the parameters for the projection "proj".

(RefLink[GeoGraphics, paclet:ref/GeoGraphics])[…,GeoProjection->Automatic] chooses a projection automatically. It will be "Mercator" for small scales, "LambertAzimuthal" for intermediate scales, and "Equirectangular" for large scales. It also chooses the "Centering" and "GridOrigin" parameters automatically.

The projection is applied to the geo background of the (RefLink[GeoGraphics, paclet:ref/GeoGraphics]) map, as well as to its geo primitives, like (RefLink[GeoPath, paclet:ref/GeoPath]) or (RefLink[GeoDisk, paclet:ref/GeoDisk]).

(RefLink[AbsoluteOptions, paclet:ref/AbsoluteOptions]) can be used to give explicit projection information for a (RefLink[GeoProjection, paclet:ref/GeoProjection]) with (RefLink[Automatic, paclet:ref/Automatic]) setting.

OpenersPrimaryExamplesSection(Spacer1)Examples  (11)

OpenersExampleSection0(Spacer1)Basic Examples  (5)

A world map is shown by default in the equirectangular projection:

GeoGraphics[GeoRange->"World"]

Use the Albers projection with default parameters:

GeoGraphics[GeoRange->"World",GeoProjection->"Albers"]

Use the Albers projection with custom parameters and draw the standard parallels:

GeoGraphics[{GeoPath[{"Parallel",30}],GeoPath[{"Parallel",50}]},GeoRange->"World",GeoProjection->{"Albers","Centering"->GeoPosition[{40,-90}],"StandardParallels"->{30,50}}]

Maps of Canada in different projections, all with a 10-degree graticule:

mapCanada[proj_]:=GeoGraphics[{EdgeForm[Black],Polygon[Entity["Country","Canada"]]},GeoProjection->proj,GeoGridLines->Quantity[10,"AngularDegrees"]]

mapCanada["Mercator"]

mapCanada["Bonne"]

mapCanada["CylindricalEqualArea"]

The near side of the Moon:

GeoGraphics[GeoRange->All,GeoModel->(Entity["Moon", Entity["PlanetaryMoon","Moon"], "Entity[\"PlanetaryMoon\", \"Moon\"]", "planetary moon"]),GeoProjection->"Orthographic",GeoGridLines->Automatic,GeoGridLinesStyle->White,Background->Black,PlotRangePadding->0.2]

OpenersExampleSection1(Spacer1)Scope  (3)

Perform projections with default or automatic parameters:

GeoGraphics[{Polygon[(Entity["Sweden", Entity["Country","Sweden"], "Entity[\"Country\", \"Sweden\"]", "country"])]},GeoProjection->"Orthographic"]

Find out which parameters were used for the projection:

AbsoluteOptions[%,GeoProjection]

Specify your own projection parameters:

GeoGraphics[{Polygon[Entity["Country","Sweden"]]},GeoProjection->{"Orthographic","Centering"->GeoPosition[{0,-40}]},Background->Black]

Project geo primitives with different projections:

a={40,-120};
b={60,-60};
c=(a+b)/2

prims={GeoStyling[Opacity[.2]],Orange,GeoDisk[c,Quantity[1000,"Kilometers"]],Blue,GeoPath[{a,b}],Point[GeoPosition[c]]};

In the equirectangular projection, the disk center is in the middle of the end points of the geodesic path:

GeoGraphics[prims,GeoProjection->"Equirectangular"]

In the Lambert azimuthal projection, the geodesic looks almost straight and the geo disk circular:

GeoGraphics[prims,GeoProjection->"LambertAzimuthal"]

OpenersExampleSection3(Spacer1)Properties & Relations  (2)

When no explicit projection is requested, one is automatically chosen:

GeoGraphics[{
Polygon[(EntityClass["Europe", EntityClass["Country","Europe"], "EntityClass[\"Country\", \"Europe\"]", "countries"])],
GeoStyling[Opacity[.2]],Red,Polygon[(Entity["Spain", Entity["Country","Spain"], "Entity[\"Country\", \"Spain\"]", "country"])]
},Frame->True,GeoProjection->Automatic]

AbsoluteOptions[%,GeoProjection]

When one or more non-geo graphic primitives appear and no projection is explicitly requested, the equirectangular projection is always used:

GeoGraphics[{
Polygon[(EntityClass["Europe", EntityClass["Country","Europe"], "EntityClass[\"Country\", \"Europe\"]", "countries"])],
GeoStyling[Opacity[.2]],
Red,Polygon[(Entity["Spain", Entity["Country","Spain"], "Entity[\"Country\", \"Spain\"]", "country"])],
Blue,Opacity[.5],Disk[{10,50},10]
},Frame->True,GeoProjection->Automatic]

AbsoluteOptions[%,GeoProjection]

Use (RefLink[GeoDisk, paclet:ref/GeoDisk]), (RefLink[Line, paclet:ref/Line])[{(RefLink[GeoPosition, paclet:ref/GeoPosition])[…], …}], etc. to place correctly projected primitives on the map:

GeoGraphics[{
Polygon[(EntityClass["Europe", EntityClass["Country","Europe"], "EntityClass[\"Country\", \"Europe\"]", "countries"])],
GeoStyling[Opacity[.2]],
Red,Polygon[(Entity["Spain", Entity["Country","Spain"], "Entity[\"Country\", \"Spain\"]", "country"])],
Blue,EdgeForm[],GeoDisk[{50,10},(QuantityUnit[1000])]
},Frame->True,GeoProjection->Automatic]

AbsoluteOptions[%,GeoProjection]

Alternatively, specify a projection explicitly to combine primitives with regular graphics on the same coordinate scale as projected geo graphics:

GeoGraphics[{
Polygon[(EntityClass["Europe", EntityClass["Country","Europe"], "EntityClass[\"Country\", \"Europe\"]", "countries"])],
GeoStyling[Opacity[.2]],Polygon[(Entity["Spain", Entity["Country","Spain"], "Entity[\"Country\", \"Spain\"]", "country"])],
Blue,EdgeForm[],GeoDisk[{50,10},(QuantityUnit[1000])],
Red,Polygon[(Entity["Spain", Entity["Country","Spain"], "Entity[\"Country\", \"Spain\"]", "country"])],
Blue,Opacity[.5],Disk[{10,50},10]
},Frame->True,GeoProjection->"CylindricalEqualArea"]

Study geo projection distortion of the graticules, the grid of lines of constant latitude and longitude:

worldGraticule[proj_]:=GeoGraphics[GeoRange->"World",GeoBackground->None,GeoGridLines->Quantity[5,"AngularDegrees"],GeoProjection->proj]

worldGraticule["Equirectangular"]

worldGraticule["Mercator"]

worldGraticule["Bonne"]

worldGraticule["Albers"]

worldGraticule["WinkelTripel"]

worldGraticule["Mollweide"]

worldGraticule["Orthographic"]

OpenersExampleSection4(Spacer1)Neat Examples  (1)

Use the gnomonic projection to map the surface of the Earth onto the faces of a polyhedron:

PolyhedronProjection[polyhedron_]:=Module[{pts3D,center,pts2D,proj,pts2Dprojected,geographics,plotrange,pts2Dscaled,rescale},
rescale[{x_,y_},{xs_,ys_}]:={Rescale[x,xs],Rescale[y,ys]};
Graphics3D[{
pts3D=First[#];
center=Mean[pts3D];
center=GeoPosition[GeoPositionXYZ[center,Norm[center]]];
pts2D=GeoPosition[GeoPositionXYZ[pts3D,Norm[pts3D[[1]]]]];
proj={"Gnomonic","Centering"->center};
pts2Dprojected=Most/@GeoGridPosition[pts2D,proj][[1]];
geographics=GeoGraphics[{Opacity[0],center,GeoPath[pts2D[[1]],CurveClosed->True]},GeoProjection->proj,GeoZoomLevel->1];
plotrange=PlotRange/.AbsoluteOptions[geographics,PlotRange];
pts2Dscaled=rescale[#,plotrange]&/@pts2Dprojected;
{Texture[ImageData[Rasterize[geographics[[1]],"Image"]]],Polygon[pts3D,VertexTextureCoordinates->pts2Dscaled]}}&/@N@Flatten[PolyhedronData[polyhedron,"Faces","Polygon"]],Lighting->"Neutral",Boxed->False,Method->{"ShrinkWrap"->True},ImageSize->Small]]

Project onto a dodecahedron:

PolyhedronProjection["Dodecahedron"]

Project onto an icosahedron:

PolyhedronProjection["Icosahedron"]

({{DocumentationFooterIconsRelatedFunction.png, ({{See Also}, {(RefLink[GeoProjectionData, paclet:ref/GeoProjectionData])  ▪  (RefLink[GeoGraphics, paclet:ref/GeoGraphics])  ▪  (RefLink[GeoGridLines, paclet:ref/GeoGridLines])  ▪  (RefLink[GeoGridPosition, paclet:ref/GeoGridPosition])  ▪  (RefLink[GeodesyData, paclet:ref/GeodesyData])  ▪  (RefLink[GeoPosition, paclet:ref/GeoPosition])  ▪  (RefLink[ViewProjection, paclet:ref/ViewProjection])}})}})

({{DocumentationFooterIconsRelatedTutorial.png, ({{Tutorials}, {▪(RefLinkPlain[GeoGraphics, paclet:tutorial/GeoGraphics])}})}})

({{DocumentationFooterIconsRelatedGuide.png, ({{Related Guides}, {▪(RefLinkPlain[Maps & Cartography, paclet:guide/MapsAndCartography])}})}})

({{(Spacer1), ({{(Spacer1)Related Links}, {(WebLink[DocumentationFooterIconsRelatedLinks-EIWL.png(Spacer1)An Elementary Introduction to the Wolfram Language, https://www.wolfram.com/language/elementary-introduction/18-geocomputation.html])(WebLink[: Geocomputation, https://www.wolfram.com/language/elementary-introduction/18-geocomputation.html])}})}})