({{, (RefLink[GeneralizedLinearModelFit, paclet:ref/GeneralizedLinearModelFit])[{(Subscript[y, 1]),(Subscript[y, 2]),…},{(Subscript[f, 1]),(Subscript[f, 2]),…},x] 
constructs a generalized linear model of the form (g^(-1))((Subscript[β, 0])+(Subscript[β, 1])(Subscript[f, 1])+(Subscript[β, 2])(Subscript[f, 2])+…) that fits the (Subscript[y, i]) for successive x values 1, 2, ….}, {, (RefLink[GeneralizedLinearModelFit, paclet:ref/GeneralizedLinearModelFit])[{{(Subscript[x, 11]),(Subscript[x, 12]),…,(Subscript[y, 1])},{(Subscript[x, 21]),(Subscript[x, 22]),…,(Subscript[y, 2])},…},{(Subscript[f, 1]),(Subscript[f, 2]),…},{(Subscript[x, 1]),(Subscript[x, 2]),…}]
constructs a generalized linear model of the form (g^(-1))((Subscript[β, 0])+(Subscript[β, 1])(Subscript[f, 1])+(Subscript[β, 2])(Subscript[f, 2])+…) where the (Subscript[f, i]) depend on the variables (Subscript[x, k]).}, {, (RefLink[GeneralizedLinearModelFit, paclet:ref/GeneralizedLinearModelFit])[{m,v}]
constructs a generalized linear model from the design matrix m and response vector v.}})

OpenersNotesSection(Spacer1)Details and Options

(RefLink[GeneralizedLinearModelFit, paclet:ref/GeneralizedLinearModelFit]) returns a symbolic (RefLink[FittedModel, paclet:ref/FittedModel]) object to represent the generalized linear model it constructs. The properties and diagnostics of the model can be obtained from model["property"].

The value of the best-fit function from (RefLink[GeneralizedLinearModelFit, paclet:ref/GeneralizedLinearModelFit]) at a particular point (Subscript[x, 1]), … can be found from model[(Subscript[x, 1]),…].

With data in the form {{(Subscript[x, 11]),(Subscript[x, 12]),… ,(Subscript[y, 1])},{(Subscript[x, 21]),(Subscript[x, 22]),… ,(Subscript[y, 2])},…}, the number of coordinates (Subscript[x, i1]), (Subscript[x, i2]), … should correspond to the number of variables (Subscript[x, i]).

Data in the form {(Subscript[y, 1]),(Subscript[y, 2]),…} is equivalent to data in the form {{1,(Subscript[y, 1])},{2,(Subscript[y, 2])},…}.

(RefLink[GeneralizedLinearModelFit, paclet:ref/GeneralizedLinearModelFit]) produces a generalized linear model of the form (OverHat[y])==(g^(-1))((Subscript[β, 0])+(Subscript[β, 1])(Subscript[f, 1])+(Subscript[β, 2])(Subscript[f, 2])+…) under the assumption that the original (Subscript[y, i]) are independent observations following an exponential family distribution with mean (Subscript[(OverHat[y]), i]) and the function g being an invertible link function.

(RefLink[GeneralizedLinearModelFit, paclet:ref/GeneralizedLinearModelFit]) takes the following options:

With the setting (RefLink[IncludeConstantBasis, paclet:ref/IncludeConstantBasis])->(RefLink[False, paclet:ref/False]), a model of the form (g^(-1))((Subscript[β, 1])(Subscript[f, 1])+(Subscript[β, 2])(Subscript[f, 2])+…) is fitted.

With the setting (RefLink[LinearOffsetFunction, paclet:ref/LinearOffsetFunction])->h, a model of the form (g^(-1))(h((Subscript[x, 1]), (Subscript[x, 2]), …) +(Subscript[β, 0])+(Subscript[β, 1])(Subscript[f, 1])+(Subscript[β, 2])(Subscript[f, 2])+…) is fitted.

With (RefLink[ConfidenceLevel, paclet:ref/ConfidenceLevel])->p, probability-p confidence intervals are computed for parameter and prediction intervals.

With the setting (RefLink[DispersionEstimatorFunction, paclet:ref/DispersionEstimatorFunction])->f, the common dispersion is estimated by f[y,(OverHat[y]),w] where y={(Subscript[y, 1]),(Subscript[y, 2]),…} is the list of observations, (OverHat[y])={(Subscript[(OverHat[y]), 1]),(Subscript[(OverHat[y]), 2]),…} is the list of predicted values, and w={(Subscript[w, 1]),(Subscript[w, 2]),…} is the list of weights for the measurements (Subscript[y, i]).

Possible settings for (RefLink[ExponentialFamily, paclet:ref/ExponentialFamily]) include: "Gaussian", "Binomial", "Poisson", "Gamma", "InverseGaussian", or "QuasiLikelihood".

Properties related to data and the fitted function obtained using model["property"] include:

Properties related to dispersion and model deviances include:

Types of residuals include:

Properties and diagnostics for parameter estimates include:

Properties related to influence measures include:

Properties of predicted values include:

Properties that measure goodness of fit include:

In (RefLink[GeneralizedLinearModelFit, paclet:ref/GeneralizedLinearModelFit])[m,v], the design matrix m is formed from the values of basis functions (Subscript[f, i]) at data points in the form {{(Subscript[f, 1]),(Subscript[f, 2]),…},{(Subscript[f, 1]),(Subscript[f, 2]),…},…}. The response vector v is the list of responses {(Subscript[y, 1]),(Subscript[y, 2]),…}.

For a design matrix m and response vector v, the model is (OverHat[v])==(g^(-1)) (m. β), where β is the vector of parameters to be estimated.

When a design matrix is used, the basis functions (Subscript[f, i]) can be specified using the form (RefLink[GeneralizedLinearModelFit, paclet:ref/GeneralizedLinearModelFit])[{m,v},{(Subscript[f, 1]),(Subscript[f, 2]),…}].

OpenersPrimaryExamplesSection(Spacer1)Examples  (30)

OpenersExampleSection0(Spacer1)Basic Examples  (1)

Define a dataset:

data={{.5,1},{1,0},{3,2},{5,3},{8,20}};

Fit a log-linear Poisson model to the data:

glm=GeneralizedLinearModelFit[data,x,x,ExponentialFamily->"Poisson"]

See the functional forms of the model:

Normal[glm]

Evaluate the model at a point:

glm[1.5]

Plot the data points and the models:

Show[ListPlot[data],Plot[glm[x],{x,0,8}]]

Compute and plot the deviance residuals for the model:

glm["DevianceResiduals"]

ListPlot[%,Filling->Axis]

OpenersExampleSection1(Spacer1)Scope  (11)

Fit a model of more than one variable:

data=Flatten[Table[{x,y,1/(x+y+RandomReal[])},{x,5},{y,5}],1];

GeneralizedLinearModelFit[data,{x,y},{x,y},ExponentialFamily->"Gamma"]

Normal[%]

Fit data to a linear combination of functions of predictor variables:

GeneralizedLinearModelFit[data,{Sin[x],Cos[y]},{x,y},ExponentialFamily->"Gamma"]//Normal

Fit a model with categorical predictor variables:

data={{a,1},{b,2},{a,1.8},{b,2.5}};

nom=GeneralizedLinearModelFit[data,x,x,NominalVariables->x,ExponentialFamily->"InverseGaussian"]

Obtain a deviance table for the model:

nom["DevianceTable"]

Fit a model given a design matrix and response vector:

dm={{1,1},{1,2},{1,3},{1,4}};
resp={1,3,6,10};

GeneralizedLinearModelFit[{dm,resp},ExponentialFamily->"Poisson"]

See the functional form:

Normal[%]

Fit the model referring to the basis functions as x and y:

GeneralizedLinearModelFit[{dm,resp},{x,y},ExponentialFamily->"Poisson"]//Normal

Obtain a list of available properties for a generalized linear model:

glm=GeneralizedLinearModelFit[Range[10],x^2,x,ExponentialFamily->"Gamma"]

glm["Properties"]

OpenersExampleSubsection0(Spacer1)Properties  (7)

OpenersExampleSubsubsection0(Spacer1)Data & Fitted Functions  (1)

Fit a generalized linear model:

data=Block[{i,j},Table[{i=RandomReal[{1,5}],j=RandomReal[{1,5}],RandomReal[InverseGaussianDistribution[1/Sqrt[5i+2j],10]]},{10}]];

glm=GeneralizedLinearModelFit[data,{x,y},{x,y},ExponentialFamily->"InverseGaussian"]

Extract the original data:

glm["Data"]

Obtain and plot the best fit:

{fit = glm["BestFit"],Show[Plot3D[fit,{x,1,5},{y,1,5}],Graphics3D[{PointSize[0.025],Point[glm["Data"]]}]]}

Obtain the fitted function as a pure function:

glm["Function"]

Get the design matrix and response vector for the fitting:

MatrixForm/@glm[{"DesignMatrix","Response"}]

OpenersExampleSubsubsection1(Spacer1)Residuals  (1)

Examine residuals for a fit:

glm=GeneralizedLinearModelFit[RandomReal[10,{100,3}],{x,y},{x,y},ExponentialFamily->"Gamma"]

{fr,ar,spr}=glm[{"FitResiduals","StandardizedPearsonResiduals","AnscombeResiduals"}];

Visualize the raw residuals:

ListPlot[fr]

Visualize Anscombe residuals and standardized Pearson residuals in stem plots:

Map[ListPlot[#,Filling->0]&,{ar,spr}]//Row

OpenersExampleSubsubsection2(Spacer1)Dispersion and Deviances  (1)

Fit a gamma regression model to some data:

data=Flatten[Table[{x,y,1/(1.2+3.7x+4.1y+RandomReal[{-2,2}])},{x,RandomReal[{1,5},10]},{y,RandomReal[{1,5},10]}],1];glm=GeneralizedLinearModelFit[data,{x,y},{x,y},ExponentialFamily->"Gamma"]

Obtain the estimated dispersion:

glm["EstimatedDispersion"]

Plot the deviances for each point:

ListPlot[glm["Deviances"],Filling->0]

Obtain the analysis of a deviance table:

glm["DevianceTable"]

Get the residual deviances from the table:

glm["DevianceTableResidualDeviances"]

Extract the numeric entries from the table:

vals=glm["DevianceTableEntries"]

Use (RefLink[Grid, paclet:ref/Grid]) to add formatting:

Grid[Join[{{"","d.f.","dev.","res.\nd.f.","res.\ndev."}},Join[{{""},{"x"},{"y"}},Map[PadLeft[#,4,SpanFromLeft]&,vals],2]]]

OpenersExampleSubsubsection3(Spacer1)Parameter Estimation Diagnostics  (1)

Obtain a formatted table of parameter information:

data=Table[{i,RandomInteger[BinomialDistribution[20,.05+i/30+Sin[i]/10]]/20},{i,1,20,.2}];
glm=GeneralizedLinearModelFit[data,{x,Sin[x],Cos[x]},x,ExponentialFamily->"Binomial"];

glm["ParameterTable"]

Extract the column of z-statistic values:

glm["ParameterZStatistics"]

Get the unformatted array of values from the table:

vals=glm["ParameterTableEntries"]

Add formatting using (RefLink[Grid, paclet:ref/Grid]):

Grid[Join[{{f,(OverHat[β]),(OverHat[σ]),z,P[Abs[Z]>Abs[z]]}},Join[{{1},{x},{Sin[x]},{Cos[x]}},vals,2]],Dividers->{GrayLevel[.5],GrayLevel[.5]}]//TraditionalForm

Add formatting via (RefLink[TableForm, paclet:ref/TableForm]):

TableForm[vals,TableHeadings->{{1,(Subscript[f, 1]),(Subscript[f, 2]),(Subscript[f, 3])},{(OverHat[β]),(OverHat[σ]),z,P[Abs[Z]>Abs[z]]}}]//TraditionalForm

OpenersExampleSubsubsection4(Spacer1)Influence Measures  (1)

Fit some data containing extreme values to a logit model:

data=Table[{i,1/(1+Exp[2+4i-Log[i]+RandomReal[]])},{i,RandomReal[{1,10},20]}];
data[[{3,8},-1]]=1-data[[{3,8},-1]];
glm=GeneralizedLinearModelFit[data,{x,Log[x]},x,ExponentialFamily->"Binomial"]

Check Cook distances to identify highly influential points:

ListPlot[glm["CookDistances"],PlotRange->{0,All},Filling->0]

Check the diagonal elements of the hat matrix to assess influence of points on the fitting:

ListPlot[glm["HatDiagonal"],PlotRange->{0,All},Filling->0]

OpenersExampleSubsubsection5(Spacer1)Prediction Values  (1)

Fit an inverse Gaussian model:

data=Flatten[Table[{x,y,1/Sqrt[1+.3x+.5y+RandomReal[]]},{x,RandomReal[5,3]},{y,RandomReal[5,3]}],1];glm=GeneralizedLinearModelFit[data,{x,y},{x,y},ExponentialFamily->"InverseGaussian"]

Plot the predicted values against the observed values:

ListPlot[Transpose[glm[{"Response","PredictedResponse"}]],FrameLabel->{"observed","predicted"},Frame->True,Axes->False]

OpenersExampleSubsubsection6(Spacer1)Goodness-of-Fit Measures  (1)

Obtain a table of goodness-of-fit measures for a log-linear Poisson model:

data=Flatten[Table[{i,j,RandomReal[5],RandomInteger[PoissonDistribution[Exp[-.3i-2j]]]},{i,RandomReal[5,5]},{j,RandomReal[5,5]}],1];

glm=GeneralizedLinearModelFit[data,{x,y,z},{x,y,z},ExponentialFamily->"Poisson"]

Grid[Transpose[{#,glm[#]}&[{"AIC","BIC","LikelihoodRatioIndex","PearsonChiSquare"}]],Alignment->Left]

Compute goodness-of-fit measures for all subsets of predictor variables:

sub=Table[Join[{i},GeneralizedLinearModelFit[data,i,{x,y,z},ExponentialFamily->"Poisson"][{"AIC","BIC","LikelihoodRatioIndex","PearsonChiSquare"}]],{i,Subsets[{x,y,z}]}]

Rank the models by AIC:

Grid[Join[{{"Model","AIC","BIC","LikelihoodRatioIndex","PearsonChiSquare"}},SortBy[sub,-#[[2]]&]]]

OpenersExampleSection2(Spacer1)Generalizations & Extensions  (1)

Perform other mathematical operations on the functional form of the model:

data=Table[{i,1/Sqrt[RandomReal[{i-1,i}]]},{i,10}];
glm=GeneralizedLinearModelFit[data,x,x,ExponentialFamily->"InverseGaussian"]

Integrate symbolically and numerically:

Integrate[glm[x],x]

NIntegrate[glm[x],{x,1,5}]

Find a predictor value that gives a particular value for the model:

FindRoot[glm[x]==.5,{x,5}]

OpenersExampleSection3(Spacer1)Options  (10)

OpenersExampleSubsection1(Spacer1)ConfidenceLevel  (1)

The default gives 95% confidence intervals:

data={{0,1},{1,1.5},{3,2},{5,4}};

glm=GeneralizedLinearModelFit[data,x,x,ExponentialFamily->"InverseGaussian"]

glm["ParameterConfidenceIntervals"]

Use 99% intervals instead:

glm=GeneralizedLinearModelFit[data,x,x,ExponentialFamily->"InverseGaussian",ConfidenceLevel->.99]

glm["ParameterConfidenceIntervals"]

Set the level to 90% within (RefLink[FittedModel, paclet:ref/FittedModel]):

glm["ParameterConfidenceIntervals",ConfidenceLevel->.9]

OpenersExampleSubsection2(Spacer1)CovarianceEstimatorFunction  (1)

Fit a generalized linear model:

data={{0,1},{1,1.5},{3,2},{5,4}};

glm=GeneralizedLinearModelFit[data,x,x,ExponentialFamily->"InverseGaussian"]

Compute the covariance matrix using the expected information matrix:

glm["CovarianceMatrix"]

Use the observed information matrix instead:

glm["CovarianceMatrix",CovarianceEstimatorFunction->"ObservedInformation"]

OpenersExampleSubsection3(Spacer1)DispersionEstimatorFunction  (1)

Fit a binomial model:

data={{1,0},{1,1},{1,1},{2,0},{2,0},{2,1},{2,1},{2,1},{2,1}};

logit=GeneralizedLinearModelFit[data,x,x,ExponentialFamily->"Binomial"]

Compute the covariance matrix:

logit["CovarianceMatrix"]

Compute the covariance matrix estimating the dispersion by Pearson's (χ^2):

logit["CovarianceMatrix",DispersionEstimatorFunction->"PearsonChiSquare"]

OpenersExampleSubsection4(Spacer1)ExponentialFamily  (1)

data={{0,1},{1,1.5},{3,2},{5,4}};

Fit data to a simple linear regression model:

GeneralizedLinearModelFit[data,x,x]//Normal

Fit to a canonical gamma regression model:

GeneralizedLinearModelFit[data,x,x,ExponentialFamily->"Gamma"]//Normal

Fit to a canonical inverse Gaussian regression model:

GeneralizedLinearModelFit[data,x,x,ExponentialFamily->"InverseGaussian"]//Normal

OpenersExampleSubsection5(Spacer1)IncludeConstantBasis  (1)

Fit a simple linear regression model:

data={{0,1},{1,0},{3,2},{5,4}};

GeneralizedLinearModelFit[data,x,x]

Fit the linear model with intercept zero:

GeneralizedLinearModelFit[data,x,x,IncludeConstantBasis->False]

OpenersExampleSubsection6(Spacer1)LinearOffsetFunction  (1)

Fit data to a canonical gamma regression model:

data={{0,1},{1,1.5},{3,2},{5,4}};

GeneralizedLinearModelFit[data,x,x,ExponentialFamily->"Gamma"]//Normal

Fit data to a gamma regression model with a known (RefLink[Sqrt, paclet:ref/Sqrt])[x] term:

GeneralizedLinearModelFit[data,x,x,ExponentialFamily->"Gamma",LinearOffsetFunction->(Sqrt[#]&)]//Normal

OpenersExampleSubsection7(Spacer1)LinkFunction  (1)

data={{0,1},{1,0},{3,2},{5,4}};

Fit a Poisson model with canonical (RefLink[Log, paclet:ref/Log]) link:

GeneralizedLinearModelFit[data,x,x,ExponentialFamily->"Poisson"]//Normal

Use a named link:

GeneralizedLinearModelFit[data,x,x,ExponentialFamily->"Poisson",LinkFunction->"IdentityLink"]//Normal

Use a pure function for a shifted (RefLink[Sqrt, paclet:ref/Sqrt]) link:

GeneralizedLinearModelFit[data,x,x,ExponentialFamily->"Poisson",LinkFunction->(Sqrt[#1+1]&)]//Normal

OpenersExampleSubsection8(Spacer1)NominalVariables  (1)

data={{a,0,1},{b,2,2},{a,2,1.8},{b,0,2.5}};

Fit the data treating the first variable as a nominal variable:

nom=GeneralizedLinearModelFit[data,{x,y},{x,y},NominalVariables->x,ExponentialFamily->"Gamma"]

Normal[nom]

Treat both variables as nominal:

GeneralizedLinearModelFit[data,{x,y},{x,y},NominalVariables->All,ExponentialFamily->"Gamma"]//Normal

OpenersExampleSubsection9(Spacer1)Weights  (1)

Fit a model using equal weights:

GeneralizedLinearModelFit[Range[10]^2,x,x]//Normal

Give explicit weights for the data points:

GeneralizedLinearModelFit[Range[10]^2,x,x,Weights->1/Range[10]]//Normal

OpenersExampleSubsection10(Spacer1)WorkingPrecision  (1)

Use (RefLink[WorkingPrecision, paclet:ref/WorkingPrecision]) to get higher precision in parameter estimates:

data=Table[{x,1/(x+x^2)},{x,10}]

glm=GeneralizedLinearModelFit[data,x,x,ExponentialFamily->"Gamma",WorkingPrecision->25]

Obtain the fitted function:

glm["BestFit"]

Reduce the precision in property computations after the fitting:

glm["BestFit",WorkingPrecision->MachinePrecision]

OpenersExampleSection4(Spacer1)Applications  (2)

Simulate some probability data:

data=BlockRandom[SeedRandom[1];RandomReal[{.8,1},20]Table[(x-1)/(1+x),{x,20}]];

Fit and visually compare binomial generalized linear models with a variety of link functions:

models=Map[Tooltip[Normal[GeneralizedLinearModelFit[data,{x,x^2},x,ExponentialFamily->"Binomial",LinkFunction->#]]]&,{"LogitLink","ProbitLink","LogLogLink","LogComplementLink","ComplementaryLogLogLink","OddsPowerLink"}];

Show[ListPlot[data,PlotRange->All],Plot[models,{x,1,20}]]

Fit count data from a contingency table to a Poisson log-linear model:

data={{groupA,agree,15},{groupA,disagree,66},{groupB,disagree,63},{groupB,disagree,90},{groupC,agree,92},{groupC,disagree,46}};

model=GeneralizedLinearModelFit[data,{var1,var2},{var1,var2},NominalVariables->All,ExponentialFamily->"Poisson"];

Display counts, predicted values, and standardized residuals in a tabular form:

Style[Grid[Join[{{"","Agree","Disagree"}},Join[{{"Group A"},{"Group B"},{"Group C"}},Partition[Map[Column[#,Alignment->{Center}]&,Transpose[model[{"Response","PredictedResponse","StandardizedPearsonResiduals"}]]],2],2]],Dividers->All],"DialogStyle"]

OpenersExampleSection5(Spacer1)Properties & Relations  (5)

(RefLink[DesignMatrix, paclet:ref/DesignMatrix]) constructs the design matrix used by (RefLink[GeneralizedLinearModelFit, paclet:ref/GeneralizedLinearModelFit]):

data=Table[{i,RandomReal[]},{i,5}]

DesignMatrix[data,x,x]//MatrixForm

glm=GeneralizedLinearModelFit[data,x,x];

glm["DesignMatrix"]//MatrixForm

By default, (RefLink[GeneralizedLinearModelFit, paclet:ref/GeneralizedLinearModelFit]) and (RefLink[LinearModelFit, paclet:ref/LinearModelFit]) fit equivalent models:

data=Table[{i,RandomReal[{i-1,i}]},{i,10}];

GeneralizedLinearModelFit[data,x,x]

LinearModelFit[data,x,x]

A default "Binomial" model is equivalent to the model for (RefLink[LogitModelFit, paclet:ref/LogitModelFit]):

data=Table[{i,RandomReal[{i-1,i}]/10},{i,10}];

GeneralizedLinearModelFit[data,x,x,ExponentialFamily->"Binomial"]//Normal

LogitModelFit[data,x,x]//Normal

(RefLink[ProbitModelFit, paclet:ref/ProbitModelFit]) is equivalent to a "Binomial" model with "ProbitLink":

GeneralizedLinearModelFit[data,x,x,ExponentialFamily->"Binomial",LinkFunction->"ProbitLink"]//Normal

ProbitModelFit[data,x,x]//Normal

(RefLink[GeneralizedLinearModelFit, paclet:ref/GeneralizedLinearModelFit]) will use the time stamps of a (RefLink[TimeSeries, paclet:ref/TimeSeries]) as variables:

ts1=TimeSeries[];

ts1["Times"]

GeneralizedLinearModelFit[ts1,x,x,ExponentialFamily->"Gamma"]

Rescale the time stamps and fit again:

ts2=TimeSeriesRescale[ts1,{.1,2}]

ts2["Times"]

GeneralizedLinearModelFit[ts2,x,x,ExponentialFamily->"Gamma"]

Find fit for the values:

GeneralizedLinearModelFit[ts1["Values"],x,x,ExponentialFamily->"Gamma"]

(RefLink[GeneralizedLinearModelFit, paclet:ref/GeneralizedLinearModelFit]) acts pathwise on a multipath (RefLink[TemporalData, paclet:ref/TemporalData]):

GeneralizedLinearModelFit[TemporalData[],x,x,ExponentialFamily->"Gamma"]

({{DocumentationFooterIconsRelatedFunction.png, ({{See Also}, {(RefLink[FittedModel, paclet:ref/FittedModel])  ▪  (RefLink[LogitModelFit, paclet:ref/LogitModelFit])  ▪  (RefLink[ProbitModelFit, paclet:ref/ProbitModelFit])  ▪  (RefLink[LinearModelFit, paclet:ref/LinearModelFit])  ▪  (RefLink[NonlinearModelFit, paclet:ref/NonlinearModelFit])  ▪  (RefLink[TimeSeriesModelFit, paclet:ref/TimeSeriesModelFit])  ▪  (RefLink[Fit, paclet:ref/Fit])  ▪  (RefLink[LeastSquares, paclet:ref/LeastSquares])  ▪  (RefLink[FindFit, paclet:ref/FindFit])}})}})

({{DocumentationFooterIconsRelatedTutorial.png, ({{Tutorials}, {▪(RefLinkPlain[Statistical Model Analysis, paclet:tutorial/StatisticalModelAnalysis])}})}})

({{DocumentationFooterIconsRelatedGuide.png, ({{Related Guides}, {▪(RefLinkPlain[Statistical Model Analysis, paclet:guide/StatisticalModelAnalysis])}, {▪(RefLinkPlain[Statistical Data Analysis, paclet:guide/Statistics])}, {▪(RefLinkPlain[Scientific Data Analysis, paclet:guide/ScientificDataAnalysis])}, {▪(RefLinkPlain[Numerical Data, paclet:guide/NumericalData])}})}})