({{, (RefLink[FactorialMomentGeneratingFunction, paclet:ref/FactorialMomentGeneratingFunction])[dist,t] 
gives the factorial moment-generating function for the distribution dist as a function of the variable t. }, {, (RefLink[FactorialMomentGeneratingFunction, paclet:ref/FactorialMomentGeneratingFunction])[dist,{(Subscript[t, 1]),(Subscript[t, 2]),…}]
gives the factorial moment-generating function for the multivariate distribution dist as a function of the variables (Subscript[t, 1]), (Subscript[t, 2]), …. }})

OpenersNotesSection(Spacer1)Details

(RefLink[FactorialMomentGeneratingFunction, paclet:ref/FactorialMomentGeneratingFunction]) is also known as probability generating function (pgf).

(RefLink[FactorialMomentGeneratingFunction, paclet:ref/FactorialMomentGeneratingFunction])[dist,t] is equivalent to (RefLink[Expectation, paclet:ref/Expectation])[(t^x),x\[Distributed]dist].

(RefLink[FactorialMomentGeneratingFunction, paclet:ref/FactorialMomentGeneratingFunction])[dist, {(Subscript[t, 1]),(Subscript[t, 2]),…}] is equivalent to (RefLink[Expectation, paclet:ref/Expectation])[((Subscript[t, 1])^(Subscript[x, 1]))((Subscript[t, 2])^(Subscript[x, 2]))…,{(Subscript[x, 1]),(Subscript[x, 2]),…}\[Distributed]dist].

The i(^th) factorial moment can be extracted from a factorial moment-generating function fmgf through (RefLink[SeriesCoefficient, paclet:ref/SeriesCoefficient])[fmgf,{t,1,i}]i!.

The probability for a discrete random variable to assume the value i can be extracted from a factorial moment-generating function expr through (RefLink[SeriesCoefficient, paclet:ref/SeriesCoefficient])[expr,{t,0,i}].

OpenersPrimaryExamplesSection(Spacer1)Examples  (19)

OpenersExampleSection0(Spacer1)Basic Examples  (3)

The factorial moment-generating function (fmgf) for a univariate discrete distribution:

FactorialMomentGeneratingFunction[PoissonDistribution[μ],t]

Compute an fmgf for a continuous univariate distribution:

FactorialMomentGeneratingFunction[NormalDistribution[μ,σ],t]

The fmgf for a multivariate distribution:

FactorialMomentGeneratingFunction[MultinomialDistribution[n,{p1,p2,p3}],{t1,t2,t3}]

OpenersExampleSection1(Spacer1)Scope  (5)

Find the factorial moment-generating function (fmgf) for a discrete formula distribution:

FactorialMomentGeneratingFunction[ProbabilityDistribution[((18^(-k))/(Sqrt[6])) Binomial[4k,2k],{k,0,Infinity,1}],t]

Compute the fmgf for data distribution:

FactorialMomentGeneratingFunction[EmpiricalDistribution[{1,2,3,3,4,5,5}],t]

Find the fmgf for a censored distribution:

FactorialMomentGeneratingFunction[CensoredDistribution[{0,10},PoissonDistribution[2]],t]

Compute the fmgf for parameter mixture distribution:

FactorialMomentGeneratingFunction[ParameterMixtureDistribution[PoissonDistribution[λ],λ\[Distributed]ExponentialDistribution[μ]],t]

Find the fmgf for the slice distribution of a random process:

FactorialMomentGeneratingFunction[PoissonProcess[μ][s],t]

OpenersExampleSection3(Spacer1)Applications  (6)

Find the fmgf for the sum of n i.i.d. geometric variates:

FactorialMomentGeneratingFunction[GeometricDistribution[p],t]^n

Compare with the fmgf of (RefLink[NegativeBinomialDistribution, paclet:ref/NegativeBinomialDistribution]):

FactorialMomentGeneratingFunction[NegativeBinomialDistribution[n,p],t]

%-%%

Find the fmgf of the sum of a random number n of i.i.d. geometric random variates, assuming n follows (RefLink[PoissonDistribution, paclet:ref/PoissonDistribution]):

Expectation[FactorialMomentGeneratingFunction[GeometricDistribution[p],t]^n,n\[Distributed]PoissonDistribution[μ]]

Compare with the fmgf of (RefLink[PolyaAeppliDistribution, paclet:ref/PolyaAeppliDistribution]):

FactorialMomentGeneratingFunction[PolyaAeppliDistribution[μ(1-p),1-p],t]

Simplify[%/%%]

Find the (RefLink[PDF, paclet:ref/PDF]) of a non-negative integer random variate from its fmgf:

fmgf[t_]=((((2-t))^3)/(((4-3 t))^5));

Use the probability generating function interpretation:

pdf=SeriesCoefficient[fmgf[z],{z,0,k},Assumptions->k≥0]

Show the probability mass function:

DiscretePlot[pdf,{k,0,25},FillingStyle->Gray]

Verify normalization:

Sum[pdf,{k,0,Infinity}]

Construct a probability generating function for (RefLink[BernoulliDistribution, paclet:ref/BernoulliDistribution]):

bpgf[z_]=FactorialMomentGeneratingFunction[BernoulliDistribution[p],z]

Construct its Lagrange transformation, and use it as a new probability generating function:

{pgf[z_]}=u/.Solve[u==z bpgf[u],u] //Simplify

Compare it with the probability generating function of a shifted (RefLink[GeometricDistribution, paclet:ref/GeometricDistribution]):

FactorialMomentGeneratingFunction[TransformedDistribution[x+1,x\[Distributed]GeometricDistribution[1-p]],z]

Apply a Lagrange transformation to the probability generating function (pgf) of (RefLink[GeometricDistribution, paclet:ref/GeometricDistribution]):

gpgf[z_]=FactorialMomentGeneratingFunction[GeometricDistribution[p],z]

u/.Solve[u==z gpgf[u]&&0<p<1&&0<u<1&&0<z<1,u,Reals]

{hpgf[z_]}=Refine[%,0<p<1&&0<z<1]

Reconstruct (RefLink[PDF, paclet:ref/PDF]):

pdf=SeriesCoefficient[hpgf[z],{z,0,k},Assumptions->0<p<1]//FullSimplify

The resulting distribution is known as Haight's distribution. It is only normalized to 1 for 0.5<p<1:

Sum[pdf,{k,1,Infinity},Assumptions->0<p<1]

Show the probability mass function:

DiscretePlot[pdf/.p->5/9,{k,0,10}]

Find the distribution of the number of times a biased coin should be flipped until heads appear twice in a row. Let p be the probability of heads. Event space is comprised of three types of events: tail (T), head then tail (HT), and two heads in a row (HH) with probabilities:

pr["T"]=(1-p);
pr["HT"]=p(1-p);
pr["HH"]=p^2;

Find the fmgf of the random variate of interest, interpreting it as the total of the number of T events added to double the number of HT events plus 2:

fmgf=t^2FactorialMomentGeneratingFunction[NegativeMultinomialDistribution[1,{pr["T"],pr["HT"]}],{t,(t^2)}]

Reconstruct (RefLink[PDF, paclet:ref/PDF]):

pdf=SeriesCoefficient[fmgf,{t,0,k},Assumptions->k≥0]

Compute mean:

mean=Limit[D[fmgf,t],t->1]//Simplify

Find variance using relation:

MomentConvert[CentralMoment[2],FactorialMoment]

variance=Factor[Limit[D[fmgf,{t,2}],t->1]+mean(1-mean)]

OpenersExampleSection4(Spacer1)Properties & Relations  (3)

(RefLink[FactorialMomentGeneratingFunction, paclet:ref/FactorialMomentGeneratingFunction]) is equivalent to (RefLink[Expectation, paclet:ref/Expectation]) of (t^x):

Expectation[t^n,n\[Distributed]GeometricDistribution[p]]

FactorialMomentGeneratingFunction[GeometricDistribution[p],t]

Simplify[%-%%,t>0]

For non-negative discrete variates, the fmgf is the probability generating function (pgf):

FactorialMomentGeneratingFunction[GeometricDistribution[p],z]

Sum[PDF[GeometricDistribution[p],k](z^k),{k,0,Infinity}]

Simplify[%==%%]

The factorial moments can be extracted from the factorial moment-generating function:

𝒟=HypergeometricDistribution[n,m,nt];

D[FactorialMomentGeneratingFunction[𝒟, t], {t, 3}]/.t->1

FactorialMoment[𝒟, 3]//Refine[#,nt≥3]&

%%-%//Simplify

Alternatively, use (RefLink[SeriesCoefficient, paclet:ref/SeriesCoefficient]):

SeriesCoefficient[3!FactorialMomentGeneratingFunction[𝒟, t],{t,1,3}]

FactorialMoment[𝒟,3]//Refine[#,nt≥3]&

%%-%//Simplify

OpenersExampleSection5(Spacer1)Possible Issues  (2)

For some distributions with long tails, factorial moments of only several low orders are defined:

FactorialMoment[BetaNegativeBinomialDistribution[7,11,13],r]

Correspondingly, the factorial moment-generating function is not defined:

FactorialMomentGeneratingFunction[BetaNegativeBinomialDistribution[7,11,13],t]

(RefLink[FactorialMomentGeneratingFunction, paclet:ref/FactorialMomentGeneratingFunction]) is not always known in closed form:

FactorialMomentGeneratingFunction[WalleniusHypergeometricDistribution[n,m,nt,w],t]

({{DocumentationFooterIconsRelatedFunction.png, ({{See Also}, {(RefLink[FactorialMoment, paclet:ref/FactorialMoment])  ▪  (RefLink[Expectation, paclet:ref/Expectation])  ▪  (RefLink[CharacteristicFunction, paclet:ref/CharacteristicFunction])  ▪  (RefLink[MomentGeneratingFunction, paclet:ref/MomentGeneratingFunction])  ▪  (RefLink[CentralMomentGeneratingFunction, paclet:ref/CentralMomentGeneratingFunction])  ▪  (RefLink[CumulantGeneratingFunction, paclet:ref/CumulantGeneratingFunction])  ▪  (RefLink[GeneratingFunction, paclet:ref/GeneratingFunction])}})}})

({{DocumentationFooterIconsRelatedGuide.png, ({{Related Guides}, {▪(RefLinkPlain[Statistical Distribution Functions, paclet:guide/StatisticalDistributionFunctions])}, {▪(RefLinkPlain[Statistical Moments and Generating Functions, paclet:guide/StatisticalMomentsAndGeneratingFunctions])}})}})