({{, (RefLink[ExponentialPowerDistribution, paclet:ref/ExponentialPowerDistribution])[κ,μ,σ] 
represents an exponential power distribution with shape parameter κ, location parameter μ, and scale parameter σ.}, {, (RefLink[ExponentialPowerDistribution, paclet:ref/ExponentialPowerDistribution])[κ]
represents an exponential power distribution with location parameter 0 and scale parameter 1.}})

OpenersNotesSection(Spacer1)Details

(RefLink[ExponentialPowerDistribution, paclet:ref/ExponentialPowerDistribution]) is also known as generalized normal distribution.

The probability density for value x in an exponential power distribution is proportional to exp(-(((Abs[x-μ])^κ)/(κ (σ^κ)))).

(RefLink[ExponentialPowerDistribution, paclet:ref/ExponentialPowerDistribution]) allows κ and σ to be any positive real numbers and μ to be any real number.

(RefLink[ExponentialPowerDistribution, paclet:ref/ExponentialPowerDistribution]) allows μ and σ to be any quantities of the same unit dimensions, and κ to be a dimensionless quantity. »

(RefLink[ExponentialPowerDistribution, paclet:ref/ExponentialPowerDistribution]) can be used with such functions as (RefLink[Mean, paclet:ref/Mean]), (RefLink[CDF, paclet:ref/CDF]), and (RefLink[RandomVariate, paclet:ref/RandomVariate]).

OpenersPrimaryExamplesSection(Spacer1)Examples  (19)

OpenersExampleSection0(Spacer1)Basic Examples  (4)

Probability density function:

Plot[Table[PDF[ExponentialPowerDistribution[κ,1,3],x],{κ,{1/2,1.5,6}}]//Evaluate,{x,-5,8},Filling->Axis,Exclusions->None]

Plot[Table[PDF[ExponentialPowerDistribution[3,μ,.8],x],{μ,{-1/2,1,2}}]//Evaluate,{x,-3,5},Filling->Axis,Exclusions->None]

Plot[Table[PDF[ExponentialPowerDistribution[3,1,σ],x],{σ,{0.7,1.1,2}}]//Evaluate,{x,-3,5},Filling->Axis,Exclusions->None]

PDF[ExponentialPowerDistribution[κ,μ,σ],x]

Cumulative distribution function:

Plot[Table[CDF[ExponentialPowerDistribution[κ,1,3],x],{κ,{1/2,1.5,6}}]//Evaluate,{x,-5,8},Filling->Axis,Exclusions->None]

Plot[Table[CDF[ExponentialPowerDistribution[3,μ,.8],x],{μ,{-1/2,1,2}}]//Evaluate,{x,-3,5},Filling->Axis,Exclusions->None]

Plot[Table[CDF[ExponentialPowerDistribution[3,1,σ],x],{σ,{0.7,1.1,2}}]//Evaluate,{x,-3,5},Filling->Axis,Exclusions->None]

CDF[ExponentialPowerDistribution[κ,μ,σ],x]

Mean and variance:

Mean[ExponentialPowerDistribution[κ,μ,σ]]

Variance[ExponentialPowerDistribution[κ,μ,σ]]

Median:

Median[ExponentialPowerDistribution[κ,μ,σ]]

OpenersExampleSection1(Spacer1)Scope  (8)

Generate a sample of pseudorandom numbers from an exponential power distribution:

data=RandomVariate[ExponentialPowerDistribution[3,1,2],10^4];

Compare its histogram to the PDF:

Show[
Histogram[data,20,"PDF"],
Plot[PDF[ExponentialPowerDistribution[3,1,2],x],{x,Min[data],Max[data]},PlotStyle->Thick]]

Distribution parameters estimation:

sample=RandomVariate[ExponentialPowerDistribution[2,1,3],10^3];

Estimate the distribution parameters from sample data:

edist=EstimatedDistribution[sample, ExponentialPowerDistribution[k,μ,σ]]

Compare the density histogram of the sample with the PDF of the estimated distribution:

Show[Histogram[sample,Automatic,"PDF"],Plot[PDF[edist,x],{x,Min[sample],Max[sample]},PlotStyle->Thick]]

Exponential power distribution is symmetric:

Skewness[ExponentialPowerDistribution[κ,μ,σ]]

Kurtosis depends only on the shape parameter κ:

Plot[Kurtosis[ExponentialPowerDistribution[κ,μ,σ]],{κ,0,10},Filling->Axis]

Kurtosis[ExponentialPowerDistribution[κ,μ,σ]]

The limiting value for kurtosis:

Limit[Kurtosis[ExponentialPowerDistribution[κ,μ,σ]],κ->∞]

Different moments with closed forms as functions of parameters:

FormulaGrid[list_,type_]:=Grid[Transpose[{list}],Alignment->{Left,Automatic},Background->{None,{{Lighter[Blend[Switch[type,M,{Blue,Green},CM,{Red,Orange},FM,{Magenta,Cyan},C,{Purple,Red}]],.8],White}}},Dividers->{None,{Darker[Gray,.6],{False},Darker[Gray,.6]}},ItemSize->30]

(RefLink[Moment, paclet:ref/Moment]):

FormulaGrid[Table[Moment[ExponentialPowerDistribution[κ,μ,σ],k],{k,5}],M]

(RefLink[CentralMoment, paclet:ref/CentralMoment]):

FormulaGrid[Table[CentralMoment[ExponentialPowerDistribution[κ,μ,σ],k],{k,5}],CM]

(RefLink[FactorialMoment, paclet:ref/FactorialMoment]):

FormulaGrid[Table[FactorialMoment[ExponentialPowerDistribution[κ,μ,σ],k]//Simplify,{k,5}],FM]

(RefLink[Cumulant, paclet:ref/Cumulant]):

FormulaGrid[Table[Cumulant[ExponentialPowerDistribution[κ,μ,σ],k],{k,5}],C]

Hazard function has a different shape depending on the parameter κ:

Plot[Table[HazardFunction[ExponentialPowerDistribution[κ,3,2],x],{κ,{1/2,2,6}}]//Evaluate,{x,-5,5},Filling->Axis,Exclusions->None]

Quantile function:

Plot[Table[Quantile[ExponentialPowerDistribution[κ,3,.2],q],{κ,{0.5,1,3}}]//Evaluate,{q,0,1},Exclusions->None,Filling->Axis]

Quantile[ExponentialPowerDistribution[κ,μ,σ],q]

Consistent use of (RefLink[Quantity, paclet:ref/Quantity]) in parameters yields (RefLink[QuantityDistribution, paclet:ref/QuantityDistribution]):

len𝒟=ExponentialPowerDistribution[(QuantityPostfix[3, "%", percent, "Percent"]),(Quantity[5.2, "yd", yards, "Yards"]),(Quantity[10, "yd", yards, "Yards"])]

Find (RefLink[QuartileDeviation, paclet:ref/QuartileDeviation]):

QuartileDeviation[len𝒟]

OpenersExampleSection2(Spacer1)Applications  (1)

(RefLink[ExponentialPowerDistribution, paclet:ref/ExponentialPowerDistribution]) can be used as a smooth approximation to the distribution of the length of a random vector from (RefLink[DirichletDistribution, paclet:ref/DirichletDistribution]):

len𝒟=TransformedDistribution[Sqrt[u^2+v^2],{u,v}\[Distributed]DirichletDistribution[{3,2,1}]];

Probability density function:

pdf=PDF[len𝒟,x]

Create a sample:

lens=RandomVariate[len𝒟,10^4];

Fit exponential power distribution to the data:

edist=EstimatedDistribution[lens,ExponentialPowerDistribution[κ,μ,σ],ParameterEstimator->{"MaximumLikelihood", MaxIterations->500}]

Compare the histogram of the sample with the PDFs of both distributions:

Show[Histogram[lens,20,"PDF"],Plot[{PDF[edist,x],pdf},{x,0,1},PlotRange->All,PlotStyle->Thick,PlotLegends->{"exponential power","length of Dirichlet vector"}]]

Compare means:

{Mean[len𝒟],Mean[edist]}

N[%]

OpenersExampleSection3(Spacer1)Properties & Relations  (5)

Exponential power distribution is closed under translation and scaling by a positive factor:

TransformedDistribution[a*u+loc,u\[Distributed]ExponentialPowerDistribution[κ,μ,σ]]

(RefLink[ExponentialPowerDistribution, paclet:ref/ExponentialPowerDistribution]) can be narrower or wider than (RefLink[NormalDistribution, paclet:ref/NormalDistribution]), depending on the value of the shape parameter κ:

{mean,sd}={Mean[ExponentialPowerDistribution[κ,μ,σ]],StandardDeviation[ExponentialPowerDistribution[κ,μ,σ]]}

Block[{μ=0,σ=4},Table[Plot[{PDF[NormalDistribution[mean,sd],x],PDF[ExponentialPowerDistribution[κ,μ,σ],x]},{x,-10,10},PlotRange->All,PlotLabel->"κ ="Text[κ]],{κ,{1.3,1.7,2.5,4}}]]

Relationships to other distributions:

(RefLink[LaplaceDistribution, paclet:ref/LaplaceDistribution]) is a special case of exponential power distribution:

CDF[ExponentialPowerDistribution[1,μ,β],x]

CDF[LaplaceDistribution[μ,β],x]

%-%%//FullSimplify

(RefLink[NormalDistribution, paclet:ref/NormalDistribution]) is a special case of (RefLink[ExponentialPowerDistribution, paclet:ref/ExponentialPowerDistribution]):

PDF[ExponentialPowerDistribution[2,μ,σ],x]

PDF[NormalDistribution[μ,σ],x]

%-%%//FullSimplify

OpenersExampleSection4(Spacer1)Neat Examples  (1)

PDFs for different κ values with CDF contours:

dist=ExponentialPowerDistribution[κ,2,1];cdf=Function[{x,κ},Evaluate[CDF[dist,x]]];
ql={0.025,0.10,0.25,0.5,0.75,0.90,0.975};
cl=Table[ColorData["Rainbow"][q],{q,Join[{0.0},ql]}];

Legended[Plot3D[PDF[dist,x],{x,-2,7},{κ,0.2,4},PlotTheme->"Marketing",MeshFunctions->{cdf},Mesh->{ql},MeshStyle->GrayLevel[0.8],MeshShading->cl,AxesLabel->Automatic,BaseStyle->Opacity[0.9],ImageSize->400,PlotRange->All],BarLegend["Rainbow",ql,LegendLabel->"prob"]]

({{DocumentationFooterIconsRelatedFunction.png, ({{See Also}, {(RefLink[NormalDistribution, paclet:ref/NormalDistribution])  ▪  (RefLink[LaplaceDistribution, paclet:ref/LaplaceDistribution])  ▪  (RefLink[Erfc, paclet:ref/Erfc])}})}})

({{DocumentationFooterIconsRelatedGuide.png, ({{Related Guides}, {▪(RefLinkPlain[Exponential-Related Distributions, paclet:guide/ExponentialRelatedDistributions])}})}})