({{, (RefLink[ExponentialDistribution, paclet:ref/ExponentialDistribution])[λ] 
represents an exponential distribution with scale inversely proportional to parameter λ.}})

OpenersNotesSection(Spacer1)Details

The probability density for value x in an exponential distribution is proportional to (e^(-λx)) for x>0, and is zero for x<0. »

(RefLink[ExponentialDistribution, paclet:ref/ExponentialDistribution]) allows λ to be any positive real number.

(RefLink[ExponentialDistribution, paclet:ref/ExponentialDistribution]) allows λ to be a quantity of any unit dimension. »

(RefLink[ExponentialDistribution, paclet:ref/ExponentialDistribution]) can be used with such functions as (RefLink[Mean, paclet:ref/Mean]), (RefLink[CDF, paclet:ref/CDF]), and (RefLink[RandomVariate, paclet:ref/RandomVariate]). »

OpenersPrimaryExamplesSection(Spacer1)Examples  (54)

OpenersExampleSection0(Spacer1)Basic Examples  (4)

Probability density function:

Plot[Table[PDF[ExponentialDistribution[λ],x],{λ,{1/2,1,2}}]//Evaluate,{x,0,3},Filling->Axis,PlotRange->All]

PDF[ExponentialDistribution[λ],x]

Cumulative distribution function:

Plot[Table[CDF[ExponentialDistribution[λ],x],{λ,{1/2,1,2}}]//Evaluate,{x,0,4},Filling->Axis]

CDF[ExponentialDistribution[λ],x]

Mean and variance:

Mean[ExponentialDistribution[λ]]

Variance[ExponentialDistribution[λ]]

Median:

Median[ExponentialDistribution[λ]]

OpenersExampleSection1(Spacer1)Scope  (7)

Generate a sample of pseudorandom numbers from an exponential distribution:

data=RandomVariate[ExponentialDistribution[3.5],10^4];

Compare its histogram to the PDF:

Show[
Histogram[data,{0,2,0.1},"PDF"],
Plot[PDF[ExponentialDistribution[3.5],x],{x,0,2},PlotStyle->Thick,PlotRange->{0,3}]]

Distribution parameters estimation:

sample=RandomVariate[ExponentialDistribution[5],10^3];

Estimate the distribution parameters from sample data:

edist=EstimatedDistribution[sample,ExponentialDistribution[λ]]

Compare the density histogram of the sample with the PDF of the estimated distribution:

Show[Histogram[sample,Automatic,"PDF"],Plot[PDF[edist,x],{x,0,1.2},PlotStyle->Thick]]

Skewness and kurtosis are constant:

Skewness[ExponentialDistribution[λ]]

Kurtosis[ExponentialDistribution[λ]]

Different moments with closed forms as functions of parameters:

FormulaGrid[list_,type_]:=Grid[Transpose[{list}],Alignment->{Left,Automatic},Background->{None,{{Lighter[Blend[Switch[type,M,{Blue,Green},CM,{Red,Orange},FM,{Magenta,Cyan},C,{Purple,Red}]],.8],White}}},Dividers->{None,{Darker[Gray,.6],{False},Darker[Gray,.6]}},ItemSize->30]

(RefLink[Moment, paclet:ref/Moment]):

FormulaGrid[Table[Moment[ExponentialDistribution[λ],r],{r,5}],M]

Closed form for symbolic order:

Moment[ExponentialDistribution[λ],r]

(RefLink[CentralMoment, paclet:ref/CentralMoment]):

FormulaGrid[Table[CentralMoment[ExponentialDistribution[λ],r],{r,5}],CM]

Closed form for symbolic order:

CentralMoment[ExponentialDistribution[λ],r]

(RefLink[FactorialMoment, paclet:ref/FactorialMoment]):

FormulaGrid[Table[FactorialMoment[ExponentialDistribution[λ],r],{r,5}],FM]

(RefLink[Cumulant, paclet:ref/Cumulant]):

FormulaGrid[Table[Cumulant[ExponentialDistribution[λ],r],{r,5}],C]

Closed form for symbolic order:

Cumulant[ExponentialDistribution[λ],r]

Hazard function of exponential distribution is constant and depends on the parameter λ:

HazardFunction[ExponentialDistribution[λ],x]

Quantile function:

Plot[Table[Quantile[ExponentialDistribution[λ],q],{λ,{0.5,1,3}}]//Evaluate,{q,0,1},Filling->Axis]

Quantile[ExponentialDistribution[λ],q]

Consistent use of (RefLink[Quantity, paclet:ref/Quantity]) in parameters yields (RefLink[QuantityDistribution, paclet:ref/QuantityDistribution]):

serviceTime𝒟=ExponentialDistribution[(Quantity[25, "per ""month", reciprocal months, (1/("Months"))])]

Convert to days:

UnitConvert[serviceTime𝒟,"Days"]//N

Find the median service time:

Median[%]

OpenersExampleSection2(Spacer1)Applications  (9)

A battery has a lifespan that is exponentially distributed with rate parameter 1/3000 per hour. Find the probability that a random battery has a lifespan of less than 2500 hours:

Probability[t<(Quantity[2500., "h", hours, "Hours"]),t\[Distributed] ExponentialDistribution[1/(Quantity[3000, "h", hours, "Hours"])]]

Compute directly using the CDF:

CDF[ExponentialDistribution[1/(Quantity[3000, "h", hours, "Hours"])],(Quantity[2500., "h", hours, "Hours"])]

A relay has an exponentially distributed lifetime with a failure rate of λ=0.002` failures per year. In order to estimate warranty costs, estimate the number of relays out of 10000 that will fail in the first six months of use. The failure rate is also known as the hazard rate:

HazardFunction[ExponentialDistribution[λ],1]->(Quantity[0.002, "per ""year", reciprocal years, (1/("Years"))])

Hence the lifetime distribution (in years) for relays is:

relayLifeDistribution=ExponentialDistribution[λ]/.%

The probability of failure within the first six months:

p=NProbability[t<Quantity[6,"Months"],t\[Distributed]relayLifeDistribution]

The expected number of failures within the first six months in the batch of 10000 relays:

Mean[BinomialDistribution[10000,p]]

A product has a time to failure that is exponentially distributed with parameter λ=1/2 (yr^(-1)). Find the product's reliability at 1, 2, and 3 years. Reliability is another name for (RefLink[SurvivalFunction, paclet:ref/SurvivalFunction]):

dist=ExponentialDistribution[(Quantity[(1/2), "per ""year", reciprocal years, (1/("Years"))])]

SurvivalFunction[dist][{(Quantity[1., "yr", years, "Years"]),(Quantity[2., "yr", years, "Years"]),(Quantity[3., "yr", years, "Years"])}]

The product's failure rate:

HazardFunction[dist,Quantity[t,"Years"]]

Suppose the lifetime of an appliance has an exponential distribution with average lifetime of 10 years. Find the appliance lifetime distribution:

{sol}=Solve[Mean[ExponentialDistribution[λ]]==(Quantity[10, "yr", years, "Years"]),λ]

applianceLifetime=ExponentialDistribution[λ]/.sol

Find the probability that a used appliance with (Subscript[t, 0]) years of use will not fail in the next 5 years:

Probability[t>(Quantity[t0, "yr", years, "Years"])+(Quantity[5. , "yr", years, "Years"])\[Conditioned]t>(Quantity[t0, "yr", years, "Years"]),t\[Distributed]applianceLifetime,Assumptions->t0>0]

Using the memoryless property of (RefLink[ExponentialDistribution, paclet:ref/ExponentialDistribution]):

Probability[t>(Quantity[5., "yr", years, "Years"]),t\[Distributed]applianceLifetime]

Assume the waiting time a customer spends in a restaurant is exponentially distributed with an average wait time of 5 minutes. Find the probability that the customer will have to wait more than 10 minutes:

waitTime𝒟=ExponentialDistribution[1/(Quantity[5, "min", minutes, "Minutes"])]

NProbability[t>(Quantity[10., "min", minutes, "Minutes"]),t\[Distributed]waitTime𝒟]

Find the probability that the customer has to wait an additional 10 minutes, given that he or she has already been waiting for at least 10 minutes (the past does not matter):

NProbability[t>(Quantity[10., "min", minutes, "Minutes"])+(Quantity[10., "min", minutes, "Minutes"])\[Conditioned]t>(Quantity[10, "min", minutes, "Minutes"]),t\[Distributed]waitTime𝒟]

The data contains waiting times in days between serious (magnitude at least 7.5 or over 1000 fatalities) earthquakes worldwide, recorded from 12/16/1902 to 3/4/1977:

earthquakesWaitingTimes=Quantity[ExampleData[{"Statistics","EarthquakeWaitingTimes"}],"Days"];

Fit (RefLink[ExponentialDistribution, paclet:ref/ExponentialDistribution]) to the data:

edist=EstimatedDistribution[earthquakesWaitingTimes,ExponentialDistribution[λ]]

Compare the histogram of the data with the PDF of the estimated distribution:

Show[Histogram[earthquakesWaitingTimes,15,"PDF",AxesLabel->Automatic],Plot[Evaluate@PDF[edist,Quantity[x,"Days"]],{x,0,2000},PlotStyle->Thick]]

Find the average number of days between major earthquakes:

Mean[edist]

Find the probability that two serious earthquakes occur within 100 days:

Probability[x≤Quantity[100,"Days"],x\[Distributed]edist]

Simulate times between the next 30 serious earthquakes occurring worldwide:

ListPlot[{RandomVariate[edist,30],{{0,Mean[edist]},{30,Mean[edist]}}},Filling->Axis,Joined->{False,True},AxesOrigin->{0,0},AxesLabel->Automatic]

Waiting times at a receiver for signals coming from four independent transmitters are exponentially distributed with parameters (Subscript[λ, 1]), (Subscript[λ, 2]), (Subscript[λ, 3]), and (Subscript[λ, 4]), respectively. Find the probability that the signal from the third transmitter arrives first to the receiver:

Probability[Min[u,v,w,z]==w,{u\[Distributed]ExponentialDistribution[λ1],v\[Distributed]ExponentialDistribution[λ2],w\[Distributed]ExponentialDistribution[λ3],z\[Distributed]ExponentialDistribution[λ4]}]

Find the distribution of the waiting time for any signal at the receiver:

𝒟=TransformedDistribution[Min[u,v,w,z],{u\[Distributed]ExponentialDistribution[λ1],v\[Distributed]ExponentialDistribution[λ2],w\[Distributed]ExponentialDistribution[λ3],z\[Distributed]ExponentialDistribution[λ4]}]

Find the average waiting time for any signal at the receiver:

Mean[𝒟]

Simulate the waiting time between signals arriving at the receiver for (Subscript[λ, 1])=1, (Subscript[λ, 2])=0.5`, (Subscript[λ, 3])=0.7`, and (Subscript[λ, 4])=0.3`:

Block[{λ1=1,λ2=0.5,λ3=0.7,λ4=0.3},ListPlot[{RandomVariate[𝒟,100],{{0,Mean[𝒟]},{100,Mean[𝒟]}}},Joined->{False,True},Filling->Axis,AxesOrigin->{0,0}]]

A system is composed of 4 independent components, each with lifespan exponentially distributed with parameter (10^(-3))per hour. Find the probability that no component fails before 500 hours:

Probability[t1>(Quantity[500, "h", hours, "Hours"])&&t2>(Quantity[500, "h", hours, "Hours"])&&t3>(Quantity[500, "h", hours, "Hours"])&&t4>(Quantity[500, "h", hours, "Hours"]),{t1,t2,t3,t4}\[Distributed]ProductDistribution[{ExponentialDistribution[1/(Quantity[1000, "h", hours, "Hours"])],4}]]

N[%]

Directly use (RefLink[SurvivalFunction, paclet:ref/SurvivalFunction]):

SurvivalFunction[ExponentialDistribution[1/(Quantity[1000, "h", hours, "Hours"])],(Quantity[500, "h", hours, "Hours"])]^4

Find the probability that exactly one component will fail in the first 1200 hours:

tmax=(Quantity[1200, "h", hours, "Hours"]);
Probability[Min[t1,t2,t3,t4]<tmax∧RankedMin[{t1,t2,t3,t4},2]>tmax,{t1,t2,t3,t4}\[Distributed]ProductDistribution[{ExponentialDistribution[1/(Quantity[1000, "h", hours, "Hours"])],4}]]

Directly use (RefLink[CDF, paclet:ref/CDF]) and (RefLink[SurvivalFunction, paclet:ref/SurvivalFunction]):

Binomial[4,1] CDF[ExponentialDistribution[1/(Quantity[1000, "h", hours, "Hours"])],(Quantity[1200, "h", hours, "Hours"])] SurvivalFunction[ExponentialDistribution[1/(Quantity[1000, "h", hours, "Hours"])],(Quantity[1200, "h", hours, "Hours"])]^3

N[%]

By using (RefLink[BooleanCountingFunction, paclet:ref/BooleanCountingFunction]), you can also define the logical condition:

ExactlyK[k_,v_]:=BooleanCountingFunction[{k},Length[v]]@@v

ExactlyK[1,{a,b,c,d}]//BooleanConvert

Probability[ExactlyK[1,{t1≤(Quantity[1200, "h", hours, "Hours"]),t2≤(Quantity[1200, "h", hours, "Hours"]),t3≤(Quantity[1200, "h", hours, "Hours"]),t4≤(Quantity[1200, "h", hours, "Hours"])}],{t1,t2,t3,t4}\[Distributed]ProductDistribution[{ExponentialDistribution[1/(Quantity[1000, "h", hours, "Hours"])],4}]]

N[%]

In an optical communication system, transmitted light generates current at the receiver. The number of electrons follows the parametric mixture of Poisson distribution and other distributions, depending on the type of light. If the source uses coherent laser light of intensity λ, then the electron count distribution is Poisson:

Bdist=TransformedDistribution[λ x,x\[Distributed]BernoulliDistribution[1]];

PDF[Bdist,x]

𝒟1=ParameterMixtureDistribution[PoissonDistribution[μ],μ\[Distributed]Bdist];

PDF[𝒟1,x]

Which is (RefLink[PoissonDistribution, paclet:ref/PoissonDistribution]):

PDF[PoissonDistribution[λ],x]

If the source uses thermal illumination, then the Poisson parameter follows (RefLink[ExponentialDistribution, paclet:ref/ExponentialDistribution]) with parameter 1/λ and the electron count distribution is:

𝒟2=ParameterMixtureDistribution[PoissonDistribution[μ],μ\[Distributed]ExponentialDistribution[1/λ]]//Simplify

These two distributions are distinguishable and allow the type of source to be determined:

Block[{λ=3},Histogram[{RandomVariate[𝒟1,10^3],RandomVariate[𝒟2,10^3]},Automatic,"PDF"]]

OpenersExampleSection3(Spacer1)Properties & Relations  (31)

Exponential distribution is closed under scaling by a positive factor:

TransformedDistribution[k*u,u\[Distributed]ExponentialDistribution[λ]]

The variance is the square of the mean:

Mean[ExponentialDistribution[λ]]^2

%-Variance[ExponentialDistribution[λ]]

The minimum of exponential distributions is exponentially distributed:

TransformedDistribution[Min[u,v],{u\[Distributed]ExponentialDistribution[(Subscript[λ, 1])],v\[Distributed]ExponentialDistribution[(Subscript[λ, 2])]}]

The minimum of n identically distributed variables:

OrderDistribution[{ExponentialDistribution[λ],n},1]

The exponential distribution is memoryless (the past does not matter):

Probability[x>ξ+p\[Conditioned]x>p,x\[Distributed]ExponentialDistribution[λ],Assumptions->ξ>0&&p>0]

Probability[x>ξ,x\[Distributed]ExponentialDistribution[λ],Assumptions->ξ>0]

%-%%

Relationships to other distributions:

(RefLink[BenktanderWeibullDistribution, paclet:ref/BenktanderWeibullDistribution]) reduces to a truncated (RefLink[ExponentialDistribution, paclet:ref/ExponentialDistribution]):

PDF[BenktanderWeibullDistribution[a,1],x]

PDF[TruncatedDistribution[{1,Infinity},ExponentialDistribution[a]],x]

FullSimplify[%-%%,x>1]

Shifted (RefLink[ExponentialDistribution, paclet:ref/ExponentialDistribution]) is a (RefLink[BenktanderWeibullDistribution, paclet:ref/BenktanderWeibullDistribution]):

TransformedDistribution[u+1,u\[Distributed]ExponentialDistribution[λ]]

Exponential distribution is a limit of a scaled (RefLink[BetaDistribution, paclet:ref/BetaDistribution]):

𝒟=TransformedDistribution[u n,u\[Distributed]BetaDistribution[1,n]];

PDF[𝒟,x]

Limit[%,n->∞]

PDF[ExponentialDistribution[1],x]

FullSimplify[%-%%,x≠0]

(RefLink[PowerDistribution, paclet:ref/PowerDistribution]) is a transformation of an exponential distribution:

TransformedDistribution[Exp[-u]/k,u\[Distributed]ExponentialDistribution[λ]]

Exponential distribution can be obtained from (RefLink[PowerDistribution, paclet:ref/PowerDistribution]):

TransformedDistribution[-Log[X],X\[Distributed]PowerDistribution[1,a]]

Exponential distribution can be obtained from (RefLink[BetaDistribution, paclet:ref/BetaDistribution]):

TransformedDistribution[-Log[X],X\[Distributed]BetaDistribution[a,1]]

Sum of independent exponentially distributed random variables follows (RefLink[ErlangDistribution, paclet:ref/ErlangDistribution]):

TransformedDistribution[u+v+w,{u,v,w}\[Distributed]ProductDistribution[{ExponentialDistribution[λ],3}]]

For an arbitrary number of variables:

CharacteristicFunction[ExponentialDistribution[λ],t]^k

CharacteristicFunction[ErlangDistribution[k,λ],t]

%-%%//FullSimplify[#,Element[k,Integers]]&

(RefLink[ExponentialDistribution, paclet:ref/ExponentialDistribution])[1] can be transformed into an extreme value distributions family:

TransformedDistribution[α-β Log[u],u\[Distributed]ExponentialDistribution[1],Assumptions->α>0&&β>0]

TransformedDistribution[α+β Log[u],u\[Distributed]ExponentialDistribution[1],Assumptions->α>0&&β>0]

TransformedDistribution[β*1/u^(1/α),u\[Distributed]ExponentialDistribution[1],Assumptions->α>0&&β>0]

TransformedDistribution[β*u^(1/α),u\[Distributed]ExponentialDistribution[1],Assumptions->α>0&&β>0]

(RefLink[ExponentialDistribution, paclet:ref/ExponentialDistribution]) is a special case of (RefLink[WeibullDistribution, paclet:ref/WeibullDistribution]):

PDF[WeibullDistribution[1,1/λ],x]

PDF[ExponentialDistribution[λ],x]

%-%%//Simplify[#,x>0]&

(RefLink[ExponentialDistribution, paclet:ref/ExponentialDistribution]) is a special case of (RefLink[GammaDistribution, paclet:ref/GammaDistribution]):

PDF[GammaDistribution[1,1/λ],x]

PDF[ExponentialDistribution[λ],x]

%-%%//Simplify[#,x>0]&

The difference of two variates from the same exponential distribution follows (RefLink[LaplaceDistribution, paclet:ref/LaplaceDistribution]):

TransformedDistribution[u-v,{u,v}\[Distributed]ProductDistribution[{ExponentialDistribution[1/λ],2}]]

The difference of two different exponential distributions follows (RefLink[VarianceGammaDistribution, paclet:ref/VarianceGammaDistribution]):

TransformedDistribution[u-v,{u\[Distributed]ExponentialDistribution[ (Subscript[λ, 1])],v\[Distributed]ExponentialDistribution[(Subscript[λ, 2])]}]

Exponential distribution is a transformation of (RefLink[LaplaceDistribution, paclet:ref/LaplaceDistribution]):

TransformedDistribution[Abs[z-μ],z\[Distributed]LaplaceDistribution[μ,β]]

(RefLink[LogisticDistribution, paclet:ref/LogisticDistribution]) is a transformation from exponential distribution:

𝒟=TransformedDistribution[μ-β Log[Exp[-u]/(1-Exp[-u])],u\[Distributed]ExponentialDistribution[1]];

PDF[𝒟,x]//Simplify[#,β>0]&

PDF[LogisticDistribution[μ,β],x]

FullSimplify[%-%%,β>0]

(RefLink[LogisticDistribution, paclet:ref/LogisticDistribution]) is a transformation of exponential distribution:

𝒟=TransformedDistribution[μ-β Log[u/v],{u,v}\[Distributed]ProductDistribution[{ExponentialDistribution[1],2}]];

PDF[𝒟,x]//Simplify[#,β>0]&

PDF[LogisticDistribution[μ,β],x]

FullSimplify[%-%%,β>0]

(RefLink[ParetoDistribution, paclet:ref/ParetoDistribution]) is a transformation of exponential distribution:

TransformedDistribution[k*Exp[u],u\[Distributed]ExponentialDistribution[α]]

Transformation of a (RefLink[ParetoDistribution, paclet:ref/ParetoDistribution]) yields an exponential distribution:

TransformedDistribution[Log[u/k],u\[Distributed]ParetoDistribution[k,λ]]

Exponential distribution is a special case of type 3 (RefLink[PearsonDistribution, paclet:ref/PearsonDistribution]):

PDF[PearsonDistribution[3,1,0,0,(1/λ),0],x]//Simplify[#,λ>0]&

PDF[ExponentialDistribution[λ],x]

%-%%//FullSimplify[#,λ>0&&x≠0]&

(RefLink[PowerDistribution, paclet:ref/PowerDistribution]) is a transformation of exponential distribution:

𝒟=TransformedDistribution[1/k Exp[- u],u\[Distributed]ExponentialDistribution[a]];

PDF[𝒟,x]//FullSimplify[#,k>0]&

PDF[PowerDistribution[k,a],x]

FullSimplify[%-%%,0<x<1/k]

Exponential distribution can be obtained from (RefLink[RayleighDistribution, paclet:ref/RayleighDistribution]):

𝒟=TransformedDistribution[1/2 u^2,u\[Distributed]RayleighDistribution[(Sqrt[1/λ])]];

PDF[𝒟,x]

PDF[ExponentialDistribution[λ],x]

%-%%

Exponential distribution is the limiting distribution of the n min((Subscript[x, 1]),…,(Subscript[x, n])) where (Subscript[x, i]) has (RefLink[UniformDistribution, paclet:ref/UniformDistribution]):

mindist=TransformedDistribution[n u,u\[Distributed]OrderDistribution[{UniformDistribution[{0,1}],n},1]];

CDF[mindist,x]

Limit[CDF[mindist,x],n->∞]

CDF[ExponentialDistribution[1],x]

%-%%//FullSimplify

The parametric mixture of (RefLink[PoissonDistribution, paclet:ref/PoissonDistribution]) and exponential distribution follows (RefLink[GeometricDistribution, paclet:ref/GeometricDistribution]):

ParameterMixtureDistribution[PoissonDistribution[μ],μ\[Distributed]ExponentialDistribution[1/λ]]//Simplify

(RefLink[KDistribution, paclet:ref/KDistribution]) can be obtained from (RefLink[ExponentialDistribution, paclet:ref/ExponentialDistribution]) and (RefLink[GammaDistribution, paclet:ref/GammaDistribution]):

TransformedDistribution[(Sqrt[u v]),{u\[Distributed]ExponentialDistribution[λ],v\[Distributed]GammaDistribution[α,β]}]

(RefLink[HoytDistribution, paclet:ref/HoytDistribution]) can be obtained from (RefLink[ExponentialDistribution, paclet:ref/ExponentialDistribution]) and (RefLink[ArcSinDistribution, paclet:ref/ArcSinDistribution]):

𝒟=TransformedDistribution[(2 q)/(1+q^2)(Sqrt[ω u v]),{u\[Distributed]ArcSinDistribution[{1/2 (1+q^2),1/2 (1+1/q^2)}],v\[Distributed]ExponentialDistribution[1]}];

Block[{q=.2,ω=3},Show[Histogram[RandomVariate[𝒟,10^4],20,"PDF"],Plot[PDF[HoytDistribution[q,ω],x],{x,0,6},PlotStyle->Thick]]]

(RefLink[ParetoDistribution, paclet:ref/ParetoDistribution]) can be obtained as a quotient of (RefLink[ExponentialDistribution, paclet:ref/ExponentialDistribution]) and (RefLink[ErlangDistribution, paclet:ref/ErlangDistribution]):

𝒟=TransformedDistribution[u/v,{u\[Distributed]ExponentialDistribution[λ],v\[Distributed]ErlangDistribution[n,λ]}];

PDF[𝒟,x]

PDF[ParetoDistribution[1,n,0],x]

FullSimplify[%-%%,x≠0]

(RefLink[ParetoDistribution, paclet:ref/ParetoDistribution]) can be obtained as a quotient of (RefLink[ExponentialDistribution, paclet:ref/ExponentialDistribution]) and (RefLink[GammaDistribution, paclet:ref/GammaDistribution]):

𝒟=TransformedDistribution[u/v,{u\[Distributed]ExponentialDistribution[λ],v\[Distributed]GammaDistribution[n,1/λ]}];

PDF[𝒟,x]

PDF[ParetoDistribution[1,n,0],x]

FullSimplify[%-%%,x≠0]

OpenersExampleSection4(Spacer1)Possible Issues  (2)

(RefLink[ExponentialDistribution, paclet:ref/ExponentialDistribution]) is not defined when λ is not a positive real number:

Mean[ExponentialDistribution[-1]]

Substitution of invalid parameters into symbolic outputs gives results that are not meaningful:

Mean[ExponentialDistribution[λ]]/.{λ->3+I}

OpenersExampleSection5(Spacer1)Neat Examples  (1)

PDFs for different λ values with CDF contours:

cdf=Function[{x,λ},Evaluate[CDF[ExponentialDistribution[λ],x]]];
ql={0.025,0.10,0.25,0.5,0.75,0.90,0.975};
cl=Table[ColorData["Rainbow"][q],{q,Join[{0.0},ql]}];

Legended[Plot3D[PDF[ExponentialDistribution[λ],x],{x,0,3},{λ,0.2,4},PlotTheme->"Marketing",MeshFunctions->{cdf},Mesh->{ql},MeshStyle->GrayLevel[0.8],MeshShading->cl,AxesLabel->Automatic,PlotPoints->100,BaseStyle->Opacity[0.9],ImageSize->400,PlotRange->{0,4}],BarLegend["Rainbow",ql,LegendLabel->"prob"]]

({{DocumentationFooterIconsRelatedFunction.png, ({{See Also}, {(RefLink[GammaDistribution, paclet:ref/GammaDistribution])  ▪  (RefLink[LaplaceDistribution, paclet:ref/LaplaceDistribution])  ▪  (RefLink[ErlangDistribution, paclet:ref/ErlangDistribution])}})}})

({{DocumentationFooterIconsRelatedTutorial.png, ({{Tutorials}, {▪(RefLinkPlain[Continuous Distributions, paclet:tutorial/ContinuousDistributions])}})}})

({{DocumentationFooterIconsRelatedGuide.png, ({{Related Guides}, {▪(RefLinkPlain[Queueing Processes, paclet:guide/QueueingProcesses])}, {▪(RefLinkPlain[Distributions in Reliability Analysis, paclet:guide/DistributionsUsedInReliabilityAnalysis])}, {▪(RefLinkPlain[Reliability, paclet:guide/Reliability])}, {▪(RefLinkPlain[Distributions Used in Actuarial Science, paclet:guide/DistributionsUsedInActuarialScience])}, {▪(RefLinkPlain[Exponential-Related Distributions, paclet:guide/ExponentialRelatedDistributions])}, {▪(RefLinkPlain[Actuarial Computation, paclet:guide/ActuarialComputation])}, {▪(RefLinkPlain[Parametric Statistical Distributions, paclet:guide/ParametricStatisticalDistributions])}, {▪(RefLinkPlain[Survival Analysis, paclet:guide/SurvivalAnalysis])}, {▪(RefLinkPlain[Distributions in Communication Systems, paclet:guide/DistributionsInCommunicationSystems])}, {▪(RefLinkPlain[Probability & Statistics with Quantities, paclet:guide/ProbabilityWithQuantities])}})}})