({{, (RefLink[EllipticThetaPrime, paclet:ref/EllipticThetaPrime])[a,u,q]
gives the derivative with respect to u of the theta function (Subscript[ϑ, a])(u,q)(a=1,…,4).}, {, (RefLink[EllipticThetaPrime, paclet:ref/EllipticThetaPrime])[a,q]
gives the theta constant (Subscript[θ, a])'(0,q).}})

OpenersNotesSection(Spacer1)Details

Mathematical function, suitable for both symbolic and numerical manipulation.

For certain special arguments, (RefLink[EllipticThetaPrime, paclet:ref/EllipticThetaPrime]) automatically evaluates to exact values.

(RefLink[EllipticThetaPrime, paclet:ref/EllipticThetaPrime]) can be evaluated to arbitrary numerical precision.

(RefLink[EllipticThetaPrime, paclet:ref/EllipticThetaPrime]) automatically threads over lists.

OpenersPrimaryExamplesSection(Spacer1)Examples  (26)

OpenersExampleSection0(Spacer1)Basic Examples  (3)

Evaluate numerically:

EllipticThetaPrime[2,2.3,1/3]

Plot[EllipticThetaPrime[2,x,1/3],{x,-6,6}]

Series expansion:

Series[EllipticThetaPrime[1,x,q],{q,0,10}]

OpenersExampleSection1(Spacer1)Scope  (15)

OpenersExampleSubsection0(Spacer1)Numerical Evaluation  (4)

Evaluate numerically:

EllipticThetaPrime[2,5,.5]

EllipticThetaPrime[1,.4,.5]

Evaluate to high precision:

N[EllipticThetaPrime[3,15,1/3],25]

The precision of the output tracks the precision of the input:

EllipticThetaPrime[3,8,.600055555555000055005]

Complex number inputs:

EllipticThetaPrime[2,.4+I,.5I]

Evaluate efficiently at high precision:

EllipticThetaPrime[2,5,.5`100]//Timing

EllipticThetaPrime[2,5,.5`10000];//Timing

OpenersExampleSubsection1(Spacer1)Specific Values   (3)

Value at zero:

EllipticThetaPrime[1,0,0]

(RefLink[EllipticThetaPrime, paclet:ref/EllipticThetaPrime]) evaluates symbolically for special arguments:

Table[EllipticThetaPrime[j, z,0],{j,4}]

Find a value of x for which (RefLink[EllipticThetaPrime, paclet:ref/EllipticThetaPrime])[3,x,1/2]=2:

xval=x/.FindRoot[EllipticThetaPrime[3,x,1/2]==2,{x,1}]//Quiet

Plot[EllipticThetaPrime[3,x,1/2],{x,-1,4},Epilog->{PointSize[Large],Red,Point[{xval,EllipticThetaPrime[3,xval,1/2]}]}]

OpenersExampleSubsection2(Spacer1)Visualization  (2)

Plot the (RefLink[EllipticThetaPrime, paclet:ref/EllipticThetaPrime]) function for various parameters:

Plot[{EllipticThetaPrime[1,x,1/2],EllipticThetaPrime[2,x,1/2],EllipticThetaPrime[3,x,1/2],EllipticThetaPrime[4,x,1/2]},{x,-5,5}]

Plot the real part of (EllipticThetaPrime[4, z, 1/3]):

ContourPlot[Re[EllipticThetaPrime[4,x+ I y,1/3]],{x,-5,5},{y,-5,5},Contours->24]

Plot the imaginary part of (EllipticThetaPrime[4, z, 1/3]):

ContourPlot[Im[EllipticThetaPrime[4,x+ I y,1/3]],{x,-5,5},{y,-5,5},Contours->24]

OpenersExampleSubsection3(Spacer1)Function Properties  (4)

Real and complex domains of (RefLink[EllipticThetaPrime, paclet:ref/EllipticThetaPrime]):

Table[FunctionDomain[EllipticThetaPrime[a,x,q],x],{a,4}]

Table[FunctionDomain[EllipticThetaPrime[a,z,q],z,Complexes],{a,4}]

(RefLink[EllipticThetaPrime, paclet:ref/EllipticThetaPrime]) is a periodic function with respect to z:

Table[FunctionPeriod[EllipticThetaPrime[a,z,q],z],{a,4}]

(RefLink[EllipticThetaPrime, paclet:ref/EllipticThetaPrime]) threads elementwise over lists:

EllipticThetaPrime[{1,2,3,4},z,q]

EllipticThetaPrime[2,{Pi/2,Pi},1/2]

(RefLink[TraditionalForm, paclet:ref/TraditionalForm]) formatting:

EllipticThetaPrime[3,z,q] // TraditionalForm

EllipticThetaPrime[a,q] // TraditionalForm

OpenersExampleSubsection4(Spacer1)Integration  (2)

Compute the indefinite integral using (RefLink[Integrate, paclet:ref/Integrate]):

Integrate[EllipticThetaPrime[a,u,q],u]

Verify the anti-derivative:

FullSimplify[D[%,u]]

Definite integral:

Integrate[EllipticThetaPrime[a,u,q],{u,0,5}]

OpenersExampleSection2(Spacer1)Generalizations & Extensions  (1)

(RefLink[EllipticThetaPrime, paclet:ref/EllipticThetaPrime]) can be applied to power series:

EllipticThetaPrime[2,z,Log[1+q]+((O[q])^4)]

OpenersExampleSection3(Spacer1)Applications  (3)

Solution of the 1D heat equation with Dirichlet boundary condition and initial condition T(x,0)=δ(x-(Subscript[x, 0])):

T[{x_,t_},x0_,L_]=1/(2L) (EllipticTheta[3,Pi/(2L) (x-x0),Exp[-Pi^2/L^2 t]]-EllipticTheta[3,Pi/(2L) (x+x0),Exp[-Pi^2/L^2 t]]);

Calculate the temperature gradient:

gradT[{x_,t_},x0_,L_]=D[T[{x,t},x0,L],x]

Plot the temperature gradient:

Plot3D[gradT[{x,t},0.6,1],{x,0,1},{t,0.01,0.1},PlotRange->All]

Electrostatic force in a NaCl-like crystal with point-like ions:

fNaCl[{x_, y_, z_}]:=16/Pi NIntegrate[{2 π t EllipticTheta[2,2 π y,(E^(-(t^2)))] EllipticTheta[2,2 π z,(E^(-(t^2)))]EllipticThetaPrime[2,2 π x,(E^(-(t^2)))],2 π t EllipticTheta[2,2 π x,(E^(-(t^2)))]EllipticTheta[2,2 π z,(E^(-(t^2)))] EllipticThetaPrime[2,2 π y,(E^(-(t^2)))],2 π t EllipticTheta[2,2 π x,(E^(-(t^2)))] EllipticTheta[2,2 π y,(E^(-(t^2)))]EllipticThetaPrime[2,2 π z,(E^(-(t^2)))]},{t,0,∞},PrecisionGoal->5]

Plot the magnitude of the force in a plane through the crystal:

ListPlot3D[Table[Norm[fNaCl[{x,y,0.3}]],{x,0,1,1/10},{y,0,1,1/10}]]//Quiet

The canonical rotational distribution function for linear molecules Ω(β)=(∑_(j=0)^∞)(2j+1)(e^(-β j (j+1))):

Ω[β_]:=(1/2)-(∫_0^∞)(1/(8 (Sqrt[π]) (t^(3/2))))(E^(-t)) (-4 t EllipticTheta[3,0,(E^(-((β (4 t+β))/(4 t))))]+β Derivative[0,1,0][EllipticThetaPrime][3,0,(E^(-((β (4 t+β))/(4 t))))])\[DifferentialD]t

Plot a numerical approximation of the partition function:

ListLinePlot[Table[Ω[β]/.Integrate[a_,{t,b_,c_}]:>NIntegrate[a,{t,10^-3,10}],{β,1/4,3,1/4}]]

OpenersExampleSection4(Spacer1)Possible Issues  (3)

Machine-precision input is insufficient to give a correct answer:

EllipticThetaPrime[1,10.^30,1/Pi]

Use arbitrary-precision arithmetic to obtain the correct result:

N[EllipticThetaPrime[1,10^30,1/Pi],20]

The first argument must be an explicit integer between 1 and 4:

EllipticThetaPrime[1+(E+1)^2-E^2-2E-1,3.,1/2]

Simplify[%]

Different argument conventions exist:

{Plot[EllipticThetaPrime[1,z,1/2],{z,0,2Pi}],
Plot[EllipticThetaPrime[1,z/(2Pi),1/2],{z,0,2Pi}]}

{Plot[EllipticThetaPrime[1,2,q],{q,0.1, 0.8}],
Plot[EllipticThetaPrime[1,2,Exp[I Pi (I τ)]],{τ,0.1, 0.8}]}

OpenersExampleSection5(Spacer1)Neat Examples  (1)

Visualize a function with a boundary of analyticity:

Module[{f,R=0.99},
f[z_?NumberQ]:=If[Abs[z]>R,0,Sin[Arg[EllipticThetaPrime[2, 1,z]]/2]^2];
DensityPlot[f[qx+I qy],{qx,-1,1},{qy,-1,1},Frame->False,RegionFunction->(Norm[{#1,#2}]<R&),ColorFunction->(Hue[2.72 #]&)]]

({{DocumentationFooterIconsRelatedFunction.png, ({{See Also}, {(RefLink[EllipticTheta, paclet:ref/EllipticTheta])  ▪  (RefLink[QPochhammer, paclet:ref/QPochhammer])}})}})

({{DocumentationFooterIconsRelatedTutorial.png, ({{Tutorials}, {▪(RefLinkPlain[Elliptic Integrals and Elliptic Functions, paclet:tutorial/EllipticIntegralsAndEllipticFunctions])}})}})

({{DocumentationFooterIconsRelatedGuide.png, ({{Related Guides}, {▪(RefLinkPlain[Elliptic Functions, paclet:guide/EllipticFunctions])}})}})