({{, (RefLink[ConnesWindow, paclet:ref/ConnesWindow])[x]
represents a Connes window function of x.}, {, (RefLink[ConnesWindow, paclet:ref/ConnesWindow])[x,α]
uses the parameter α.}})

OpenersNotesSection(Spacer1)Details

(RefLink[ConnesWindow, paclet:ref/ConnesWindow])[x,α] is equal to ({{{, ({{(((((α^2)-4 (x^2)))^2)/(α^4)), -(1/2)≤x≤(1/2)}, {0, (Abs[x])>(1/2)}})}}).

(RefLink[ConnesWindow, paclet:ref/ConnesWindow])[x] is equivalent to (RefLink[ConnesWindow, paclet:ref/ConnesWindow])[x,1].

(RefLink[ConnesWindow, paclet:ref/ConnesWindow]) automatically threads over lists.

OpenersPrimaryExamplesSection(Spacer1)Examples  (15)

OpenersExampleSection0(Spacer1)Basic Examples  (3)

Shape of a 1D Connes window:

Plot[ConnesWindow[x],{x,-1,1}]

Shape of a 2D Connes window:

Plot3D[ConnesWindow[x]ConnesWindow[y],{x,-1,1},{y,-1,1},PlotRange->All]

Extract the continuous function representing the Connes window:

FunctionExpand[ConnesWindow[x]]

Parameterized Connes window:

FunctionExpand[ConnesWindow[x,α]]

OpenersExampleSection1(Spacer1)Scope  (6)

Shape of a 1D Connes window using a specified parameter:

Plot[ConnesWindow[x,1.5],{x,-1,1}]

Variation of the shape as a function of the parameter α:

Plot3D[ConnesWindow[x,α],{α,1,5},{x,-1,1}]

Translated and dilated Connes window:

Plot[ConnesWindow[(x-1)/2],{x,-1,3}]

2D Connes window with a circular support:

Plot3D[ConnesWindow[Sqrt[x^2+y^2]],{x,-1,1},{y,-1,1},PlotRange->All]

Evaluate numerically:

ConnesWindow[0.1]

Discrete Connes window of length 15:

ListPlot[Array[ConnesWindow,15,{-1/2,1/2}], Filling->Axis]

Discrete 15×10 2D Connes window:

ListPointPlot3D[Array[ConnesWindow[#1] ConnesWindow[#2]&,{15,10},{{-1/2,1/2}}], Filling->Axis]

OpenersExampleSection3(Spacer1)Applications  (3)

Create a moving-average filter of length 11:

a=ConstantArray[1/11,11]

Smooth the filter using a Connes window:

a2=#/Total[#]&[a Array[ConnesWindow,11,{-1/2,1/2}]];

Log-magnitude plot of the frequency spectrum of the filters:

LogLinearPlot[Evaluate[20Log[10,Abs@ListFourierSequenceTransform[#,ω]]&/@{a,a2}],{ω,0.0314,Pi},PlotRange->All,GridLines->Automatic,ImageSize->300]

Use a window specification to calculate a sample (RefLink[PowerSpectralDensity, paclet:ref/PowerSpectralDensity]):

proc=ARMAProcess[1,{.5},{.3},1];
data=RandomFunction[proc,{50}];

Calculate the spectrum:

spec=PowerSpectralDensity[data,w,ConnesWindow];

Compare to spectral density calculated without a windowing function:

sd=PowerSpectralDensity[data,w];

sd===spec

The plot shows that the window smooths the spectral density:

Plot[{sd,spec},{w,-π,π},PlotRange->All,PlotLegends->{"no window","with window"}]

Compare to the theoretical spectral density of the process:

Plot[{spec,Evaluate@PowerSpectralDensity[proc,w]},{w,-π,π},PlotLegends->{"data","process"}]

Use a window specification for time series estimation:

data=RandomFunction[ARMAProcess[1,{.3},{.4},1],{300}];

Specify the window for the spectral estimator:

EstimatedProcess[data,ARMAProcess[1,1],ProcessEstimator->{"SpectralEstimator", "Window"->ConnesWindow}]

OpenersExampleSection4(Spacer1)Properties & Relations  (2)

The area under the Connes window:

area=Integrate[ConnesWindow[x],{x,-∞,∞}]

Normalize to create a window with unit area:

Plot[{ConnesWindow[x],ConnesWindow[x]/area},{x,-1,1}]

Fourier transform of the Connes window:

f=FourierTransform[ConnesWindow[x],x,w]

Power spectrum of the Connes window:

LogLinearPlot[20 Log[10,Abs[f]],{w,.1,80}]

OpenersExampleSection5(Spacer1)Possible Issues  (1)

2D sampling of a Connes window will use a different parameter for each row of samples when passed as a symbol to (RefLink[Array, paclet:ref/Array]):

Array[ConnesWindow,{30,30},{{-1/2,1/2}}]//ListPlot3D

Use a pure function instead:

Array[ConnesWindow[#1] ConnesWindow[#2]&,{30,30},{{-1/2,1/2}}]//ListPlot3D

({{DocumentationFooterIconsRelatedFunction.png, ({{See Also}, {(RefLink[Array, paclet:ref/Array])  ▪  (RefLink[WelchWindow, paclet:ref/WelchWindow])  ▪  (RefLink[TukeyWindow, paclet:ref/TukeyWindow])  ▪  (RefLink[BartlettWindow, paclet:ref/BartlettWindow])  ▪  (RefLink[BlackmanWindow, paclet:ref/BlackmanWindow])  ▪  (RefLink[HannWindow, paclet:ref/HannWindow])}})}})

({{DocumentationFooterIconsRelatedGuide.png, ({{Related Guides}, {▪(RefLinkPlain[Filter-Design Window Functions, paclet:guide/WindowFunctions])}})}})