({{, (RefLink[ComplexListPlot, paclet:ref/ComplexListPlot])[{(Subscript[z, 1]),(Subscript[z, 2]),…}] 
plots complex numbers (Subscript[z, 1]), (Subscript[z, 2]), … as points in the complex plane.}, {, (RefLink[ComplexListPlot, paclet:ref/ComplexListPlot])[{(Subscript[data, 1]),(Subscript[data, 2]),…}]
plots data from all (Subscript[data, i]).}, {, (RefLink[ComplexListPlot, paclet:ref/ComplexListPlot])[{…,w[(Subscript[data, i]),…],…}]
plots (Subscript[data, i]) with features defined by the symbolic wrapper w.}})

OpenersNotesSection(Spacer1)Details and Options

The (Subscript[data, i]) have the following forms and interpretations:

The following wrappers w can be used for the (Subscript[data, i]):

Wrappers w can be applied at multiple levels:

(RefLink[Callout, paclet:ref/Callout]), (RefLink[Labeled, paclet:ref/Labeled]) and (RefLink[Placed, paclet:ref/Placed]) can use the following positions pos:

(RefLink[ComplexListPlot, paclet:ref/ComplexListPlot]) has the same options as (RefLink[Graphics, paclet:ref/Graphics]), with the following additions and changes:

(RefLink[LabelingFunction, paclet:ref/LabelingFunction])->f specifies that each point should have a label given by f[value,index,lbls], where value is the value associated with the point, index is its position in the data and lbls is the list of relevant labels.

Typical settings for (RefLink[PlotLegends, paclet:ref/PlotLegends]) include:

The arguments supplied to functions in (RefLink[MeshFunctions, paclet:ref/MeshFunctions])are x, y, θ, r where θ and r are the argument and radius of the (Subscript[z, i]). Functions in (RefLink[ColorFunction, paclet:ref/ColorFunction]) are by default supplied with scaled versions of these arguments.

(RefLink[ScalingFunctions, paclet:ref/ScalingFunctions])->"scale" scales the modulus of the (Subscript[z, i]). (RefLink[ScalingFunctions, paclet:ref/ScalingFunctions])->{"scalex","scaley"} scales the real and imaginary components, respectively.

OpenersPrimaryExamplesSection(Spacer1)Examples  (154)

OpenersExampleSection0(Spacer1)Basic Examples  (4)

Plot a set of complex numbers:

ComplexListPlot[{-2-2 I,-1-I,0,1+I,2+2 I}]

Plot multiple sets of complex numbers:

ComplexListPlot[{RandomComplex[{0,1+I},100],RandomComplex[{-2-2I,2+2I},100]}]

Plot several (Subscript[data, i]) with a legend:

data=Table[a t Exp[2 π I t],{a,2,4},{t,0,1,0.02}];
ComplexListPlot[data,PlotLegends->{"a=2","a=3","a=4"}]

Label each point with a callout:

ComplexListPlot[Callout[#,#]&/@Table[(E^(π I k/4)),{k,1,8}]]

OpenersExampleSection1(Spacer1)Scope  (39)

OpenersExampleSubsection0(Spacer1)Data  (7)

A list of complex values {(Subscript[z, 1]),(Subscript[z, 2]),…} is plotted as a list of (Re[(Subscript[z, i])],Im[(Subscript[z, i])]) pairs:

ComplexListPlot[Sin[Range[40]+2I]]

Plot multiple sets of regular data:

ComplexListPlot[{Sin[Range[40]+2I],Cos[Range[40]+2I]}]

Non-numeric and missing data is excluded:

ComplexListPlot[{1+I,2+2I,Missing["NotAvailable"],4+4I,None,6+6I,""}]

Use (RefLink[MaxPlotPoints, paclet:ref/MaxPlotPoints]) to limit the number of points used:

data=Table[Exp[2Pi I Random[]],{n,200}];
Table[ComplexListPlot[data,MaxPlotPoints->mp],{mp,{Infinity,100,50}}]

(RefLink[PlotRange, paclet:ref/PlotRange]) is selected automatically:

{ComplexListPlot[{0,1+I,2+2I,3+3I,4+20I,5+5I,20+6I}],
ComplexListPlot[{0,1+I,2+2I,3+3I,4+20I,5+5I,20+6I},PlotRange->All]}

Use (RefLink[PlotRange, paclet:ref/PlotRange]) to focus on areas of interest:

{ComplexListPlot[{0,1+I,2+2I,3+3I,4+100I,5+5I,20+6I}],
ComplexListPlot[{0,1+I,2+2I,3+3I,4+100I,5+5I,20+6I},PlotRange->{0,7+7I}]}

Use (RefLink[ScalingFunctions, paclet:ref/ScalingFunctions]) to scale the axes:

ComplexListPlot[Table[(10^k)+(2^k)I,{k,-2,5}],ScalingFunctions->{"Log10","Log2"}]

OpenersExampleSubsection1(Spacer1)Special Data  (4)

Specify strings to use as labels:

ComplexListPlot[{1+I->"a",2+2I->"b",3+3I->"c",4+4I->"d",5+3I->"e",6+2I->"f",7+I->"g"}]
ComplexListPlot[{1+I,2+2 I,3+3 I,4+4 I,5+3 I,6+2 I,7+I}->{"a","b","c","d","e","f","g"}]

Specify a location for labels:

ComplexListPlot[{1+I,2+2 I,3+3 I,4+4 I,5+3 I,6+2 I,7+I}->{"a","b","c","d","e","f","g"},LabelingFunction->Above]

Numeric values in an (RefLink[Association, paclet:ref/Association]) are used as the (x,y) coordinates:

ComplexListPlot[<|"a"->2+I,"b"->3-I,"c"->5+2I,"d"->7,"e"->11+2I,"f"->13-3I|>]

Plot data in a (RefLink[SparseArray, paclet:ref/SparseArray]):

ComplexListPlot[SparseArray[Table[Random[]+Random[]I,{25}]]]

OpenersExampleSubsection2(Spacer1)Wrappers  (6)

Use wrappers on individual data, datasets or collections of datasets:

{ComplexListPlot[{{1+I,Style[3+2I,Red],6+3I},{1+4I,3+5I,6+6I}},PlotStyle->PointSize[0.05]],
ComplexListPlot[{Style[{1+I,3+2I,6+3I},Red],{1+4I,3+5I,6+6I}},PlotStyle->PointSize[0.05]],
ComplexListPlot[Style[{{1+I,3+2I,6+3I},{1+4I,3+5I,6+6I}},Red],PlotStyle->PointSize[0.05]]}

Wrappers can be nested:

{ComplexListPlot[{{1+I,Style[3+2I,Red],6+3I},{1+4I,3+5I,6+6I}},PlotStyle->PointSize[0.05]],
ComplexListPlot[{Style[{1+I,Style[3+2I,Red],6+3I},Green],{1+4I,3+5I,6+6I}},PlotStyle->PointSize[0.05]],
ComplexListPlot[Style[{Style[{1+I,Style[3+2I,Red],6+3I},Green],{1+4I,3+5I,6+6I}},Blue],PlotStyle->PointSize[0.05]]}

Use a specific label for all of the points:

ComplexListPlot[Tooltip[Table[k+Sqrt[k]I,{k,10}],"square roots"]]

Label points with automatically positioned text:

ComplexListPlot[Table[Labeled[RandomComplex[{0,1+I}],i],{i,20}],PlotStyle->PointSize[Medium],ImageSize->300]

Use (RefLink[PopupWindow, paclet:ref/PopupWindow]) to click an eigenvalue to see a corresponding eigenvector:

{evalues,evecs}=Eigensystem[RandomComplex[{-1-I,1+I},{4,4}]];
ComplexListPlot[PopupWindow@@@Transpose[{evalues,evecs}],PlotStyle->PointSize[0.04]]

(RefLink[Button, paclet:ref/Button]) can be used to trigger any action:

evalues=Eigenvalues[RandomComplex[{-1-I,1+I},{8,8}]];
ComplexListPlot[Button[#,Speak[#]]&/@evalues,PlotStyle->PointSize[0.02]]

OpenersExampleSubsection3(Spacer1)Labeling and Legending  (16)

Label points with automatically positioned text:

ComplexListPlot[Table[Labeled[RandomComplex[{0,1+I}],i],{i,20}]]

Place the labels relative to the points:

Table[ComplexListPlot[Table[Labeled[RandomComplex[{0,1+I}],i,p],{i,20}],PlotLabel->p],{p,{Above,Below,Before,After}}]

Label data with (RefLink[Labeled, paclet:ref/Labeled]):

ComplexListPlot[{
Labeled[NestList[(0.9+0.1I)#&,1+I,30],0.1],Labeled[NestList[(0.9+0.2I)#&,1+I,30],0.2]
}]

Label data with (RefLink[PlotLabels, paclet:ref/PlotLabels]):

ComplexListPlot[{
NestList[(0.9+0.1I)#&,1+I,30],NestList[(0.9+0.2I)#&,1+I,30]
},PlotLabels->{0.1,0.2}]

Place the label near the points at a particular x value:

ComplexListPlot[{
Labeled[NestList[(0.9+0.1I)#&,1+I,30],0.1,0.1],Labeled[NestList[(0.9+0.2I)#&,1+I,30],0.2,0.3]
}]

Use a scaled position:

ComplexListPlot[{
Labeled[NestList[(0.9+0.1I)#&,1+I,30],0.1,Scaled[0.1]],Labeled[NestList[(0.9+0.2I)#&,1+I,30],0.2,Scaled[0.1]]
}]

Specify the text position relative to the point:

ComplexListPlot[{
Labeled[NestList[(0.9+0.1I)#&,1+I,30],0.1,{Scaled[0.1],Above}],Labeled[NestList[(0.9+0.2I)#&,1+I,30],0.2,{Scaled[0.1],Below}]
}]

Label data automatically with (RefLink[Callout, paclet:ref/Callout]):

ComplexListPlot[{
Callout[NestList[(0.9+0.1I)#&,1+I,30],0.1],Callout[NestList[(0.9+0.2I)#&,1+I,30],0.2]
}]

Place a label with a specific location:

ComplexListPlot[{
Callout[NestList[(0.9+0.1I)#&,1+I,30],0.1,Above],Callout[NestList[(0.9+0.2I)#&,1+I,30],0.2,Below]
}]

Specify label names with (RefLink[LabelingFunction, paclet:ref/LabelingFunction]):

ComplexListPlot[z/.Solve[(z^6)==1,z],LabelingFunction->(DisplayForm[RowBox[{"(",#1[[1]],#1[[2]],")"}]]&)]

ComplexListPlot[z/.Solve[(z^12)==1,z],LabelingFunction->(Arg[#1[[1]]+I#[[2]]]&)]

For dense sets of points, some labels may be turned into tooltips by default:

Quiet@ComplexListPlot[z/.Solve[(z^50)==1,z],LabelingFunction->(Arg[#1[[1]]+I#[[2]]]&)]

Increasing the size of the plot will show more labels:

Quiet@ComplexListPlot[z/.Solve[(z^50)==1,z],LabelingFunction->(Arg[#1[[1]]+I#[[2]]]&),ImageSize->500]

Include legends for each (Subscript[data, i]):

ComplexListPlot[{
NestList[(0.9+0.1I)#&,1+I,30],NestList[(0.9+0.2I)#&,1+I,30]
},PlotLegends->{0.1,0.2}]

Use (RefLink[Legended, paclet:ref/Legended]) to provide a legend for a specific dataset:

matrix=RandomComplex[{-1-I,1+I},{10,10}];
evals1=Eigenvalues[matrix];
evals2=Eigenvalues[((matrix+ConjugateTranspose[matrix])/2)];
ComplexListPlot[{evals1,Legended[evals2,"eigenvalues of the\nsymmetric matrix"]}]

Use (RefLink[Placed, paclet:ref/Placed]) to change the legend location:

ComplexListPlot[{evals1,Legended[evals2,Placed["eigenvalues of the symmetric matrix",Below]]}]

Use association keys as labels:

ComplexListPlot[<|"random"->evals1,"symmetric"->evals2|>,PlotLabels->Automatic]

OpenersExampleSubsection4(Spacer1)Presentation  (6)

Multiple datasets are automatically colored to be distinct:

f=(((z^6)+(z^3)+1)/((z^10)-1024));
zeros=z/.Solve[f==0,z];
poles=z/.Solve[Denominator[f]==0,z];
ComplexListPlot[{zeros,poles}]

Provide explicit styling to different sets:

ComplexListPlot[{zeros,poles},PlotStyle->{Blue,Red}]

Include legends for each curve:

ComplexListPlot[{zeros,poles},PlotLegends->{"zeros","poles"}]

Use a plot theme:

ComplexListPlot[{zeros,poles},PlotTheme->"Marketing"]

Include legends for each dataset:

ComplexListPlot[{zeros,poles},PlotLegends->{"zeros","poles"}]

Use (RefLink[Legended, paclet:ref/Legended]) to provide a legend for a specific dataset:

ComplexListPlot[{zeros,Legended[poles,"poles"]}]

Provide an interactive (RefLink[Tooltip, paclet:ref/Tooltip]) for the data:

ComplexListPlot[Table[Tooltip[Exp[2Pi I k/10],Exp[2Pi I k/10]],{k,0,9}]]

Use shapes to distinguish different datasets:

ComplexListPlot[Table[Exp[2Pi I k/n],{n,{3,5,7}},{k,0,n-1}],PlotMarkers->Automatic]

Use labels to distinguish different datasets:

ComplexListPlot[Table[Exp[2Pi I k/n],{n,{3,5,7}},{k,0,n-1}],PlotMarkers->{"3","5","7"}]

Use (RefLink[Joined, paclet:ref/Joined]) to connect datasets with lines:

ComplexListPlot[Table[Exp[2Pi I k/10],{k,0,10}],Joined->True]

Use (RefLink[InterpolationOrder, paclet:ref/InterpolationOrder]) to smooth joined data:

Table[ComplexListPlot[Table[Exp[2Pi I k/10],{k,0,10}],Joined->True,InterpolationOrder->io],{io,{0,1,2}}]

OpenersExampleSection2(Spacer1)Options  (96)

OpenersExampleSubsection5(Spacer1)AspectRatio  (1)

Use numerical values for (RefLink[AspectRatio, paclet:ref/AspectRatio]):

ComplexListPlot[Table[x+I Sin[x],{x,0,2Pi,0.1}],AspectRatio->1/GoldenRatio]

OpenersExampleSubsection6(Spacer1)AxesLabel  (1)

Specify different labels for the real and imaginary axes:

ComplexListPlot[Table[(E^(2π I k/12)),{k,0,11}],AxesLabel->{"ℜ","ℑ"}]

ComplexListPlot[Table[(E^(2π I k/12)),{k,0,11}],AxesLabel->{"Re","Im"}]

ComplexListPlot[Table[(E^(2π I k/12)),{k,0,11}],AxesLabel->{"x","I y"}]

OpenersExampleSubsection7(Spacer1)AxesOrigin  (2)

The locations of the axes are determined automatically:

ComplexListPlot[Table[10+3I+(E^(2π I k/12)),{k,0,11}]]

Specify where the axes cross:

ComplexListPlot[Table[10+3I+(E^(2π I k/12)),{k,0,11}],AxesOrigin->{0,0}]

OpenersExampleSubsection8(Spacer1)ClippingStyle  (4)

(RefLink[ClippingStyle, paclet:ref/ClippingStyle]) requires at least one dataset to be (RefLink[Joined, paclet:ref/Joined]):

{ComplexListPlot[Table[x+I Sin[x]/x^2,{x,-10,10,0.2}],ClippingStyle->Red],
ComplexListPlot[Table[x+I Sin[x]/x^2,{x,-10,10,0.2}],ClippingStyle->Red,Joined->True]}//Quiet

Omit clipped regions of the plot:

ComplexListPlot[Table[x+I Sin[x]/x^2,{x,-10,10,0.2}],ClippingStyle->None,Joined->True]//Quiet

Show clipped regions as red at the bottom and thick at the top:

ComplexListPlot[Table[x+I Sin[x]/x^2,{x,-10,10,0.2}],ClippingStyle->{Red,Thick},Joined->True]//Quiet

Show clipped regions as red and thick:

ComplexListPlot[Table[x+I Sin[x]/x^2,{x,-10,10,0.2}],ClippingStyle->Directive[Red,Thick],Joined->True]//Quiet

OpenersExampleSubsection9(Spacer1)ColorFunction  (3)

Color by scaled x, y, θ and r coordinates:

Table[ComplexListPlot[Table[Sin[2x]Exp[I x],{x,0,2π,.1}],Joined->True,PlotLabel->Hue[var],ColorFunction->Function[{x,y,θ,r},Evaluate[Hue[var]]]],{var,{x,y,θ,r}}]

(RefLink[ColorFunction, paclet:ref/ColorFunction]) has higher priority than (RefLink[PlotStyle, paclet:ref/PlotStyle]) for coloring the curve:

ComplexListPlot[Table[t Exp[I t],{t,0,4Pi,.1}],ColorFunction->"Rainbow",Joined->True,PlotStyle->Directive[Red,Thick]]

Use (RefLink[Automatic, paclet:ref/Automatic]) in (RefLink[MeshShading, paclet:ref/MeshShading]) to use (RefLink[ColorFunction, paclet:ref/ColorFunction]):

ComplexListPlot[Table[t Exp[I t],{t,0,4Pi,.1}],ColorFunction->"Rainbow",Joined->True,PlotStyle->Directive[Red,Thick],Mesh->10,MeshShading->{Automatic,Black},MeshStyle->None]

OpenersExampleSubsection10(Spacer1)ColorFunctionScaling  (4)

(RefLink[ColorFunctionScaling, paclet:ref/ColorFunctionScaling]) requires at least one dataset to be (RefLink[Joined, paclet:ref/Joined]):

{ComplexListPlot[Table[t Exp[I t],{t,0,4Pi,.1}],ColorFunction->"Rainbow",ColorFunctionScaling->True],
ComplexListPlot[Table[t Exp[I t],{t,0,4Pi,.1}],ColorFunction->"Rainbow",ColorFunctionScaling->True,Joined->True]}

Color the curve based on the scaled y value:

ComplexListPlot[Table[0.25(I+Exp[I t]),{t,0,2Pi,.1}],ColorFunction->Function[{x,y},Hue[y]],Joined->True,ColorFunctionScaling->True]

Color the curve based on the unscaled y value:

ComplexListPlot[Table[0.25(I+Exp[I t]),{t,0,2Pi,.1}],ColorFunction->Function[{x,y},Hue[y]],Joined->True,ColorFunctionScaling->False]

Color by unscaled x, y, θ and r coordinates:

Table[ComplexListPlot[Table[Sin[2x]Exp[I x],{x,0,2π,.05}],Joined->True,ColorFunctionScaling->False,PlotLabel->Hue[var],ColorFunction->Function[{x,y,θ,r},Evaluate[Hue[var]]]],{var,{x,y,θ,r}}]

OpenersExampleSubsection11(Spacer1)ImageSize  (1)

The number of points that are labeled directly may depend on the image size:

data=RandomComplex[{0,10+10I},200]->Range[200];

ComplexListPlot[data]

Smaller graphics will have fewer labeled points:

ComplexListPlot[data,ImageSize->200]

Larger graphics will have more labeled points:

ComplexListPlot[data,ImageSize->500]

OpenersExampleSubsection12(Spacer1)InterpolationOrder  (4)

(RefLink[InterpolationOrder, paclet:ref/InterpolationOrder]) requires at least one dataset to be (RefLink[Joined, paclet:ref/Joined]):

{ComplexListPlot[Table[t Exp[I t],{t,0,4Pi,1}],InterpolationOrder->2],ComplexListPlot[Table[t Exp[I t],{t,0,4Pi,1}],InterpolationOrder->2,Joined->True]}

By default, linear interpolation is used:

ComplexListPlot[Table[t Exp[I t],{t,0,4Pi,1}],Joined->True,InterpolationOrder->None,Mesh->Full]

Use zero-order or piecewise-constant interpolation:

ComplexListPlot[Table[t Exp[I t],{t,0,4Pi,1}],Joined->True,InterpolationOrder->0,Mesh->Full]

Interpolation order 0 to 3:

Table[ComplexListPlot[Table[t Exp[I t],{t,0,4Pi,1}],Joined->True,InterpolationOrder->i,Mesh->Full,PlotLabel->i],{i,0,3}]

OpenersExampleSubsection13(Spacer1)Joined  (3)

Join the points in a dataset:

data=Table[t Exp[2π I t],{t,0,10,.1}];
Table[ComplexListPlot[data,Joined->s],{s,{False,True}}]

Join the first dataset with a line, but use points for the second dataset:

ComplexListPlot[Table[40BesselJ[n,x]+I BesselI[n,x],{n,1,2},{x,0,5,.1}],Joined->{True,False}]

Join the dataset with a line and show the original points:

ComplexListPlot[Table[40BesselJ[1,x]+I BesselI[1,x],{x,0,5,.1}],Joined->True,Mesh->All]

OpenersExampleSubsection14(Spacer1)LabelingFunction  (7)

A (RefLink[Rule, paclet:ref/Rule]) can be used to label points if the lists of values and labels are the same length:

ComplexListPlot[{1,(E^((2 I π)/7)),(E^((4 I π)/7)),(E^((6 I π)/7)),(E^((8 I π)/7)),(E^((10 I π)/7)),(E^((12 I π)/7))}->{0,1,2,3,4,5,6}]

A list of rules and values can be used to label selected points:

ComplexListPlot[{1->0,(E^((2 I π)/7))->1,(E^((4 I π)/7))->2,(E^((6 I π)/7))->3,(E^((8 I π)/7)),(E^((10 I π)/7)),(E^((12 I π)/7))}]

Use (RefLink[LabelingFunction, paclet:ref/LabelingFunction])->(RefLink[None, paclet:ref/None]) to suppress the labels:

ComplexListPlot[{1,(E^((2 I π)/7)),(E^((4 I π)/7)),(E^((6 I π)/7)),(E^((8 I π)/7)),(E^((10 I π)/7)),(E^((12 I π)/7))}->{0,1,2,3,4,5,6},LabelingFunction->None]

Put the labels above the points:

ComplexListPlot[{1,(E^((2 I π)/7)),(E^((4 I π)/7)),(E^((6 I π)/7)),(E^((8 I π)/7)),(E^((10 I π)/7)),(E^((12 I π)/7))}->{0,1,2,3,4,5,6},LabelingFunction->Above]

Put them in a (RefLink[Tooltip, paclet:ref/Tooltip]):

ComplexListPlot[{1,(E^((2 I π)/7)),(E^((4 I π)/7)),(E^((6 I π)/7)),(E^((8 I π)/7)),(E^((10 I π)/7)),(E^((12 I π)/7))}->{0,1,2,3,4,5,6},LabelingFunction->Tooltip]

Label the points as ordered pairs:

ComplexListPlot[{1,(E^((2 I π)/7)),(E^((4 I π)/7)),(E^((6 I π)/7)),(E^((8 I π)/7)),(E^((10 I π)/7)),(E^((12 I π)/7))},LabelingFunction->(DisplayForm[ToBoxes[TraditionalForm[#1]]/.{"{"->"(","}"->")"}]&)]

Label the points with their indices:

ComplexListPlot[{1,(E^((2 I π)/7)),(E^((4 I π)/7)),(E^((6 I π)/7)),(E^((8 I π)/7)),(E^((10 I π)/7)),(E^((12 I π)/7))},LabelingFunction->(Last[#2]-1&)]

OpenersExampleSubsection15(Spacer1)LabelingSize  (3)

Textual labels are shown at their actual sizes:

ComplexListPlot[{1,(E^((2 I π)/7)),(E^((4 I π)/7)),(E^((6 I π)/7)),(E^((8 I π)/7)),(E^((10 I π)/7)),(E^((12 I π)/7))}->{"zeroth","first","second","third","fourth","fifth","sixth"}]

Specify a maximum size for textual labels:

ComplexListPlot[{1,(E^((2 I π)/7)),(E^((4 I π)/7)),(E^((6 I π)/7)),(E^((8 I π)/7)),(E^((10 I π)/7)),(E^((12 I π)/7))}->{"zeroth","first","second","third","fourth","fifth","sixth"},LabelingSize->25]

Image labels are automatically resized:

images={,,,,,,};

ComplexListPlot[{1,(E^((2 I π)/7)),(E^((4 I π)/7)),(E^((6 I π)/7)),(E^((8 I π)/7)),(E^((10 I π)/7)),(E^((12 I π)/7))}->images]

Specify a maximum size for image labels:

ComplexListPlot[{1,(E^((2 I π)/7)),(E^((4 I π)/7)),(E^((6 I π)/7)),(E^((8 I π)/7)),(E^((10 I π)/7)),(E^((12 I π)/7))}->images,LabelingSize->50]

Show image labels at their natural sizes:

ComplexListPlot[{1,(E^((2 I π)/7)),(E^((4 I π)/7)),(E^((6 I π)/7)),(E^((8 I π)/7)),(E^((10 I π)/7)),(E^((12 I π)/7))}->images,ImageSize->72 8,LabelingSize->Full]

OpenersExampleSubsection16(Spacer1)MaxPlotPoints  (1)

Use (RefLink[MaxPlotPoints, paclet:ref/MaxPlotPoints]) to limit the number of points used:

data=Table[k Exp[2Pi I k/100],{k,200}];
Table[ComplexListPlot[data,MaxPlotPoints->mp],{mp,{Infinity,100,50}}]

OpenersExampleSubsection17(Spacer1)Mesh  (6)

(RefLink[Mesh, paclet:ref/Mesh]) requires at least one dataset to be (RefLink[Joined, paclet:ref/Joined]):

{ComplexListPlot[Table[t Exp[I t],{t,20}],Mesh->10],ComplexListPlot[Table[t Exp[I t],{t,20}],Mesh->10,Joined->True]}

The initial and final sampling meshes are typically the same:

{ComplexListPlot[Table[t Exp[I t],{t,20}],Mesh->Full,Joined->True],ComplexListPlot[Table[t Exp[I t],{t,20}],Mesh->All,Joined->True]}

Interpolated data may introduce points:

{ComplexListPlot[Table[t Exp[I t],{t,20}],Mesh->Full,Joined->True,InterpolationOrder->2],ComplexListPlot[Table[t Exp[I t],{t,20}],Mesh->All,Joined->True,InterpolationOrder->2]}

Use 20 mesh levels evenly spaced in the x direction:

ComplexListPlot[Table[t Exp[I t],{t,20}],Mesh->20,Joined->True]

Use an explicit list of values for the mesh in the x direction:

ComplexListPlot[Table[t Exp[I t],{t,20}],Mesh->{{-9,1,2,5,8}},Joined->True]

Use explicit styles at specific points:

ComplexListPlot[Table[t Exp[I t],{t,20}],Mesh->{Table[{x,Directive[Hue[x/20],PointSize[Large]]},{x,-10,10}]},Joined->True,ColorFunction->(Hue[#1/20]&),ColorFunctionScaling->False]

OpenersExampleSubsection18(Spacer1)MeshFunctions  (3)

(RefLink[MeshFunctions, paclet:ref/MeshFunctions]) requires at least one dataset to be (RefLink[Joined, paclet:ref/Joined]):

{ComplexListPlot[Table[t Exp[I t],{t,20}],Mesh->10,MeshFunctions->{#1&}],ComplexListPlot[Table[t Exp[I t],{t,20}],Mesh->10,MeshFunctions->{#1&},Joined->True]}

Show 5 mesh levels in the x direction (red) and 10 in the y direction (blue):

ComplexListPlot[Table[t Exp[I t],{t,20}],Joined->True,Mesh->{5,10},MeshFunctions->{#1&,#2&},MeshStyle->{Directive[PointSize[Large],Red],Directive[PointSize[Medium],Blue]}]

Use a mesh evenly spaced in the x,  y,  θ and r directions:

Table[ComplexListPlot[Table[Sin[2 x] Exp[I x],{x,0,2 π,.05}],Joined->True,Mesh->5,MeshStyle->AbsolutePointSize[5],MeshFunctions->Function[{x,y,θ,r},Evaluate[var]],PlotLabel->var],{var,{x,y,θ,r}}]

OpenersExampleSubsection19(Spacer1)MeshShading  (7)

(RefLink[MeshShading, paclet:ref/MeshShading]) requires at least one dataset to be (RefLink[Joined, paclet:ref/Joined]):

{ComplexListPlot[Table[t Exp[I t],{t,20}],Mesh->10,MeshShading->{Red,Blue}],ComplexListPlot[Table[t Exp[I t],{t,20}],Mesh->10,MeshShading->{Red,Blue},Joined->True]}

Alternate red and blue segments of equal width in the x direction:

ComplexListPlot[Table[t Exp[I t],{t,20}],Mesh->10,MeshFunctions->{#1&},MeshShading->{Red,Blue},Joined->True]

Use (RefLink[None, paclet:ref/None]) to remove segments:

ComplexListPlot[Table[t Exp[I t],{t,20}],Mesh->10,MeshFunctions->{#1&},MeshShading->{Red,None},Joined->True]

(RefLink[MeshShading, paclet:ref/MeshShading]) can be used with (RefLink[PlotStyle, paclet:ref/PlotStyle]):

ComplexListPlot[Table[t Exp[I t],{t,20}],Mesh->10,MeshFunctions->{#1&},MeshShading->{Red,Blue},PlotStyle->Dashed,Joined->True]

(RefLink[MeshShading, paclet:ref/MeshShading]) has higher priority than (RefLink[PlotStyle, paclet:ref/PlotStyle]):

ComplexListPlot[Table[t Exp[I t],{t,20}],Mesh->10,MeshFunctions->{#1&},MeshShading->{Red,Blue},PlotStyle->Black,Joined->True]

Use (RefLink[PlotStyle, paclet:ref/PlotStyle]) for some segments by setting (RefLink[MeshShading, paclet:ref/MeshShading]) to (RefLink[Automatic, paclet:ref/Automatic]):

ComplexListPlot[Table[t Exp[I t],{t,20}],Mesh->10,MeshFunctions->{#1&},MeshShading->{Red,Automatic},PlotStyle->Black,Joined->True]

(RefLink[MeshShading, paclet:ref/MeshShading]) can be used with (RefLink[ColorFunction, paclet:ref/ColorFunction]):

ComplexListPlot[Table[t Exp[I t],{t,20}],Mesh->10,MeshFunctions->{#1&},MeshShading->{Black,Automatic},ColorFunction->Function[{x,y},Hue[x]],Joined->True]

OpenersExampleSubsection20(Spacer1)PlotLabel  (1)

Add an overall label to the plot:

ComplexListPlot[Table[(E^(2π I k/12)),{k,0,11}],PlotLabel->"12th roots of unity"]

OpenersExampleSubsection21(Spacer1)PlotLabels  (5)

Specify text to label sets of points:

ComplexListPlot[{Sin[Range[20]+2I],Range[-5,10]+2I},PlotLabels->{"circle","line"}]

Place the labels above the points:

ComplexListPlot[{Sin[Range[20]+2I],Range[-5,10]+2I},PlotLabels->Placed[{"circle","line"},Above]]

Use callouts to identify the points:

ComplexListPlot[{Sin[Range[20]+2I],Range[-5,10]+2I},PlotLabels->{Callout["circle",{Scaled[0.25],Above}],Callout["line",{Scaled[0.25],Below}]}]

Use the keys from an (RefLink[Association, paclet:ref/Association]) as labels:

ComplexListPlot[<|"circle"->Sin[Range[20]+2I],"line"->Range[-5,10]+2I|>,PlotLabels->Automatic,PlotLegends->False]

Use (RefLink[None, paclet:ref/None]) to not add a label:

ComplexListPlot[{Sin[Range[20]+2I],Range[-5,10]+2I},PlotLabels->{None,"line"}]

OpenersExampleSubsection22(Spacer1)PlotLegends  (6)

Generate a legend using labels:

ComplexListPlot[{Sin[Range[20]+2I],Range[-5,10]+2I},PlotLegends->{"circle","line"}]

Generate a legend using placeholders:

ComplexListPlot[{Sin[Range[20]+2I],Range[-5,10]+2I},PlotLegends->Automatic]

Legends use the same styles as the plot:

ComplexListPlot[{Sin[Range[20]+2I],Range[-5,10]+2I},PlotLegends->{"circle","line"},PlotStyle->{Red,Blue}]

Use (RefLink[Placed, paclet:ref/Placed]) to specify the legend placement:

Table[ComplexListPlot[{Sin[Range[20]+2I],Range[-5,10]+2I},PlotLegends->Placed[{"circle","line"},pos],PlotStyle->{Red,Blue}],{pos,{Above,Below,Before,After}}]

Place the legend inside the plot:

ComplexListPlot[{Sin[Range[20]+2I],Range[-5,10]+2I},PlotLegends->Placed[{"circle","line"},{0.85,0.25}],PlotStyle->{Red,Blue}]

Use (RefLink[PlotLegends, paclet:ref/PlotLegends]) to change the appearance:

ComplexListPlot[{Sin[Range[20]+2I],Range[-5,10]+2I},PlotLegends->PointLegend[{"circle","line"},LegendMarkerSize->10,LegendFunction->Frame]]

OpenersExampleSubsection23(Spacer1)PlotMarkers  (8)

(RefLink[ComplexListPlot, paclet:ref/ComplexListPlot]) normally uses distinct colors to distinguish different sets of data:

ComplexListPlot[Table[Sin[2(t+p)]Exp[I (t+p)],{p,0,3Pi/2,Pi/2},{t,0,Pi/2,0.05}],PlotMarkers->None]

Automatically use colors and shapes to distinguish sets of data:

ComplexListPlot[Table[Sin[2(t+p)]Exp[I (t+p)],{p,0,3Pi/2,Pi/2},{t,0,Pi/2,0.05}],PlotMarkers->Automatic]

Use shapes only:

ComplexListPlot[Table[Sin[2(t+p)]Exp[I (t+p)],{p,0,3Pi/2,Pi/2},{t,0,Pi/2,0.05}],PlotMarkers->Automatic,PlotStyle->Black]

Change the size of the default plot markers:

Table[ComplexListPlot[Table[Sin[2(t+p)]Exp[I (t+p)],{p,0,3Pi/2,Pi/2},{t,0,Pi/2,0.05}],PlotMarkers->{Automatic,s}],{s,{Small,Medium,Large}}]

Use arbitrary text for plot markers:

ComplexListPlot[Table[Sin[2(t+p)]Exp[I (t+p)],{p,0,3Pi/2,Pi/2},{t,0,Pi/2,0.05}],PlotMarkers->{"1","2","3","4"}]

Use explicit graphics for plot markers:

{m1,m2,m3,m4}=Graphics/@{Circle[{0,0},1],Disk[{0,0},1],Line[{{-0.5,-0.5},{0.5,-0.5},{0.5,0.5},{-0.5,0.5},{-0.5,-0.5}}],Polygon[{{-0.5,-0.5},{0.5,-0.5},{0,(Sqrt[3])/4}}]}

ComplexListPlot[Table[Sin[2(t+p)]Exp[I (t+p)],{p,0,3Pi/2,Pi/2},{t,0,Pi/2,0.05}],PlotMarkers->Table[{s,0.03},{s,{m1,m2,m3,m4}}]]

Use the same symbol for all the sets of data:

ComplexListPlot[Table[Sin[2(t+p)]Exp[I (t+p)],{p,0,3Pi/2,Pi/2},{t,0,Pi/2,0.05}],PlotMarkers->"●"]

Explicitly use a symbol and size:

Table[ComplexListPlot[Table[Sin[2(t+p)]Exp[I (t+p)],{p,0,3Pi/2,Pi/2},{t,0,Pi/2,0.05}],PlotMarkers->{"●",s}],{s,{4,8,12}}]

OpenersExampleSubsection24(Spacer1)PlotRange  (4)

(RefLink[PlotRange, paclet:ref/PlotRange]) is automatically calculated:

ComplexListPlot[Fourier[Table[Cos[2 π 3 t],{t,0,2,0.05}]]]

Show the whole dataset:

ComplexListPlot[Fourier[Table[Cos[2 π 3 t],{t,0,2,0.05}]],PlotRange->All]

Explicitly choose the x and y ranges:

ComplexListPlot[Fourier[Table[Cos[2 π 3 t],{t,0,2,0.05}]],PlotRange->{{-3,3},{-2,2}}]

Implicitly choose the x and y ranges by giving complex coordinates of the bottom-left and top-right corners:

ComplexListPlot[Fourier[Table[Cos[2 π 3 t],{t,0,2,0.05}]],PlotRange->{-3-2I,3+2I}]

OpenersExampleSubsection25(Spacer1)PlotStyle  (7)

Use different style directives:

Table[ComplexListPlot[Table[Sin[3x]Exp[I x],{x,0,Pi,0.05}],PlotStyle->ps],{ps,{Red,PointSize[Large],Darker[Green],Directive[Red,PointSize[Large]]}}]

By default, different styles are chosen for multiple datasets:

ComplexListPlot[Table[c Sin[3 x]Exp[I x],{c,3},{x,0,Pi,0.05}]]

Explicitly specify the style for different datasets:

ComplexListPlot[Table[c Sin[3 x]Exp[I x],{c,3},{x,0,Pi,0.05}],PlotStyle->{Red,Green,Blue}]

(RefLink[PlotStyle, paclet:ref/PlotStyle]) applies to both curves and points:

ComplexListPlot[Table[c Sin[3 x]Exp[I x],{c,3},{x,0,Pi,0.05}],PlotStyle->{Red,Green,Blue},Joined->{False,True,False}]

(RefLink[PlotStyle, paclet:ref/PlotStyle]) can be combined with (RefLink[ColorFunction, paclet:ref/ColorFunction]):

ComplexListPlot[Table[c Sin[3 x]Exp[I x],{c,3},{x,0,Pi,0.05}],PlotStyle->Thick,Joined->True,ColorFunction->Function[{x,y},Hue[x]]]

(RefLink[PlotStyle, paclet:ref/PlotStyle]) can be combined with (RefLink[MeshShading, paclet:ref/MeshShading]):

ComplexListPlot[Table[c Sin[3 x]Exp[I x],{c,3},{x,0,Pi,0.05}],PlotStyle->Dashed,Joined->True,Mesh->10,MeshFunctions->{#3&},MeshShading->{Red,Blue}]

(RefLink[MeshStyle, paclet:ref/MeshStyle]) by default uses the same style as (RefLink[PlotStyle, paclet:ref/PlotStyle]):

ComplexListPlot[Table[c Sin[3 x]Exp[I x],{c,3},{x,0,Pi,0.05}],PlotStyle->Red,Joined->True,Mesh->All]

OpenersExampleSubsection26(Spacer1)PlotTheme  (2)

Use a theme with simple ticks and grid lines in a bright color scheme:

ComplexListPlot[Table[c Sin[3 x]Exp[I x],{c,3},{x,0,Pi,0.05}],PlotTheme->"Business"]

Change the color scheme:

ComplexListPlot[Table[c Sin[3 x]Exp[I x],{c,3},{x,0,Pi,0.05}],PlotTheme->"Business",PlotStyle->96]

OpenersExampleSubsection27(Spacer1)PolarAxes  (2)

Add polar axes and polar grid lines:

ComplexListPlot[Table[(1+3Sin[4t])Exp[I t],{t,0,6π,.05}],PolarAxes->True,PolarGridLines->True]

Control the radial and polar axes independently:

ComplexListPlot[Table[a Cos[3t]Exp[I t],{a,5},{t,0,Pi,0.05}],PolarAxes->{True,False}]

OpenersExampleSubsection28(Spacer1)PolarAxesOrigin  (2)

Specify the angular axes and radial axes to intersect at (0,6):

ComplexListPlot[Table[(1+3Sin[4t])Exp[I t],{t,0,6π,.05}],PolarAxes->True,PolarGridLines->True,PolarAxesOrigin->{0,6}]

Place radial axes at the right of the graph:

ComplexListPlot[Table[(1+3Sin[4t])Exp[I t],{t,0,6π,.05}],PolarAxes->True,PolarGridLines->True,PolarAxesOrigin->{{Right,Up},Automatic},PolarTicks->{None,Automatic}]

OpenersExampleSubsection29(Spacer1)PolarGridLines  (2)

Use automatically chosen polar grid lines:

ComplexListPlot[Table[Sin[4t]Exp[I t],{t,0,6π,.05}],PolarAxes->True,PolarGridLines->True]

Draw grid lines at the specified positions:

ComplexListPlot[Table[2Sin[4t]Exp[I t],{t,0,6π,.05}],PolarAxes->{True,False},PolarGridLines->{Range[0,2Pi,Pi/4],{1,2}},PolarTicks->{"Degrees",None}]

ComplexListPlot[Table[2Sin[4t]Exp[I t],{t,0,6π,.05}],PolarAxes->{False,True},PolarGridLines->{Range[0,2Pi,Pi/4],{1,2}},PolarTicks->{None,Automatic},GridLinesStyle->Orange]

OpenersExampleSubsection30(Spacer1)PolarTicks  (4)

Place polar tick marks and labels automatically:

ComplexListPlot[Table[5Cos[2t]Exp[I t],{t,0,6π,.05}],PolarAxes->Automatic,PolarTicks->Automatic]

Modify the angular ticks:

ComplexListPlot[Table[5Cos[2t]Exp[I t],{t,0,6π,.05}],PolarAxes->Automatic,PolarTicks->{Range[-Pi+Pi/12,Pi,Pi/12],Automatic}]

Indicate angles with degrees:

ComplexListPlot[Table[5Cos[2t]Exp[I t],{t,0,6π,.05}],PolarAxes->Automatic,PolarTicks->{"Degrees",Automatic}]

Place polar tick marks at the specified positions:

ComplexListPlot[Table[6Cos[2t]Exp[I t],{t,0,6π,.05}],PolarAxes->{True,True},PolarTicks->{Range[0,2Pi-Pi/4,Pi/4],Range[0,10,2]}]

OpenersExampleSubsection31(Spacer1)ScalingFunctions  (3)

A single scaling function scales the data radially:

ComplexListPlot[Table[(((10I))^t),{t,-5,6}],Joined->True,PlotRange->All,Mesh->All,ScalingFunctions->"Log10"]

data=Table[(1/t)Exp[I t],{t,20}];
{ComplexListPlot[data,Joined->True,PlotRange->All,Mesh->All],
ComplexListPlot[data,Joined->True,PlotRange->All,Mesh->All,ScalingFunctions->"Reciprocal"]}

Specifying two scaling functions scales the data in the x and y directions separately:

ComplexListPlot[Table[(10^x)+I (2^x),{x,8}],ScalingFunctions->{"Log10","Log2"}]

(RefLink[None, paclet:ref/None]) indicates no scaling in the specified direction:

ComplexListPlot[Table[(10^x)+(((-1))^k)x I,{k,2},{x,-3,8}],ScalingFunctions->{"Log10",None}]

OpenersExampleSection3(Spacer1)Applications  (9)

Plot roots of unity:

Manipulate[ComplexListPlot[Labeled[Exp[#],#]&/@Table[2Pi I k/n,{k,0,n-1}],Prolog->{Circle[]},ImageSize->Medium,PlotMarkers->{Automatic, Medium},PlotRange->{{-1.2,1.2},{-1.2,1.2}}],{{n,6},2,20,1}]

Plot a discrete time signal and its spectrum:

signal=Table[Mod[i/2,10]/10,{i,100}];

{ListPlot[signal,Filling->Axis],
ComplexListPlot[Fourier[signal],PlotRange->All]}

Graph zeros of the zeta function:

Quiet@ComplexListPlot[Table[N[ZetaZero[k]],{k,20}]]

Graph eigenvalues of a Cauchy matrix:

matrix=Table[1/(i+j-I),{i,1,10},{j,1,10}];

ComplexListPlot[1.Eigenvalues[matrix],ScalingFunctions->{"Log","Log"}]

Graphs solutions of sin(2 z)==cos(sin(z))+1:

roots=NSolve[Sin[2z]==1+Cos[Sin[z]]&&-2π≤Re[z]≤2π&&-2π≤Im[z]≤2π,z];

ComplexListPlot[z/.roots,Ticks->{Range[-2Pi,2Pi,Pi],Range[-2Pi,2Pi,Pi]}]

Show Gershgorin discs and eigenvalues for a matrix:

A={{10+6I,-1,2,1},{1.2,8-3I,2.2,2.5},{-2,3,2+5I,1},{1,-1,-1,I-11}};

{MatrixForm[A],
ComplexListPlot[Eigenvalues[A],PlotStyle->Directive[Black,PointSize[.02]],PlotRange->{{-15,15},{-10,15}},Prolog->{Opacity[.4],Blue,
MapIndexed[Disk[{Re[#1[[#2]]][[1]],Im[#1[[#2]]][[1]]},(Total[Abs[#1]]-Abs[#1[[#2]]])[[1]]]&,A]}]}

Show the eigenvalues for a PDE problem. Seek solutions of the structurally damped wave equation (Subscript[u, tt])-ϵ (Subscript[u, xxt])=(Subscript[u, xx]), u(0,t)=u(π,t)=0 of the form u(x,t)=(e^(λ t))sin(n x):

ϵ=.1;
eValues=Flatten[Table[{(1/2) (-(n^2) ϵ-n (Sqrt[-4+(n^2) (ϵ^2)])),(1/2) (-(n^2) ϵ+n (Sqrt[-4+(n^2) (ϵ^2)]))},{n,1,100}]];
ComplexListPlot[eValues,PlotRange->{{-42,1},{-11,11}},PlotStyle->Directive[Red,PointSize[.015]],Epilog->{Gray,Circle[{-(1/ϵ),0},(1/ϵ)]}]

Visualize iterations of Newton's method:

ComplexListPlot[Last[Reap[FindRoot[(z^3)-1,{z,2-0.7I},Method->"Newton",EvaluationMonitor:>Sow[z]]]],Joined->True,Mesh->Full,LabelingFunction->(Last[#2]-1&)]

The eigenvalues of bipartite graphs are symmetric about the imaginary axis:

g=Graph[{1\[DirectedEdge]6,1\[DirectedEdge]10,2\[DirectedEdge]11,4\[DirectedEdge]11,5\[DirectedEdge]2,5\[DirectedEdge]4,6\[DirectedEdge]9,7\[DirectedEdge]4,7\[DirectedEdge]6,7\[DirectedEdge]8,7\[DirectedEdge]10,8\[DirectedEdge]1,9\[DirectedEdge]2,9\[DirectedEdge]8,11\[DirectedEdge]8},VertexStyle->{v_?OddQ->Red,v_?EvenQ->Blue}];

{g,ComplexListPlot[Eigenvalues[AdjacencyMatrix[g]]]}

OpenersExampleSection4(Spacer1)Properties & Relations  (2)

Use (RefLink[ListPlot, paclet:ref/ListPlot]), (RefLink[ListLinePlot, paclet:ref/ListLinePlot]) or (RefLink[ListPolarPlot, paclet:ref/ListPolarPlot]) for real data:

{ListPlot[Table[{x,Exp[x]},{x,-Pi,Pi,.1}]],
ListLinePlot[Table[{x,Exp[x]},{x,-Pi,Pi,.1}]],
ListPolarPlot[Table[{x,Exp[x]},{x,-Pi,Pi,.1}]]}

(RefLink[ComplexListPlot, paclet:ref/ComplexListPlot]) is closely related to (RefLink[ListPlot, paclet:ref/ListPlot]):

data=Table[Exp[I x],{x,-Pi,Pi,.1}];
{ComplexListPlot[data],ListPlot[ReIm[data],AspectRatio->Automatic]}

OpenersExampleSection5(Spacer1)Possible Issues  (2)

Real-valued data is plotted along the x axis.:

{ListPlot[{10,11,12,13}],ListPlot[{{10,0},{11,0},{12,0},{13,0}}],ComplexListPlot[{10,11,12,13}]}

Radial scaling is different when using the same scaling functions in the real and imaginary directions:

data=Table[(((10I))^t),{t,-4,4,.1}];
{ComplexListPlot[data,Joined->True,Mesh->All,ScalingFunctions->"Log10"],
ComplexListPlot[data,Joined->True,Mesh->All,ScalingFunctions->{"Log10","Log10"}]}

OpenersExampleSection7(Spacer1)Neat Examples  (2)

Eigenvalue analysis of the weighted adjacency matrix of the wins by teams in the National Hockey League in the 2010–2011 regular season:

g=ExampleData[{"NetworkGraph","NationalHockeyLeague"}]
ComplexListPlot[Eigenvalues[WeightedAdjacencyMatrix[g]],PlotStyle->{Orange,PointSize[.02]},PlotRange->All]

Symmetry in the real parts of the eigenvalues of an adjacency matrix for a graph suggests that the graph may be bipartite, but in this case the graph is not bipartite:

g=ExampleData[{"NetworkGraph","SimpleFoodWeb"}]
ComplexListPlot[Eigenvalues[AdjacencyMatrix[g]],PlotStyle->{Black,PointSize[.025]},PlotRange->All]
BipartiteGraphQ[g]

({{DocumentationFooterIconsRelatedFunction.png, ({{See Also}, {(RefLink[ListPlot, paclet:ref/ListPlot])  ▪  (RefLink[ReImPlot, paclet:ref/ReImPlot])  ▪  (RefLink[AbsArgPlot, paclet:ref/AbsArgPlot])  ▪  (RefLink[ComplexPlot, paclet:ref/ComplexPlot])  ▪  (RefLink[ComplexPlot3D, paclet:ref/ComplexPlot3D])  ▪  (RefLink[ReIm, paclet:ref/ReIm])  ▪  (RefLink[Abs, paclet:ref/Abs])  ▪  (RefLink[Arg, paclet:ref/Arg])  ▪  (RefLink[I, paclet:ref/I])  ▪  (RefLink[ListPolarPlot, paclet:ref/ListPolarPlot])  ▪  (RefLink[PolarPlot, paclet:ref/PolarPlot])  ▪  (RefLink[MandelbrotSetPlot, paclet:ref/MandelbrotSetPlot])  ▪  (RefLink[JuliaSetPlot, paclet:ref/JuliaSetPlot])}})}})

({{DocumentationFooterIconsRelatedGuide.png, ({{Related Guides}, {▪(RefLinkPlain[Complex Visualization, paclet:guide/ComplexVisualization])}})}})