({{, (RefLink[AsymptoticLessEqual, paclet:ref/AsymptoticLessEqual])[f,g,x->(SuperStar[x])] 
gives conditions for f(x)⪯g(x) or f(x)∈O(g(x)) as x->(SuperStar[x]).}, {, (RefLink[AsymptoticLessEqual, paclet:ref/AsymptoticLessEqual])[f,g,{(Subscript[x, 1]),…,(Subscript[x, n])}->{(Subscript[x, 1]^( * )),…,(Subscript[x, n]^( * ))}]
gives conditions for f((Subscript[x, 1]),…,(Subscript[x, n]))⪯g((Subscript[x, 1]),…,(Subscript[x, n])) or f((Subscript[x, 1]),…,(Subscript[x, n]))∈O(g((Subscript[x, 1]),…,(Subscript[x, n]))) as {(Subscript[x, 1]),…,(Subscript[x, n])}->{(Subscript[x, 1]^( * )),…,(Subscript[x, n]^( * ))}.}})

OpenersNotesSection(Spacer1)Details and Options

Asymptotic less or equal is also expressed as f is big-o of g, f is upper bounded by g, f is of order at most g, and f grows at most as fast as g. The point (SuperStar[x]) is often assumed from context.

Asymptotic less or equal is an order relation and means (Abs[f(x)])≤c (Abs[g(x)]) when x is near (SuperStar[x]) for some constant c>0.

Typical uses include expressing simple upper bounds for functions and sequences near some point. It is frequently used for solutions to equations and to give simple upper bounds for computational complexity.

For a finite limit point (SuperStar[x]) and {(Subscript[x, 1]^( * )),…,(Subscript[x, n]^( * ))}:

For an infinite limit point:

(RefLink[AsymptoticLessEqual, paclet:ref/AsymptoticLessEqual])[f[x],g[x],x->(SuperStar[x])] exists if and only if (RefLink[MaxLimit, paclet:ref/MaxLimit])[(RefLink[Abs, paclet:ref/Abs])[f[x]/g[x]],x->(SuperStar[x])]<∞ when g[x] does not have an infinite set of zeros near (SuperStar[x]).

The following options can be given:

Possible settings for (RefLink[Direction, paclet:ref/Direction]) include:

(RefLink[Direction, paclet:ref/Direction])->(RefLink[Exp, paclet:ref/Exp])[i θ] at (SuperStar[x]) indicates the direction tangent of a curve approaching the limit point (SuperStar[x]).

Possible settings for (RefLink[GenerateConditions, paclet:ref/GenerateConditions]) include:

Possible settings for (RefLink[PerformanceGoal, paclet:ref/PerformanceGoal]) include (RefLink[$PerformanceGoal, paclet:ref/$PerformanceGoal]), "Quality" and "Speed". With the "Quality" setting, (RefLink[Limit, paclet:ref/Limit]) typically solves more problems or produces simpler results, but it potentially uses more time and memory.

OpenersPrimaryExamplesSection(Spacer1)Examples  (39)

OpenersExampleSection0(Spacer1)Basic Examples  (2)

Verify that x⪯(x^2) as x->∞:

AsymptoticLessEqual[x,x^2,x->∞]

Visualize the two functions:

Plot[{x,x^2},{x,0,10},PlotLegends->"Expressions"]

Verify that x+y⪯(x^2)+(y^2) as {x,y}->∞:

AsymptoticLessEqual[x+y,x^2+y^2,{x,y}->∞]

Visualize the two functions:

Plot3D[{x+y,x^2+y^2},{x,0,10},{y,0,10},PlotLegends->"Expressions"]

OpenersExampleSection1(Spacer1)Scope  (9)

Compare functions that are not strictly positive:

AsymptoticLessEqual[x,-x^2,x->∞]

Show that (1/(x^2)) diverges no faster than (1/(x sin(x))) at the origin:

AsymptoticLessEqual[(1/(x^2)),(1/(x Sin[x])),x->0]

Answers may be Boolean expressions rather than explicit (RefLink[True, paclet:ref/True]) or (RefLink[False, paclet:ref/False]):

AsymptoticLessEqual[Sin[x-2],Sinh[p(x-2)],x->2]

When comparing functions with parameters, conditions for the result may be generated:

AsymptoticLessEqual[(1/(((x-1))^p)),(10/(x-1)), x->1]

By default, a two-sided comparison of the functions is made:

AsymptoticLessEqual[(x^4),(x^2) UnitStep[x], x->0]

When comparing larger values of x, (x^4) is indeed no bigger than (x^2) (UnitStepSeq[x]):

AsymptoticLessEqual[(x^4),(x^2) UnitStep[x], x->0,Direction->"FromAbove"]

The relationship fails for smaller values of x:

AsymptoticLessEqual[(x^4),(x^2) UnitStep[x], x->0,Direction->"FromBelow"]

Visualize the two functions:

Plot[{(x^4),(x^2)UnitStep[x]},{x,-1,1},PlotTheme->{"DashedLines","Detailed"}]

Functions like (RefLink[Sqrt, paclet:ref/Sqrt]) may have the same relationship in both real directions along the negative reals:

AsymptoticLessEqual[(((Sqrt[z]-I))^3), (z+1),z->-1]

If approached from above in the complex plane, the same relationship is observed:

AsymptoticLessEqual[(((Sqrt[z]-I))^3), (z+1),z->-1,Direction->-I]

However, approaching from below in the complex plane produces a different result:

AsymptoticLessEqual[(((Sqrt[z]-I))^3), (z+1),z->-1,Direction->I]

This is due to a branch cut where the imaginary part of (RefLink[Sqrt, paclet:ref/Sqrt]) reverses sign as the axis is crossed:

TableForm[Table[{-1+Δ,Sqrt[-1+Δ],Abs[Sqrt[-1+Δ]-I]},{Δ,{0.01,-0.01,0.01I,-0.01I}}],TableHeadings->{None,{z,(Sqrt[z]),HoldForm@Abs[Sqrt[z]-I]}}]

Hence, the relationship does not hold in the complex plane in general:

AsymptoticLessEqual[(((Sqrt[z]-I))^3), (z+1),z->-1,Direction->Complexes]

Visualize the relative sizes of the functions when approached from the four real and imaginary directions:

Plot[{Abs[ ((-1+Δz)/(((Sqrt[-1+Δz]-I))^3))],Abs[ ((-1+I Δz)/(((Sqrt[-1+I Δz]-I))^3))]},{Δz,-1,1},]

Compare multivariate functions:

AsymptoticLessEqual[(((x-1))^2)(y-2), Sin[ x]Cos[3y/4],{x,y}->{1,2}]

Visualize the norms of the two functions:

Show[Plot3D[{Abs[(((x-1))^2)(y-2)],Abs[Sin[ x]Cos[ 3y/4]]},{x,y}∈Disk[{1,2},.25],PlotTheme->"Detailed"],Graphics3D[{Black,Sphere[{1,2,0},.02]}],ViewPoint->{1.36,-2.75,1.42}]

Compare multivariate functions at infinity:

AsymptoticLessEqual[ Exp[x]Log[y],x y,{x,y}->{-∞,∞}]

Use parameters when comparing multivariate functions:

AsymptoticLessEqual[Sinh[x]y,Sinh[a x]y^2,{x,y}->{∞,1}]

OpenersExampleSection2(Spacer1)Options  (10)

OpenersExampleSubsection0(Spacer1)Assumptions  (1)

Specify conditions on parameters using (RefLink[Assumptions, paclet:ref/Assumptions]):

AsymptoticLessEqual[1+x^a,1,x->0,Assumptions->a≥0]

Different assumptions can produce different results:

AsymptoticLessEqual[1+x^a,1,x->0,Assumptions->a<0]

OpenersExampleSubsection1(Spacer1)Direction  (5)

Test the relation from below:

AsymptoticLessEqual[Sin[x],x UnitStep[x],x->0,Direction->"FromBelow"]

Equivalently:

AsymptoticLessEqual[Sin[x],x UnitStep[x],x->0,Direction->1]

Test the relation from above:

AsymptoticLessEqual[Sin[x],x UnitStep[x],x->0,Direction->"FromAbove"]

Equivalently:

AsymptoticLessEqual[Sin[x],x UnitStep[x],x->0,Direction->-1]

Test the relation at piecewise discontinuities:

AsymptoticLessEqual[Cos[x/2],FractionalPart[x^2]Sin[x],x->2,Direction->"FromBelow"]

AsymptoticLessEqual[Cos[x/2],FractionalPart[x^2]Sin[x],x->2,Direction->"FromAbove"]

Since it fails in one direction, the two-sided result is false as well:

AsymptoticLessEqual[Cos[x/2],FractionalPart[x^2]Sin[x],x->2,Direction->"TwoSided"]

Visualize the two functions and their ratio:

Plot[{Cos[x/2],FractionalPart[x^2]Sin[x],Abs[((FractionalPart[x^2]Sin[x])/(Cos[x/2]))]},{x,1.5,2.5},PlotLegends->"Expressions"]

The relationship at a simple pole is independent of the direction of approach:

AsymptoticLessEqual[Tan[x],(2/(2x-π)),x->π/2,Direction->"FromBelow"]

AsymptoticLessEqual[Tan[x],(2/(2x-π)),x->π/2,Direction->"FromAbove"]

AsymptoticLessEqual[Tan[x],(2/(2x-π)),x->π/2,Direction->(Reals)]

AsymptoticLessEqual[Tan[x],(2/(2x-π)),x->π/2,Direction->(Complexes)]

Test the relation at a branch cut:

AsymptoticLessEqual[ Sqrt[x-1]-I,Tanh[x],x->0,Direction->+I]

AsymptoticLessEqual[ Sqrt[x-1]-I,Tanh[x],x->0,Direction->-I]

AsymptoticLessEqual[ Sqrt[x-1]-I,Tanh[x],x->0,Direction->Reals]

AsymptoticLessEqual[ Sqrt[x-1]-I,Tanh[x],x->0,Direction->Complexes]

Compute the relation, approaching from different quadrants:

f[x_,y_] := Sin[x y]

g[x_,y_]:=x+Abs[y]

Approaching the origin from the first quadrant:

AsymptoticLessEqual[f[x,y],g[x,y],{x,y}->{0,0},Direction->"FromAbove"]

Equivalently:

AsymptoticLessEqual[f[x,y],g[x,y],{x,y}->{0,0},Direction->{"FromAbove","FromAbove"}]

Approach the origin from the right half-plane:

AsymptoticLessEqual[f[x,y],g[x,y],{x,y}->{0,0},Direction->{"FromAbove",Reals}]

Approaching the origin from the bottom half-plane:

AsymptoticLessEqual[f[x,y],g[x,y],{x,y}->{0,0},Direction->{Reals,"FromBelow"}]

Visualize the ratio of the functions:

DensityPlot[Abs[Sin[x y]/(x+Abs[y])],{x,-1,1},{y,-1,1},PlotLegends->Automatic,ClippingStyle->Automatic]//Quiet

OpenersExampleSubsection2(Spacer1)GenerateConditions  (3)

Return a result without stating conditions:

AsymptoticLessEqual[1+x^n,1,x->0,GenerateConditions->False]

This result is only valid if n>0:

AsymptoticLessEqual[1+x^n,1,x->0]

Return unevaluated if the results depend on the value of parameters:

AsymptoticLessEqual[Exp[-a x],1,x->∞,GenerateConditions->None]

By default, conditions are generated that guarantee a result:

AsymptoticLessEqual[Exp[-a x],1,x->∞]

By default, conditions are not generated if only special values invalidate the result:

AsymptoticLessEqual[x y,(((x-a))^2)+(y^2),{x,y}->{0,0}]

With (RefLink[GenerateConditions, paclet:ref/GenerateConditions])->(RefLink[True, paclet:ref/True]), even these non-generic conditions are reported:

AsymptoticLessEqual[x y,(((x-a))^2)+(y^2),{x,y}->{0,0},GenerateConditions->True]

OpenersExampleSubsection3(Spacer1)PerformanceGoal  (1)

Use (RefLink[PerformanceGoal, paclet:ref/PerformanceGoal]) to avoid potentially expensive computations:

f=2 y (z^2)-(z^3)+y (((x-2 y+3 z))^2)-z (((x-2 y+3 z))^2);
g=(y^2)-2 y z+(z^2)-y (x-2 y+3 z)+z (x-2 y+3 z)+(((x-2 y+3 z))^2);

AsymptoticLessEqual[f,g,{x,y,z}->{0,0,0},PerformanceGoal->"Speed"]//AbsoluteTiming

The default setting uses all available techniques to try to produce a result:

AsymptoticLessEqual[f,g,{x,y,z}->{0,0,0}]//AbsoluteTiming

OpenersExampleSection3(Spacer1)Applications  (10)

OpenersExampleSubsection4(Spacer1)Basic Applications  (4)

Show that ⋯⪯(x^3)⪯(x^2)⪯x⪯1 at 0:

{AsymptoticLessEqual[(x^3),(x^2),x->0],AsymptoticLessEqual[(x^2),x,x->0],AsymptoticLessEqual[(x^1),(x^0),x->0]}

Establish this symbolically:

AsymptoticLessEqual[(x^k),(x^l),x->0,Assumptions->{k,l}∈(Integers) && k≥l≥0]

Visualize the functions:

Plot[{1,Abs[x],Abs[(x^2)],Abs[(x^3)]},{x,-1,1},PlotLegends->"Expressions"]

This relationship extends to all real powers:

AsymptoticLessEqual[(x^k),(x^l),x->0,Assumptions-> k≥l]

Visualize functions with fractional and negative powers:

Plot[{Abs[1/x],Abs[1/(Sqrt[x])],1,Abs[(Sqrt[x])],Abs[x]},{x,-1,1},PlotLegends->"Expressions"]

Show that 1⪯x⪯(x^2)⪯(x^3)⪯⋯ at ∞:

{AsymptoticLessEqual[1,x,x->∞],AsymptoticLessEqual[x,(x^2),x->∞],AsymptoticLessEqual[(x^2),(x^3),x->∞]}

Establish this symbolically:

AsymptoticLessEqual[(x^k),(x^l),x->∞,Assumptions->{k,l}∈(Integers) && 0≤k≤l]

Visualize the relationship in a logarithmic plot:

LogPlot[{1,Abs[x],Abs[(x^2)],Abs[(x^3)]},{x,10,100},PlotLegends->"Expressions"]

This relationship extends to all real powers:

AsymptoticLessEqual[(x^k),(x^l),x->∞,Assumptions-> k≤l]

Visualize functions with fractional and negative powers:

LogPlot[{Abs[1/x],Abs[1/(Sqrt[x])],1,Abs[(Sqrt[x])],Abs[x]},{x,10,100},PlotLegends->"Expressions"]

Show that (x^2)⪯ (x^2)( sin(1/x)+2)⪯x at 0:

AsymptoticLessEqual[(x^2),(x^2)(Sin[1/x]+2),x->0]

AsymptoticLessEqual[(x^2)(Sin[1/x]+2),x,x->0]

Visualize the three functions:

Plot[{Abs[x],Abs[(x^2)(Sin[1/x]+2)],(x^2)},{x,-1/3,1/3},PlotLegends->"Expressions"]

Show that x⪯(x^2) (sin(x)+2)⪯(x^2) at ∞:

AsymptoticLessEqual[x,(x^2)(Sin[x]+2),x->∞]

AsymptoticLessEqual[(x^2)(Sin[x]+2),(x^2),x->∞]

Visualize the three functions:

LogPlot[{x,(x^2)(Sin[x]+2),(x^2)},{x,1,100},PlotLegends->"Expressions"]

OpenersExampleSubsection5(Spacer1)Computational Complexity  (4)

Simple sorting algorithms (bubble sort, insertion sort) take approximately a (n^2) steps to sort n objects, while optimal general algorithms (heap sort, merge sort) take approximately b n (RefLink[Log, paclet:ref/Log])[n] steps to do the sort. Show that b n log(n)∈O(a (n^2)), so that optimal algorithms are never slower for large enough collections of objects:

AsymptoticLessEqual[b n Log[n],a (n^2),n->∞,Assumptions->a b>0]

Certain special algorithms (counting sort, radix sort), where there is information ahead of time about the possible inputs, can run in c n time. Show that c n∈O(b n log(n)):

AsymptoticLessEqual[c n,b n Log[n],n->∞,Assumptions-> b c>0]

Visualize the growth of the three time scales:

LogPlot[{(n^2),n Log[n],n},{n,10,1000},PlotLabel->Row[{n∈HoldForm@O[n Log[n]],n Log[n]∈HoldForm@O[(n^2)]}, Spacer[10]],PlotLegends->"Expressions"]

In a bubble sort, adjoining neighbors are compared and swapped if they are out of order. After one pass of n-1 comparisons, the largest element is at the end. The process is then repeated on remaining n-1 elements, and so forth, until only two elements at the very beginning remain. If comparison and swap takes c steps, the total number of steps for the sort is as follows:

Sum[c(i-1),{i,n,2,-1}]

The polynomial is in O((n^2)):

AsymptoticLessEqual[(1/2) (-c n+c (n^2)),(n^2),n->∞,Assumptions->c>0]

It is also in Ω((n^2)):

AsymptoticGreaterEqual[(1/2) (-c n+c (n^2)),(n^2),n->∞,Assumptions->c>0]

Thus (1/2) (c (n^2)-c n)∈Θ((n^2)), and the algorithm is said to have quadratic run time:

AsymptoticEqual[(1/2) (-c n+c (n^2)),(n^2),n->∞,Assumptions->c>0]

In a merge sort, the list of elements is split in two, each half is sorted, and then the two halves are combined. Thus, the time T[n] to do the sort will be the sum of some constant time b to compute the middle, 2T[n/2] to sort each half, and some multiple a n of the number of elements to combine the two halves:

reqn=T[n]==2T[n/2]+ a n +b

Solve the recurrence equation to find the time t to sort n elements:

t=RSolveValue[reqn,T[n],n]//Expand

Show that t∈O(n log(n)):

AsymptoticLessEqual[t,n Log[n],n->∞,Assumptions->a>0]

Conversely, t∈O(n log(n)):

AsymptoticGreaterEqual[t,n Log[n],n->∞,Assumptions->a>0]

Hence t∈Θ(n log(n)), and the algorithm is said to have n log(n) run time:

AsymptoticEqual[t,n Log[n],n->∞,Assumptions->a>0]

The traveling salesperson problem (TSP) consists of finding the shortest route connecting n cities. A naive algorithm is to try all n! routes. The Held–Karp algorithm improves that to roughly (n^2) (2^n) steps. Show that (n^2) (2^n)∈O(n!):

AsymptoticLessEqual[n^2 (2^n),n!,n->∞]

Both algorithms show that the complexity class of TSP is no worse than EXPTIME, which are problems that can be solved in time (2^(p(n))). For Held–Karp, using p(n)==a n for some a>1 suffices:

AsymptoticLessEqual[(n^2) (2^n),(2^(2n)),n->∞]

For the factorial, it is necessary to use a higher-degree polynomial, for example p(n)=(n^2):

AsymptoticLessEqual[n!,(2^(n^2)),n->∞]

Approximate solutions can be found in (n^3) time, so the approximate TSP is in the complexity class P of problems solvable in polynomial time. Any polynomial algorithm is faster than an exponential one, or (n^k)∈O((2^n)):

AsymptoticLessEqual[(n^k),(2^n),n->∞]

OpenersExampleSubsection6(Spacer1)Convergence Testing  (2)

A sequence (Subscript[a, n]) is said to be absolutely summable if (∑_(n=1)^∞)(Abs[(Subscript[a, n])])<∞. If a second sequence (Subscript[b, n])≺(Subscript[a, n]), the comparison test states that (Subscript[b, n]) is absolutely summable if (Subscript[a, n]) is. Use the test to show that (∑_(n=1)^∞)1/((n^2)+n+1) converges by comparing with the sum of 1/(n^2):

AsymptoticLessEqual[(1/(n^2)),(1/((n^2)+n+1)), n->∞]

As (∑_(n=1)^∞)1/(n^2) converges, so does the sum of interest:

Sum[(1/(Abs[(n^2)])),{n,1,∞}]

Compare with the answer given by (RefLink[SumConvergence, paclet:ref/SumConvergence]):

SumConvergence[(1/((n^2)+n+1)),n]

Another sequence comparable to 1/(n^2) is  (PrimePi[n])/((n^3)log(n)), and thus it is also absolutely summable:

AsymptoticLessEqual[((PrimePi[n])/(Log[n](n^3))),(1/(n^2)),n->∞]

Show that (∑_(n=1)^∞)1/((n^2) sin(1/(Sqrt[n])))  convergence by comparing with the sum of 1/(n^(3/2)):

AsymptoticEqual[(1/(n^(3/2))),(1/((n^2)Sin[1/(Sqrt[n])])), n->∞]

Sum[(1/(Abs[(n^(3/2))])),{n,1,∞}]

A function f is said to be absolutely integrable on [a,b] if (∫_a^b)(Abs[f(x)])dx<∞. If f and g are continuous on the open interval (a,b) and f⪯g at both a and b, the comparison test states that if g is absolutely integrable, then f is as well. Use the test to show that (cot^(-1))(x)/x is absolutely integrable on [1,∞]:

AsymptoticLessEqual[((ArcCot[x])/x),(1/(x^2)), x->∞]

AsymptoticLessEqual[((ArcCot[x])/x),(1/(x^2)), x->1]

Since (cot^(-1))(x)/x⪯1/(x^2) and 1/(x^2) is integrable on [1,∞], so is (cot^(-1))(x)/x:

Integrate[(1/(x^2)),{x,1,∞}]

The function exp(-x) is absolutely integrable on [1,∞]:

Integrate[Abs[Exp[-x]],{x,1,∞}]

At both 1 and ∞, exp(-(x^2)) (x^k)⪯exp(-x), and hence the absolute integrability of exp(-(x^2))(x^k) follows:

AsymptoticLessEqual[Exp[-(x^2)](x^k),Exp[-x], x->∞]

AsymptoticLessEqual[Exp[-(x^2)](x^k),Exp[-x], x->1]

At 0, exp(-(x^2)) (x^k)⪯exp(-x) for k≥0:

AsymptoticLessEqual[Exp[-(x^2)](x^k),Exp[-x], x->0,Assumptions->k≥0]

Show that these functions are absolutely integrable over [0,∞] because exp(-x) is:

Integrate[Exp[-x],{x,0,∞}]

For k<0, exp(-(x^2)) (x^k)⪯̸exp(-x), so the comparison test gives no information about convergence:

AsymptoticLessEqual[Exp[-(x^2)](x^k),Exp[-x], x->0,Assumptions->k<0]

OpenersExampleSection4(Spacer1)Properties & Relations  (8)

(RefLink[AsymptoticLessEqual, paclet:ref/AsymptoticLessEqual]) is a reflexive relation, i.e. f(x)⪯f(x):

AsymptoticLessEqual[f[x],f[x],x->x0]

And it is a transitive relation, i.e. f(x)⪯g(x) and g(x)⪯h(x) implies f(x)⪯h(x):

{f,g,h}={x,(x^2),(x^3)};

{AsymptoticLessEqual[f,g,x->∞],AsymptoticLessEqual[g,h,x->∞],AsymptoticLessEqual[f,h,x->∞]}

However it is not symmetric, i.e. f(x)⪯g(x) does not imply g(x)⪯f(x):

{AsymptoticLessEqual[f,g,x->∞],AsymptoticLessEqual[g,f,x->∞]}

(RefLink[AsymptoticLessEqual, paclet:ref/AsymptoticLessEqual])[f[x],g[x],x->(Subscript[x, 0])] iff (RefLink[MaxLimit, paclet:ref/MaxLimit])[(RefLink[Abs, paclet:ref/Abs])[f[x]/g[x]],x->(Subscript[x, 0])]<∞:

{f,g}={x Sin[x],x};

{AsymptoticLessEqual[f,g,x->∞],MaxLimit[Abs[f/g],x->∞]}

{f,g}={x Sin[x],(Sqrt[x])};

{AsymptoticLessEqual[f,g,x->∞],MaxLimit[Abs[f/g],x->∞]}

(RefLink[AsymptoticLessEqual, paclet:ref/AsymptoticLessEqual])[f[x],g[x],x->(Subscript[x, 0])] if (RefLink[Limit, paclet:ref/Limit])[(RefLink[Abs, paclet:ref/Abs])[f[x]/g[x]],x->(Subscript[x, 0])]<∞:

{f,g}={x,(x^2)};

{AsymptoticLessEqual[f,g,x->∞],Limit[Abs[f/g],x->∞]}

However, when the limit is (RefLink[Indeterminate, paclet:ref/Indeterminate]), it is inconclusive:

{f,g}={x Sin[x],x};

{AsymptoticLessEqual[f,g,x->∞],Limit[Abs[f/g],x->∞]}

{f,g}={x Sin[x],(Sqrt[x])};

{AsymptoticLessEqual[f,g,x->∞],Limit[Abs[f/g],x->∞]}

If f(x)⪯g(x), then g(x)⪰f(x):

{f,g}={x,(x^2)/(1+x)};

{AsymptoticLessEqual[f,g,x->∞],AsymptoticGreaterEqual[g,f,x->∞]}

If f(x)⪯g(x) and f(x)⪰g(x), then f(x)≍g(x):

{f,g}={x,(x^2)/(1+x)};

{AsymptoticLessEqual[f,g,x->∞],AsymptoticGreaterEqual[f,g,x->∞],AsymptoticEqual[f,g,x->∞]}

If f(x)≍g(x) or f(x)≺g(x), then f(x)⪯g(x):

{f,g}={x,(x^2)/(1+x)};

{AsymptoticEqual[f,g,x->∞],AsymptoticLessEqual[f,g,x->∞]}

{f,g}={x,(x^3)/(1+x)};

{AsymptoticLess[f,g,x->∞],AsymptoticLessEqual[f,g,x->∞]}

However, f(x)⪯g(x) does not imply f(x)≍g(x) or f(x)≺g(x):

{f,g}={Sin[x]/x,1/x};

{AsymptoticLessEqual[f,g,x->∞],AsymptoticLess[f,g,x->∞],AsymptoticEqual[g,x,x->∞]}

If f(x)⪯g(x) and g(x)≍h(x), then f(x)⪯h(x):

{f,g,h}={x,(x^2),(x^3)/(1+x)};

{AsymptoticLessEqual[f,g,x->∞],AsymptoticEqual[g,h,x->∞],AsymptoticLessEqual[f,h,x->∞]}

If f(x)⪯g(x) and g(x)∼h(x), then f(x)⪯h(x):

{f,g,h}={x,(x^2),(x^3)/(1+x)};

{AsymptoticLessEqual[f,g,x->∞],AsymptoticEquivalent[g,h,x->∞],AsymptoticLessEqual[f,h,x->∞]}

({{DocumentationFooterIconsRelatedFunction.png, ({{See Also}, {(RefLink[AsymptoticLess, paclet:ref/AsymptoticLess])  ▪  (RefLink[AsymptoticGreaterEqual, paclet:ref/AsymptoticGreaterEqual])  ▪  (RefLink[AsymptoticGreater, paclet:ref/AsymptoticGreater])  ▪  (RefLink[AsymptoticEqual, paclet:ref/AsymptoticEqual])  ▪  (RefLink[AsymptoticEquivalent, paclet:ref/AsymptoticEquivalent])  ▪  (RefLink[MaxLimit, paclet:ref/MaxLimit])}})}})

({{DocumentationFooterIconsRelatedGuide.png, ({{Related Guides}, {▪(RefLinkPlain[Asymptotics, paclet:guide/Asymptotics])}})}})