({{, (RefLink[AngularGauge, paclet:ref/AngularGauge])[value] 
draws a gauge showing value in the range 0 to 1.}, {, (RefLink[AngularGauge, paclet:ref/AngularGauge])[value,{min,max}]
draws a gauge showing value in a range of min to max.}, {, (RefLink[AngularGauge, paclet:ref/AngularGauge])[(RefLink[Dynamic, paclet:ref/Dynamic])[value],…]
allows value to be set interactively using the gauge.}, {, (RefLink[AngularGauge, paclet:ref/AngularGauge])[{(Subscript[value, 1]),(Subscript[value, 2]),…},…]
draws a gauge showing multiple values.}})

OpenersNotesSection(Spacer1)Details and Options

Values less than min or greater than max are clipped to the respective limits.

Undefined values or bad input is taken to be missing and typically displays the min value.

Units may be assigned to value, min, and max by using (RefLink[Quantity, paclet:ref/Quantity]).

The units do not need to be the same, but must be compatible.

(RefLink[AngularGauge, paclet:ref/AngularGauge]) has the same options as (RefLink[Graphics, paclet:ref/Graphics]) with the following additions and changes:

(RefLink[GaugeLabels, paclet:ref/GaugeLabels]) can take the following forms:

(RefLink[GaugeLabels, paclet:ref/GaugeLabels])->(RefLink[Placed, paclet:ref/Placed])[label,pos] can use the positions pos:

A list of built-in settings for (RefLink[GaugeMarkers, paclet:ref/GaugeMarkers]), (RefLink[GaugeFaceElementFunction, paclet:ref/GaugeFaceElementFunction]), and (RefLink[GaugeFrameElementFunction, paclet:ref/GaugeFrameElementFunction]) can be obtained from ChartElementData["AngularGauge"]. A visual gallery is available in the Chart Element Schemes palette.

(RefLink[GaugeMarkers, paclet:ref/GaugeMarkers])->(RefLink[Placed, paclet:ref/Placed])[marker,pos] can be used to control where the marker is placed in the gauge. The possible positions pos are:

(RefLink[ScaleOrigin, paclet:ref/ScaleOrigin]) can take the following values:

The angles in (RefLink[ScaleOrigin, paclet:ref/ScaleOrigin]) are measured in radians, counterclockwise from the positive x axis. The values need not be between 0 and 2 π.

Scales run counterclockwise when (Subscript[θ, min])<(Subscript[θ, max]) and clockwise when (Subscript[θ, min])>(Subscript[θ, max]).

If (RefLink[Abs, paclet:ref/Abs])[(Subscript[θ, max])-(Subscript[θ, min])]>2(RefLink[Pi, paclet:ref/Pi]), the scale will overlap itself.

The radial component r of the scale origin is scaled to run from 0 at the center of the gauge to 1 at the edge of the face.

(RefLink[ScalePadding, paclet:ref/ScalePadding]) can take the following forms:

(RefLink[TargetUnits, paclet:ref/TargetUnits])->(RefLink[Automatic, paclet:ref/Automatic]) automatically selects the units based on the input. If no units are present, none will be displayed.

(RefLink[TargetUnits, paclet:ref/TargetUnits])->unit displays unit in the gauge, even if no units were present in the input.

OpenersPrimaryExamplesSection(Spacer1)Examples  (104)

OpenersExampleSection0(Spacer1)Basic Examples  (4)

Generate a dial gauge for a particular value:

AngularGauge[42,{0,100}]

Generate a gauge using values with units:

AngularGauge[LinguisticAssistant,{LinguisticAssistant,LinguisticAssistant},GaugeLabels->"Unit"]

Generate a gauge that displays multiple values:

AngularGauge[{15,42,63,88},{0,100}]

Generate a dial gauge with an interactive value:

DynamicModule[{y=0},AngularGauge[Dynamic[y],{0,100}]]

OpenersExampleSection1(Spacer1)Scope  (22)

OpenersExampleSubsection0(Spacer1)Data and Layouts  (7)

Data values are clipped to be within the range of the scale:

AngularGauge[{-500,1,8,14.68},{0,10}]

Nonreal data is taken to be missing and typically uses the minimum value of the gauge:

Table[AngularGauge[a,{0,10}],
{a,{2+2I,"Hi"}}]

The min and max specified are sorted so that the smaller number of the list is always min:

AngularGauge[42,{100,0}]

Generate a gauge using values with units:

AngularGauge[LinguisticAssistant,{LinguisticAssistant,LinguisticAssistant},GaugeLabels->"Unit"]

Specify the displayed units with (RefLink[TargetUnits, paclet:ref/TargetUnits]):

AngularGauge[LinguisticAssistant,{LinguisticAssistant,LinguisticAssistant},GaugeLabels->"Unit",TargetUnits->"Kilometers"/"Hours"]

Change the position of the scale:

AngularGauge[42,{0,100},ScaleOrigin->Left]

Display the gauge as a semicircle:

AngularGauge[88,{0,100},ScaleOrigin->{π,0}]

Use (RefLink[Dynamic, paclet:ref/Dynamic]) to make an interactive gauge:

DynamicModule[{x},Column[{AngularGauge[Dynamic[x],GaugeLabels->Automatic],Slider[Dynamic[x]],Button["Reset",x=0]}]]

OpenersExampleSubsection1(Spacer1)Styling and Appearance  (9)

Use a theme to control the overall appearance:

AngularGauge[42,{0,100},PlotTheme->"Business"]

Use explicit styles for the markers:

AngularGauge[{2,17,42,88},{0,100},GaugeStyle->{Red,Green,Blue,Yellow}]

Use any gradient or indexed color schemes from (RefLink[ColorData, paclet:ref/ColorData]) to style the markers:

Table[AngularGauge[{2,17,42,88},{0,100},GaugeStyle->f],{f,{61,"Pastel"}}]

Change the type of markers used:

Table[AngularGauge[42,{0,100},GaugeMarkers->f],{f,{"BezelBevelNeedle","ShinyHubNeedle"}}]

Change where the markers are placed:

Table[AngularGauge[42,{0,100},GaugeMarkers->Placed[Automatic,f]],{f,{"Center","InsideScale","OutsideScale","Frame","DivisionCenter","ScaleRange"}}]

Use any graphic or image for the marker:

AngularGauge[42,{0,100},GaugeMarkers->Placed[,#]]&/@{"InsideScale","DivisionCenter"}

Change the style of the face of the gauge:

Table[AngularGauge[42,{0,100},GaugeFaceStyle->c],{c,{LightGray,LightOrange}}]

Change the style of the frame around the gauge:

Table[AngularGauge[42,{0,100},GaugeFrameStyle->c],{c,{Black,LightOrange}}]

Specify ranges of the scale to be colored on the dial face:

AngularGauge[20,{0,100},ScaleRanges->{{50,60},{60,70},{70,80},{80,100}}]

OpenersExampleSubsection2(Spacer1)Labeling  (6)

Use (RefLink[GaugeLabels, paclet:ref/GaugeLabels]) to add a label to the gauge face:

AngularGauge[88, {0, 100} ,GaugeLabels -> "MPH"]

Add a display of the scale value:

AngularGauge[9, {0, 10} ,GaugeLabels ->"Value"]

Add a display of the gauge units:

AngularGauge[Quantity[9,"Feet"], {0, 10} ,GaugeLabels ->"Unit"]

Show units and scale value:

AngularGauge[Quantity[9,"Feet"], {0, 10} ,GaugeLabels ->Full]

Use (RefLink[Placed, paclet:ref/Placed]) to change the location of the label on the face of the gauge:

AngularGauge[86, {0, 100} ,GaugeLabels ->Placed[ "% Complete",Above]]

Use a list to specify more than one label:

AngularGauge[68.2, {0,100} ,GaugeLabels->{"Tank Pressure","Value"}]

OpenersExampleSection2(Spacer1)Options  (72)

OpenersExampleSubsection3(Spacer1)Background  (1)

Insert a background color behind the gauge:

AngularGauge[42,{0,100},Background->LightBlue]

Use (RefLink[GaugeFaceStyle, paclet:ref/GaugeFaceStyle]) to set the face style:

AngularGauge[42,{0,100},GaugeFaceStyle->LightBlue]

OpenersExampleSubsection4(Spacer1)GaugeFaceElementFunction  (3)

List built-in settings for (RefLink[GaugeFaceElementFunction, paclet:ref/GaugeFaceElementFunction]):

ChartElementData["AngularGauge","Face"]

For detailed settings, use Palettes ▶ Chart Element Schemes:

Table[AngularGauge[42,{0,100},GaugeFrameStyle->None,GaugeFaceStyle->LightBlue,GaugeFaceElementFunction->f,PlotLabel->f],{f,{"GlassSector","OscillatingSector"}}]

Write a custom (RefLink[GaugeFaceElementFunction, paclet:ref/GaugeFaceElementFunction]):

f[{{θ1_,θ2_},{r1_,r2_}},__]:=First[ParametricPlot[(Max[r,0.65+0.1Abs[Cos[θ^1.3]]Sin[16θ]]){ Cos[θ],Sin[θ]},{θ,θ1,θ2},{r,r1,r2},Mesh->None,PlotPoints->{30,3},PlotStyle->Directive[Opacity[1],LightGray],BoundaryStyle->Gray]]

AngularGauge[42,{0,100},GaugeFrameStyle->None,GaugeFaceElementFunction->f]

OpenersExampleSubsection5(Spacer1)GaugeFaceStyle  (3)

Specify the style for the gauge face:

Table[AngularGauge[42,{0,100},GaugeFaceStyle->c],{c,{LightGray,LightOrange}}]

Use (RefLink[None, paclet:ref/None]) to turn off the face:

AngularGauge[42,{0,100},GaugeFaceStyle->None,Background->LightBlue]

Use a (RefLink[Texture, paclet:ref/Texture]) as a gauge face:

AngularGauge[42,{0,100},TicksStyle->Black,GaugeFaceStyle->Texture[ExampleData[{"ColorTexture","Amboyna"}]]]

AngularGauge[42,{0,100},TicksStyle->Black,GaugeFaceStyle->Texture[ImageCrop[Graphics3D[Sphere[],Boxed->False]]]]

OpenersExampleSubsection6(Spacer1)GaugeFrameElementFunction  (3)

List built-in settings for (RefLink[GaugeFrameElementFunction, paclet:ref/GaugeFrameElementFunction]):

ChartElementData["AngularGauge","Frame"]

For detailed settings, use Palettes ▶ Chart Element Schemes:

Table[AngularGauge[42,{0,100},GaugeFrameElementFunction->f,PlotLabel->f],{f,{"BezelSector","GlassSector"}}]

Construct a custom rendering function:

f[{{tmin_,tmax_},{rmin_,rmax_}},___]:=Module[{inpts,outpts},
inpts=Array[rmin{Cos[2π #/100],Sin[2π #/100]}&,100];
outpts=Array[rmax{Cos[2π #/100],Sin[2π #/100]}&,100];
{EdgeForm[Directive[Thick,Dashed,Gray]],LightGray,FilledCurve[{{Line[inpts]},{Line[outpts]}}]}]

AngularGauge[5.5,{0,10},GaugeFrameElementFunction->f]

OpenersExampleSubsection7(Spacer1)GaugeFrameSize  (3)

Make the frame have an explicit width scaled to the size of the gauge face:

{AngularGauge[42,{0,100},GaugeFrameSize->.4],
AngularGauge[42,{0,100},GaugeFrameSize->.05]}

Use (RefLink[None, paclet:ref/None]) to turn off the frame:

AngularGauge[42,{0,100},GaugeFrameSize->None]

Use named sizes for the frame:

AngularGauge[42,{0,100},GaugeFrameSize->#]&/@{Tiny,Small ,Medium,Large}

OpenersExampleSubsection8(Spacer1)GaugeFrameStyle  (1)

Use directives to change the rendering of the gauge frame:

AngularGauge[42,{0,100},GaugeFrameStyle->#]&/@{Black,LightOrange}

OpenersExampleSubsection9(Spacer1)GaugeLabels  (10)

Show the value as a label:

AngularGauge[55,{0,100},GaugeLabels->Automatic]

Specify a label:

AngularGauge[55,{0,100},GaugeLabels->Style["💡",24]]

Labels can be any expression:

Table[AngularGauge[55,{0,100},GaugeLabels->label],{label,{(Sqrt[(x^x)]),,}}]

If units are present, they can be added as a label to the gauge:

{AngularGauge[42, {0, 100}, TargetUnits->"psi",GaugeLabels->"Unit"],AngularGauge[Quantity[6.5,"Feet"], {0, 10}, GaugeLabels->"Unit"]}

Use (RefLink[Placed, paclet:ref/Placed]) to control label placement:

Table[AngularGauge[9, {0, 10}, GaugeLabels ->Placed["Value",p]],{p,{Left,Top,Right}}]

Position labels at values along the scale:

Table[AngularGauge[9, {0, 10}, GaugeLabels ->Placed["Value",{p,{0.5,0.5}}]],{p,{0,5,10}}]

Position labels using a scaled coordinate system along the scale:

Table[AngularGauge[9, {0, 10}, GaugeLabels ->Placed["Value",{Scaled[p],{0.5,0.5}}]],{p,{0,1/2,1}}]

Use a scaled coordinate system over the entire gauge:

Table[AngularGauge[9, {0, 10}, GaugeLabels ->Placed["Value",p]],{p,{{0.35,0.5},{0.1,0.9},{0.5,0.65}}}]

Place all labels at the middle of the scale and vary the coordinates within the label:

Table[AngularGauge[9, {0, 10}, GaugeLabels ->Placed["Value",{Scaled[0.5],p}]],{p,{{0.5,0},{0.5,1},{0.5,2.75}}}]

Use a list to specify more than one label:

AngularGauge[9, {0, 10}, TargetUnits->"RPM",GaugeLabels -> {"×1000", 
    "Unit","Value"}]

OpenersExampleSubsection10(Spacer1)GaugeMarkers  (8)

Turn the markers on and off:

Table[AngularGauge[42,{0,100},GaugeMarkers->typ],{typ,{Automatic,None}}]

List built-in settings for (RefLink[GaugeMarkers, paclet:ref/GaugeMarkers]):

ChartElementData["AngularGauge","Markers"]

For detailed settings, use Palettes ▶ Chart Element Schemes:

Table[AngularGauge[42,{0,100},GaugeMarkers->typ],{typ,{"BevelNeedle","TwoToneNeedle","BezelBevelNeedle","ShinyHubNeedle"}}]

Use an image or graphic for a marker:

AngularGauge[42,{0,100},GaugeMarkers->]

Use (RefLink[Placed, paclet:ref/Placed]) to change the location of the marker:

Table[AngularGauge[42,{0,100},GaugeMarkers->Placed["PolarMarker",loc]],{loc,{"InsideScale","OutsideScale","Scale","Frame"}}]

Fill a cumulative bar to the value:

AngularGauge[42,{0,100},GaugeMarkers->Placed[Automatic,"ScaleRange"]]

Fill segments that are centered on division values:

{AngularGauge[42,{0,100},GaugeMarkers->Placed[Automatic,"DivisionCenter"]],
AngularGauge[42,{0,100},GaugeMarkers->Placed[Automatic,"DivisionCenter"],TicksStyle->Gray]}

Sequential markers are activated when the value rounds to the division value:

{AngularGauge[94.99,{0,100},ScaleDivisions->{5,2},TicksStyle->Gray,GaugeMarkers->Placed[Automatic,"DivisionCenter"]],AngularGauge[95,{0,100},ScaleDivisions->{5,2},TicksStyle->Gray,GaugeMarkers->Placed[Automatic,"DivisionCenter"]]}

Fill segments that are between division values:

{AngularGauge[42,{0,100},GaugeMarkers->Placed[Automatic,"DivisionInterval"]],
AngularGauge[42,{0,100},GaugeMarkers->Placed[Automatic,"DivisionInterval"],TicksStyle->Gray]}

Sequential markers are activated when the value is greater than or equal to the division value:

{AngularGauge[99.99,{0,100},ScaleDivisions->{5,2},TicksStyle->Gray,GaugeMarkers->Placed[Automatic,"DivisionInterval"]],AngularGauge[100,{0,100},ScaleDivisions->{5,2},TicksStyle->Gray,GaugeMarkers->Placed[Automatic,"DivisionInterval"]]}

Use an image or graphic for a cumulative marker:

AngularGauge[42,{0,100},GaugeMarkers->Placed[,"DivisionInterval"]]

OpenersExampleSubsection11(Spacer1)GaugeStyle  (5)

Style the gauge marker:

Table[AngularGauge[42,{0,100},GaugeStyle->s],{s,{Red,Darker[Blue]}}]

By default, different styles are chosen for multiple markers:

AngularGauge[{10,27,45,62,80,97},{0,100}]

Specify a list of styles:

AngularGauge[{10,27,45,62,80,97},{0,100},GaugeStyle->{Red,Orange,Yellow,Green,Blue,Purple}]

Use any gradient or indexed color schemes from (RefLink[ColorData, paclet:ref/ColorData]):

Table[AngularGauge[{10,27,45,62,80,97},{0,100},GaugeStyle->s],{s,{"BlueGreenYellow",24}}]

Specify the style for cumulative markers up to the gauge value:

Table[AngularGauge[42,{0,100},GaugeMarkers->p,GaugeStyle->Blue],{p,{"DivisionCenter","ScaleRange"}}]

Specify an additional style for markers beyond the gauge value:

Table[AngularGauge[42,{0,100},GaugeMarkers->p,GaugeStyle->{Blue,Lighter[Blue,0.7]}],{p,{"DivisionCenter","ScaleRange"}}]

Use (RefLink[None, paclet:ref/None]) to not use any style:

Table[AngularGauge[42,{0,100},GaugeMarkers->p,GaugeStyle->{Blue,None}],{p,{"DivisionCenter","ScaleRange"}}]

OpenersExampleSubsection12(Spacer1)LabelStyle  (1)

Style the labels:

AngularGauge[42,{0,100},LabelStyle->{18,Blue}]

OpenersExampleSubsection13(Spacer1)PerformanceGoal  (2)

Generate a gauge with tooltips on the gauge markers:

AngularGauge[{2,5.5,9},{0,10},PerformanceGoal->"Quality"]

Emphasize performance by disabling interactive behaviors:

AngularGauge[{2,5.5,9},{0,10},PerformanceGoal->"Speed"]

OpenersExampleSubsection14(Spacer1)PlotTheme  (4)

Create gauges using a variety of base themes:

Multicolumn[Table[Labeled[AngularGauge[7,{0,10},PlotTheme->t,ImageSize->125],t],{t,{"Business","Detailed","Marketing","Minimal","Monochrome","Scientific","Web","Classic"}}]]

Combine the base themes with the "GaugeHalf" feature theme:

Multicolumn[Table[Labeled[AngularGauge[7,{0,10},PlotTheme->{t,"GaugeHalf"},ImageSize->125],t],{t,{"Business","Detailed","Marketing","Minimal","Monochrome","Scientific","Web","Classic"}}]]

Combine the "Marketing" theme with a scale origin:

AngularGauge[37,{0,100},PlotTheme->"Marketing",ScaleOrigin->{6Pi/5,-Pi/5}]

The "Sparkline" theme fits gauges in the surrounding text:

gauge=AngularGauge[0.54,PlotTheme->"Sparkline"]

TextCell[Row[{"Sparkline gauges ",gauge," match the surrounding text size."}],FontFamily->"Arial",FontSize->32]

OpenersExampleSubsection15(Spacer1)ScaleDivisions  (2)

Specify the total number of divisions:

AngularGauge[42,{0,100},ScaleDivisions->10]

Specify the number of major and minor divisions:

AngularGauge[42,{0,100},ScaleDivisions->{5,4}]

OpenersExampleSubsection16(Spacer1)ScaleOrigin  (4)

Use (RefLink[ScaleOrigin, paclet:ref/ScaleOrigin]) to specify a radial position for the scale:

AngularGauge[42,{0,100},ScaleOrigin->.75]

Use a relative location for the center of the scale:

AngularGauge[42,{0,100},ScaleOrigin->Left]

Specify a starting and ending angle for the scale:

AngularGauge[42,{0,100},ScaleOrigin->{π,-π/2}]

Change the order of the endpoints to reverse the scale direction:

AngularGauge[42,{0,100},ScaleOrigin->{-π/2,π}]

Change the endpoints to use the opposite arc of the scale:

AngularGauge[42,{0,100},ScaleOrigin->{π,3π/2},ScalePadding->All]

Change the order of the endpoints to reverse the scale direction:

AngularGauge[42,{0,100},ScaleOrigin->{3π/2,π},ScalePadding->All]

Specify a radial and angular position for the scale:

Table[AngularGauge[42,{0,100},ScaleOrigin->f,ScalePadding->All,PlotLabel->f],{f,{{Left,.75},{{π,-Pi/2},1}}}]

OpenersExampleSubsection17(Spacer1)ScalePadding  (5)

Use automatically determined angular padding:

AngularGauge[42,{0,100},ScaleOrigin->{0,π/2},ScalePadding->Automatic]

Full padding will ensure a "nice" dial face shape:

AngularGauge[42,{0,100},ScaleOrigin->{π/4,3π/4},ScalePadding->Full]

Leave no angular padding around the scale:

AngularGauge[42,{0,100},ScaleOrigin->{0,π},ScalePadding->None]

Specify a constant angular padding:

AngularGauge[42,{0,100},ScaleOrigin->{0,π},ScalePadding->π/12]

Specify different angular padding on each side:

AngularGauge[42,{0,100},ScaleOrigin->{0,π/2},ScalePadding->{π/20,11π/20}]

OpenersExampleSubsection18(Spacer1)ScaleRanges  (7)

Highlight a range of values on the scale:

AngularGauge[42,{0,100},ScaleRanges->{80,100}]

Specify multiple ranges:

AngularGauge[42,{0,100},ScaleRanges->{{50,75},{75,90},{90,100}}]

Style the entire region behind the scale:

AngularGauge[42,{0,100},ScaleRangeStyle->Directive[White,EdgeForm[Black]],GaugeFrameStyle->None,GaugeMarkers->#,ScaleRanges->All]&/@{Automatic,"DivisionCenter"}

Ranges need not be contiguous or distinct:

AngularGauge[42,{0,100},ScaleRanges->{{0,25},{50,75},{75,100},{65,85}}]

Directly associate a style with a range, using range->style:

AngularGauge[42,{0,100},ScaleRanges->{{0,33}->Green,{33,66}->Yellow,{66,100}->Red}]

(RefLink[ScaleRanges, paclet:ref/ScaleRanges]) appears in front of the gauge face:

AngularGauge[42,{0,100},ScaleRanges->All,GaugeFaceStyle->LightGray]

Change the scale range width:

AngularGauge[17,{0,100},ScaleRanges->{{{0,33},.1},{{33,66},.1},{{66,100},.1}},ScaleRangeStyle->24]

Vary the width for each scale range:

AngularGauge[17,{0,100},ScaleRanges->{{{0,33},{0,0.1}},{{33,66},{0,0.2}},{{66,100},{0,0.3}}},ScaleRangeStyle->24]

OpenersExampleSubsection19(Spacer1)ScaleRangeStyle  (8)

By default, the scale ranges are styles based on the marker color:

AngularGauge[42,{0,100},GaugeStyle->#,ScaleRanges->{{50,70},{70,80},{80,90},{90,100}}]&/@{Automatic,Orange}

Apply a style to every range:

AngularGauge[42,{0,100},ScaleRanges->{{50,70},{70,80},{80,90},{90,100}},AxesStyle->None,ScaleRangeStyle->EdgeForm[{Darker@Gray}]]

Use a list of directives to style each range separately:

AngularGauge[42,{0,100},ScaleRanges->{{70,80},{80,90},{90,100}},ScaleRangeStyle->{Yellow,Orange,Red}]

Styles will repeat cyclically if necessary:

AngularGauge[42,{0,100},ScaleRanges->Table[{i,i+10},{i,0,100,10}],ScaleRangeStyle->{Yellow,Orange}]

Use (RefLink[ScaleRangeStyle, paclet:ref/ScaleRangeStyle])->{(RefLink[None, paclet:ref/None]),style} to apply a style to the scale only:

AngularGauge[42,{0,100},ScaleRanges->{80,100},ScaleRangeStyle->{None,Red}]

Apply a style to the backgrounds and foregrounds of all the ranges:

AngularGauge[42,{0,100},ScaleRanges->{{0,20},{80,100}},ScaleRangeStyle->{{LightBlue,Blue},{LightRed,Red}}]

Color the scale ranges with built-in color schemes:

Table[AngularGauge[42,{0,100},ScaleRanges->{{0,20},{20,50},{50,80},{80,100}},ScaleRangeStyle->f],{f,{"BlueGreenYellow",24}}]

Define a one-dimensional color function:

CoolColor[ z_ ] :=RGBColor[1-z,z,1];

AngularGauge[42,{0,100},ScaleRanges->{{0,20},{20,50},{50,80},{80,100}},ScaleRangeStyle->CoolColor]

OpenersExampleSubsection20(Spacer1)TargetUnits  (2)

By default, units are determined automatically:

AngularGauge[LinguisticAssistant,{LinguisticAssistant,LinguisticAssistant},GaugeLabels->"Unit"]

Specify the displayed units:

AngularGauge[LinguisticAssistant,{LinguisticAssistant,LinguisticAssistant},GaugeLabels->"Unit",TargetUnits->"Feet"]

OpenersExampleSection3(Spacer1)Applications  (6)

Use a gauge as a control in (RefLink[Manipulate, paclet:ref/Manipulate]):

Manipulate[Plot[Sin[a x],{x,0,4Pi}],{{a,1},0,4,AngularGauge[##,ImageSize->125]&},ControlPlacement->Left]

Visualize leaf count for successive integrals:

AngularGauge[Dynamic[exp],{0,300}]

Do[(Pause[.4];exp=LeafCount[Integrate[1/(x^n-1),x]];),{n,10}];

Monitor memory used by processes with an indicator of the max memory used:

AngularGauge[{MemoryInUse[],MaxMemoryUsed[]}/10.^9,{0,4},GaugeMarkers->{"DivisionInterval","Frame"},GaugeFrameSize->0.25,GaugeStyle->{{Green,None},Red}]

Monitor progress when integrating a differential equation:

AngularGauge[Dynamic[t],{0,30},PlotLabel->"Currently estimating x=",GaugeStyle->Black]

sol=NDSolve[{y'[x]==y[x]Cos[x+y[x]],y[0]==1},y,{x,0,30},EvaluationMonitor:>(Pause[0.02];(t=x))]

Visualize properties of noble gases:

Partition[Table[Grid[{{Style[element,"Section"],SpanFromLeft},{AngularGauge[ElementData[element,"AtomicWeight"],{0,200},GaugeLabels->"AMU",PlotLabel->"Atomic Weight",ImageSize->130],
ThermometerGauge[ElementData[element,"CriticalTemperature"],{0,500},ImageSize -> {75, 300},GaugeLabels->Placed[ Rotate["Critical Temperature (K)",π/2],{.1,.5}]]},
{AngularGauge[ElementData[element,"CriticalPressure"],{0,10},GaugeLabels->Placed["Mega pascals",{.5,.35}],PlotLabel->"Critical Pressure",ImageSize->130],SpanFromAbove}},Frame->True,Alignment->Bottom],{element,ElementData["NobleGas"][[1;;6]]}],2]//Grid

Visualize the first two derivatives of a polynomial:

Manipulate[With[{f=Function[x,x^3+3x^2-3x-1]},
Column[{Row[{AngularGauge[(D[f[x],{x,1}]/.x->p),{-20,20},GaugeLabels->{Placed["(1^st) Derivative",{.5,.7}],Automatic}],
AngularGauge[(D[f[x],{x,2}]/.x->p),{-20,20},GaugeLabels->{Placed["(2^nd) Derivative",{.5,.7}],Automatic}]}],
Plot[f[t],{t,-4,2},Epilog->{PointSize[Large],Red,Point[{p,f[p]}]},ImageSize->Medium]},Center]],{{p,-3.5},-4,2}]

({{DocumentationFooterIconsRelatedFunction.png, ({{See Also}, {(RefLink[ClockGauge, paclet:ref/ClockGauge])  ▪  (RefLink[VerticalGauge, paclet:ref/VerticalGauge])  ▪  (RefLink[Slider, paclet:ref/Slider])  ▪  (RefLink[VerticalSlider, paclet:ref/VerticalSlider])  ▪  (RefLink[ProgressIndicator, paclet:ref/ProgressIndicator])  ▪  (RefLink[Locator, paclet:ref/Locator])  ▪  (RefLink[Slider2D, paclet:ref/Slider2D])  ▪  (RefLink[ColorSlider, paclet:ref/ColorSlider])  ▪  (RefLink[Control, paclet:ref/Control])  ▪  (RefLink[LocatorPane, paclet:ref/LocatorPane])  ▪  (RefLink[ControlsRendering, paclet:ref/ControlsRendering])}})}})

({{DocumentationFooterIconsRelatedGuide.png, ({{Related Guides}, {▪(RefLinkPlain[Gauges, paclet:guide/Gauges])}, {▪(RefLinkPlain[Dynamic Visualization, paclet:guide/DynamicVisualization])}, {▪(RefLinkPlain[Data Visualization, paclet:guide/DataVisualization])}, {▪(RefLinkPlain[Charting and Information Visualization, paclet:guide/ChartingAndInformationVisualization])}})}})

({{(Spacer1), ({{(Spacer1)Related Links}, {(WebLink[DocumentationFooterIconsRelatedLinks-EIWL.png(Spacer1)An Elementary Introduction to the Wolfram Language, https://www.wolfram.com/language/elementary-introduction/24-more-forms-of-visualization.html])(WebLink[: More Forms of Visualization, https://www.wolfram.com/language/elementary-introduction/24-more-forms-of-visualization.html])}})}})