# VERIFICATION OF THE SIMPLEST TOMIMATSU-SATO SOLUTION OF THE
#                    ERNST EQUATION.
# ---------------------------------------------------------------
# This program was developed in 1986 for the Grad Student Rational
# Calculator program of F. J. Ernst.  Here we rewrite the program
# for Maple.  Reference: J. Math. Phys. 15, 1409 (1974).
# ---------------------------------------------------------------
# Employ the FJE ENTERPRISES revision of difforms package:
#read `fjeforms.m`; with(fjeforms):
with(share): readshare(fjeforms,fjeforms): with(fjeforms);
# Introduce two constants:
defform(p=const,q=const):
# and two auxilliary variables
v := x^2-1:
w := 1-y^2:
# Introduce three-dimensional duality operator.  define it
# by giving its value for basic forms (and using linearity).
# This choice is equivalent to specifying a conformally flat
# three-metric (which serves just as well as a flat one
# for writing out the "Ernst Equation").
DIMENSION := 3:
`star`(1) := &^(d(x),d(y),d(phi)):
`star`(&^(d(x),d(y),d(phi))) := 1:
`star`(d(x)) := v * &^(d(y),d(phi)):
`star`(&^(d(y),d(phi))) := d(x)/v:
`star`(d(y)) := w * &^(d(phi),d(x)):
`star`(&^(d(phi),d(x))) := d(y)/w:
`star`(d(phi)) := &^(d(x),d(y))/(v*w):
# Numerator and denominator of the xi-potential for the
# simplest Tomimatsu-Sato solution.  See Phys. Rev. Lett.
# 29, 1344 (1972).
num := p^2*(x^4-1)+q^2*(y^4-1)-2*I*p*q*x*y*(x^2-y^2);
den := 2*p*x*(x^2-1)-2*I*q*y*(1-y^2);
# In the case of the Kerr metric, one would have
# num := p*x - I*q*y;
# den := 1;
# Let us now evaluate D *dN - N *dD, where * is the duality
# operator for differential forms.
Grad := simpform(expand(den*star(d(num)) - num*star(d(den)))):
# Left and right sides of "Ernst Equation" should be equal.
left := expand((cc(num)*num - (p^2+q^2)*cc(den)*den)*star(d(Grad)));
right := star(expand(2*(cc(num)*d(num)-(p^2+q^2)*cc(den)*d(den)) &^ Grad));
if left=right then
     Solution := true
else
     Solution := false
fi;
quit
