Multiple Classes in a Visual Basic Component

To create the component for this example, see the first few steps of the Multiple Classes in a .NET Component. Then create a Microsoft^® Visual Basic^® application as follows:

Review the sample application for this example in matlabroot\toolbox\dotnetbuilder\Examples\VSVersion\NET\SpectraExample\SpectraVBApp\SpectraApp.vb.

The program listing is shown here.

SpectraApp.vb

Imports System

Imports MathWorks.MATLAB.NET.Utility
Imports MathWorks.MATLAB.NET.Arrays

Imports SpectraComp


Namespace MathWorks.Examples.SpectraApp

    ' <summary>
    ' This application computes and plots the power spectral density of an input signal. 
    ' </summary>
    Class SpectraDemoApp

#Region " MAIN "

        ' <summary>
        ' The main entry point for the application.
        ' </summary>
        Shared Sub Main(ByVal args() As String)
            Try
                Const interval As Double = 0.01   ' The sampling interval
                Const numSamples As Integer = 1001   ' The number of samples

                ' Construct input data as sin(2*PI*15*t) + (sin(2*PI*40*t) plus a
                ' random signal.  Duration= 10; Sampling interval= 0.01
                Dim data As MWNumericArray = New MWNumericArray(MWArrayComplexity.Real, 
                                             MWNumericType.Double, numSamples)

                Dim random As Random = New Random

                ' Initialize data 
                Dim t As Double
                Dim idx As Integer
                For idx = 1 To numSamples
                    t = (idx - 1) * interval
                    data(idx) = New MWNumericArray(Math.Sin(2.0 * Math.PI * 15.0 * t) + 
                                    Math.Sin(2.0 * Math.PI * 40.0 * t) + 
                                    random.NextDouble())
                Next idx

                ' Create a new signal analyzer object
                Dim signalAnalyzer As SignalAnalyzer = New SignalAnalyzer

                ' Compute the fft and power spectral density for the data array
                Dim argsOut() As MWArray = signalAnalyzer.computefft(3, data, 
                                                 MWArray.op_Implicit(interval))

                ' Print the first twenty elements of each result array
                Dim numElements As Integer = 20
                Dim resultArray As MWNumericArray = 
                         New MWNumericArray(MWArrayComplexity.Complex, 
                                    MWNumericType.Double, numElements)

                For idx = 1 To numElements
                    resultArray(idx) = (CType(argsOut(0), MWNumericArray))(idx)
                Next idx

                Console.WriteLine("FFT:{0}{1}{2}", Chr(10), resultArray, Chr(10))

                For idx = 1 To numElements
                    resultArray(idx) = (CType(argsOut(1), MWNumericArray))(idx)
                Next idx

                Console.WriteLine("Frequency:{0}{1}{2}", Chr(10), resultArray, Chr(10))

                For idx = 1 To numElements
                    resultArray(idx) = (CType(argsOut(2), MWNumericArray))(idx)
                Next idx

                Console.WriteLine("Power Spectral Density:{0}{1}{2}", 
                  Chr(10), resultArray, Chr(10))

                ' Create a new plotter object
                Dim plotter As Plotter = New Plotter

                ' Plot the fft and power spectral density for the data array
                plotter.plotfft(argsOut(0), argsOut(1), argsOut(2))

                Console.ReadLine()  ' Wait for user to exit application

            Catch exception As Exception
                Console.WriteLine("Error: {0}", exception)

            End Try
        End Sub
#End Region

    End Class
End Namespace

The program does the following:

Constructs an input array with values representing a random signal with two sinusoids at 15 and 40 Hz embedded inside of it
Uses MWNumericArray to handle data conversion
Note
For information about these data conversion classes, see the MATLAB MWArray Class Library Reference, available in the matlabroot\help\dotnetbuilder\MWArrayAPI folder, where matlabroot represents your MATLAB^® installation folder
Instantiates a SignalAnalyzer object
Calls the computefft method, which computes the FFT, frequency, and the spectral density
Instantiates a Plotter object
Calls the plotfft method, which plots the data
Uses a try/catch block to handle exceptions

The following statements

Dim data As MWNumericArray = New MWNumericArray_
    (MWArrayComplexity.Real, MWNumericType.Double, numSamples)
...
Dim resultArray As MWNumericArray = New MWNumericArray_
    (MWArrayComplexity.Complex, 
     MWNumericType.Double, numElements)

show how to use the MWArray class library to construct the necessary data types.

The following statement

Dim signalAnalyzer As SignalAnalyzer = New SignalAnalyzer

creates an instance of the class SignalAnalyzer, and the following statement

Dim argsOut() As MWArray = 
    signalAnalyzer.computefft(3, data, 
        MWArray.op_Implicit(interval))

calls the method computefft and request three outputs.

Build the SpectraApp application using Visual Studio^® .NET.
1. The SpectraVBApp folder contains a Visual Studio .NET project file for this example. Open the project in Visual Studio .NET by double-clicking SpectraVBApp.vbproj in Windows^® Explorer. You can also open it from the desktop by right-clicking SpectraVBApp.vbproj > Open Outside MATLAB.
2. Add a reference to the MWArray component, which is matlabroot\toolbox\dotnetbuilder\bin\architecture\framework_version\mwarray.dll.
3. If necessary, add (or update the location of) a reference to the SpectraComp component which you built in a previous step. (The component, SpectraComp.dll, is in the \SpectraExample\SpectraComp\x86\V2.0\Debug\distrib subfolder of your work area.)
Build and run the application in Visual Studio .NET.

Documentation

Multiple Classes in a Visual Basic Component

Note

MATLAB Compiler SDK Documentation

Support